CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ## Copyright (C) 2020 Soeren Apel <soeren@apelpie.net>
   7 ##
   8 ## This program is free software: you can redistribute it and/or modify
   9 ## it under the terms of the GNU General Public License as published by
  10 ## the Free Software Foundation, either version 2 of the License, or
  11 ## (at your option) any later version.
  12 ##
  13 ## This program is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License
  19 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 ##
  21
  22 cmake_minimum_required(VERSION 2.8.12)
  23
  24 project(pulseview C CXX)
  25
  26 include(GNUInstallDirs)
  27
  28 # Let AUTOMOC and AUTOUIC process GENERATED files.
  29 if(POLICY CMP0071)
  30         cmake_policy(SET CMP0071 NEW)
  31 endif()
  32
  33 # Only interpret if() arguments as variables or keywords when unquoted.
  34 if(POLICY CMP0054)
  35         cmake_policy(SET CMP0054 NEW)
  36 endif()
  37
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  39
  40 #===============================================================================
  41 #= User Options
  42 #-------------------------------------------------------------------------------
  43
  44 option(DISABLE_WERROR "Build without -Werror" TRUE)
  45 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  46 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
  47 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  48 option(ENABLE_FLOW "Build with libsigrokflow" FALSE)
  49 option(ENABLE_TESTS "Enable unit tests" FALSE)
  50 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  51
  52 if(WIN32)
  53         # On Windows/MinGW we need to statically link to libraries.
  54         # This option is user configurable, but enable it by default on win32.
  55         set(STATIC_PKGDEPS_LIBS TRUE)
  56
  57         # Windows does not support UNIX signals.
  58         set(ENABLE_SIGNALS FALSE)
  59 endif()
  60
  61 if(NOT CMAKE_BUILD_TYPE)
  62         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  63         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  64         FORCE)
  65 endif()
  66
  67 #===============================================================================
  68 #= Documentation
  69 #-------------------------------------------------------------------------------
  70
  71 add_subdirectory(manual)
  72
  73 #===============================================================================
  74 #= Dependencies
  75 #-------------------------------------------------------------------------------
  76
  77 include(CheckCSourceCompiles)
  78 include(CheckCXXCompilerFlag)
  79 include(CheckCXXSourceCompiles)
  80 include(CMakePushCheckState)
  81 include(memaccess)
  82
  83 find_package(PkgConfig)
  84
  85 check_cxx_compiler_flag("-std=c++17" HAVE_STD_CXX_17)
  86 check_cxx_compiler_flag("-std=c++14" HAVE_STD_CXX_14)
  87 check_cxx_compiler_flag("-std=c++11" HAVE_STD_CXX_11)
  88 if(HAVE_STD_CXX_17)
  89         message(STATUS "Using C++17 for the application build")
  90         set(CMAKE_CXX_STANDARD 17)
  91         set(REQUIRED_STD_CXX_FLAGS "-std=c++17")
  92 elseif(HAVE_STD_CXX_14)
  93         message(STATUS "Using C++14 for the application build")
  94         set(CMAKE_CXX_STANDARD 14)
  95         set(REQUIRED_STD_CXX_FLAGS "-std=c++14")
  96 elseif(HAVE_STD_CXX_11)
  97         message(STATUS "Using C++11 for the application build")
  98         set(CMAKE_CXX_STANDARD 11)
  99         set(REQUIRED_STD_CXX_FLAGS "-std=c++11")
 100 else()
 101         message(FATAL_ERROR "Need modern C++, at least language standard 11")
 102 endif()
 103
 104 list(APPEND PKGDEPS glib-2.0>=2.28.0)
 105
 106 # Try to find the prefered glibmm-2.4. If not found then add glibmm-2.68
 107 # to the dependency list.
 108 pkg_check_modules(GLIBMM_2_4 glibmm-2.4>2.28.0)
 109 if(GLIBMM_2_4_FOUND)
 110         list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
 111 else()
 112         list(APPEND PKGDEPS glibmm-2.68>=2.68.0)
 113 endif()
 114
 115 if(ENABLE_FLOW)
 116         list(APPEND PKGDEPS gstreamermm-1.0>=1.8.0)
 117         list(APPEND PKGDEPS libsigrokflow>=0.1.0)
 118 endif()
 119
 120 set(LIBSR_CXX_BINDING "libsigrokcxx>=0.5.2")
 121 list(APPEND PKGDEPS "${LIBSR_CXX_BINDING}")
 122
 123 if(ENABLE_DECODE)
 124         list(APPEND PKGDEPS libsigrokdecode>=0.5.2)
 125 endif()
 126
 127 if(ANDROID)
 128         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
 129 endif()
 130
 131 pkg_check_modules(LIBSRCXX ${LIBSR_CXX_BINDING})
 132 if(NOT LIBSRCXX_FOUND OR NOT LIBSRCXX_VERSION)
 133         message(FATAL_ERROR "libsigrok C++ bindings missing, check libsigrok's 'configure' output (missing dependencies?)")
 134 endif()
 135 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
 136
 137 set(CMAKE_AUTOMOC TRUE)
 138
 139 find_package(Qt5 5.3 COMPONENTS Core Gui LinguistTools Widgets Svg REQUIRED)
 140
 141 message(STATUS "Qt version: ${Qt5_VERSION}")
 142
 143 if(WIN32)
 144         # MXE workaround: Use pkg-config to find Qt5 libs.
 145         # https://github.com/mxe/mxe/issues/1642
 146         # Not required (and doesn't work) on MSYS2.
 147         if(NOT DEFINED ENV{MSYSTEM})
 148                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets>=5.3 Qt5Gui>=5.3 Qt5Svg>=5.3)
 149         endif()
 150 endif()
 151
 152 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
 153
 154 set(BOOSTCOMPS filesystem serialization system)
 155 if(ENABLE_TESTS)
 156         list(APPEND BOOSTCOMPS unit_test_framework)
 157 endif()
 158
 159 if(ENABLE_STACKTRACE)
 160         include(FindBacktrace)
 161         if (Backtrace_FOUND)
 162                 set(_Boost_STACKTRACE_BACKTRACE_HEADERS "boost/stacktrace.hpp")
 163                 list(APPEND BOOSTCOMPS stacktrace_backtrace)
 164         else()
 165                 set(_Boost_STACKTRACE_BASIC_HEADERS     "boost/stacktrace.hpp")
 166                 list(APPEND BOOSTCOMPS stacktrace_basic)
 167         endif()
 168         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 169 else()
 170         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 171 endif()
 172
 173 # Find the platform's thread library (needed for C++11 threads).
 174 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 175 find_package(Threads REQUIRED)
 176
 177 # Check for explicit link against libatomic
 178 #
 179 # Depending on the toolchain, linking a program using atomic functions may need
 180 # "-latomic" explicitly passed to the linker
 181 #
 182 # This check first tests if atomics are available in the C-library, if not and
 183 # libatomic exists, then it runs the same test with -latomic added to the
 184 # linker flags.
 185
 186 # Helper for checking for atomics
 187 function(check_working_cxx_atomics varname additional_lib)
 188         cmake_push_check_state()
 189         set(CMAKE_REQUIRED_FLAGS "${REQUIRED_STD_CXX_FLAGS}")
 190         set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
 191         set(CMAKE_REQUIRED_QUIET 1)
 192         CHECK_CXX_SOURCE_COMPILES("
 193 #include <atomic>
 194 std::atomic<int> x;
 195 int main() {
 196         return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
 197 }
 198 " ${varname})
 199         cmake_pop_check_state()
 200 endfunction(check_working_cxx_atomics)
 201
 202 # First check if atomics work without the library.
 203 # If not, check if the library exists, and atomics work with it.
 204 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
 205 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
 206         message(STATUS "Atomics provided by the C-library - yes")
 207 else()
 208         message(STATUS "Atomics provided by the C-library - no")
 209         find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
 210         if(LIBATOMIC_LIBRARY)
 211                 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
 212                 if (HAVE_CXX_ATOMICS_WITH_LIB)
 213                         message(STATUS "Atomics provided by libatomic - yes")
 214                 else()
 215                         message(STATUS "Atomics provided by libatomic - no")
 216                         message(FATAL_ERROR "Compiler must support std::atomic!")
 217                 endif()
 218         else()
 219                 message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
 220         endif()
 221 endif()
 222
 223 # Check availability of features which depend on library versions.
 224 # TODO Ideally use check_symbol_exists() instead, reduce boilerplate.
 225 if(ENABLE_DECODE)
 226         cmake_push_check_state()
 227         set(CMAKE_REQUIRED_INCLUDES "${PKGDEPS_INCLUDE_DIRS}")
 228         set(CMAKE_REQUIRED_LIBRARIES "sigrokdecode")
 229         foreach (LPATH ${PKGDEPS_LIBRARY_DIRS})
 230                 list(APPEND CMAKE_REQUIRED_LINK_OPTIONS "-L${LPATH}")
 231         endforeach ()
 232         check_c_source_compiles("
 233         #include <libsigrokdecode/libsigrokdecode.h>
 234         int main(int argc, char *argv[])
 235         {
 236                 (void)argc;
 237                 (void)argv;
 238                 return srd_session_send_eof(NULL);
 239         }
 240         " HAVE_SRD_SESSION_SEND_EOF)
 241         cmake_pop_check_state()
 242 endif()
 243
 244 #===============================================================================
 245 #= System Introspection
 246 #-------------------------------------------------------------------------------
 247
 248 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 249
 250 #===============================================================================
 251 #= Config Header
 252 #-------------------------------------------------------------------------------
 253
 254 set(PV_TITLE PulseView)
 255 set(PV_VERSION_STRING "0.5.0")
 256
 257 if(GLIBMM_2_4_FOUND)
 258         set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
 259 else()
 260         set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.68_VERSION})
 261 endif()
 262
 263 include(GetGitRevisionDescription)
 264
 265 # Append the revision hash unless we are exactly on a tagged release.
 266 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
 267 if(NOT PV_TAG_VERSION_STRING)
 268         get_git_head_revision(PV_REVSPEC PV_HASH)
 269         if(PV_HASH)
 270                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
 271                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
 272         endif()
 273
 274         # Non-tagged releases use the unstable manual
 275         set(PV_MANUAL_VERSION "unstable")
 276 else()
 277         # Tagged releases use a fixed manual version
 278         set(PV_MANUAL_VERSION ${PV_VERSION_STRING})
 279 endif()
 280
 281 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 282         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 283         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 284         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 285         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 286 endif()
 287
 288 message(STATUS "${PV_TITLE} version: ${PV_VERSION_STRING}")
 289
 290 configure_file (
 291         ${PROJECT_SOURCE_DIR}/config.h.in
 292         ${PROJECT_BINARY_DIR}/config.h
 293 )
 294
 295 #===============================================================================
 296 #= Sources
 297 #-------------------------------------------------------------------------------
 298
 299 set(pulseview_SOURCES
 300         main.cpp
 301         pv/application.cpp
 302         pv/devicemanager.cpp
 303         pv/globalsettings.cpp
 304         pv/logging.cpp
 305         pv/mainwindow.cpp
 306         pv/metadata_obj.cpp
 307         pv/session.cpp
 308         pv/storesession.cpp
 309         pv/util.cpp
 310         pv/binding/binding.cpp
 311         pv/binding/inputoutput.cpp
 312         pv/binding/device.cpp
 313         pv/data/analog.cpp
 314         pv/data/analogsegment.cpp
 315         pv/data/logic.cpp
 316         pv/data/logicsegment.cpp
 317         pv/data/mathsignal.cpp
 318         pv/data/signalbase.cpp
 319         pv/data/signaldata.cpp
 320         pv/data/segment.cpp
 321         pv/devices/device.cpp
 322         pv/devices/file.cpp
 323         pv/devices/hardwaredevice.cpp
 324         pv/devices/inputfile.cpp
 325         pv/devices/sessionfile.cpp
 326         pv/dialogs/connect.cpp
 327         pv/dialogs/inputoutputoptions.cpp
 328         pv/dialogs/settings.cpp
 329         pv/dialogs/storeprogress.cpp
 330         pv/popups/deviceoptions.cpp
 331         pv/popups/channels.cpp
 332         pv/prop/bool.cpp
 333         pv/prop/double.cpp
 334         pv/prop/enum.cpp
 335         pv/prop/int.cpp
 336         pv/prop/property.cpp
 337         pv/prop/string.cpp
 338         pv/subwindows/subwindowbase.cpp
 339         pv/toolbars/mainbar.cpp
 340         pv/views/trace/analogsignal.cpp
 341         pv/views/trace/cursor.cpp
 342         pv/views/trace/cursorpair.cpp
 343         pv/views/trace/flag.cpp
 344         pv/views/trace/header.cpp
 345         pv/views/trace/mathsignal.cpp
 346         pv/views/trace/marginwidget.cpp
 347         pv/views/trace/logicsignal.cpp
 348         pv/views/trace/ruler.cpp
 349         pv/views/trace/signal.cpp
 350         pv/views/trace/timeitem.cpp
 351         pv/views/trace/timemarker.cpp
 352         pv/views/trace/trace.cpp
 353         pv/views/trace/tracegroup.cpp
 354         pv/views/trace/tracepalette.cpp
 355         pv/views/trace/tracetreeitem.cpp
 356         pv/views/trace/tracetreeitemowner.cpp
 357         pv/views/trace/triggermarker.cpp
 358         pv/views/trace/view.cpp
 359         pv/views/trace/viewitem.cpp
 360         pv/views/trace/viewitemowner.cpp
 361         pv/views/trace/viewitempaintparams.cpp
 362         pv/views/trace/viewport.cpp
 363         pv/views/trace/viewwidget.cpp
 364         pv/views/viewbase.cpp
 365         pv/views/trace/standardbar.cpp
 366         pv/widgets/colorbutton.cpp
 367         pv/widgets/colorpopup.cpp
 368         pv/widgets/devicetoolbutton.cpp
 369         pv/widgets/exportmenu.cpp
 370         pv/widgets/flowlayout.cpp
 371         pv/widgets/importmenu.cpp
 372         pv/widgets/popup.cpp
 373         pv/widgets/popuptoolbutton.cpp
 374         pv/widgets/sweeptimingwidget.cpp
 375         pv/widgets/timestampspinbox.cpp
 376         pv/widgets/wellarray.cpp
 377 )
 378
 379 # This list includes only QObject derived class headers.
 380 set(pulseview_HEADERS
 381         pv/exprtk.hpp
 382         pv/logging.hpp
 383         pv/globalsettings.hpp
 384         pv/mainwindow.hpp
 385         pv/metadata_obj.hpp
 386         pv/session.hpp
 387         pv/storesession.hpp
 388         pv/binding/device.hpp
 389         pv/data/analog.hpp
 390         pv/data/analogsegment.hpp
 391         pv/data/logic.hpp
 392         pv/data/logicsegment.hpp
 393         pv/data/mathsignal.hpp
 394         pv/data/signalbase.hpp
 395         pv/dialogs/connect.hpp
 396         pv/dialogs/inputoutputoptions.hpp
 397         pv/dialogs/settings.hpp
 398         pv/dialogs/storeprogress.hpp
 399         pv/popups/channels.hpp
 400         pv/popups/deviceoptions.hpp
 401         pv/prop/bool.hpp
 402         pv/prop/double.hpp
 403         pv/prop/enum.hpp
 404         pv/prop/int.hpp
 405         pv/prop/property.hpp
 406         pv/prop/string.hpp
 407         pv/subwindows/subwindowbase.hpp
 408         pv/toolbars/mainbar.hpp
 409         pv/views/trace/analogsignal.hpp
 410         pv/views/trace/cursor.hpp
 411         pv/views/trace/flag.hpp
 412         pv/views/trace/header.hpp
 413         pv/views/trace/logicsignal.hpp
 414         pv/views/trace/mathsignal.hpp
 415         pv/views/trace/marginwidget.hpp
 416         pv/views/trace/ruler.hpp
 417         pv/views/trace/signal.hpp
 418         pv/views/trace/timeitem.hpp
 419         pv/views/trace/timemarker.hpp
 420         pv/views/trace/trace.hpp
 421         pv/views/trace/tracegroup.hpp
 422         pv/views/trace/tracetreeitem.hpp
 423         pv/views/trace/triggermarker.hpp
 424         pv/views/trace/view.hpp
 425         pv/views/trace/viewitem.hpp
 426         pv/views/trace/viewport.hpp
 427         pv/views/trace/viewwidget.hpp
 428         pv/views/viewbase.hpp
 429         pv/views/trace/standardbar.hpp
 430         pv/widgets/colorbutton.hpp
 431         pv/widgets/colorpopup.hpp
 432         pv/widgets/devicetoolbutton.hpp
 433         pv/widgets/exportmenu.hpp
 434         pv/widgets/flowlayout.hpp
 435         pv/widgets/importmenu.hpp
 436         pv/widgets/popup.hpp
 437         pv/widgets/popuptoolbutton.hpp
 438         pv/widgets/sweeptimingwidget.hpp
 439         pv/widgets/timestampspinbox.hpp
 440         pv/widgets/wellarray.hpp
 441 )
 442
 443 set(pulseview_RESOURCES
 444         pulseview.qrc
 445 )
 446
 447 if(ENABLE_SIGNALS)
 448         list(APPEND pulseview_SOURCES signalhandler.cpp)
 449         list(APPEND pulseview_HEADERS signalhandler.hpp)
 450 endif()
 451
 452 if(ENABLE_DECODE)
 453         list(APPEND pulseview_SOURCES
 454                 pv/binding/decoder.cpp
 455                 pv/data/decodesignal.cpp
 456                 pv/data/decode/annotation.cpp
 457                 pv/data/decode/decoder.cpp
 458                 pv/data/decode/row.cpp
 459                 pv/data/decode/rowdata.cpp
 460                 pv/subwindows/decoder_selector/item.cpp
 461                 pv/subwindows/decoder_selector/model.cpp
 462                 pv/subwindows/decoder_selector/subwindow.cpp
 463                 pv/views/decoder_binary/view.cpp
 464                 pv/views/decoder_binary/QHexView.cpp
 465                 pv/views/tabular_decoder/model.cpp
 466                 pv/views/tabular_decoder/view.cpp
 467                 pv/views/trace/decodetrace.cpp
 468                 pv/widgets/decodergroupbox.cpp
 469                 pv/widgets/decodermenu.cpp
 470         )
 471
 472         list(APPEND pulseview_HEADERS
 473                 pv/data/decodesignal.hpp
 474                 pv/subwindows/decoder_selector/subwindow.hpp
 475                 pv/views/decoder_binary/view.hpp
 476                 pv/views/decoder_binary/QHexView.hpp
 477                 pv/views/tabular_decoder/view.hpp
 478                 pv/views/trace/decodetrace.hpp
 479                 pv/widgets/decodergroupbox.hpp
 480                 pv/widgets/decodermenu.hpp
 481         )
 482 endif()
 483
 484 if(WIN32)
 485         # Use the sigrok icon for the pulseview.exe executable.
 486         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 487         enable_language(RC)
 488         list(APPEND pulseview_SOURCES pulseviewico.rc)
 489 endif()
 490
 491 if(ANDROID)
 492         list(APPEND pulseview_SOURCES
 493                 android/assetreader.cpp
 494                 android/loghandler.cpp
 495         )
 496 endif()
 497
 498 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 499
 500 #===============================================================================
 501 #= Translations
 502 #-------------------------------------------------------------------------------
 503
 504 file(GLOB TS_FILES ${CMAKE_SOURCE_DIR}/l10n/*.ts)
 505 set_property(SOURCE ${TS_FILES} PROPERTY OUTPUT_LOCATION ${CMAKE_BINARY_DIR}/l10n)
 506 if (NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
 507         configure_file("translations.qrc" "translations.qrc" COPYONLY)
 508 endif ()
 509
 510 qt5_add_translation(QM_FILES ${TS_FILES})
 511 qt5_create_translation(QM_FILES ${pulseview_SOURCES} ${TS_FILES})
 512
 513 qt5_add_resources(pulseview_RESOURCES_RCC ${CMAKE_BINARY_DIR}/translations.qrc)
 514
 515 #===============================================================================
 516 #= Global Definitions
 517 #-------------------------------------------------------------------------------
 518
 519 add_definitions(-DQT_NO_KEYWORDS)
 520 add_definitions(-D__STDC_LIMIT_MACROS)
 521 add_definitions(-Wall -Wextra)
 522 add_definitions(${REQUIRED_STD_CXX_FLAGS})
 523
 524 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
 525 if(WIN32)
 526         add_definitions(-Wa,-mbig-obj -O3)
 527 endif()
 528
 529 if(ENABLE_FLOW)
 530         add_definitions(-DENABLE_FLOW)
 531 endif()
 532
 533 if(ENABLE_DECODE)
 534         add_definitions(-DENABLE_DECODE)
 535 endif()
 536
 537 if(NOT DISABLE_WERROR)
 538         add_definitions(-Werror)
 539 endif()
 540
 541 if(ENABLE_SIGNALS)
 542         add_definitions(-DENABLE_SIGNALS)
 543 endif()
 544
 545 if(ENABLE_STACKTRACE)
 546         add_definitions(-DENABLE_STACKTRACE -no-pie -fno-pie)
 547         if (Backtrace_FOUND)
 548                 add_definitions(-DBOOST_STACKTRACE_USE_BACKTRACE)
 549         endif()
 550 endif()
 551
 552 #===============================================================================
 553 #= Global Include Directories
 554 #-------------------------------------------------------------------------------
 555
 556 include_directories(
 557         ${CMAKE_CURRENT_BINARY_DIR}
 558         ${CMAKE_CURRENT_SOURCE_DIR}
 559         ${Boost_INCLUDE_DIRS}
 560 )
 561
 562 if(STATIC_PKGDEPS_LIBS)
 563         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 564 else()
 565         include_directories(${PKGDEPS_INCLUDE_DIRS})
 566 endif()
 567
 568 #===============================================================================
 569 #= Linker Configuration
 570 #-------------------------------------------------------------------------------
 571
 572 link_directories(${Boost_LIBRARY_DIRS})
 573
 574 set(PULSEVIEW_LINK_LIBS
 575         ${Boost_LIBRARIES}
 576         ${QT_LIBRARIES}
 577         ${CMAKE_THREAD_LIBS_INIT}
 578         ${LIBATOMIC_LIBRARY}
 579 )
 580
 581 if(STATIC_PKGDEPS_LIBS)
 582         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 583         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
 584 else()
 585         link_directories(${PKGDEPS_LIBRARY_DIRS})
 586         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 587 endif()
 588
 589 if(WIN32)
 590         # On Windows we need to statically link the libqsvg imageformat
 591         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 592         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
 593         # Qt < 5.8.0), and all Qt libs and their dependencies.
 594         add_definitions(-DQT_STATICPLUGIN)
 595         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
 596         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
 597         if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
 598                 list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
 599         endif()
 600         list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
 601 endif()
 602
 603 if(ENABLE_STACKTRACE)
 604         list(APPEND PULSEVIEW_LINK_LIBS ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
 605         link_libraries("-no-pie -fno-pie")
 606 endif()
 607
 608 if(ANDROID)
 609         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 610 endif()
 611
 612 set(INPUT_FILES_LIST ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC} ${QM_FILES})
 613 if(ANDROID)
 614         add_library(${PROJECT_NAME} SHARED ${INPUT_FILES_LIST})
 615 else()
 616         add_executable(${PROJECT_NAME} ${INPUT_FILES_LIST})
 617 endif()
 618
 619 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 620
 621 if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
 622         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 623         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 624 endif()
 625
 626 #===============================================================================
 627 #= Installation
 628 #-------------------------------------------------------------------------------
 629
 630 # Install the executable.
 631 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 632
 633 # Install the manpage.
 634 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 635
 636 # Install the desktop file.
 637 install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 638
 639 # Install the AppData/AppStream file.
 640 install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
 641
 642 # Install the PulseView icons.
 643 install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
 644 install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
 645
 646 # Generate Windows installer script.
 647 configure_file(contrib/pulseview_cross.nsi.in ${CMAKE_CURRENT_BINARY_DIR}/contrib/pulseview_cross.nsi @ONLY)
 648
 649 #===============================================================================
 650 #= Packaging (handled by CPack)
 651 #-------------------------------------------------------------------------------
 652
 653 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 654 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 655 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 656 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 657 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 658 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 659 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 660 set(CPACK_SOURCE_GENERATOR "TGZ")
 661
 662 include(CPack)
 663
 664 #===============================================================================
 665 #= Tests
 666 #-------------------------------------------------------------------------------
 667
 668 if(ENABLE_TESTS)
 669         add_subdirectory(test)
 670         enable_testing()
 671         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 672 endif()