pv/exprtk.hpp: Fix Windows build issues.
[pulseview.git] / CMakeLists.txt
1 ##
2 ## This file is part of the PulseView project.
3 ##
4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
6 ## Copyright (C) 2020 Soeren Apel <soeren@apelpie.net>
7 ##
8 ## This program is free software: you can redistribute it and/or modify
9 ## it under the terms of the GNU General Public License as published by
10 ## the Free Software Foundation, either version 2 of the License, or
11 ## (at your option) any later version.
12 ##
13 ## This program is distributed in the hope that it will be useful,
14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
16 ## GNU General Public License for more details.
17 ##
18 ## You should have received a copy of the GNU General Public License
19 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
20 ##
21
22 cmake_minimum_required(VERSION 2.8.12)
23
24 project(pulseview C CXX)
25
26 include(GNUInstallDirs)
27
28 # Let AUTOMOC and AUTOUIC process GENERATED files.
29 if(POLICY CMP0071)
30         cmake_policy(SET CMP0071 NEW)
31 endif()
32
33 # Only interpret if() arguments as variables or keywords when unquoted.
34 if(POLICY CMP0054)
35         cmake_policy(SET CMP0054 NEW)
36 endif()
37
38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
39
40 #===============================================================================
41 #= User Options
42 #-------------------------------------------------------------------------------
43
44 option(DISABLE_WERROR "Build without -Werror" TRUE)
45 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
46 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
47 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
48 option(ENABLE_FLOW "Build with libsigrokflow" FALSE)
49 option(ENABLE_TESTS "Enable unit tests" FALSE)
50 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
51
52 if(WIN32)
53         # On Windows/MinGW we need to statically link to libraries.
54         # This option is user configurable, but enable it by default on win32.
55         set(STATIC_PKGDEPS_LIBS TRUE)
56
57         # Windows does not support UNIX signals.
58         set(ENABLE_SIGNALS FALSE)
59 endif()
60
61 if(NOT CMAKE_BUILD_TYPE)
62         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
63         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
64         FORCE)
65 endif()
66
67 #===============================================================================
68 #= Documentation
69 #-------------------------------------------------------------------------------
70
71 add_subdirectory(manual)
72
73 #===============================================================================
74 #= Dependencies
75 #-------------------------------------------------------------------------------
76
77 list(APPEND PKGDEPS glib-2.0>=2.28.0)
78 list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
79
80 if(ENABLE_FLOW)
81         list(APPEND PKGDEPS gstreamermm-1.0>=1.8.0)
82         list(APPEND PKGDEPS libsigrokflow>=0.1.0)
83 endif()
84
85 set(LIBSR_CXX_BINDING "libsigrokcxx>=0.5.2")
86 list(APPEND PKGDEPS "${LIBSR_CXX_BINDING}")
87
88 if(ENABLE_DECODE)
89         list(APPEND PKGDEPS libsigrokdecode>=0.5.2)
90 endif()
91
92 if(ANDROID)
93         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
94 endif()
95
96 find_package(PkgConfig)
97 pkg_check_modules(LIBSRCXX ${LIBSR_CXX_BINDING})
98 if(NOT LIBSRCXX_FOUND OR NOT LIBSRCXX_VERSION)
99         message(FATAL_ERROR "libsigrok C++ bindings missing, check libsigrok's 'configure' output (missing dependencies?)")
100 endif()
101 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
102
103 set(CMAKE_AUTOMOC TRUE)
104
105 find_package(Qt5 5.3 COMPONENTS Core Gui LinguistTools Widgets Svg REQUIRED)
106
107 message(STATUS "Qt version: ${Qt5_VERSION}")
108
109 if(WIN32)
110         # MXE workaround: Use pkg-config to find Qt5 libs.
111         # https://github.com/mxe/mxe/issues/1642
112         # Not required (and doesn't work) on MSYS2.
113         if(NOT DEFINED ENV{MSYSTEM})
114                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets>=5.3 Qt5Gui>=5.3 Qt5Svg>=5.3)
115         endif()
116 endif()
117
118 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
119
120 set(BOOSTCOMPS filesystem serialization system)
121 if(ENABLE_TESTS)
122         list(APPEND BOOSTCOMPS unit_test_framework)
123 endif()
124
125 if(ENABLE_STACKTRACE)
126         include(FindBacktrace)
127         if (Backtrace_FOUND)
128                 set(_Boost_STACKTRACE_BACKTRACE_HEADERS "boost/stacktrace.hpp")
129                 list(APPEND BOOSTCOMPS stacktrace_backtrace)
130         else()
131                 set(_Boost_STACKTRACE_BASIC_HEADERS     "boost/stacktrace.hpp")
132                 list(APPEND BOOSTCOMPS stacktrace_basic)
133         endif()
134         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
135 else()
136         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
137 endif()
138
139 # Find the platform's thread library (needed for C++11 threads).
140 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
141 find_package(Threads REQUIRED)
142
143 # Check for explicit link against libatomic
144 #
145 # Depending on the toolchain, linking a program using atomic functions may need
146 # "-latomic" explicitly passed to the linker
147 #
148 # This check first tests if atomics are available in the C-library, if not and
149 # libatomic exists, then it runs the same test with -latomic added to the
150 # linker flags.
151
152 # Helper for checking for atomics
153 function(check_working_cxx_atomics varname additional_lib)
154   include(CheckCXXSourceCompiles)
155   include(CMakePushCheckState)
156   cmake_push_check_state()
157   set(CMAKE_REQUIRED_FLAGS "-std=c++11")
158   set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
159   set(CMAKE_REQUIRED_QUIET 1)
160   CHECK_CXX_SOURCE_COMPILES("
161 #include <atomic>
162 std::atomic<int> x;
163 int main() {
164   return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
165 }
166 " ${varname})
167   cmake_pop_check_state()
168 endfunction(check_working_cxx_atomics)
169
170 # First check if atomics work without the library.
171 # If not, check if the library exists, and atomics work with it.
172 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
173 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
174   message(STATUS "Atomics provided by the C-library - yes")
175 else()
176   message(STATUS "Atomics provided by the C-library - no")
177   find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
178   if(LIBATOMIC_LIBRARY)
179     check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
180     if (HAVE_CXX_ATOMICS_WITH_LIB)
181       message(STATUS "Atomics provided by libatomic - yes")
182     else()
183       message(STATUS "Atomics provided by libatomic - no")
184       message(FATAL_ERROR "Compiler must support std::atomic!")
185     endif()
186   else()
187     message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
188   endif()
189 endif()
190
191 #===============================================================================
192 #= System Introspection
193 #-------------------------------------------------------------------------------
194
195 include(memaccess)
196 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
197
198 #===============================================================================
199 #= Config Header
200 #-------------------------------------------------------------------------------
201
202 set(PV_TITLE PulseView)
203 set(PV_VERSION_STRING "0.5.0")
204
205 set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
206
207 include(GetGitRevisionDescription)
208
209 # Append the revision hash unless we are exactly on a tagged release.
210 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
211 if(NOT PV_TAG_VERSION_STRING)
212         get_git_head_revision(PV_REVSPEC PV_HASH)
213         if(PV_HASH)
214                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
215                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
216         endif()
217
218         # Non-tagged releases use the unstable manual
219         set(PV_MANUAL_VERSION "unstable")
220 else()
221         # Tagged releases use a fixed manual version
222         set(PV_MANUAL_VERSION ${PV_VERSION_STRING})
223 endif()
224
225 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
226         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
227         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
228         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
229         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
230 endif()
231
232 message(STATUS "${PV_TITLE} version: ${PV_VERSION_STRING}")
233
234 configure_file (
235         ${PROJECT_SOURCE_DIR}/config.h.in
236         ${PROJECT_BINARY_DIR}/config.h
237 )
238
239 #===============================================================================
240 #= Sources
241 #-------------------------------------------------------------------------------
242
243 set(pulseview_SOURCES
244         main.cpp
245         pv/application.cpp
246         pv/devicemanager.cpp
247         pv/globalsettings.cpp
248         pv/logging.cpp
249         pv/mainwindow.cpp
250         pv/metadata_obj.cpp
251         pv/session.cpp
252         pv/storesession.cpp
253         pv/util.cpp
254         pv/binding/binding.cpp
255         pv/binding/inputoutput.cpp
256         pv/binding/device.cpp
257         pv/data/analog.cpp
258         pv/data/analogsegment.cpp
259         pv/data/logic.cpp
260         pv/data/logicsegment.cpp
261         pv/data/mathsignal.cpp
262         pv/data/signalbase.cpp
263         pv/data/signaldata.cpp
264         pv/data/segment.cpp
265         pv/devices/device.cpp
266         pv/devices/file.cpp
267         pv/devices/hardwaredevice.cpp
268         pv/devices/inputfile.cpp
269         pv/devices/sessionfile.cpp
270         pv/dialogs/connect.cpp
271         pv/dialogs/inputoutputoptions.cpp
272         pv/dialogs/settings.cpp
273         pv/dialogs/storeprogress.cpp
274         pv/popups/deviceoptions.cpp
275         pv/popups/channels.cpp
276         pv/prop/bool.cpp
277         pv/prop/double.cpp
278         pv/prop/enum.cpp
279         pv/prop/int.cpp
280         pv/prop/property.cpp
281         pv/prop/string.cpp
282         pv/subwindows/subwindowbase.cpp
283         pv/toolbars/mainbar.cpp
284         pv/views/trace/analogsignal.cpp
285         pv/views/trace/cursor.cpp
286         pv/views/trace/cursorpair.cpp
287         pv/views/trace/flag.cpp
288         pv/views/trace/header.cpp
289         pv/views/trace/mathsignal.cpp
290         pv/views/trace/marginwidget.cpp
291         pv/views/trace/logicsignal.cpp
292         pv/views/trace/ruler.cpp
293         pv/views/trace/signal.cpp
294         pv/views/trace/timeitem.cpp
295         pv/views/trace/timemarker.cpp
296         pv/views/trace/trace.cpp
297         pv/views/trace/tracegroup.cpp
298         pv/views/trace/tracepalette.cpp
299         pv/views/trace/tracetreeitem.cpp
300         pv/views/trace/tracetreeitemowner.cpp
301         pv/views/trace/triggermarker.cpp
302         pv/views/trace/view.cpp
303         pv/views/trace/viewitem.cpp
304         pv/views/trace/viewitemowner.cpp
305         pv/views/trace/viewitempaintparams.cpp
306         pv/views/trace/viewport.cpp
307         pv/views/trace/viewwidget.cpp
308         pv/views/viewbase.cpp
309         pv/views/trace/standardbar.cpp
310         pv/widgets/colorbutton.cpp
311         pv/widgets/colorpopup.cpp
312         pv/widgets/devicetoolbutton.cpp
313         pv/widgets/exportmenu.cpp
314         pv/widgets/flowlayout.cpp
315         pv/widgets/importmenu.cpp
316         pv/widgets/popup.cpp
317         pv/widgets/popuptoolbutton.cpp
318         pv/widgets/sweeptimingwidget.cpp
319         pv/widgets/timestampspinbox.cpp
320         pv/widgets/wellarray.cpp
321 )
322
323 # This list includes only QObject derived class headers.
324 set(pulseview_HEADERS
325         pv/exprtk.hpp
326         pv/logging.hpp
327         pv/globalsettings.hpp
328         pv/mainwindow.hpp
329         pv/metadata_obj.hpp
330         pv/session.hpp
331         pv/storesession.hpp
332         pv/binding/device.hpp
333         pv/data/analog.hpp
334         pv/data/analogsegment.hpp
335         pv/data/logic.hpp
336         pv/data/logicsegment.hpp
337         pv/data/mathsignal.hpp
338         pv/data/signalbase.hpp
339         pv/dialogs/connect.hpp
340         pv/dialogs/inputoutputoptions.hpp
341         pv/dialogs/settings.hpp
342         pv/dialogs/storeprogress.hpp
343         pv/popups/channels.hpp
344         pv/popups/deviceoptions.hpp
345         pv/prop/bool.hpp
346         pv/prop/double.hpp
347         pv/prop/enum.hpp
348         pv/prop/int.hpp
349         pv/prop/property.hpp
350         pv/prop/string.hpp
351         pv/subwindows/subwindowbase.hpp
352         pv/toolbars/mainbar.hpp
353         pv/views/trace/analogsignal.hpp
354         pv/views/trace/cursor.hpp
355         pv/views/trace/flag.hpp
356         pv/views/trace/header.hpp
357         pv/views/trace/logicsignal.hpp
358         pv/views/trace/mathsignal.hpp
359         pv/views/trace/marginwidget.hpp
360         pv/views/trace/ruler.hpp
361         pv/views/trace/signal.hpp
362         pv/views/trace/timeitem.hpp
363         pv/views/trace/timemarker.hpp
364         pv/views/trace/trace.hpp
365         pv/views/trace/tracegroup.hpp
366         pv/views/trace/tracetreeitem.hpp
367         pv/views/trace/triggermarker.hpp
368         pv/views/trace/view.hpp
369         pv/views/trace/viewitem.hpp
370         pv/views/trace/viewport.hpp
371         pv/views/trace/viewwidget.hpp
372         pv/views/viewbase.hpp
373         pv/views/trace/standardbar.hpp
374         pv/widgets/colorbutton.hpp
375         pv/widgets/colorpopup.hpp
376         pv/widgets/devicetoolbutton.hpp
377         pv/widgets/exportmenu.hpp
378         pv/widgets/flowlayout.hpp
379         pv/widgets/importmenu.hpp
380         pv/widgets/popup.hpp
381         pv/widgets/popuptoolbutton.hpp
382         pv/widgets/sweeptimingwidget.hpp
383         pv/widgets/timestampspinbox.hpp
384         pv/widgets/wellarray.hpp
385 )
386
387 set(pulseview_RESOURCES
388         pulseview.qrc
389 )
390
391 if(ENABLE_SIGNALS)
392         list(APPEND pulseview_SOURCES signalhandler.cpp)
393         list(APPEND pulseview_HEADERS signalhandler.hpp)
394 endif()
395
396 if(ENABLE_DECODE)
397         list(APPEND pulseview_SOURCES
398                 pv/binding/decoder.cpp
399                 pv/data/decodesignal.cpp
400                 pv/data/decode/annotation.cpp
401                 pv/data/decode/decoder.cpp
402                 pv/data/decode/row.cpp
403                 pv/data/decode/rowdata.cpp
404                 pv/subwindows/decoder_selector/item.cpp
405                 pv/subwindows/decoder_selector/model.cpp
406                 pv/subwindows/decoder_selector/subwindow.cpp
407                 pv/views/decoder_binary/view.cpp
408                 pv/views/decoder_binary/QHexView.cpp
409                 pv/views/tabular_decoder/model.cpp
410                 pv/views/tabular_decoder/view.cpp
411                 pv/views/trace/decodetrace.cpp
412                 pv/widgets/decodergroupbox.cpp
413                 pv/widgets/decodermenu.cpp
414         )
415
416         list(APPEND pulseview_HEADERS
417                 pv/data/decodesignal.hpp
418                 pv/subwindows/decoder_selector/subwindow.hpp
419                 pv/views/decoder_binary/view.hpp
420                 pv/views/decoder_binary/QHexView.hpp
421                 pv/views/tabular_decoder/view.hpp
422                 pv/views/trace/decodetrace.hpp
423                 pv/widgets/decodergroupbox.hpp
424                 pv/widgets/decodermenu.hpp
425         )
426 endif()
427
428 if(WIN32)
429         # Use the sigrok icon for the pulseview.exe executable.
430         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
431         enable_language(RC)
432         list(APPEND pulseview_SOURCES pulseviewico.rc)
433 endif()
434
435 if(ANDROID)
436         list(APPEND pulseview_SOURCES
437                 android/assetreader.cpp
438                 android/loghandler.cpp
439         )
440 endif()
441
442 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
443
444 #===============================================================================
445 #= Translations
446 #-------------------------------------------------------------------------------
447
448 file(GLOB TS_FILES ${CMAKE_SOURCE_DIR}/l10n/*.ts)
449 set_property(SOURCE ${TS_FILES} PROPERTY OUTPUT_LOCATION ${CMAKE_BINARY_DIR}/l10n)
450 if (NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
451         configure_file("translations.qrc" "translations.qrc" COPYONLY)
452 endif ()
453
454 qt5_add_translation(QM_FILES ${TS_FILES})
455 qt5_create_translation(QM_FILES ${pulseview_SOURCES} ${TS_FILES})
456
457 qt5_add_resources(pulseview_RESOURCES_RCC ${CMAKE_BINARY_DIR}/translations.qrc)
458
459 #===============================================================================
460 #= Global Definitions
461 #-------------------------------------------------------------------------------
462
463 add_definitions(-DQT_NO_KEYWORDS)
464 add_definitions(-D__STDC_LIMIT_MACROS)
465 add_definitions(-Wall -Wextra)
466 add_definitions(-std=c++11)
467 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
468
469 if(ENABLE_FLOW)
470         add_definitions(-DENABLE_FLOW)
471 endif()
472
473 if(ENABLE_DECODE)
474         add_definitions(-DENABLE_DECODE)
475 endif()
476
477 if(NOT DISABLE_WERROR)
478         add_definitions(-Werror)
479 endif()
480
481 if(ENABLE_SIGNALS)
482         add_definitions(-DENABLE_SIGNALS)
483 endif()
484
485 if(ENABLE_STACKTRACE)
486         add_definitions(-DENABLE_STACKTRACE -no-pie -fno-pie)
487         if (Backtrace_FOUND)
488                 add_definitions(-DBOOST_STACKTRACE_USE_BACKTRACE)
489         endif()
490 endif()
491
492 #===============================================================================
493 #= Global Include Directories
494 #-------------------------------------------------------------------------------
495
496 include_directories(
497         ${CMAKE_CURRENT_BINARY_DIR}
498         ${CMAKE_CURRENT_SOURCE_DIR}
499         ${Boost_INCLUDE_DIRS}
500 )
501
502 if(STATIC_PKGDEPS_LIBS)
503         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
504 else()
505         include_directories(${PKGDEPS_INCLUDE_DIRS})
506 endif()
507
508 #===============================================================================
509 #= Linker Configuration
510 #-------------------------------------------------------------------------------
511
512 link_directories(${Boost_LIBRARY_DIRS})
513
514 set(PULSEVIEW_LINK_LIBS
515         ${Boost_LIBRARIES}
516         ${QT_LIBRARIES}
517         ${CMAKE_THREAD_LIBS_INIT}
518         ${LIBATOMIC_LIBRARY}
519 )
520
521 if(STATIC_PKGDEPS_LIBS)
522         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
523         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
524 else()
525         link_directories(${PKGDEPS_LIBRARY_DIRS})
526         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
527 endif()
528
529 if(WIN32)
530         # On Windows we need to statically link the libqsvg imageformat
531         # plugin (and the QtSvg component) for SVG graphics/icons to work.
532         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
533         # Qt < 5.8.0), and all Qt libs and their dependencies.
534         add_definitions(-DQT_STATICPLUGIN)
535         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
536         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
537         if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
538                 list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
539         endif()
540         list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
541 endif()
542
543 if(ENABLE_STACKTRACE)
544         list(APPEND PULSEVIEW_LINK_LIBS ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
545         link_libraries("-no-pie -fno-pie")
546 endif()
547
548 if(ANDROID)
549         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
550 endif()
551
552 set(INPUT_FILES_LIST ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC} ${QM_FILES})
553 if(ANDROID)
554         add_library(${PROJECT_NAME} SHARED ${INPUT_FILES_LIST})
555 else()
556         add_executable(${PROJECT_NAME} ${INPUT_FILES_LIST})
557 endif()
558
559 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
560
561 if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
562         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
563         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
564 endif()
565
566 #===============================================================================
567 #= Installation
568 #-------------------------------------------------------------------------------
569
570 # Install the executable.
571 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
572
573 # Install the manpage.
574 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
575
576 # Install the desktop file.
577 install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
578
579 # Install the AppData/AppStream file.
580 install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
581
582 # Install the PulseView icons.
583 install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
584 install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
585
586 # Generate Windows installer script.
587 configure_file(contrib/pulseview_cross.nsi.in ${CMAKE_CURRENT_BINARY_DIR}/contrib/pulseview_cross.nsi @ONLY)
588
589 #===============================================================================
590 #= Packaging (handled by CPack)
591 #-------------------------------------------------------------------------------
592
593 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
594 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
595 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
596 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
597 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
598 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
599 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
600 set(CPACK_SOURCE_GENERATOR "TGZ")
601
602 include(CPack)
603
604 #===============================================================================
605 #= Tests
606 #-------------------------------------------------------------------------------
607
608 if(ENABLE_TESTS)
609         add_subdirectory(test)
610         enable_testing()
611         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
612 endif()