CMakeLists.txt

   1 ##
   2 ## This file is part of the PulseView project.
   3 ##
   4 ## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
   5 ## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ## Copyright (C) 2020 Soeren Apel <soeren@apelpie.net>
   7 ##
   8 ## This program is free software: you can redistribute it and/or modify
   9 ## it under the terms of the GNU General Public License as published by
  10 ## the Free Software Foundation, either version 2 of the License, or
  11 ## (at your option) any later version.
  12 ##
  13 ## This program is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License
  19 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 ##
  21
  22 cmake_minimum_required(VERSION 2.8.12)
  23
  24 project(pulseview C CXX)
  25
  26 include(GNUInstallDirs)
  27
  28 # Let AUTOMOC and AUTOUIC process GENERATED files.
  29 if(POLICY CMP0071)
  30         cmake_policy(SET CMP0071 NEW)
  31 endif()
  32
  33 # Only interpret if() arguments as variables or keywords when unquoted.
  34 if(POLICY CMP0054)
  35         cmake_policy(SET CMP0054 NEW)
  36 endif()
  37
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
  39
  40 #===============================================================================
  41 #= User Options
  42 #-------------------------------------------------------------------------------
  43
  44 option(DISABLE_WERROR "Build without -Werror" TRUE)
  45 option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
  46 option(ENABLE_STACKTRACE "Enable stack trace when crashing" FALSE)
  47 option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
  48 option(ENABLE_FLOW "Build with libsigrokflow" FALSE)
  49 option(ENABLE_TESTS "Enable unit tests" FALSE)
  50 option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
  51
  52 if(WIN32)
  53         # On Windows/MinGW we need to statically link to libraries.
  54         # This option is user configurable, but enable it by default on win32.
  55         set(STATIC_PKGDEPS_LIBS TRUE)
  56
  57         # Windows does not support UNIX signals.
  58         set(ENABLE_SIGNALS FALSE)
  59 endif()
  60
  61 if(NOT CMAKE_BUILD_TYPE)
  62         set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  63         "Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
  64         FORCE)
  65 endif()
  66
  67 #===============================================================================
  68 #= Documentation
  69 #-------------------------------------------------------------------------------
  70
  71 add_subdirectory(manual)
  72
  73 #===============================================================================
  74 #= Dependencies
  75 #-------------------------------------------------------------------------------
  76
  77 include(CheckCSourceCompiles)
  78 include(CheckCXXSourceCompiles)
  79 include(CMakePushCheckState)
  80 include(memaccess)
  81
  82 find_package(PkgConfig)
  83
  84 list(APPEND PKGDEPS glib-2.0>=2.28.0)
  85
  86 # Try to find the prefered glibmm-2.4. If not found then add glibmm-2.68
  87 # to the dependency list.
  88 pkg_check_modules(GLIBMM_2_4 glibmm-2.4>2.28.0)
  89 if(GLIBMM_2_4_FOUND)
  90         list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
  91 else()
  92         list(APPEND PKGDEPS glibmm-2.68>=2.68.0)
  93 endif()
  94
  95 if(ENABLE_FLOW)
  96         list(APPEND PKGDEPS gstreamermm-1.0>=1.8.0)
  97         list(APPEND PKGDEPS libsigrokflow>=0.1.0)
  98 endif()
  99
 100 set(LIBSR_CXX_BINDING "libsigrokcxx>=0.5.2")
 101 list(APPEND PKGDEPS "${LIBSR_CXX_BINDING}")
 102
 103 if(ENABLE_DECODE)
 104         list(APPEND PKGDEPS libsigrokdecode>=0.5.2)
 105 endif()
 106
 107 if(ANDROID)
 108         list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
 109 endif()
 110
 111 pkg_check_modules(LIBSRCXX ${LIBSR_CXX_BINDING})
 112 if(NOT LIBSRCXX_FOUND OR NOT LIBSRCXX_VERSION)
 113         message(FATAL_ERROR "libsigrok C++ bindings missing, check libsigrok's 'configure' output (missing dependencies?)")
 114 endif()
 115 pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
 116
 117 set(CMAKE_AUTOMOC TRUE)
 118
 119 find_package(Qt5 5.3 COMPONENTS Core Gui LinguistTools Widgets Svg REQUIRED)
 120
 121 message(STATUS "Qt version: ${Qt5_VERSION}")
 122
 123 if(WIN32)
 124         # MXE workaround: Use pkg-config to find Qt5 libs.
 125         # https://github.com/mxe/mxe/issues/1642
 126         # Not required (and doesn't work) on MSYS2.
 127         if(NOT DEFINED ENV{MSYSTEM})
 128                 pkg_check_modules(QT5ALL REQUIRED Qt5Widgets>=5.3 Qt5Gui>=5.3 Qt5Svg>=5.3)
 129         endif()
 130 endif()
 131
 132 set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
 133
 134 set(BOOSTCOMPS filesystem serialization system)
 135 if(ENABLE_TESTS)
 136         list(APPEND BOOSTCOMPS unit_test_framework)
 137 endif()
 138
 139 if(ENABLE_STACKTRACE)
 140         include(FindBacktrace)
 141         if (Backtrace_FOUND)
 142                 set(_Boost_STACKTRACE_BACKTRACE_HEADERS "boost/stacktrace.hpp")
 143                 list(APPEND BOOSTCOMPS stacktrace_backtrace)
 144         else()
 145                 set(_Boost_STACKTRACE_BASIC_HEADERS     "boost/stacktrace.hpp")
 146                 list(APPEND BOOSTCOMPS stacktrace_basic)
 147         endif()
 148         find_package(Boost 1.65.1 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 149 else()
 150         find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
 151 endif()
 152
 153 # Find the platform's thread library (needed for C++11 threads).
 154 # This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
 155 find_package(Threads REQUIRED)
 156
 157 # Check for explicit link against libatomic
 158 #
 159 # Depending on the toolchain, linking a program using atomic functions may need
 160 # "-latomic" explicitly passed to the linker
 161 #
 162 # This check first tests if atomics are available in the C-library, if not and
 163 # libatomic exists, then it runs the same test with -latomic added to the
 164 # linker flags.
 165
 166 # Helper for checking for atomics
 167 function(check_working_cxx_atomics varname additional_lib)
 168         cmake_push_check_state()
 169         set(CMAKE_REQUIRED_FLAGS "-std=c++11")
 170         set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
 171         set(CMAKE_REQUIRED_QUIET 1)
 172         CHECK_CXX_SOURCE_COMPILES("
 173 #include <atomic>
 174 std::atomic<int> x;
 175 int main() {
 176         return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
 177 }
 178 " ${varname})
 179         cmake_pop_check_state()
 180 endfunction(check_working_cxx_atomics)
 181
 182 # First check if atomics work without the library.
 183 # If not, check if the library exists, and atomics work with it.
 184 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
 185 if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
 186         message(STATUS "Atomics provided by the C-library - yes")
 187 else()
 188         message(STATUS "Atomics provided by the C-library - no")
 189         find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
 190         if(LIBATOMIC_LIBRARY)
 191                 check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
 192                 if (HAVE_CXX_ATOMICS_WITH_LIB)
 193                         message(STATUS "Atomics provided by libatomic - yes")
 194                 else()
 195                         message(STATUS "Atomics provided by libatomic - no")
 196                         message(FATAL_ERROR "Compiler must support std::atomic!")
 197                 endif()
 198         else()
 199                 message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
 200         endif()
 201 endif()
 202
 203 # Check availability of features which depend on library versions.
 204 # TODO Ideally use check_symbol_exists() instead, reduce boilerplate.
 205 if(ENABLE_DECODE)
 206         cmake_push_check_state()
 207         set(CMAKE_REQUIRED_INCLUDES "${PKGDEPS_INCLUDE_DIRS}")
 208         set(CMAKE_REQUIRED_LIBRARIES "sigrokdecode")
 209         foreach (LPATH ${PKGDEPS_LIBRARY_DIRS})
 210                 list(APPEND CMAKE_REQUIRED_LINK_OPTIONS "-L${LPATH}")
 211         endforeach ()
 212         check_c_source_compiles("
 213         #include <libsigrokdecode/libsigrokdecode.h>
 214         int main(int argc, char *argv[])
 215         {
 216                 (void)argc;
 217                 (void)argv;
 218                 return srd_session_send_eof(NULL);
 219         }
 220         " HAVE_SRD_SESSION_SEND_EOF)
 221         cmake_pop_check_state()
 222 endif()
 223
 224 #===============================================================================
 225 #= System Introspection
 226 #-------------------------------------------------------------------------------
 227
 228 memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
 229
 230 #===============================================================================
 231 #= Config Header
 232 #-------------------------------------------------------------------------------
 233
 234 set(PV_TITLE PulseView)
 235 set(PV_VERSION_STRING "0.5.0")
 236
 237 if(GLIBMM_2_4_FOUND)
 238         set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
 239 else()
 240         set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.68_VERSION})
 241 endif()
 242
 243 include(GetGitRevisionDescription)
 244
 245 # Append the revision hash unless we are exactly on a tagged release.
 246 git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
 247 if(NOT PV_TAG_VERSION_STRING)
 248         get_git_head_revision(PV_REVSPEC PV_HASH)
 249         if(PV_HASH)
 250                 string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
 251                 set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
 252         endif()
 253
 254         # Non-tagged releases use the unstable manual
 255         set(PV_MANUAL_VERSION "unstable")
 256 else()
 257         # Tagged releases use a fixed manual version
 258         set(PV_MANUAL_VERSION ${PV_VERSION_STRING})
 259 endif()
 260
 261 if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
 262         set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
 263         set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
 264         set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
 265         set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
 266 endif()
 267
 268 message(STATUS "${PV_TITLE} version: ${PV_VERSION_STRING}")
 269
 270 configure_file (
 271         ${PROJECT_SOURCE_DIR}/config.h.in
 272         ${PROJECT_BINARY_DIR}/config.h
 273 )
 274
 275 #===============================================================================
 276 #= Sources
 277 #-------------------------------------------------------------------------------
 278
 279 set(pulseview_SOURCES
 280         main.cpp
 281         pv/application.cpp
 282         pv/devicemanager.cpp
 283         pv/globalsettings.cpp
 284         pv/logging.cpp
 285         pv/mainwindow.cpp
 286         pv/metadata_obj.cpp
 287         pv/session.cpp
 288         pv/storesession.cpp
 289         pv/util.cpp
 290         pv/binding/binding.cpp
 291         pv/binding/inputoutput.cpp
 292         pv/binding/device.cpp
 293         pv/data/analog.cpp
 294         pv/data/analogsegment.cpp
 295         pv/data/logic.cpp
 296         pv/data/logicsegment.cpp
 297         pv/data/mathsignal.cpp
 298         pv/data/signalbase.cpp
 299         pv/data/signaldata.cpp
 300         pv/data/segment.cpp
 301         pv/devices/device.cpp
 302         pv/devices/file.cpp
 303         pv/devices/hardwaredevice.cpp
 304         pv/devices/inputfile.cpp
 305         pv/devices/sessionfile.cpp
 306         pv/dialogs/connect.cpp
 307         pv/dialogs/inputoutputoptions.cpp
 308         pv/dialogs/settings.cpp
 309         pv/dialogs/storeprogress.cpp
 310         pv/popups/deviceoptions.cpp
 311         pv/popups/channels.cpp
 312         pv/prop/bool.cpp
 313         pv/prop/double.cpp
 314         pv/prop/enum.cpp
 315         pv/prop/int.cpp
 316         pv/prop/property.cpp
 317         pv/prop/string.cpp
 318         pv/subwindows/subwindowbase.cpp
 319         pv/toolbars/mainbar.cpp
 320         pv/views/trace/analogsignal.cpp
 321         pv/views/trace/cursor.cpp
 322         pv/views/trace/cursorpair.cpp
 323         pv/views/trace/flag.cpp
 324         pv/views/trace/header.cpp
 325         pv/views/trace/mathsignal.cpp
 326         pv/views/trace/marginwidget.cpp
 327         pv/views/trace/logicsignal.cpp
 328         pv/views/trace/ruler.cpp
 329         pv/views/trace/signal.cpp
 330         pv/views/trace/timeitem.cpp
 331         pv/views/trace/timemarker.cpp
 332         pv/views/trace/trace.cpp
 333         pv/views/trace/tracegroup.cpp
 334         pv/views/trace/tracepalette.cpp
 335         pv/views/trace/tracetreeitem.cpp
 336         pv/views/trace/tracetreeitemowner.cpp
 337         pv/views/trace/triggermarker.cpp
 338         pv/views/trace/view.cpp
 339         pv/views/trace/viewitem.cpp
 340         pv/views/trace/viewitemowner.cpp
 341         pv/views/trace/viewitempaintparams.cpp
 342         pv/views/trace/viewport.cpp
 343         pv/views/trace/viewwidget.cpp
 344         pv/views/viewbase.cpp
 345         pv/views/trace/standardbar.cpp
 346         pv/widgets/colorbutton.cpp
 347         pv/widgets/colorpopup.cpp
 348         pv/widgets/devicetoolbutton.cpp
 349         pv/widgets/exportmenu.cpp
 350         pv/widgets/flowlayout.cpp
 351         pv/widgets/importmenu.cpp
 352         pv/widgets/popup.cpp
 353         pv/widgets/popuptoolbutton.cpp
 354         pv/widgets/sweeptimingwidget.cpp
 355         pv/widgets/timestampspinbox.cpp
 356         pv/widgets/wellarray.cpp
 357 )
 358
 359 # This list includes only QObject derived class headers.
 360 set(pulseview_HEADERS
 361         pv/exprtk.hpp
 362         pv/logging.hpp
 363         pv/globalsettings.hpp
 364         pv/mainwindow.hpp
 365         pv/metadata_obj.hpp
 366         pv/session.hpp
 367         pv/storesession.hpp
 368         pv/binding/device.hpp
 369         pv/data/analog.hpp
 370         pv/data/analogsegment.hpp
 371         pv/data/logic.hpp
 372         pv/data/logicsegment.hpp
 373         pv/data/mathsignal.hpp
 374         pv/data/signalbase.hpp
 375         pv/dialogs/connect.hpp
 376         pv/dialogs/inputoutputoptions.hpp
 377         pv/dialogs/settings.hpp
 378         pv/dialogs/storeprogress.hpp
 379         pv/popups/channels.hpp
 380         pv/popups/deviceoptions.hpp
 381         pv/prop/bool.hpp
 382         pv/prop/double.hpp
 383         pv/prop/enum.hpp
 384         pv/prop/int.hpp
 385         pv/prop/property.hpp
 386         pv/prop/string.hpp
 387         pv/subwindows/subwindowbase.hpp
 388         pv/toolbars/mainbar.hpp
 389         pv/views/trace/analogsignal.hpp
 390         pv/views/trace/cursor.hpp
 391         pv/views/trace/flag.hpp
 392         pv/views/trace/header.hpp
 393         pv/views/trace/logicsignal.hpp
 394         pv/views/trace/mathsignal.hpp
 395         pv/views/trace/marginwidget.hpp
 396         pv/views/trace/ruler.hpp
 397         pv/views/trace/signal.hpp
 398         pv/views/trace/timeitem.hpp
 399         pv/views/trace/timemarker.hpp
 400         pv/views/trace/trace.hpp
 401         pv/views/trace/tracegroup.hpp
 402         pv/views/trace/tracetreeitem.hpp
 403         pv/views/trace/triggermarker.hpp
 404         pv/views/trace/view.hpp
 405         pv/views/trace/viewitem.hpp
 406         pv/views/trace/viewport.hpp
 407         pv/views/trace/viewwidget.hpp
 408         pv/views/viewbase.hpp
 409         pv/views/trace/standardbar.hpp
 410         pv/widgets/colorbutton.hpp
 411         pv/widgets/colorpopup.hpp
 412         pv/widgets/devicetoolbutton.hpp
 413         pv/widgets/exportmenu.hpp
 414         pv/widgets/flowlayout.hpp
 415         pv/widgets/importmenu.hpp
 416         pv/widgets/popup.hpp
 417         pv/widgets/popuptoolbutton.hpp
 418         pv/widgets/sweeptimingwidget.hpp
 419         pv/widgets/timestampspinbox.hpp
 420         pv/widgets/wellarray.hpp
 421 )
 422
 423 set(pulseview_RESOURCES
 424         pulseview.qrc
 425 )
 426
 427 if(ENABLE_SIGNALS)
 428         list(APPEND pulseview_SOURCES signalhandler.cpp)
 429         list(APPEND pulseview_HEADERS signalhandler.hpp)
 430 endif()
 431
 432 if(ENABLE_DECODE)
 433         list(APPEND pulseview_SOURCES
 434                 pv/binding/decoder.cpp
 435                 pv/data/decodesignal.cpp
 436                 pv/data/decode/annotation.cpp
 437                 pv/data/decode/decoder.cpp
 438                 pv/data/decode/row.cpp
 439                 pv/data/decode/rowdata.cpp
 440                 pv/subwindows/decoder_selector/item.cpp
 441                 pv/subwindows/decoder_selector/model.cpp
 442                 pv/subwindows/decoder_selector/subwindow.cpp
 443                 pv/views/decoder_binary/view.cpp
 444                 pv/views/decoder_binary/QHexView.cpp
 445                 pv/views/tabular_decoder/model.cpp
 446                 pv/views/tabular_decoder/view.cpp
 447                 pv/views/trace/decodetrace.cpp
 448                 pv/widgets/decodergroupbox.cpp
 449                 pv/widgets/decodermenu.cpp
 450         )
 451
 452         list(APPEND pulseview_HEADERS
 453                 pv/data/decodesignal.hpp
 454                 pv/subwindows/decoder_selector/subwindow.hpp
 455                 pv/views/decoder_binary/view.hpp
 456                 pv/views/decoder_binary/QHexView.hpp
 457                 pv/views/tabular_decoder/view.hpp
 458                 pv/views/trace/decodetrace.hpp
 459                 pv/widgets/decodergroupbox.hpp
 460                 pv/widgets/decodermenu.hpp
 461         )
 462 endif()
 463
 464 if(WIN32)
 465         # Use the sigrok icon for the pulseview.exe executable.
 466         set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
 467         enable_language(RC)
 468         list(APPEND pulseview_SOURCES pulseviewico.rc)
 469 endif()
 470
 471 if(ANDROID)
 472         list(APPEND pulseview_SOURCES
 473                 android/assetreader.cpp
 474                 android/loghandler.cpp
 475         )
 476 endif()
 477
 478 qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
 479
 480 #===============================================================================
 481 #= Translations
 482 #-------------------------------------------------------------------------------
 483
 484 file(GLOB TS_FILES ${CMAKE_SOURCE_DIR}/l10n/*.ts)
 485 set_property(SOURCE ${TS_FILES} PROPERTY OUTPUT_LOCATION ${CMAKE_BINARY_DIR}/l10n)
 486 if (NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
 487         configure_file("translations.qrc" "translations.qrc" COPYONLY)
 488 endif ()
 489
 490 qt5_add_translation(QM_FILES ${TS_FILES})
 491 qt5_create_translation(QM_FILES ${pulseview_SOURCES} ${TS_FILES})
 492
 493 qt5_add_resources(pulseview_RESOURCES_RCC ${CMAKE_BINARY_DIR}/translations.qrc)
 494
 495 #===============================================================================
 496 #= Global Definitions
 497 #-------------------------------------------------------------------------------
 498
 499 add_definitions(-DQT_NO_KEYWORDS)
 500 add_definitions(-D__STDC_LIMIT_MACROS)
 501 add_definitions(-Wall -Wextra)
 502 add_definitions(-std=c++11)
 503 add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
 504 if(WIN32)
 505         add_definitions(-Wa,-mbig-obj -O3)
 506 endif()
 507
 508 if(ENABLE_FLOW)
 509         add_definitions(-DENABLE_FLOW)
 510 endif()
 511
 512 if(ENABLE_DECODE)
 513         add_definitions(-DENABLE_DECODE)
 514 endif()
 515
 516 if(NOT DISABLE_WERROR)
 517         add_definitions(-Werror)
 518 endif()
 519
 520 if(ENABLE_SIGNALS)
 521         add_definitions(-DENABLE_SIGNALS)
 522 endif()
 523
 524 if(ENABLE_STACKTRACE)
 525         add_definitions(-DENABLE_STACKTRACE -no-pie -fno-pie)
 526         if (Backtrace_FOUND)
 527                 add_definitions(-DBOOST_STACKTRACE_USE_BACKTRACE)
 528         endif()
 529 endif()
 530
 531 #===============================================================================
 532 #= Global Include Directories
 533 #-------------------------------------------------------------------------------
 534
 535 include_directories(
 536         ${CMAKE_CURRENT_BINARY_DIR}
 537         ${CMAKE_CURRENT_SOURCE_DIR}
 538         ${Boost_INCLUDE_DIRS}
 539 )
 540
 541 if(STATIC_PKGDEPS_LIBS)
 542         include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
 543 else()
 544         include_directories(${PKGDEPS_INCLUDE_DIRS})
 545 endif()
 546
 547 #===============================================================================
 548 #= Linker Configuration
 549 #-------------------------------------------------------------------------------
 550
 551 link_directories(${Boost_LIBRARY_DIRS})
 552
 553 set(PULSEVIEW_LINK_LIBS
 554         ${Boost_LIBRARIES}
 555         ${QT_LIBRARIES}
 556         ${CMAKE_THREAD_LIBS_INIT}
 557         ${LIBATOMIC_LIBRARY}
 558 )
 559
 560 if(STATIC_PKGDEPS_LIBS)
 561         link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
 562         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
 563 else()
 564         link_directories(${PKGDEPS_LIBRARY_DIRS})
 565         list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
 566 endif()
 567
 568 if(WIN32)
 569         # On Windows we need to statically link the libqsvg imageformat
 570         # plugin (and the QtSvg component) for SVG graphics/icons to work.
 571         # We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
 572         # Qt < 5.8.0), and all Qt libs and their dependencies.
 573         add_definitions(-DQT_STATICPLUGIN)
 574         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
 575         list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
 576         if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
 577                 list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
 578         endif()
 579         list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
 580 endif()
 581
 582 if(ENABLE_STACKTRACE)
 583         list(APPEND PULSEVIEW_LINK_LIBS ${CMAKE_DL_LIBS} ${Backtrace_LIBRARIES})
 584         link_libraries("-no-pie -fno-pie")
 585 endif()
 586
 587 if(ANDROID)
 588         list(APPEND PULSEVIEW_LINK_LIBS "-llog")
 589 endif()
 590
 591 set(INPUT_FILES_LIST ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC} ${QM_FILES})
 592 if(ANDROID)
 593         add_library(${PROJECT_NAME} SHARED ${INPUT_FILES_LIST})
 594 else()
 595         add_executable(${PROJECT_NAME} ${INPUT_FILES_LIST})
 596 endif()
 597
 598 target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
 599
 600 if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
 601         # Pass -mwindows so that no "DOS box" opens when PulseView is started.
 602         set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
 603 endif()
 604
 605 #===============================================================================
 606 #= Installation
 607 #-------------------------------------------------------------------------------
 608
 609 # Install the executable.
 610 install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
 611
 612 # Install the manpage.
 613 install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
 614
 615 # Install the desktop file.
 616 install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
 617
 618 # Install the AppData/AppStream file.
 619 install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
 620
 621 # Install the PulseView icons.
 622 install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
 623 install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
 624
 625 # Generate Windows installer script.
 626 configure_file(contrib/pulseview_cross.nsi.in ${CMAKE_CURRENT_BINARY_DIR}/contrib/pulseview_cross.nsi @ONLY)
 627
 628 #===============================================================================
 629 #= Packaging (handled by CPack)
 630 #-------------------------------------------------------------------------------
 631
 632 set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
 633 set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
 634 set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
 635 set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
 636 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
 637 set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
 638 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
 639 set(CPACK_SOURCE_GENERATOR "TGZ")
 640
 641 include(CPack)
 642
 643 #===============================================================================
 644 #= Tests
 645 #-------------------------------------------------------------------------------
 646
 647 if(ENABLE_TESTS)
 648         add_subdirectory(test)
 649         enable_testing()
 650         add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
 651 endif()