Lower glib-2.0 requirement to 2.24.0.
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the sigrok project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 m4_define([srd_package_version_major], [0])
25 m4_define([srd_package_version_minor], [1])
26 m4_define([srd_package_version_micro], [0])
27 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro])
28
29 AC_INIT([libsigrokdecode], [srd_package_version],
30         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
31         [http://www.sigrok.org])
32 AC_CONFIG_HEADER([config.h])
33 AC_CONFIG_MACRO_DIR([autostuff])
34 AC_CONFIG_AUX_DIR([autostuff])
35
36 # We require at least automake 1.11 (needed for 'silent rules').
37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
40
41 AH_TOP([#ifndef SRD_CONFIG_H
42 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
43 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
44
45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
46 # and enforce use of SRD_API to explicitly mark all public API functions.
47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
48
49 # Checks for programs.
50 AC_PROG_CXX
51 AC_PROG_CC
52 AC_PROG_CPP
53 AC_PROG_INSTALL
54 AC_PROG_LN_S
55
56 # Initialize libtool.
57 LT_INIT
58
59 # Initialize pkg-config.
60 # We require at least 0.22, as "Requires.private" behaviour changed there.
61 PKG_PROG_PKG_CONFIG([0.22])
62
63 # Library version for libsigrokdecode (NOT the same as the package version).
64 # Carefully read the libtool docs before updating these numbers!
65 # The algorithm for determining which number to change (and how) is nontrivial!
66 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
67 SRD_LIB_VERSION_CURRENT=0
68 SRD_LIB_VERSION_REVISION=0
69 SRD_LIB_VERSION_AGE=0
70 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
71 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
72 AC_SUBST(SRD_LIB_VERSION_CURRENT)
73 AC_SUBST(SRD_LIB_VERSION_REVISION)
74 AC_SUBST(SRD_LIB_VERSION_AGE)
75 AC_SUBST(SRD_LIB_VERSION)
76 AC_SUBST(SRD_LIB_LDFLAGS)
77
78 # Checks for libraries.
79
80 # libglib-2.0 is always needed.
81 # Note: glib-2.0 is part of the libsigrokdecode API
82 # (hard pkg-config requirement).
83 AM_PATH_GLIB_2_0([2.24.0],
84         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
85
86 # Python support. We require at least Python >= 3.0.
87 AC_ARG_VAR([PYTHON3_CONFIG], [path to python3-config utility])
88 AC_CHECK_PROGS([PYTHON3_CONFIG], [python3-config python3.3-config python3.2-config python3.1-config python3.0-config])
89 CPPFLAGS_PYTHON=""
90 LDFLAGS_PYTHON=""
91 case "$build" in
92 *mingw*)
93         # We currently hardcode the paths to the Python 3.2 default install
94         # location as there's no 'python-config' script on Windows, it seems.
95         # Note: We add both the /c/ and c:/ syntax (needed for cmake).
96         AC_MSG_WARN([using hardcoded Python3 configuration on MinGW])
97         CPPFLAGS_PYTHON="-I/c/Python32/include -Ic:/Python32/include"
98         LDFLAGS_PYTHON="-L/c/Python32/libs -Lc:/Python32/libs -lpython32"
99         ;;
100 *)
101         # We know that Linux has 'python3-config'.
102         # On Darwin, Macports has python3.x-config, fink has python3-config.
103         # Mac OS X (Snow Leopard) ships with 'python-config' per default, but
104         # that's Python 2.x, so not useful for us.
105         # Everything else is untested, we just hope some $PYTHON3_CONFIG
106         # (i.e., any of the tools we check for above) is available.
107         if test -n "$PYTHON3_CONFIG"; then
108                 CPPFLAGS_PYTHON="$($PYTHON3_CONFIG --includes)"
109                 LDFLAGS_PYTHON="$($PYTHON3_CONFIG --ldflags)"
110         else
111                 AC_MSG_ERROR([python3-config not found])
112         fi
113         ;;
114 esac
115 AC_SUBST(CPPFLAGS_PYTHON)
116 AC_SUBST(LDFLAGS_PYTHON)
117
118 # Checks for header files.
119 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
120 # AC_CHECK_HEADERS([])
121
122 # Checks for typedefs, structures, and compiler characteristics.
123 AC_C_INLINE
124 AC_TYPE_INT8_T
125 AC_TYPE_INT16_T
126 AC_TYPE_INT32_T
127 AC_TYPE_INT64_T
128 AC_TYPE_UINT8_T
129 AC_TYPE_UINT16_T
130 AC_TYPE_UINT32_T
131 AC_TYPE_UINT64_T
132 AC_TYPE_SIZE_T
133
134 # Checks for library functions.
135 AC_CHECK_FUNCS([memset strtoull])
136
137 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
138 AC_SUBST(MAKEFLAGS, '--no-print-directory')
139 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
140
141 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
142 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
143 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
144 SRD_PACKAGE_VERSION=srd_package_version
145
146 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
147 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
148 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
149 AC_SUBST(SRD_PACKAGE_VERSION)
150
151 AC_CONFIG_FILES([Makefile
152                  sigrokdecode.h
153                  libsigrokdecode.pc
154                  decoders/Makefile
155                  decoders/avr_isp/Makefile
156                  decoders/can/Makefile
157                  decoders/dcf77/Makefile
158                  decoders/edid/Makefile
159                  decoders/i2c/Makefile
160                  decoders/i2cdemux/Makefile
161                  decoders/i2cfilter/Makefile
162                  decoders/i2s/Makefile
163                  decoders/jtag/Makefile
164                  decoders/jtag_stm32/Makefile
165                  decoders/lm75/Makefile
166                  decoders/lpc/Makefile
167                  decoders/maxim_ds28ea00/Makefile
168                  decoders/mlx90614/Makefile
169                  decoders/mx25lxx05d/Makefile
170                  decoders/mxc6225xu/Makefile
171                  decoders/nunchuk/Makefile
172                  decoders/onewire_link/Makefile
173                  decoders/onewire_network/Makefile
174                  decoders/pan1321/Makefile
175                  decoders/rtc8564/Makefile
176                  decoders/sdcard_spi/Makefile
177                  decoders/spi/Makefile
178                  decoders/tlc5620/Makefile
179                  decoders/transitioncounter/Makefile
180                  decoders/uart/Makefile
181                  decoders/uart_dump/Makefile
182                  decoders/usb_protocol/Makefile
183                  decoders/usb_signalling/Makefile
184                 ])
185
186 AC_OUTPUT
187
188 echo
189 echo "libsigrokdecode configuration summary:"
190 echo
191 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
192 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
193 echo "  - Prefix: $prefix"
194 echo
195 echo "Detected libraries:"
196 echo
197
198 # Note: This only works for libs with pkg-config integration.
199 for lib in "glib-2.0"; do
200         if `$PKG_CONFIG --exists $lib`; then
201                 ver=`$PKG_CONFIG --modversion $lib`
202                 answer="yes ($ver)"
203         else
204                 answer="no"
205         fi
206         echo "  - $lib: $answer"
207 done
208
209 echo
210 echo "Detected Python:"
211 echo
212 echo "  - Python CPPFLAGS: $CPPFLAGS_PYTHON"
213 echo "  - Python LDFLAGS: $LDFLAGS_PYTHON"
214 echo
215