uart: don't re-calculate in-frame bit position, just count the bits
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the libsigrokdecode project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 AC_INIT([libsigrokdecode], [0.6.0],
25         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
26         [http://www.sigrok.org])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_AUX_DIR([autostuff])
29 AC_CONFIG_HEADERS([config.h version.h])
30
31 # We require at least automake 1.11 (needed for 'silent rules').
32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news color-tests])
33 AM_SILENT_RULES([yes])
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
35
36 AC_CANONICAL_HOST
37
38 # Checks for programs.
39 AC_PROG_CC
40 AC_PROG_INSTALL
41 AC_PROG_LN_S
42
43 AC_C_CONST
44
45 # Required for per-target flags or subdir-objects with C sources.
46 AM_PROG_CC_C_O
47
48 # Support building Windows DLLs.
49 AC_LIBTOOL_WIN32_DLL
50 AM_PROG_CC_STDC
51 AM_PROG_LIBTOOL
52
53 # Set the standard the C library headers should conform to.
54 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
55 #ifndef _POSIX_C_SOURCE
56 # define _POSIX_C_SOURCE 200112L
57 #endif])
58
59 # Get compiler versions.
60 SR_PROG_VERSION([$CC], [srd_cc_version])
61
62 # Initialize libtool.
63 LT_INIT
64
65 # Set up the libsigrokdecode version defines.
66 SR_PKG_VERSION_SET([SRD_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
67
68 # Library version for libsigrokdecode (NOT the same as the package version).
69 # Carefully read the libtool docs before updating these numbers!
70 # The algorithm for determining which number to change (and how) is nontrivial!
71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
72 # Format: current:revision:age.
73 SR_LIB_VERSION_SET([SRD_LIB_VERSION], [4:0:0])
74
75 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
76
77 # Initialize pkg-config.
78 # We require at least 0.22, as "Requires.private" behaviour changed there.
79 PKG_PROG_PKG_CONFIG
80
81 ############################
82 ##  Package dependencies  ##
83 ############################
84
85 # Initialize pkg-config.
86 # We require at least 0.22, as "Requires.private" behaviour changed there.
87 PKG_PROG_PKG_CONFIG([0.22])
88
89 # Collect the pkg-config module names of all dependencies in SRD_PKGLIBS.
90 # These are used to derive the compiler flags and for the "Requires.private"
91 # field in the generated libsigrokdecode.pc file.
92 SRD_PKGLIBS=
93 SRD_PKGLIBS_TESTS=
94
95 # Keep track of all checked modules so we can list them at the end.
96 SR_PKG_CHECK_SUMMARY([srd_pkglibs_summary])
97
98 # Python 3 is always needed.
99 # Starting with Python 3.8 we need to check for "python-3.8-embed"
100 # first, since usually only that variant will add "-lpython3.8".
101 # https://docs.python.org/3/whatsnew/3.8.html#debug-build-uses-the-same-abi-as-release-build
102 SR_PKG_CHECK([python3], [SRD_PKGLIBS],
103         [python-3.10-embed], [python-3.9-embed], [python-3.8-embed], [python3-embed], [python-3.8 >= 3.8], [python-3.7 >= 3.7], [python-3.6 >= 3.6], [python-3.5 >= 3.5], [python-3.4 >= 3.4], [python-3.3 >= 3.3], [python-3.2 >= 3.2], [python3 >= 3.2])
104 AS_IF([test "x$sr_have_python3" = xno],
105         [AC_MSG_ERROR([Cannot find Python 3 development headers.])])
106
107 # We also need to find the name of the python3 executable (for 'make install').
108 # Some OSes call this python3, some call it python3.2, etc. etc.
109 AC_ARG_VAR([PYTHON3], [Python 3 interpreter])
110 AC_CHECK_PROGS([PYTHON3], [python3.8 python3.7 python3.6 python3.5 python3.4 python3.3 python3.2 python3])
111 AS_IF([test "x$PYTHON3" = x],
112         [AC_MSG_ERROR([Cannot find Python 3 interpreter.])])
113
114 ######################
115 ##  Feature checks  ##
116 ######################
117
118 # Keep track of all checked modules so we can list them at the end.
119 SR_PKG_CHECK_SUMMARY([srd_pkglibs_opt_summary])
120
121 # The Check unit testing framework is optional. Disable if not found.
122 SR_PKG_CHECK([check], [SRD_PKGLIBS_TESTS], [check >= 0.9.4])
123 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
124
125 # Enable the C99 standard if possible, and enforce the use
126 # of SRD_API to explicitly mark all public API functions.
127 SRD_EXTRA_CFLAGS=
128 SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
129 SR_CHECK_COMPILE_FLAGS([SRD_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
130
131 # Select suitable compiler warning flags.
132 SR_ARG_ENABLE_WARNINGS([SRD_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes -Wshadow -Wformat=2 -Wno-format-nonliteral -Wfloat-equal])
133
134 # Link against libm, this is required (among other things) by Python.
135 SRD_EXTRA_LIBS=
136 SR_SEARCH_LIBS([SRD_EXTRA_LIBS], [pow], [m])
137
138 AC_SYS_LARGEFILE
139
140 AC_C_BIGENDIAN
141
142 #########################
143 ##  Optional features. ##
144 #########################
145
146 # Enable IRMP support by default. Accept user overrides.
147 AC_ARG_ENABLE([irmp],
148         [AS_HELP_STRING([--enable-irmp], [enable IRMP shared object [default=yes]])],
149         [], [enable_irmp_so=yes])
150 AM_CONDITIONAL([WITH_IRMP], [test "x$enable_irmp_so" = "xyes"])
151 test -n "$enable_irmp_so" || enable_irmp_so=no
152
153 ##############################
154 ##  Finalize configuration  ##
155 ##############################
156
157 AC_SUBST([SRD_PKGLIBS])
158
159 # Retrieve the compile and link flags for all modules combined.
160 # Also, bail out at this point if any module dependency is not met.
161 PKG_CHECK_MODULES([LIBSIGROKDECODE], [glib-2.0 >= 2.34 $SRD_PKGLIBS])
162 PKG_CHECK_MODULES([LIBIRMP], [glib-2.0 >= 2.34 $SRD_PKGLIBS])
163 PKG_CHECK_MODULES([TESTS], [$SRD_PKGLIBS_TESTS glib-2.0 $SRD_PKGLIBS])
164
165 srd_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
166
167 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
168         [The canonical host libsigrokdecode will run on.])
169
170 AC_CONFIG_FILES([Makefile libsigrokdecode.pc])
171
172 AC_OUTPUT
173
174 cat >&AS_MESSAGE_FD <<_EOF
175
176 libsigrokdecode configuration summary:
177  - Package version................. $SRD_PACKAGE_VERSION
178  - Library ABI version............. $SRD_LIB_VERSION
179  - Prefix.......................... $prefix
180  - Building on..................... $build
181  - Building for.................... $host
182  - Building shared / static........ $enable_shared / $enable_static
183
184 Compile configuration:
185  - C compiler...................... $CC
186  - C compiler version.............. $srd_cc_version
187  - C compiler flags................ $CFLAGS
188  - Additional C compiler flags..... $SRD_EXTRA_CFLAGS
189  - C compiler warnings............. $SRD_WFLAGS
190  - Linker flags.................... $LDFLAGS
191
192 Detected libraries (required):
193  - glib-2.0 >= 2.34................ $srd_glib_version
194 $srd_pkglibs_summary
195 Detected libraries (optional):
196 $srd_pkglibs_opt_summary
197 Optional features:
198   - IRMP support library .......... $enable_irmp_so
199 _EOF