[pulseview.git] / CMakeLists.txt

##
## This file is part of the PulseView project.
##
## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 2 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

cmake_minimum_required(VERSION 2.8.6)

include(FindPkgConfig)
include(GNUInstallDirs)

project(pulseview)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")

#===============================================================================
#= User Options
#-------------------------------------------------------------------------------

option(DISABLE_WERROR "Build without -Werror" FALSE)
option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
option(ENABLE_COTIRE "Enable cotire" FALSE)
option(ENABLE_TESTS "Enable unit tests" FALSE)
option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)

if(WIN32)
	# On Windows/MinGW we need to statically link to libraries.
	# This option is user configurable, but enable it by default on win32.
	set(STATIC_PKGDEPS_LIBS TRUE)

	# For boost-thread we need two additional settings on win32:
	set(Boost_USE_STATIC_LIBS ON)
	add_definitions(-DBOOST_THREAD_USE_LIB)

	# Windows does not support UNIX signals.
	set(ENABLE_SIGNALS FALSE)
endif()

if(NOT CMAKE_BUILD_TYPE)
	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	FORCE)
endif()

#===============================================================================
#= Dependencies
#-------------------------------------------------------------------------------

list(APPEND PKGDEPS libsigrokxx>=0.3.0)

if(ENABLE_DECODE)
	list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
endif()

if(ANDROID)
	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
endif()

find_package(PkgConfig)
pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})

if(FORCE_QT4)
	set(Qt5Core_FOUND FALSE)
else()
	find_package(Qt5Core QUIET)
endif()

if(Qt5Core_FOUND)
	message("-- Using Qt5")
	find_package(Qt5Widgets REQUIRED)
	find_package(Qt5Gui REQUIRED)
	find_package(Qt5Svg REQUIRED)
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
else()
	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
endif()

if(WIN32)
	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	# The library is named libboost_thread_win32* (not libboost_thread*).
	find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 REQUIRED)
else()
	find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
endif()

# Find the platform's thread library (needed for C++11 threads).
# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
find_package(Threads REQUIRED)

#===============================================================================
#= System Introspection
#-------------------------------------------------------------------------------

include(memaccess)
memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)

#===============================================================================
#= Config Header
#-------------------------------------------------------------------------------

set(PV_TITLE PulseView)
set(PV_DESCRIPTION "A GUI for sigrok")

set(PV_VERSION_MAJOR 0)
set(PV_VERSION_MINOR 2)
set(PV_VERSION_MICRO 0)
set(PV_VERSION_STRING
	${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
)

configure_file (
	${PROJECT_SOURCE_DIR}/config.h.in
	${PROJECT_BINARY_DIR}/config.h
)

#===============================================================================
#= Sources
#-------------------------------------------------------------------------------

set(pulseview_SOURCES
	main.cpp
	pv/application.cpp
	pv/devicemanager.cpp
	pv/mainwindow.cpp
	pv/sigsession.cpp
	pv/storesession.cpp
	pv/util.cpp
	pv/data/analog.cpp
	pv/data/analogsnapshot.cpp
	pv/data/logic.cpp
	pv/data/logicsnapshot.cpp
	pv/data/signaldata.cpp
	pv/data/snapshot.cpp
	pv/dialogs/about.cpp
	pv/dialogs/connect.cpp
	pv/dialogs/storeprogress.cpp
	pv/popups/deviceoptions.cpp
	pv/popups/channels.cpp
	pv/prop/bool.cpp
	pv/prop/double.cpp
	pv/prop/enum.cpp
	pv/prop/int.cpp
	pv/prop/property.cpp
	pv/prop/string.cpp
	pv/prop/binding/binding.cpp
	pv/prop/binding/deviceoptions.cpp
	pv/toolbars/samplingbar.cpp
	pv/view/analogsignal.cpp
	pv/view/cursor.cpp
	pv/view/cursorheader.cpp
	pv/view/cursorpair.cpp
	pv/view/header.cpp
	pv/view/marginwidget.cpp
	pv/view/logicsignal.cpp
	pv/view/rowitem.cpp
	pv/view/rowitemowner.cpp
	pv/view/ruler.cpp
	pv/view/selectableitem.cpp
	pv/view/signal.cpp
	pv/view/timemarker.cpp
	pv/view/trace.cpp
	pv/view/tracegroup.cpp
	pv/view/tracepalette.cpp
	pv/view/view.cpp
	pv/view/viewport.cpp
	pv/widgets/colourbutton.cpp
	pv/widgets/colourpopup.cpp
	pv/widgets/popup.cpp
	pv/widgets/popuptoolbutton.cpp
	pv/widgets/sweeptimingwidget.cpp
	pv/widgets/wellarray.cpp
)

# This list includes only QObject derived class headers.
set(pulseview_HEADERS
	pv/mainwindow.hpp
	pv/sigsession.hpp
	pv/storesession.hpp
	pv/dialogs/about.hpp
	pv/dialogs/connect.hpp
	pv/dialogs/storeprogress.hpp
	pv/popups/channels.hpp
	pv/popups/deviceoptions.hpp
	pv/prop/bool.hpp
	pv/prop/double.hpp
	pv/prop/enum.hpp
	pv/prop/int.hpp
	pv/prop/property.hpp
	pv/prop/string.hpp
	pv/prop/binding/deviceoptions.hpp
	pv/toolbars/samplingbar.hpp
	pv/view/cursor.hpp
	pv/view/cursorheader.hpp
	pv/view/header.hpp
	pv/view/logicsignal.hpp
	pv/view/marginwidget.hpp
	pv/view/rowitem.hpp
	pv/view/ruler.hpp
	pv/view/selectableitem.hpp
	pv/view/signal.hpp
	pv/view/timemarker.hpp
	pv/view/trace.hpp
	pv/view/tracegroup.hpp
	pv/view/view.hpp
	pv/view/viewport.hpp
	pv/widgets/colourbutton.hpp
	pv/widgets/colourpopup.hpp
	pv/widgets/popup.hpp
	pv/widgets/popuptoolbutton.hpp
	pv/widgets/sweeptimingwidget.hpp
	pv/widgets/wellarray.hpp
)

set(pulseview_FORMS
	pv/dialogs/about.ui
)

set(pulseview_RESOURCES
	pulseview.qrc
)

if(ENABLE_SIGNALS)
	list(APPEND pulseview_SOURCES signalhandler.cpp)
	list(APPEND pulseview_HEADERS signalhandler.hpp)
endif()

if(ENABLE_DECODE)
	list(APPEND pulseview_SOURCES
		pv/data/decoderstack.cpp
		pv/data/decode/annotation.cpp
		pv/data/decode/decoder.cpp
		pv/data/decode/row.cpp
		pv/data/decode/rowdata.cpp
		pv/prop/binding/decoderoptions.cpp
		pv/view/decodetrace.cpp
		pv/widgets/decodergroupbox.cpp
		pv/widgets/decodermenu.cpp
	)

	list(APPEND pulseview_HEADERS
		pv/data/decoderstack.hpp
		pv/view/decodetrace.hpp
		pv/widgets/decodergroupbox.hpp
		pv/widgets/decodermenu.hpp
	)
endif()

if(WIN32)
	# Use the sigrok icon for the pulseview.exe executable.
	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	enable_language(RC)
	list(APPEND pulseview_SOURCES pulseviewico.rc)
endif()

if(ANDROID)
	list(APPEND pulseview_SOURCES android/loghandler.cpp)
endif()

if(Qt5Core_FOUND)
	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
else()
	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	include(${QT_USE_FILE})
endif()

#===============================================================================
#= Global Definitions
#-------------------------------------------------------------------------------

add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
add_definitions(-D__STDC_LIMIT_MACROS)
add_definitions(-Wall -Wextra)
add_definitions(-std=c++11)

if(ENABLE_DECODE)
	add_definitions(-DENABLE_DECODE)
endif()

if(NOT DISABLE_WERROR)
	add_definitions(-Werror)
endif()

if(ENABLE_SIGNALS)
	add_definitions(-DENABLE_SIGNALS)
endif()

#===============================================================================
#= Global Include Directories
#-------------------------------------------------------------------------------

include_directories(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${Boost_INCLUDE_DIRS}
	${QT_INCLUDE_DIRS}
)

if(STATIC_PKGDEPS_LIBS)
	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
else()
	include_directories(${PKGDEPS_INCLUDE_DIRS})
endif()

#===============================================================================
#= Linker Configuration
#-------------------------------------------------------------------------------

link_directories(${Boost_LIBRARY_DIRS})

set(PULSEVIEW_LINK_LIBS
	${Boost_LIBRARIES}
	${QT_LIBRARIES}
	${CMAKE_THREAD_LIBS_INIT}
)

if(STATIC_PKGDEPS_LIBS)
	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
if(WIN32)
	# Workaround for a MinGW linking issue.
	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
endif()
else()
	link_directories(${PKGDEPS_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
endif()

if(WIN32)
	# On Windows we need to statically link the libqsvg imageformat
	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	add_definitions(-DQT_STATICPLUGIN)
	link_directories("${QT_PLUGINS_DIR}/imageformats")
	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
endif()

if(ANDROID)
	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
endif()

if(ANDROID)
add_library(${PROJECT_NAME} SHARED
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
else()
add_executable(${PROJECT_NAME}
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
endif()

target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})

if(WIN32)
	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
endif()

if(ENABLE_COTIRE)
	include(cotire)
	cotire(${PROJECT_NAME})
endif()

#===============================================================================
#= Installation
#-------------------------------------------------------------------------------

# Install the executable.
install(TARGETS ${PROJECT_NAME} DESTINATION bin/)

# Install the manpage.
install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)

#===============================================================================
#= Packaging (handled by CPack)
#-------------------------------------------------------------------------------

set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
set(CPACK_SOURCE_PACKAGE_FILE_NAME
	"${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
set(CPACK_SOURCE_GENERATOR "TGZ")

include(CPack)

#===============================================================================
#= Tests
#-------------------------------------------------------------------------------

if(ENABLE_TESTS)
	add_subdirectory(test)
	enable_testing()
	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
endif()
Commit	Line	Data
	1	##
	2	## This file is part of the PulseView project.
	3	##
	4	## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
	5	## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 2 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
	21	cmake_minimum_required(VERSION 2.8.6)
	22
	23	include(FindPkgConfig)
	24	include(GNUInstallDirs)
	25
	26	project(pulseview)
	27
	28	list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
	29
	30	#===============================================================================
	31	#= User Options
	32	#-------------------------------------------------------------------------------
	33
	34	option(DISABLE_WERROR "Build without -Werror" FALSE)
	35	option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
	36	option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
	37	option(ENABLE_COTIRE "Enable cotire" FALSE)
	38	option(ENABLE_TESTS "Enable unit tests" FALSE)
	39	option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
	40	option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
	41
	42	if(WIN32)
	43	# On Windows/MinGW we need to statically link to libraries.
	44	# This option is user configurable, but enable it by default on win32.
	45	set(STATIC_PKGDEPS_LIBS TRUE)
	46
	47	# For boost-thread we need two additional settings on win32:
	48	set(Boost_USE_STATIC_LIBS ON)
	49	add_definitions(-DBOOST_THREAD_USE_LIB)
	50
	51	# Windows does not support UNIX signals.
	52	set(ENABLE_SIGNALS FALSE)
	53	endif()
	54
	55	if(NOT CMAKE_BUILD_TYPE)
	56	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	57	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	58	FORCE)
	59	endif()
	60
	61	#===============================================================================
	62	#= Dependencies
	63	#-------------------------------------------------------------------------------
	64
	65	list(APPEND PKGDEPS libsigrokxx>=0.3.0)
	66
	67	if(ENABLE_DECODE)
	68	list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
	69	endif()
	70
	71	if(ANDROID)
	72	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
	73	endif()
	74
	75	find_package(PkgConfig)
	76	pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
	77
	78	if(FORCE_QT4)
	79	set(Qt5Core_FOUND FALSE)
	80	else()
	81	find_package(Qt5Core QUIET)
	82	endif()
	83
	84	if(Qt5Core_FOUND)
	85	message("-- Using Qt5")
	86	find_package(Qt5Widgets REQUIRED)
	87	find_package(Qt5Gui REQUIRED)
	88	find_package(Qt5Svg REQUIRED)
	89	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
	90	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
	91	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
	92	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
	93	else()
	94	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
	95	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
	96	endif()
	97
	98	if(WIN32)
	99	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	100	# The library is named libboost_thread_win32* (not libboost_thread*).
	101	find_package(Boost 1.42 COMPONENTS filesystem system thread_win32 REQUIRED)
	102	else()
	103	find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
	104	endif()
	105
	106	# Find the platform's thread library (needed for C++11 threads).
	107	# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
	108	find_package(Threads REQUIRED)
	109
	110	#===============================================================================
	111	#= System Introspection
	112	#-------------------------------------------------------------------------------
	113
	114	include(memaccess)
	115	memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
	116
	117	#===============================================================================
	118	#= Config Header
	119	#-------------------------------------------------------------------------------
	120
	121	set(PV_TITLE PulseView)
	122	set(PV_DESCRIPTION "A GUI for sigrok")
	123
	124	set(PV_VERSION_MAJOR 0)
	125	set(PV_VERSION_MINOR 2)
	126	set(PV_VERSION_MICRO 0)
	127	set(PV_VERSION_STRING
	128	${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
	129	)
	130
	131	configure_file (
	132	${PROJECT_SOURCE_DIR}/config.h.in
	133	${PROJECT_BINARY_DIR}/config.h
	134	)
	135
	136	#===============================================================================
	137	#= Sources
	138	#-------------------------------------------------------------------------------
	139
	140	set(pulseview_SOURCES
	141	main.cpp
	142	pv/application.cpp
	143	pv/devicemanager.cpp
	144	pv/mainwindow.cpp
	145	pv/sigsession.cpp
	146	pv/storesession.cpp
	147	pv/util.cpp
	148	pv/data/analog.cpp
	149	pv/data/analogsnapshot.cpp
	150	pv/data/logic.cpp
	151	pv/data/logicsnapshot.cpp
	152	pv/data/signaldata.cpp
	153	pv/data/snapshot.cpp
	154	pv/dialogs/about.cpp
	155	pv/dialogs/connect.cpp
	156	pv/dialogs/storeprogress.cpp
	157	pv/popups/deviceoptions.cpp
	158	pv/popups/channels.cpp
	159	pv/prop/bool.cpp
	160	pv/prop/double.cpp
	161	pv/prop/enum.cpp
	162	pv/prop/int.cpp
	163	pv/prop/property.cpp
	164	pv/prop/string.cpp
	165	pv/prop/binding/binding.cpp
	166	pv/prop/binding/deviceoptions.cpp
	167	pv/toolbars/samplingbar.cpp
	168	pv/view/analogsignal.cpp
	169	pv/view/cursor.cpp
	170	pv/view/cursorheader.cpp
	171	pv/view/cursorpair.cpp
	172	pv/view/header.cpp
	173	pv/view/marginwidget.cpp
	174	pv/view/logicsignal.cpp
	175	pv/view/rowitem.cpp
	176	pv/view/rowitemowner.cpp
	177	pv/view/ruler.cpp
	178	pv/view/selectableitem.cpp
	179	pv/view/signal.cpp
	180	pv/view/timemarker.cpp
	181	pv/view/trace.cpp
	182	pv/view/tracegroup.cpp
	183	pv/view/tracepalette.cpp
	184	pv/view/view.cpp
	185	pv/view/viewport.cpp
	186	pv/widgets/colourbutton.cpp
	187	pv/widgets/colourpopup.cpp
	188	pv/widgets/popup.cpp
	189	pv/widgets/popuptoolbutton.cpp
	190	pv/widgets/sweeptimingwidget.cpp
	191	pv/widgets/wellarray.cpp
	192	)
	193
	194	# This list includes only QObject derived class headers.
	195	set(pulseview_HEADERS
	196	pv/mainwindow.hpp
	197	pv/sigsession.hpp
	198	pv/storesession.hpp
	199	pv/dialogs/about.hpp
	200	pv/dialogs/connect.hpp
	201	pv/dialogs/storeprogress.hpp
	202	pv/popups/channels.hpp
	203	pv/popups/deviceoptions.hpp
	204	pv/prop/bool.hpp
	205	pv/prop/double.hpp
	206	pv/prop/enum.hpp
	207	pv/prop/int.hpp
	208	pv/prop/property.hpp
	209	pv/prop/string.hpp
	210	pv/prop/binding/deviceoptions.hpp
	211	pv/toolbars/samplingbar.hpp
	212	pv/view/cursor.hpp
	213	pv/view/cursorheader.hpp
	214	pv/view/header.hpp
	215	pv/view/logicsignal.hpp
	216	pv/view/marginwidget.hpp
	217	pv/view/rowitem.hpp
	218	pv/view/ruler.hpp
	219	pv/view/selectableitem.hpp
	220	pv/view/signal.hpp
	221	pv/view/timemarker.hpp
	222	pv/view/trace.hpp
	223	pv/view/tracegroup.hpp
	224	pv/view/view.hpp
	225	pv/view/viewport.hpp
	226	pv/widgets/colourbutton.hpp
	227	pv/widgets/colourpopup.hpp
	228	pv/widgets/popup.hpp
	229	pv/widgets/popuptoolbutton.hpp
	230	pv/widgets/sweeptimingwidget.hpp
	231	pv/widgets/wellarray.hpp
	232	)
	233
	234	set(pulseview_FORMS
	235	pv/dialogs/about.ui
	236	)
	237
	238	set(pulseview_RESOURCES
	239	pulseview.qrc
	240	)
	241
	242	if(ENABLE_SIGNALS)
	243	list(APPEND pulseview_SOURCES signalhandler.cpp)
	244	list(APPEND pulseview_HEADERS signalhandler.hpp)
	245	endif()
	246
	247	if(ENABLE_DECODE)
	248	list(APPEND pulseview_SOURCES
	249	pv/data/decoderstack.cpp
	250	pv/data/decode/annotation.cpp
	251	pv/data/decode/decoder.cpp
	252	pv/data/decode/row.cpp
	253	pv/data/decode/rowdata.cpp
	254	pv/prop/binding/decoderoptions.cpp
	255	pv/view/decodetrace.cpp
	256	pv/widgets/decodergroupbox.cpp
	257	pv/widgets/decodermenu.cpp
	258	)
	259
	260	list(APPEND pulseview_HEADERS
	261	pv/data/decoderstack.hpp
	262	pv/view/decodetrace.hpp
	263	pv/widgets/decodergroupbox.hpp
	264	pv/widgets/decodermenu.hpp
	265	)
	266	endif()
	267
	268	if(WIN32)
	269	# Use the sigrok icon for the pulseview.exe executable.
	270	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	271	enable_language(RC)
	272	list(APPEND pulseview_SOURCES pulseviewico.rc)
	273	endif()
	274
	275	if(ANDROID)
	276	list(APPEND pulseview_SOURCES android/loghandler.cpp)
	277	endif()
	278
	279	if(Qt5Core_FOUND)
	280	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	281	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	282	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	283	else()
	284	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	285	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	286	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	287	include(${QT_USE_FILE})
	288	endif()
	289
	290	#===============================================================================
	291	#= Global Definitions
	292	#-------------------------------------------------------------------------------
	293
	294	add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
	295	add_definitions(-D__STDC_LIMIT_MACROS)
	296	add_definitions(-Wall -Wextra)
	297	add_definitions(-std=c++11)
	298
	299	if(ENABLE_DECODE)
	300	add_definitions(-DENABLE_DECODE)
	301	endif()
	302
	303	if(NOT DISABLE_WERROR)
	304	add_definitions(-Werror)
	305	endif()
	306
	307	if(ENABLE_SIGNALS)
	308	add_definitions(-DENABLE_SIGNALS)
	309	endif()
	310
	311	#===============================================================================
	312	#= Global Include Directories
	313	#-------------------------------------------------------------------------------
	314
	315	include_directories(
	316	${CMAKE_CURRENT_BINARY_DIR}
	317	${CMAKE_CURRENT_SOURCE_DIR}
	318	${Boost_INCLUDE_DIRS}
	319	${QT_INCLUDE_DIRS}
	320	)
	321
	322	if(STATIC_PKGDEPS_LIBS)
	323	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
	324	else()
	325	include_directories(${PKGDEPS_INCLUDE_DIRS})
	326	endif()
	327
	328	#===============================================================================
	329	#= Linker Configuration
	330	#-------------------------------------------------------------------------------
	331
	332	link_directories(${Boost_LIBRARY_DIRS})
	333
	334	set(PULSEVIEW_LINK_LIBS
	335	${Boost_LIBRARIES}
	336	${QT_LIBRARIES}
	337	${CMAKE_THREAD_LIBS_INIT}
	338	)
	339
	340	if(STATIC_PKGDEPS_LIBS)
	341	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	342	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
	343	if(WIN32)
	344	# Workaround for a MinGW linking issue.
	345	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
	346	endif()
	347	else()
	348	link_directories(${PKGDEPS_LIBRARY_DIRS})
	349	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
	350	endif()
	351
	352	if(WIN32)
	353	# On Windows we need to statically link the libqsvg imageformat
	354	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	355	add_definitions(-DQT_STATICPLUGIN)
	356	link_directories("${QT_PLUGINS_DIR}/imageformats")
	357	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
	358	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
	359	endif()
	360
	361	if(ANDROID)
	362	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
	363	endif()
	364
	365	if(ANDROID)
	366	add_library(${PROJECT_NAME} SHARED
	367	${pulseview_SOURCES}
	368	${pulseview_HEADERS_MOC}
	369	${pulseview_FORMS_HEADERS}
	370	${pulseview_RESOURCES_RCC}
	371	)
	372	else()
	373	add_executable(${PROJECT_NAME}
	374	${pulseview_SOURCES}
	375	${pulseview_HEADERS_MOC}
	376	${pulseview_FORMS_HEADERS}
	377	${pulseview_RESOURCES_RCC}
	378	)
	379	endif()
	380
	381	target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
	382
	383	if(WIN32)
	384	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	385	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
	386	endif()
	387
	388	if(ENABLE_COTIRE)
	389	include(cotire)
	390	cotire(${PROJECT_NAME})
	391	endif()
	392
	393	#===============================================================================
	394	#= Installation
	395	#-------------------------------------------------------------------------------
	396
	397	# Install the executable.
	398	install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
	399
	400	# Install the manpage.
	401	install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
	402
	403	#===============================================================================
	404	#= Packaging (handled by CPack)
	405	#-------------------------------------------------------------------------------
	406
	407	set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
	408	set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
	409	set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
	410	set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
	411	set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
	412	set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
	413	set(CPACK_SOURCE_PACKAGE_FILE_NAME
	414	"${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
	415	set(CPACK_SOURCE_GENERATOR "TGZ")
	416
	417	include(CPack)
	418
	419	#===============================================================================
	420	#= Tests
	421	#-------------------------------------------------------------------------------
	422
	423	if(ENABLE_TESTS)
	424	add_subdirectory(test)
	425	enable_testing()
	426	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
	427	endif()