[pulseview.git] / CMakeLists.txt

##
## This file is part of the PulseView project.
##
## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 2 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

cmake_minimum_required(VERSION 2.8.6)

include(FindPkgConfig)
include(GNUInstallDirs)

project(pulseview)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")

#===============================================================================
#= User Options
#-------------------------------------------------------------------------------

option(DISABLE_WERROR "Build without -Werror" FALSE)
option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
option(ENABLE_TESTS "Enable unit tests" FALSE)
option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)

if(WIN32)
	# On Windows/MinGW we need to statically link to libraries.
	# This option is user configurable, but enable it by default on win32.
	set(STATIC_PKGDEPS_LIBS TRUE)

	# For boost-thread we need two additional settings on win32:
	set(Boost_USE_STATIC_LIBS ON)
	add_definitions(-DBOOST_THREAD_USE_LIB)

	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	# The library is named libboost_thread_win32* (not libboost_thread*).
	set(Boost_THREADAPI win32)

	# Windows does not support UNIX signals.
	set(ENABLE_SIGNALS FALSE)
endif()

if(NOT CMAKE_BUILD_TYPE)
	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	FORCE)
endif()

#===============================================================================
#= Dependencies
#-------------------------------------------------------------------------------

list(APPEND PKGDEPS libsigrokcxx>=0.4.0)

if(ENABLE_DECODE)
	list(APPEND PKGDEPS libsigrokdecode>=0.4.0)
endif()

if(ANDROID)
	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
endif()

find_package(PkgConfig)
pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})

if(FORCE_QT4)
	set(Qt5Core_FOUND FALSE)
else()
	find_package(Qt5Core QUIET)
endif()

if(Qt5Core_FOUND)
	message("-- Using Qt5")
	find_package(Qt5Widgets REQUIRED)
	find_package(Qt5Gui REQUIRED)
	find_package(Qt5Svg REQUIRED)
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
else()
	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
endif()

if(ENABLE_TESTS)
	find_package(Boost 1.48 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
else()
	find_package(Boost 1.48 COMPONENTS filesystem system thread REQUIRED)
endif()

# Find the platform's thread library (needed for C++11 threads).
# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
find_package(Threads REQUIRED)

#===============================================================================
#= System Introspection
#-------------------------------------------------------------------------------

include(memaccess)
memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)

#===============================================================================
#= Config Header
#-------------------------------------------------------------------------------

set(PV_TITLE PulseView)
set(PV_DESCRIPTION "A GUI for sigrok")
set(PV_VERSION_STRING "0.3.0")

include(GetGitRevisionDescription)
git_describe(PV_TAG_VERSION_STRING --tags --dirty)

if(NOT PV_TAG_VERSION_STRING AND EXISTS "${PROJECT_SOURCE_DIR}/VERSION")
	# Read the version from a file that is distributed with
	# the source package (see writepackageversion.cmake).
	file(STRINGS "${PROJECT_SOURCE_DIR}/VERSION" PV_TAG_VERSION_STRING LIMIT_COUNT 1)
endif()

if(PV_TAG_VERSION_STRING MATCHES
		"^pulseview-([0-9]+\\.[0-9]+\\.[0-9]+)(-[0-9a-z]+)?(-g[-0-9a-z]+)?$")
	set(PV_TAG_VERSION ${CMAKE_MATCH_1})
	set(PV_TAG_PATCHLEVEL ${CMAKE_MATCH_2})
	set(PV_TAG_REVHASH ${CMAKE_MATCH_3})

	if(PV_VERSION_STRING VERSION_GREATER ${PV_TAG_VERSION})
		# Tagged version older than current one: indicate pre-release.
		set(PV_VERSION_STRING "${PV_VERSION_STRING}-pre${PV_TAG_REVHASH}")
	else()
		# For post-release changes, indicate the patch level.
		set(PV_VERSION_STRING "${PV_TAG_VERSION}${PV_TAG_PATCHLEVEL}${PV_TAG_REVHASH}")
	endif()
endif()

if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
	set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
	set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
	set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
	set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
endif()

message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")

configure_file (
	${PROJECT_SOURCE_DIR}/config.h.in
	${PROJECT_BINARY_DIR}/config.h
)

#===============================================================================
#= Sources
#-------------------------------------------------------------------------------

set(pulseview_SOURCES
	main.cpp
	pv/application.cpp
	pv/devicemanager.cpp
	pv/mainwindow.cpp
	pv/session.cpp
	pv/storesession.cpp
	pv/util.cpp
	pv/binding/binding.cpp
	pv/binding/inputoutput.cpp
	pv/binding/device.cpp
	pv/data/analog.cpp
	pv/data/analogsegment.cpp
	pv/data/logic.cpp
	pv/data/logicsegment.cpp
	pv/data/signaldata.cpp
	pv/data/segment.cpp
	pv/devices/device.cpp
	pv/devices/file.cpp
	pv/devices/hardwaredevice.cpp
	pv/devices/inputfile.cpp
	pv/devices/sessionfile.cpp
	pv/dialogs/about.cpp
	pv/dialogs/connect.cpp
	pv/dialogs/inputoutputoptions.cpp
	pv/dialogs/storeprogress.cpp
	pv/popups/deviceoptions.cpp
	pv/popups/channels.cpp
	pv/prop/bool.cpp
	pv/prop/double.cpp
	pv/prop/enum.cpp
	pv/prop/int.cpp
	pv/prop/property.cpp
	pv/prop/string.cpp
	pv/toolbars/mainbar.cpp
	pv/view/analogsignal.cpp
	pv/view/cursor.cpp
	pv/view/cursorpair.cpp
	pv/view/flag.cpp
	pv/view/header.cpp
	pv/view/marginwidget.cpp
	pv/view/logicsignal.cpp
	pv/view/rowitem.cpp
	pv/view/ruler.cpp
	pv/view/signal.cpp
	pv/view/timeitem.cpp
	pv/view/timemarker.cpp
	pv/view/trace.cpp
	pv/view/tracegroup.cpp
	pv/view/tracepalette.cpp
	pv/view/tracetreeitem.cpp
	pv/view/tracetreeitemowner.cpp
	pv/view/view.cpp
	pv/view/viewitem.cpp
	pv/view/viewitemowner.cpp
	pv/view/viewitempaintparams.cpp
	pv/view/viewport.cpp
	pv/view/viewwidget.cpp
	pv/widgets/colourbutton.cpp
	pv/widgets/colourpopup.cpp
	pv/widgets/devicetoolbutton.cpp
	pv/widgets/exportmenu.cpp
	pv/widgets/hidingmenubar.cpp
	pv/widgets/importmenu.cpp
	pv/widgets/popup.cpp
	pv/widgets/popuptoolbutton.cpp
	pv/widgets/sweeptimingwidget.cpp
	pv/widgets/timestampspinbox.cpp
	pv/widgets/wellarray.cpp
)

# This list includes only QObject derived class headers.
set(pulseview_HEADERS
	pv/mainwindow.hpp
	pv/session.hpp
	pv/storesession.hpp
	pv/binding/device.hpp
	pv/dialogs/about.hpp
	pv/dialogs/connect.hpp
	pv/dialogs/inputoutputoptions.hpp
	pv/dialogs/storeprogress.hpp
	pv/popups/channels.hpp
	pv/popups/deviceoptions.hpp
	pv/prop/bool.hpp
	pv/prop/double.hpp
	pv/prop/enum.hpp
	pv/prop/int.hpp
	pv/prop/property.hpp
	pv/prop/string.hpp
	pv/toolbars/mainbar.hpp
	pv/view/cursor.hpp
	pv/view/flag.hpp
	pv/view/header.hpp
	pv/view/logicsignal.hpp
	pv/view/marginwidget.hpp
	pv/view/rowitem.hpp
	pv/view/ruler.hpp
	pv/view/signal.hpp
	pv/view/timeitem.hpp
	pv/view/timemarker.hpp
	pv/view/trace.hpp
	pv/view/tracegroup.hpp
	pv/view/tracetreeitem.hpp
	pv/view/view.hpp
	pv/view/viewitem.hpp
	pv/view/viewport.hpp
	pv/view/viewwidget.hpp
	pv/widgets/colourbutton.hpp
	pv/widgets/colourpopup.hpp
	pv/widgets/devicetoolbutton.hpp
	pv/widgets/exportmenu.hpp
	pv/widgets/hidingmenubar.hpp
	pv/widgets/importmenu.hpp
	pv/widgets/popup.hpp
	pv/widgets/popuptoolbutton.hpp
	pv/widgets/sweeptimingwidget.hpp
	pv/widgets/timestampspinbox.hpp
	pv/widgets/wellarray.hpp
)

set(pulseview_FORMS
	pv/dialogs/about.ui
)

set(pulseview_RESOURCES
	pulseview.qrc
)

if(ENABLE_SIGNALS)
	list(APPEND pulseview_SOURCES signalhandler.cpp)
	list(APPEND pulseview_HEADERS signalhandler.hpp)
endif()

if(ENABLE_DECODE)
	list(APPEND pulseview_SOURCES
		pv/binding/decoder.cpp
		pv/data/decoderstack.cpp
		pv/data/decode/annotation.cpp
		pv/data/decode/decoder.cpp
		pv/data/decode/row.cpp
		pv/data/decode/rowdata.cpp
		pv/view/decodetrace.cpp
		pv/widgets/decodergroupbox.cpp
		pv/widgets/decodermenu.cpp
	)

	list(APPEND pulseview_HEADERS
		pv/data/decoderstack.hpp
		pv/view/decodetrace.hpp
		pv/widgets/decodergroupbox.hpp
		pv/widgets/decodermenu.hpp
	)
endif()

if(WIN32)
	# Use the sigrok icon for the pulseview.exe executable.
	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	enable_language(RC)
	list(APPEND pulseview_SOURCES pulseviewico.rc)
endif()

if(ANDROID)
	list(APPEND pulseview_SOURCES
		android/assetreader.cpp
		android/loghandler.cpp
	)
endif()

if(Qt5Core_FOUND)
	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
else()
	# Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
	# https://bugreports.qt.io/browse/QTBUG-22829
	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
		OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	include(${QT_USE_FILE})
endif()

#===============================================================================
#= Global Definitions
#-------------------------------------------------------------------------------

add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
add_definitions(-D__STDC_LIMIT_MACROS)
add_definitions(-Wall -Wextra)
add_definitions(-std=c++11)

if(ENABLE_DECODE)
	add_definitions(-DENABLE_DECODE)
endif()

if(NOT DISABLE_WERROR)
	add_definitions(-Werror)
endif()

if(ENABLE_SIGNALS)
	add_definitions(-DENABLE_SIGNALS)
endif()

#===============================================================================
#= Global Include Directories
#-------------------------------------------------------------------------------

include_directories(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${Boost_INCLUDE_DIRS}
	${QT_INCLUDE_DIRS}
)

if(STATIC_PKGDEPS_LIBS)
	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
else()
	include_directories(${PKGDEPS_INCLUDE_DIRS})
endif()

#===============================================================================
#= Linker Configuration
#-------------------------------------------------------------------------------

link_directories(${Boost_LIBRARY_DIRS})

set(PULSEVIEW_LINK_LIBS
	${Boost_LIBRARIES}
	${QT_LIBRARIES}
	${CMAKE_THREAD_LIBS_INIT}
)

if(STATIC_PKGDEPS_LIBS)
	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
if(WIN32)
	# Workaround for a MinGW linking issue.
	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
endif()
else()
	link_directories(${PKGDEPS_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
endif()

if(WIN32)
	# On Windows we need to statically link the libqsvg imageformat
	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	add_definitions(-DQT_STATICPLUGIN)
	link_directories("${QT_PLUGINS_DIR}/imageformats")
	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
endif()

if(ANDROID)
	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
endif()

if(ANDROID)
add_library(${PROJECT_NAME} SHARED
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
else()
add_executable(${PROJECT_NAME}
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
endif()

target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})

if(WIN32)
	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
endif()

#===============================================================================
#= Installation
#-------------------------------------------------------------------------------

# Install the executable.
install(TARGETS ${PROJECT_NAME} DESTINATION bin/)

# Install the manpage.
install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)

# Generate Windows installer script.
configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)

#===============================================================================
#= Packaging (handled by CPack)
#-------------------------------------------------------------------------------

set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
set(CPACK_SOURCE_GENERATOR "TGZ")
set(CPACK_INSTALL_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/CMake/writepackageversion.cmake)

include(CPack)

#===============================================================================
#= Tests
#-------------------------------------------------------------------------------

if(ENABLE_TESTS)
	add_subdirectory(test)
	enable_testing()
	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
endif()
Commit	Line	Data
	1	##
	2	## This file is part of the PulseView project.
	3	##
	4	## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
	5	## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 2 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
	21	cmake_minimum_required(VERSION 2.8.6)
	22
	23	include(FindPkgConfig)
	24	include(GNUInstallDirs)
	25
	26	project(pulseview)
	27
	28	list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
	29
	30	#===============================================================================
	31	#= User Options
	32	#-------------------------------------------------------------------------------
	33
	34	option(DISABLE_WERROR "Build without -Werror" FALSE)
	35	option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
	36	option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
	37	option(ENABLE_TESTS "Enable unit tests" FALSE)
	38	option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
	39	option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
	40
	41	if(WIN32)
	42	# On Windows/MinGW we need to statically link to libraries.
	43	# This option is user configurable, but enable it by default on win32.
	44	set(STATIC_PKGDEPS_LIBS TRUE)
	45
	46	# For boost-thread we need two additional settings on win32:
	47	set(Boost_USE_STATIC_LIBS ON)
	48	add_definitions(-DBOOST_THREAD_USE_LIB)
	49
	50	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	51	# The library is named libboost_thread_win32* (not libboost_thread*).
	52	set(Boost_THREADAPI win32)
	53
	54	# Windows does not support UNIX signals.
	55	set(ENABLE_SIGNALS FALSE)
	56	endif()
	57
	58	if(NOT CMAKE_BUILD_TYPE)
	59	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	60	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	61	FORCE)
	62	endif()
	63
	64	#===============================================================================
	65	#= Dependencies
	66	#-------------------------------------------------------------------------------
	67
	68	list(APPEND PKGDEPS libsigrokcxx>=0.4.0)
	69
	70	if(ENABLE_DECODE)
	71	list(APPEND PKGDEPS libsigrokdecode>=0.4.0)
	72	endif()
	73
	74	if(ANDROID)
	75	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
	76	endif()
	77
	78	find_package(PkgConfig)
	79	pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
	80
	81	if(FORCE_QT4)
	82	set(Qt5Core_FOUND FALSE)
	83	else()
	84	find_package(Qt5Core QUIET)
	85	endif()
	86
	87	if(Qt5Core_FOUND)
	88	message("-- Using Qt5")
	89	find_package(Qt5Widgets REQUIRED)
	90	find_package(Qt5Gui REQUIRED)
	91	find_package(Qt5Svg REQUIRED)
	92	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
	93	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
	94	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
	95	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
	96	else()
	97	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
	98	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
	99	endif()
	100
	101	if(ENABLE_TESTS)
	102	find_package(Boost 1.48 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
	103	else()
	104	find_package(Boost 1.48 COMPONENTS filesystem system thread REQUIRED)
	105	endif()
	106
	107	# Find the platform's thread library (needed for C++11 threads).
	108	# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
	109	find_package(Threads REQUIRED)
	110
	111	#===============================================================================
	112	#= System Introspection
	113	#-------------------------------------------------------------------------------
	114
	115	include(memaccess)
	116	memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
	117
	118	#===============================================================================
	119	#= Config Header
	120	#-------------------------------------------------------------------------------
	121
	122	set(PV_TITLE PulseView)
	123	set(PV_DESCRIPTION "A GUI for sigrok")
	124	set(PV_VERSION_STRING "0.3.0")
	125
	126	include(GetGitRevisionDescription)
	127	git_describe(PV_TAG_VERSION_STRING --tags --dirty)
	128
	129	if(NOT PV_TAG_VERSION_STRING AND EXISTS "${PROJECT_SOURCE_DIR}/VERSION")
	130	# Read the version from a file that is distributed with
	131	# the source package (see writepackageversion.cmake).
	132	file(STRINGS "${PROJECT_SOURCE_DIR}/VERSION" PV_TAG_VERSION_STRING LIMIT_COUNT 1)
	133	endif()
	134
	135	if(PV_TAG_VERSION_STRING MATCHES
	136	"^pulseview-([0-9]+\\.[0-9]+\\.[0-9]+)(-[0-9a-z]+)?(-g[-0-9a-z]+)?$")
	137	set(PV_TAG_VERSION ${CMAKE_MATCH_1})
	138	set(PV_TAG_PATCHLEVEL ${CMAKE_MATCH_2})
	139	set(PV_TAG_REVHASH ${CMAKE_MATCH_3})
	140
	141	if(PV_VERSION_STRING VERSION_GREATER ${PV_TAG_VERSION})
	142	# Tagged version older than current one: indicate pre-release.
	143	set(PV_VERSION_STRING "${PV_VERSION_STRING}-pre${PV_TAG_REVHASH}")
	144	else()
	145	# For post-release changes, indicate the patch level.
	146	set(PV_VERSION_STRING "${PV_TAG_VERSION}${PV_TAG_PATCHLEVEL}${PV_TAG_REVHASH}")
	147	endif()
	148	endif()
	149
	150	if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
	151	set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
	152	set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
	153	set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
	154	set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
	155	endif()
	156
	157	message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
	158
	159	configure_file (
	160	${PROJECT_SOURCE_DIR}/config.h.in
	161	${PROJECT_BINARY_DIR}/config.h
	162	)
	163
	164	#===============================================================================
	165	#= Sources
	166	#-------------------------------------------------------------------------------
	167
	168	set(pulseview_SOURCES
	169	main.cpp
	170	pv/application.cpp
	171	pv/devicemanager.cpp
	172	pv/mainwindow.cpp
	173	pv/session.cpp
	174	pv/storesession.cpp
	175	pv/util.cpp
	176	pv/binding/binding.cpp
	177	pv/binding/inputoutput.cpp
	178	pv/binding/device.cpp
	179	pv/data/analog.cpp
	180	pv/data/analogsegment.cpp
	181	pv/data/logic.cpp
	182	pv/data/logicsegment.cpp
	183	pv/data/signaldata.cpp
	184	pv/data/segment.cpp
	185	pv/devices/device.cpp
	186	pv/devices/file.cpp
	187	pv/devices/hardwaredevice.cpp
	188	pv/devices/inputfile.cpp
	189	pv/devices/sessionfile.cpp
	190	pv/dialogs/about.cpp
	191	pv/dialogs/connect.cpp
	192	pv/dialogs/inputoutputoptions.cpp
	193	pv/dialogs/storeprogress.cpp
	194	pv/popups/deviceoptions.cpp
	195	pv/popups/channels.cpp
	196	pv/prop/bool.cpp
	197	pv/prop/double.cpp
	198	pv/prop/enum.cpp
	199	pv/prop/int.cpp
	200	pv/prop/property.cpp
	201	pv/prop/string.cpp
	202	pv/toolbars/mainbar.cpp
	203	pv/view/analogsignal.cpp
	204	pv/view/cursor.cpp
	205	pv/view/cursorpair.cpp
	206	pv/view/flag.cpp
	207	pv/view/header.cpp
	208	pv/view/marginwidget.cpp
	209	pv/view/logicsignal.cpp
	210	pv/view/rowitem.cpp
	211	pv/view/ruler.cpp
	212	pv/view/signal.cpp
	213	pv/view/timeitem.cpp
	214	pv/view/timemarker.cpp
	215	pv/view/trace.cpp
	216	pv/view/tracegroup.cpp
	217	pv/view/tracepalette.cpp
	218	pv/view/tracetreeitem.cpp
	219	pv/view/tracetreeitemowner.cpp
	220	pv/view/view.cpp
	221	pv/view/viewitem.cpp
	222	pv/view/viewitemowner.cpp
	223	pv/view/viewitempaintparams.cpp
	224	pv/view/viewport.cpp
	225	pv/view/viewwidget.cpp
	226	pv/widgets/colourbutton.cpp
	227	pv/widgets/colourpopup.cpp
	228	pv/widgets/devicetoolbutton.cpp
	229	pv/widgets/exportmenu.cpp
	230	pv/widgets/hidingmenubar.cpp
	231	pv/widgets/importmenu.cpp
	232	pv/widgets/popup.cpp
	233	pv/widgets/popuptoolbutton.cpp
	234	pv/widgets/sweeptimingwidget.cpp
	235	pv/widgets/timestampspinbox.cpp
	236	pv/widgets/wellarray.cpp
	237	)
	238
	239	# This list includes only QObject derived class headers.
	240	set(pulseview_HEADERS
	241	pv/mainwindow.hpp
	242	pv/session.hpp
	243	pv/storesession.hpp
	244	pv/binding/device.hpp
	245	pv/dialogs/about.hpp
	246	pv/dialogs/connect.hpp
	247	pv/dialogs/inputoutputoptions.hpp
	248	pv/dialogs/storeprogress.hpp
	249	pv/popups/channels.hpp
	250	pv/popups/deviceoptions.hpp
	251	pv/prop/bool.hpp
	252	pv/prop/double.hpp
	253	pv/prop/enum.hpp
	254	pv/prop/int.hpp
	255	pv/prop/property.hpp
	256	pv/prop/string.hpp
	257	pv/toolbars/mainbar.hpp
	258	pv/view/cursor.hpp
	259	pv/view/flag.hpp
	260	pv/view/header.hpp
	261	pv/view/logicsignal.hpp
	262	pv/view/marginwidget.hpp
	263	pv/view/rowitem.hpp
	264	pv/view/ruler.hpp
	265	pv/view/signal.hpp
	266	pv/view/timeitem.hpp
	267	pv/view/timemarker.hpp
	268	pv/view/trace.hpp
	269	pv/view/tracegroup.hpp
	270	pv/view/tracetreeitem.hpp
	271	pv/view/view.hpp
	272	pv/view/viewitem.hpp
	273	pv/view/viewport.hpp
	274	pv/view/viewwidget.hpp
	275	pv/widgets/colourbutton.hpp
	276	pv/widgets/colourpopup.hpp
	277	pv/widgets/devicetoolbutton.hpp
	278	pv/widgets/exportmenu.hpp
	279	pv/widgets/hidingmenubar.hpp
	280	pv/widgets/importmenu.hpp
	281	pv/widgets/popup.hpp
	282	pv/widgets/popuptoolbutton.hpp
	283	pv/widgets/sweeptimingwidget.hpp
	284	pv/widgets/timestampspinbox.hpp
	285	pv/widgets/wellarray.hpp
	286	)
	287
	288	set(pulseview_FORMS
	289	pv/dialogs/about.ui
	290	)
	291
	292	set(pulseview_RESOURCES
	293	pulseview.qrc
	294	)
	295
	296	if(ENABLE_SIGNALS)
	297	list(APPEND pulseview_SOURCES signalhandler.cpp)
	298	list(APPEND pulseview_HEADERS signalhandler.hpp)
	299	endif()
	300
	301	if(ENABLE_DECODE)
	302	list(APPEND pulseview_SOURCES
	303	pv/binding/decoder.cpp
	304	pv/data/decoderstack.cpp
	305	pv/data/decode/annotation.cpp
	306	pv/data/decode/decoder.cpp
	307	pv/data/decode/row.cpp
	308	pv/data/decode/rowdata.cpp
	309	pv/view/decodetrace.cpp
	310	pv/widgets/decodergroupbox.cpp
	311	pv/widgets/decodermenu.cpp
	312	)
	313
	314	list(APPEND pulseview_HEADERS
	315	pv/data/decoderstack.hpp
	316	pv/view/decodetrace.hpp
	317	pv/widgets/decodergroupbox.hpp
	318	pv/widgets/decodermenu.hpp
	319	)
	320	endif()
	321
	322	if(WIN32)
	323	# Use the sigrok icon for the pulseview.exe executable.
	324	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	325	enable_language(RC)
	326	list(APPEND pulseview_SOURCES pulseviewico.rc)
	327	endif()
	328
	329	if(ANDROID)
	330	list(APPEND pulseview_SOURCES
	331	android/assetreader.cpp
	332	android/loghandler.cpp
	333	)
	334	endif()
	335
	336	if(Qt5Core_FOUND)
	337	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	338	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	339	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	340	else()
	341	# Workaroud for QTBUG-22829: -DBOOST_NEXT_PRIOR_HPP_INCLUDED.
	342	# https://bugreports.qt.io/browse/QTBUG-22829
	343	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS}
	344	OPTIONS -DBOOST_NEXT_PRIOR_HPP_INCLUDED)
	345	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	346	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	347	include(${QT_USE_FILE})
	348	endif()
	349
	350	#===============================================================================
	351	#= Global Definitions
	352	#-------------------------------------------------------------------------------
	353
	354	add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
	355	add_definitions(-D__STDC_LIMIT_MACROS)
	356	add_definitions(-Wall -Wextra)
	357	add_definitions(-std=c++11)
	358
	359	if(ENABLE_DECODE)
	360	add_definitions(-DENABLE_DECODE)
	361	endif()
	362
	363	if(NOT DISABLE_WERROR)
	364	add_definitions(-Werror)
	365	endif()
	366
	367	if(ENABLE_SIGNALS)
	368	add_definitions(-DENABLE_SIGNALS)
	369	endif()
	370
	371	#===============================================================================
	372	#= Global Include Directories
	373	#-------------------------------------------------------------------------------
	374
	375	include_directories(
	376	${CMAKE_CURRENT_BINARY_DIR}
	377	${CMAKE_CURRENT_SOURCE_DIR}
	378	${Boost_INCLUDE_DIRS}
	379	${QT_INCLUDE_DIRS}
	380	)
	381
	382	if(STATIC_PKGDEPS_LIBS)
	383	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
	384	else()
	385	include_directories(${PKGDEPS_INCLUDE_DIRS})
	386	endif()
	387
	388	#===============================================================================
	389	#= Linker Configuration
	390	#-------------------------------------------------------------------------------
	391
	392	link_directories(${Boost_LIBRARY_DIRS})
	393
	394	set(PULSEVIEW_LINK_LIBS
	395	${Boost_LIBRARIES}
	396	${QT_LIBRARIES}
	397	${CMAKE_THREAD_LIBS_INIT}
	398	)
	399
	400	if(STATIC_PKGDEPS_LIBS)
	401	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	402	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
	403	if(WIN32)
	404	# Workaround for a MinGW linking issue.
	405	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
	406	endif()
	407	else()
	408	link_directories(${PKGDEPS_LIBRARY_DIRS})
	409	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
	410	endif()
	411
	412	if(WIN32)
	413	# On Windows we need to statically link the libqsvg imageformat
	414	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	415	add_definitions(-DQT_STATICPLUGIN)
	416	link_directories("${QT_PLUGINS_DIR}/imageformats")
	417	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
	418	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
	419	endif()
	420
	421	if(ANDROID)
	422	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
	423	endif()
	424
	425	if(ANDROID)
	426	add_library(${PROJECT_NAME} SHARED
	427	${pulseview_SOURCES}
	428	${pulseview_HEADERS_MOC}
	429	${pulseview_FORMS_HEADERS}
	430	${pulseview_RESOURCES_RCC}
	431	)
	432	else()
	433	add_executable(${PROJECT_NAME}
	434	${pulseview_SOURCES}
	435	${pulseview_HEADERS_MOC}
	436	${pulseview_FORMS_HEADERS}
	437	${pulseview_RESOURCES_RCC}
	438	)
	439	endif()
	440
	441	target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
	442
	443	if(WIN32)
	444	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	445	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
	446	endif()
	447
	448	#===============================================================================
	449	#= Installation
	450	#-------------------------------------------------------------------------------
	451
	452	# Install the executable.
	453	install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
	454
	455	# Install the manpage.
	456	install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
	457
	458	# Generate Windows installer script.
	459	configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)
	460
	461	#===============================================================================
	462	#= Packaging (handled by CPack)
	463	#-------------------------------------------------------------------------------
	464
	465	set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
	466	set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
	467	set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
	468	set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
	469	set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
	470	set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
	471	set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
	472	set(CPACK_SOURCE_GENERATOR "TGZ")
	473	set(CPACK_INSTALL_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/CMake/writepackageversion.cmake)
	474
	475	include(CPack)
	476
	477	#===============================================================================
	478	#= Tests
	479	#-------------------------------------------------------------------------------
	480
	481	if(ENABLE_TESTS)
	482	add_subdirectory(test)
	483	enable_testing()
	484	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
	485	endif()