[pulseview.git] / CMakeLists.txt

##
## This file is part of the PulseView project.
##
## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 2 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

cmake_minimum_required(VERSION 2.8.12)

include(GNUInstallDirs)

project(pulseview)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")

#===============================================================================
#= User Options
#-------------------------------------------------------------------------------

option(DISABLE_WERROR "Build without -Werror" FALSE)
option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
option(ENABLE_TESTS "Enable unit tests" TRUE)
option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)

if(WIN32)
	# On Windows/MinGW we need to statically link to libraries.
	# This option is user configurable, but enable it by default on win32.
	set(STATIC_PKGDEPS_LIBS TRUE)

	# Windows does not support UNIX signals.
	set(ENABLE_SIGNALS FALSE)
endif()

if(NOT CMAKE_BUILD_TYPE)
	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	FORCE)
endif()

#===============================================================================
#= Dependencies
#-------------------------------------------------------------------------------

list(APPEND PKGDEPS glib-2.0>=2.28.0)
list(APPEND PKGDEPS glibmm-2.4>=2.28.0)

list(APPEND PKGDEPS libsigrokcxx>=0.6.0)

if(ENABLE_DECODE)
	list(APPEND PKGDEPS libsigrokdecode>=0.6.0)
endif()

if(ANDROID)
	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
endif()

find_package(PkgConfig)
pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})

set(CMAKE_AUTOMOC TRUE)

find_package(Qt5 COMPONENTS Core Gui Widgets Svg REQUIRED)

if(WIN32)
	# MXE workaround: Use pkg-config to find Qt5 libs.
	# https://github.com/mxe/mxe/issues/1642
	# Not required (and doesn't work) on MSYS2.
	if(NOT DEFINED ENV{MSYSTEM})
		pkg_check_modules(QT5ALL REQUIRED Qt5Widgets Qt5Gui Qt5Svg)
	endif()
endif()

set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)

set(BOOSTCOMPS filesystem serialization system)
if(ENABLE_TESTS)
	list(APPEND BOOSTCOMPS unit_test_framework)
endif()
find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)

# Find the platform's thread library (needed for C++11 threads).
# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
find_package(Threads REQUIRED)

# Check for explicit link against libatomic
#
# Depending on the toolchain, linking a program using atomic functions may need
# "-latomic" explicitly passed to the linker
#
# This check first tests if atomics are available in the C-library, if not and
# libatomic exists, then it runs the same test with -latomic added to the
# linker flags.

# Helper for checking for atomics
function(check_working_cxx_atomics varname additional_lib)
  include(CheckCXXSourceCompiles)
  include(CMakePushCheckState)
  cmake_push_check_state()
  set(CMAKE_REQUIRED_FLAGS "-std=c++11")
  set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
  set(CMAKE_REQUIRED_QUIET 1)
  CHECK_CXX_SOURCE_COMPILES("
#include <atomic>
std::atomic<int> x;
int main() {
  return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
}
" ${varname})
  cmake_pop_check_state()
endfunction(check_working_cxx_atomics)

# First check if atomics work without the library.
# If not, check if the library exists, and atomics work with it.
check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
  message(STATUS "Atomics provided by the C-library - yes")
else()
  message(STATUS "Atomics provided by the C-library - no")
  find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
  if(LIBATOMIC_LIBRARY)
    check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
    if (HAVE_CXX_ATOMICS_WITH_LIB)
      message(STATUS "Atomics provided by libatomic - yes")
    else()
      message(STATUS "Atomics provided by libatomic - no")
      message(FATAL_ERROR "Compiler must support std::atomic!")
    endif()
  else()
    message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
  endif()
endif()

#===============================================================================
#= System Introspection
#-------------------------------------------------------------------------------

include(memaccess)
memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)

#===============================================================================
#= Config Header
#-------------------------------------------------------------------------------

set(PV_TITLE PulseView)
set(PV_VERSION_STRING "0.5.0")

set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})

include(GetGitRevisionDescription)

# Append the revision hash unless we are exactly on a tagged release.
git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
if(NOT PV_TAG_VERSION_STRING)
	get_git_head_revision(PV_REVSPEC PV_HASH)
	if(PV_HASH)
		string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
		set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
	endif()
endif()

if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
	set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
	set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
	set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
	set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
endif()

message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")

configure_file (
	${PROJECT_SOURCE_DIR}/config.h.in
	${PROJECT_BINARY_DIR}/config.h
)

#===============================================================================
#= Sources
#-------------------------------------------------------------------------------

set(pulseview_SOURCES
	main.cpp
	pv/application.cpp
	pv/devicemanager.cpp
	pv/globalsettings.cpp
	pv/mainwindow.cpp
	pv/session.cpp
	pv/storesession.cpp
	pv/util.cpp
	pv/binding/binding.cpp
	pv/binding/inputoutput.cpp
	pv/binding/device.cpp
	pv/data/analog.cpp
	pv/data/analogsegment.cpp
	pv/data/logic.cpp
	pv/data/logicsegment.cpp
	pv/data/signalbase.cpp
	pv/data/signaldata.cpp
	pv/data/segment.cpp
	pv/devices/device.cpp
	pv/devices/file.cpp
	pv/devices/hardwaredevice.cpp
	pv/devices/inputfile.cpp
	pv/devices/sessionfile.cpp
	pv/dialogs/connect.cpp
	pv/dialogs/inputoutputoptions.cpp
	pv/dialogs/settings.cpp
	pv/dialogs/storeprogress.cpp
	pv/popups/deviceoptions.cpp
	pv/popups/channels.cpp
	pv/prop/bool.cpp
	pv/prop/double.cpp
	pv/prop/enum.cpp
	pv/prop/int.cpp
	pv/prop/property.cpp
	pv/prop/string.cpp
	pv/toolbars/mainbar.cpp
	pv/views/trace/analogsignal.cpp
	pv/views/trace/cursor.cpp
	pv/views/trace/cursorpair.cpp
	pv/views/trace/flag.cpp
	pv/views/trace/header.cpp
	pv/views/trace/marginwidget.cpp
	pv/views/trace/logicsignal.cpp
	pv/views/trace/rowitem.cpp
	pv/views/trace/ruler.cpp
	pv/views/trace/signal.cpp
	pv/views/trace/timeitem.cpp
	pv/views/trace/timemarker.cpp
	pv/views/trace/trace.cpp
	pv/views/trace/tracegroup.cpp
	pv/views/trace/tracepalette.cpp
	pv/views/trace/tracetreeitem.cpp
	pv/views/trace/tracetreeitemowner.cpp
	pv/views/trace/triggermarker.cpp
	pv/views/trace/view.cpp
	pv/views/trace/viewitem.cpp
	pv/views/trace/viewitemowner.cpp
	pv/views/trace/viewitempaintparams.cpp
	pv/views/trace/viewport.cpp
	pv/views/trace/viewwidget.cpp
	pv/views/viewbase.cpp
	pv/views/trace/standardbar.cpp
	pv/widgets/colourbutton.cpp
	pv/widgets/colourpopup.cpp
	pv/widgets/devicetoolbutton.cpp
	pv/widgets/exportmenu.cpp
	pv/widgets/importmenu.cpp
	pv/widgets/popup.cpp
	pv/widgets/popuptoolbutton.cpp
	pv/widgets/sweeptimingwidget.cpp
	pv/widgets/timestampspinbox.cpp
	pv/widgets/wellarray.cpp
)

# This list includes only QObject derived class headers.
set(pulseview_HEADERS
	pv/globalsettings.hpp
	pv/mainwindow.hpp
	pv/session.hpp
	pv/storesession.hpp
	pv/binding/device.hpp
	pv/data/analog.hpp
	pv/data/analogsegment.hpp
	pv/data/logic.hpp
	pv/data/logicsegment.hpp
	pv/data/signalbase.hpp
	pv/dialogs/connect.hpp
	pv/dialogs/inputoutputoptions.hpp
	pv/dialogs/settings.hpp
	pv/dialogs/storeprogress.hpp
	pv/popups/channels.hpp
	pv/popups/deviceoptions.hpp
	pv/prop/bool.hpp
	pv/prop/double.hpp
	pv/prop/enum.hpp
	pv/prop/int.hpp
	pv/prop/property.hpp
	pv/prop/string.hpp
	pv/toolbars/mainbar.hpp
	pv/views/trace/analogsignal.hpp
	pv/views/trace/cursor.hpp
	pv/views/trace/flag.hpp
	pv/views/trace/header.hpp
	pv/views/trace/logicsignal.hpp
	pv/views/trace/marginwidget.hpp
	pv/views/trace/rowitem.hpp
	pv/views/trace/ruler.hpp
	pv/views/trace/signal.hpp
	pv/views/trace/timeitem.hpp
	pv/views/trace/timemarker.hpp
	pv/views/trace/trace.hpp
	pv/views/trace/tracegroup.hpp
	pv/views/trace/tracetreeitem.hpp
	pv/views/trace/triggermarker.hpp
	pv/views/trace/view.hpp
	pv/views/trace/viewitem.hpp
	pv/views/trace/viewport.hpp
	pv/views/trace/viewwidget.hpp
	pv/views/viewbase.hpp
	pv/views/trace/standardbar.hpp
	pv/widgets/colourbutton.hpp
	pv/widgets/colourpopup.hpp
	pv/widgets/devicetoolbutton.hpp
	pv/widgets/exportmenu.hpp
	pv/widgets/importmenu.hpp
	pv/widgets/popup.hpp
	pv/widgets/popuptoolbutton.hpp
	pv/widgets/sweeptimingwidget.hpp
	pv/widgets/timestampspinbox.hpp
	pv/widgets/wellarray.hpp
)

set(pulseview_RESOURCES
	pulseview.qrc
)

if(ENABLE_SIGNALS)
	list(APPEND pulseview_SOURCES signalhandler.cpp)
	list(APPEND pulseview_HEADERS signalhandler.hpp)
endif()

if(ENABLE_DECODE)
	list(APPEND pulseview_SOURCES
		pv/binding/decoder.cpp
		pv/data/decodesignal.cpp
		pv/data/decode/annotation.cpp
		pv/data/decode/decoder.cpp
		pv/data/decode/row.cpp
		pv/data/decode/rowdata.cpp
		pv/views/trace/decodetrace.cpp
		pv/widgets/decodergroupbox.cpp
		pv/widgets/decodermenu.cpp
	)

	list(APPEND pulseview_HEADERS
		pv/data/decodesignal.hpp
		pv/views/trace/decodetrace.hpp
		pv/widgets/decodergroupbox.hpp
		pv/widgets/decodermenu.hpp
	)
endif()

if(WIN32)
	# Use the sigrok icon for the pulseview.exe executable.
	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	enable_language(RC)
	list(APPEND pulseview_SOURCES pulseviewico.rc)
endif()

if(ANDROID)
	list(APPEND pulseview_SOURCES
		android/assetreader.cpp
		android/loghandler.cpp
	)
endif()

qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})

#===============================================================================
#= Global Definitions
#-------------------------------------------------------------------------------

add_definitions(-DQT_NO_KEYWORDS)
add_definitions(-D__STDC_LIMIT_MACROS)
add_definitions(-Wall -Wextra)
add_definitions(-std=c++11)
add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)

if(ENABLE_DECODE)
	add_definitions(-DENABLE_DECODE)
endif()

if(NOT DISABLE_WERROR)
	add_definitions(-Werror)
endif()

if(ENABLE_SIGNALS)
	add_definitions(-DENABLE_SIGNALS)
endif()

#===============================================================================
#= Global Include Directories
#-------------------------------------------------------------------------------

include_directories(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${Boost_INCLUDE_DIRS}
)

if(STATIC_PKGDEPS_LIBS)
	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
else()
	include_directories(${PKGDEPS_INCLUDE_DIRS})
endif()

#===============================================================================
#= Linker Configuration
#-------------------------------------------------------------------------------

link_directories(${Boost_LIBRARY_DIRS})

set(PULSEVIEW_LINK_LIBS
	${Boost_LIBRARIES}
	${QT_LIBRARIES}
	${CMAKE_THREAD_LIBS_INIT}
	${LIBATOMIC_LIBRARY}
)

if(STATIC_PKGDEPS_LIBS)
	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
else()
	link_directories(${PKGDEPS_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
endif()

if(WIN32)
	# On Windows we need to statically link the libqsvg imageformat
	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	# We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
	# Qt < 5.8.0), and all Qt libs and their dependencies.
	add_definitions(-DQT_STATICPLUGIN)
	list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
	list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
	if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
		list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
	endif()
	list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
endif()

if(ANDROID)
	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
endif()

if(ANDROID)
	add_library(${PROJECT_NAME} SHARED ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
else()
	add_executable(${PROJECT_NAME} ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
endif()

target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})

if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
endif()

#===============================================================================
#= Installation
#-------------------------------------------------------------------------------

# Install the executable.
install(TARGETS ${PROJECT_NAME} DESTINATION bin/)

# Install the manpage.
install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)

# Install the desktop file.
install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)

# Install the AppData/AppStream file.
install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)

# Install the PulseView icons.
install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)

# Generate Windows installer script.
configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)

#===============================================================================
#= Packaging (handled by CPack)
#-------------------------------------------------------------------------------

set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
set(CPACK_SOURCE_GENERATOR "TGZ")

include(CPack)

#===============================================================================
#= Tests
#-------------------------------------------------------------------------------

if(ENABLE_TESTS)
	add_subdirectory(test)
	enable_testing()
	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
endif()
Commit	Line	Data
0aad432c	1	##
190fc91a	2	## This file is part of the PulseView project.
68c4a3b3 JH	3	##
68c4a3b3 JH	4	## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
3933e8a9	5	## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
68c4a3b3 JH	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 2 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
e222f01e	21	cmake_minimum_required(VERSION 2.8.12)
0cf9fb24	22
52bbe600	23	include(GNUInstallDirs)
df944399	24
a8d3fb2d	25	project(pulseview)
df944399	26
cf2b5b64 UH	27	list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
cf2b5b64 UH	28
30588653	29	#===============================================================================
506523c1 JH	30	#= User Options
	31	#-------------------------------------------------------------------------------
	32
5f606159	33	option(DISABLE_WERROR "Build without -Werror" FALSE)
140181a4	34	option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
19f511a4	35	option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
f513bec5	36	option(ENABLE_TESTS "Enable unit tests" TRUE)
61e1e13e	37	option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
b04e278d AG	38
b04e278d AG	39	if(WIN32)
7d297a01 UH	40	# On Windows/MinGW we need to statically link to libraries.
7d297a01 UH	41	# This option is user configurable, but enable it by default on win32.
b04e278d	42	set(STATIC_PKGDEPS_LIBS TRUE)
6987ceeb	43
0aad432c	44	# Windows does not support UNIX signals.
140181a4	45	set(ENABLE_SIGNALS FALSE)
b04e278d	46	endif()
506523c1	47
552f686e	48	if(NOT CMAKE_BUILD_TYPE)
7591fe23 UH	49	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	50	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	51	FORCE)
552f686e JH	52	endif()
552f686e JH	53
506523c1	54	#===============================================================================
30588653 AG	55	#= Dependencies
	56	#-------------------------------------------------------------------------------
	57
e1e2666e	58	list(APPEND PKGDEPS glib-2.0>=2.28.0)
d93ac5e8 UH	59	list(APPEND PKGDEPS glibmm-2.4>=2.28.0)
d93ac5e8 UH	60
18145427	61	list(APPEND PKGDEPS libsigrokcxx>=0.6.0)
df944399	62
269528f5	63	if(ENABLE_DECODE)
e37a0c3e	64	list(APPEND PKGDEPS libsigrokdecode>=0.6.0)
269528f5 JH	65	endif()
269528f5 JH	66
aff51746 MC	67	if(ANDROID)
	68	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
	69	endif()
	70
d52d8455 JH	71	find_package(PkgConfig)
	72	pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
	73
e222f01e	74	set(CMAKE_AUTOMOC TRUE)
e222f01e UH	75
e222f01e UH	76	find_package(Qt5 COMPONENTS Core Gui Widgets Svg REQUIRED)
e7ab88e3	77
09f55d96 UH	78	if(WIN32)
	79	# MXE workaround: Use pkg-config to find Qt5 libs.
	80	# https://github.com/mxe/mxe/issues/1642
929b9b19 UH	81	# Not required (and doesn't work) on MSYS2.
	82	if(NOT DEFINED ENV{MSYSTEM})
	83	pkg_check_modules(QT5ALL REQUIRED Qt5Widgets Qt5Gui Qt5Svg)
	84	endif()
09f55d96	85	endif()
9e8e84fc	86
e7ab88e3	87	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
2e2946fe	88
b8f1cdeb	89	set(BOOSTCOMPS filesystem serialization system)
226a1527	90	if(ENABLE_TESTS)
d68d75c2	91	list(APPEND BOOSTCOMPS unit_test_framework)
2a21747e	92	endif()
d68d75c2	93	find_package(Boost 1.55 COMPONENTS ${BOOSTCOMPS} REQUIRED)
df944399	94
858ae630 UH	95	# Find the platform's thread library (needed for C++11 threads).
858ae630 UH	96	# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
2b76309a AJ	97	find_package(Threads REQUIRED)
2b76309a AJ	98
4da54b6b SM	99	# Check for explicit link against libatomic
	100	#
	101	# Depending on the toolchain, linking a program using atomic functions may need
	102	# "-latomic" explicitly passed to the linker
	103	#
	104	# This check first tests if atomics are available in the C-library, if not and
	105	# libatomic exists, then it runs the same test with -latomic added to the
	106	# linker flags.
	107
	108	# Helper for checking for atomics
	109	function(check_working_cxx_atomics varname additional_lib)
	110	include(CheckCXXSourceCompiles)
	111	include(CMakePushCheckState)
	112	cmake_push_check_state()
	113	set(CMAKE_REQUIRED_FLAGS "-std=c++11")
	114	set(CMAKE_REQUIRED_LIBRARIES "${additional_lib}")
	115	set(CMAKE_REQUIRED_QUIET 1)
	116	CHECK_CXX_SOURCE_COMPILES("
	117	#include <atomic>
	118	std::atomic<int> x;
	119	int main() {
	120	return std::atomic_fetch_add_explicit(&x, 1, std::memory_order_seq_cst);
	121	}
	122	" ${varname})
	123	cmake_pop_check_state()
	124	endfunction(check_working_cxx_atomics)
	125
	126	# First check if atomics work without the library.
	127	# If not, check if the library exists, and atomics work with it.
	128	check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITHOUT_LIB "")
	129	if(HAVE_CXX_ATOMICS_WITHOUT_LIB)
	130	message(STATUS "Atomics provided by the C-library - yes")
	131	else()
	132	message(STATUS "Atomics provided by the C-library - no")
	133	find_library(LIBATOMIC_LIBRARY NAMES atomic PATH_SUFFIXES lib)
	134	if(LIBATOMIC_LIBRARY)
	135	check_working_cxx_atomics(HAVE_CXX_ATOMICS_WITH_LIB "${LIBATOMIC_LIBRARY}")
	136	if (HAVE_CXX_ATOMICS_WITH_LIB)
	137	message(STATUS "Atomics provided by libatomic - yes")
	138	else()
	139	message(STATUS "Atomics provided by libatomic - no")
	140	message(FATAL_ERROR "Compiler must support std::atomic!")
	141	endif()
	142	else()
	143	message(FATAL_ERROR "Compiler appears to require libatomic, but cannot find it.")
	144	endif()
	145	endif()
	146
9df8453f MC	147	#===============================================================================
	148	#= System Introspection
	149	#-------------------------------------------------------------------------------
	150
	151	include(memaccess)
	152	memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
	153
075fb499 AG	154	#===============================================================================
	155	#= Config Header
	156	#-------------------------------------------------------------------------------
	157
f7951df4	158	set(PV_TITLE PulseView)
e2649143	159	set(PV_VERSION_STRING "0.5.0")
f7951df4	160
d93ac5e8 UH	161	set(PV_GLIBMM_VERSION ${PKGDEPS_glibmm-2.4_VERSION})
d93ac5e8 UH	162
1e8c82e9	163	include(GetGitRevisionDescription)
1e8c82e9	164
812c0e35 DE	165	# Append the revision hash unless we are exactly on a tagged release.
	166	git_describe(PV_TAG_VERSION_STRING --match "pulseview-${PV_VERSION_STRING}" --exact-match)
	167	if(NOT PV_TAG_VERSION_STRING)
	168	get_git_head_revision(PV_REVSPEC PV_HASH)
	169	if(PV_HASH)
	170	string(SUBSTRING "${PV_HASH}" 0 7 PV_SHORTHASH)
	171	set(PV_VERSION_STRING "${PV_VERSION_STRING}-git-${PV_SHORTHASH}")
d69b3c31 DE	172	endif()
	173	endif()
	174
	175	if(PV_VERSION_STRING MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)(-[-0-9a-z]*)?$")
1e8c82e9 DE	176	set(PV_VERSION_MAJOR ${CMAKE_MATCH_1})
	177	set(PV_VERSION_MINOR ${CMAKE_MATCH_2})
	178	set(PV_VERSION_MICRO ${CMAKE_MATCH_3})
	179	set(PV_VERSION_SUFFIX ${CMAKE_MATCH_4})
1e8c82e9 DE	180	endif()
1e8c82e9 DE	181
1e8c82e9	182	message("-- ${PV_TITLE} version: ${PV_VERSION_STRING}")
075fb499 AG	183
	184	configure_file (
	185	${PROJECT_SOURCE_DIR}/config.h.in
	186	${PROJECT_BINARY_DIR}/config.h
	187	)
df944399	188
30588653 AG	189	#===============================================================================
	190	#= Sources
	191	#-------------------------------------------------------------------------------
	192
a8d3fb2d	193	set(pulseview_SOURCES
df944399	194	main.cpp
dac1bb97	195	pv/application.cpp
107ca6d3	196	pv/devicemanager.cpp
bf9f1268	197	pv/globalsettings.cpp
51e77110	198	pv/mainwindow.cpp
f65cd27b	199	pv/session.cpp
0fbda3c2	200	pv/storesession.cpp
f0c9f81c	201	pv/util.cpp
61703a01	202	pv/binding/binding.cpp
0c913637	203	pv/binding/inputoutput.cpp
3cc9ad7b	204	pv/binding/device.cpp
1b1ec774	205	pv/data/analog.cpp
f3d66e52	206	pv/data/analogsegment.cpp
1b1ec774	207	pv/data/logic.cpp
f3d66e52	208	pv/data/logicsegment.cpp
bf0edd2b	209	pv/data/signalbase.cpp
1b1ec774	210	pv/data/signaldata.cpp
f3d66e52	211	pv/data/segment.cpp
da30ecb7	212	pv/devices/device.cpp
474e817a	213	pv/devices/file.cpp
da30ecb7	214	pv/devices/hardwaredevice.cpp
5237f0c5	215	pv/devices/inputfile.cpp
da30ecb7	216	pv/devices/sessionfile.cpp
9663c82b	217	pv/dialogs/connect.cpp
e93f5538	218	pv/dialogs/inputoutputoptions.cpp
bf9f1268	219	pv/dialogs/settings.cpp
0fbda3c2	220	pv/dialogs/storeprogress.cpp
51d4a9ab	221	pv/popups/deviceoptions.cpp
6ac6242b	222	pv/popups/channels.cpp
de1d99bb	223	pv/prop/bool.cpp
b912c99c	224	pv/prop/double.cpp
820c3dea	225	pv/prop/enum.cpp
a2b92157	226	pv/prop/int.cpp
c8df6005	227	pv/prop/property.cpp
7112a458	228	pv/prop/string.cpp
7c657094	229	pv/toolbars/mainbar.cpp
1573bf16 SA	230	pv/views/trace/analogsignal.cpp
	231	pv/views/trace/cursor.cpp
	232	pv/views/trace/cursorpair.cpp
	233	pv/views/trace/flag.cpp
	234	pv/views/trace/header.cpp
	235	pv/views/trace/marginwidget.cpp
	236	pv/views/trace/logicsignal.cpp
	237	pv/views/trace/rowitem.cpp
	238	pv/views/trace/ruler.cpp
	239	pv/views/trace/signal.cpp
1573bf16 SA	240	pv/views/trace/timeitem.cpp
	241	pv/views/trace/timemarker.cpp
	242	pv/views/trace/trace.cpp
	243	pv/views/trace/tracegroup.cpp
	244	pv/views/trace/tracepalette.cpp
	245	pv/views/trace/tracetreeitem.cpp
	246	pv/views/trace/tracetreeitemowner.cpp
	247	pv/views/trace/triggermarker.cpp
	248	pv/views/trace/view.cpp
	249	pv/views/trace/viewitem.cpp
	250	pv/views/trace/viewitemowner.cpp
	251	pv/views/trace/viewitempaintparams.cpp
	252	pv/views/trace/viewport.cpp
	253	pv/views/trace/viewwidget.cpp
f4e57597	254	pv/views/viewbase.cpp
e0ba4f6f	255	pv/views/trace/standardbar.cpp
91e8bf08 JH	256	pv/widgets/colourbutton.cpp
91e8bf08 JH	257	pv/widgets/colourpopup.cpp
079d39ea	258	pv/widgets/devicetoolbutton.cpp
ce6001b8	259	pv/widgets/exportmenu.cpp
56b6fc88	260	pv/widgets/importmenu.cpp
6e3f046e	261	pv/widgets/popup.cpp
6a91973f	262	pv/widgets/popuptoolbutton.cpp
1198b887	263	pv/widgets/sweeptimingwidget.cpp
806d3e1e	264	pv/widgets/timestampspinbox.cpp
0c0e1888	265	pv/widgets/wellarray.cpp
df944399 JH	266	)
df944399 JH	267
0aad432c	268	# This list includes only QObject derived class headers.
a8d3fb2d	269	set(pulseview_HEADERS
bf9f1268	270	pv/globalsettings.hpp
2acdb232	271	pv/mainwindow.hpp
f65cd27b	272	pv/session.hpp
2acdb232	273	pv/storesession.hpp
3cc9ad7b	274	pv/binding/device.hpp
7db61e77 SA	275	pv/data/analog.hpp
	276	pv/data/analogsegment.hpp
	277	pv/data/logic.hpp
	278	pv/data/logicsegment.hpp
bf0edd2b	279	pv/data/signalbase.hpp
2acdb232	280	pv/dialogs/connect.hpp
e93f5538	281	pv/dialogs/inputoutputoptions.hpp
bf9f1268	282	pv/dialogs/settings.hpp
2acdb232 JH	283	pv/dialogs/storeprogress.hpp
	284	pv/popups/channels.hpp
	285	pv/popups/deviceoptions.hpp
	286	pv/prop/bool.hpp
	287	pv/prop/double.hpp
	288	pv/prop/enum.hpp
	289	pv/prop/int.hpp
	290	pv/prop/property.hpp
	291	pv/prop/string.hpp
7c657094	292	pv/toolbars/mainbar.hpp
1573bf16 SA	293	pv/views/trace/analogsignal.hpp
	294	pv/views/trace/cursor.hpp
	295	pv/views/trace/flag.hpp
	296	pv/views/trace/header.hpp
	297	pv/views/trace/logicsignal.hpp
	298	pv/views/trace/marginwidget.hpp
	299	pv/views/trace/rowitem.hpp
	300	pv/views/trace/ruler.hpp
	301	pv/views/trace/signal.hpp
1573bf16 SA	302	pv/views/trace/timeitem.hpp
	303	pv/views/trace/timemarker.hpp
	304	pv/views/trace/trace.hpp
	305	pv/views/trace/tracegroup.hpp
	306	pv/views/trace/tracetreeitem.hpp
	307	pv/views/trace/triggermarker.hpp
	308	pv/views/trace/view.hpp
	309	pv/views/trace/viewitem.hpp
	310	pv/views/trace/viewport.hpp
	311	pv/views/trace/viewwidget.hpp
f4e57597	312	pv/views/viewbase.hpp
e0ba4f6f	313	pv/views/trace/standardbar.hpp
2acdb232 JH	314	pv/widgets/colourbutton.hpp
2acdb232 JH	315	pv/widgets/colourpopup.hpp
079d39ea	316	pv/widgets/devicetoolbutton.hpp
ce6001b8	317	pv/widgets/exportmenu.hpp
56b6fc88	318	pv/widgets/importmenu.hpp
2acdb232 JH	319	pv/widgets/popup.hpp
	320	pv/widgets/popuptoolbutton.hpp
	321	pv/widgets/sweeptimingwidget.hpp
806d3e1e	322	pv/widgets/timestampspinbox.hpp
2acdb232	323	pv/widgets/wellarray.hpp
df944399 JH	324	)
df944399 JH	325
8b9056d4 UH	326	set(pulseview_RESOURCES
	327	pulseview.qrc
	328	)
	329
140181a4 JH	330	if(ENABLE_SIGNALS)
140181a4 JH	331	list(APPEND pulseview_SOURCES signalhandler.cpp)
2acdb232	332	list(APPEND pulseview_HEADERS signalhandler.hpp)
140181a4 JH	333	endif()
140181a4 JH	334
269528f5 JH	335	if(ENABLE_DECODE)
269528f5 JH	336	list(APPEND pulseview_SOURCES
3cc9ad7b	337	pv/binding/decoder.cpp
ad908057	338	pv/data/decodesignal.cpp
269528f5 JH	339	pv/data/decode/annotation.cpp
269528f5 JH	340	pv/data/decode/decoder.cpp
f9101a91 JH	341	pv/data/decode/row.cpp
f9101a91 JH	342	pv/data/decode/rowdata.cpp
1573bf16	343	pv/views/trace/decodetrace.cpp
269528f5 JH	344	pv/widgets/decodergroupbox.cpp
269528f5 JH	345	pv/widgets/decodermenu.cpp
269528f5 JH	346	)
	347
	348	list(APPEND pulseview_HEADERS
ad908057	349	pv/data/decodesignal.hpp
1573bf16	350	pv/views/trace/decodetrace.hpp
2acdb232 JH	351	pv/widgets/decodergroupbox.hpp
2acdb232 JH	352	pv/widgets/decodermenu.hpp
269528f5 JH	353	)
	354	endif()
	355
fe15e0bc UH	356	if(WIN32)
	357	# Use the sigrok icon for the pulseview.exe executable.
	358	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	359	enable_language(RC)
61e1e13e	360	list(APPEND pulseview_SOURCES pulseviewico.rc)
fe15e0bc UH	361	endif()
fe15e0bc UH	362
9137928c	363	if(ANDROID)
dddff2e7 DE	364	list(APPEND pulseview_SOURCES
	365	android/assetreader.cpp
	366	android/loghandler.cpp
	367	)
9137928c MC	368	endif()
9137928c MC	369
8b9056d4 UH	370	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
8b9056d4 UH	371
30588653 AG	372	#===============================================================================
	373	#= Global Definitions
	374	#-------------------------------------------------------------------------------
	375
e222f01e	376	add_definitions(-DQT_NO_KEYWORDS)
ac223c1e	377	add_definitions(-D__STDC_LIMIT_MACROS)
a9974171	378	add_definitions(-Wall -Wextra)
95d43108	379	add_definitions(-std=c++11)
a838ed7b	380	add_definitions(-DBOOST_MATH_DISABLE_FLOAT128=1)
5f606159	381
269528f5 JH	382	if(ENABLE_DECODE)
	383	add_definitions(-DENABLE_DECODE)
	384	endif()
	385
5f606159 JH	386	if(NOT DISABLE_WERROR)
	387	add_definitions(-Werror)
	388	endif()
df944399	389
9632990d UH	390	if(ENABLE_SIGNALS)
	391	add_definitions(-DENABLE_SIGNALS)
	392	endif()
	393
30588653 AG	394	#===============================================================================
	395	#= Global Include Directories
	396	#-------------------------------------------------------------------------------
	397
b04e278d AG	398	include_directories(
b04e278d AG	399	${CMAKE_CURRENT_BINARY_DIR}
cef18fc6	400	${CMAKE_CURRENT_SOURCE_DIR}
b04e278d AG	401	${Boost_INCLUDE_DIRS}
	402	)
	403
	404	if(STATIC_PKGDEPS_LIBS)
	405	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
	406	else()
	407	include_directories(${PKGDEPS_INCLUDE_DIRS})
	408	endif()
df944399	409
30588653 AG	410	#===============================================================================
	411	#= Linker Configuration
	412	#-------------------------------------------------------------------------------
	413
b04e278d AG	414	link_directories(${Boost_LIBRARY_DIRS})
	415
	416	set(PULSEVIEW_LINK_LIBS
	417	${Boost_LIBRARIES}
	418	${QT_LIBRARIES}
2b76309a	419	${CMAKE_THREAD_LIBS_INIT}
4da54b6b	420	${LIBATOMIC_LIBRARY}
b04e278d AG	421	)
	422
	423	if(STATIC_PKGDEPS_LIBS)
cddf172d	424	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
09f55d96	425	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LDFLAGS})
b04e278d	426	else()
cddf172d UH	427	link_directories(${PKGDEPS_LIBRARY_DIRS})
cddf172d UH	428	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
b04e278d	429	endif()
df944399	430
11a04e2a UH	431	if(WIN32)
	432	# On Windows we need to statically link the libqsvg imageformat
	433	# plugin (and the QtSvg component) for SVG graphics/icons to work.
356fb5c0 UH	434	# We also need QWindowsIntegrationPlugin, Qt5PlatformSupport (only for
356fb5c0 UH	435	# Qt < 5.8.0), and all Qt libs and their dependencies.
11a04e2a	436	add_definitions(-DQT_STATICPLUGIN)
09f55d96 UH	437	list(APPEND PULSEVIEW_LINK_LIBS Qt5::QSvgPlugin)
09f55d96 UH	438	list(APPEND PULSEVIEW_LINK_LIBS Qt5::QWindowsIntegrationPlugin)
356fb5c0 UH	439	if(Qt5Gui_VERSION VERSION_LESS 5.8.0)
	440	list(APPEND PULSEVIEW_LINK_LIBS -lQt5PlatformSupport)
	441	endif()
	442	list(APPEND PULSEVIEW_LINK_LIBS ${QT5ALL_LDFLAGS})
11a04e2a UH	443	endif()
11a04e2a UH	444
9137928c MC	445	if(ANDROID)
	446	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
	447	endif()
	448
26807061	449	if(ANDROID)
8b9056d4	450	add_library(${PROJECT_NAME} SHARED ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
26807061	451	else()
8b9056d4	452	add_executable(${PROJECT_NAME} ${pulseview_SOURCES} ${pulseview_RESOURCES_RCC})
26807061	453	endif()
df944399	454
5a13850b	455	target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
f0fa92c6	456
b732b48f	457	if(WIN32 AND NOT ${CMAKE_BUILD_TYPE} STREQUAL "Debug")
61e1e13e UH	458	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
61e1e13e UH	459	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
b0d8c0dc UH	460	endif()
b0d8c0dc UH	461
30588653 AG	462	#===============================================================================
	463	#= Installation
	464	#-------------------------------------------------------------------------------
	465
52bbe600	466	# Install the executable.
cd6606c2 AG	467	install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
cd6606c2 AG	468
52bbe600 UH	469	# Install the manpage.
	470	install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
	471
96e282c4 UH	472	# Install the desktop file.
	473	install(FILES contrib/org.sigrok.PulseView.desktop DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications)
	474
22fc985b UH	475	# Install the AppData/AppStream file.
	476	install(FILES contrib/org.sigrok.PulseView.appdata.xml DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/metainfo)
	477
09594425 UH	478	# Install the PulseView icons.
	479	install(FILES icons/pulseview.png DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/48x48/apps)
	480	install(FILES icons/pulseview.svg DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps)
	481
f9cb49cc DE	482	# Generate Windows installer script.
	483	configure_file(contrib/pulseview_cross.nsi.in contrib/pulseview_cross.nsi @ONLY)
	484
cd6606c2 AG	485	#===============================================================================
	486	#= Packaging (handled by CPack)
	487	#-------------------------------------------------------------------------------
	488
b02a8cbf JH	489	set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
	490	set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
	491	set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
cd6606c2 AG	492	set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
	493	set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
	494	set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
1e8c82e9	495	set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CMAKE_PROJECT_NAME}-${PV_VERSION_STRING}")
1d2fb87d	496	set(CPACK_SOURCE_GENERATOR "TGZ")
cd6606c2 AG	497
cd6606c2 AG	498	include(CPack)
bc1c1462	499
30588653 AG	500	#===============================================================================
	501	#= Tests
	502	#-------------------------------------------------------------------------------
	503
77e8ac52	504	if(ENABLE_TESTS)
fb746bcc	505	add_subdirectory(test)
951c583c	506	enable_testing()
fb746bcc	507	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
0aad432c	508	endif()