[pulseview.git] / CMakeLists.txt

##
## This file is part of the PulseView project.
##
## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
##
## This program is free software: you can redistribute it and/or modify
## it under the terms of the GNU General Public License as published by
## the Free Software Foundation, either version 2 of the License, or
## (at your option) any later version.
##
## This program is distributed in the hope that it will be useful,
## but WITHOUT ANY WARRANTY; without even the implied warranty of
## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
## GNU General Public License for more details.
##
## You should have received a copy of the GNU General Public License
## along with this program.  If not, see <http://www.gnu.org/licenses/>.
##

cmake_minimum_required(VERSION 2.8.6)

include(FindPkgConfig)
include(GNUInstallDirs)

project(pulseview)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")

#===============================================================================
#= User Options
#-------------------------------------------------------------------------------

option(DISABLE_WERROR "Build without -Werror" FALSE)
option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
option(ENABLE_TESTS "Enable unit tests" FALSE)
option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)

if(WIN32)
	# On Windows/MinGW we need to statically link to libraries.
	# This option is user configurable, but enable it by default on win32.
	set(STATIC_PKGDEPS_LIBS TRUE)

	# For boost-thread we need two additional settings on win32:
	set(Boost_USE_STATIC_LIBS ON)
	add_definitions(-DBOOST_THREAD_USE_LIB)

	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	# The library is named libboost_thread_win32* (not libboost_thread*).
	set(Boost_THREADAPI win32)

	# Windows does not support UNIX signals.
	set(ENABLE_SIGNALS FALSE)
endif()

if(NOT CMAKE_BUILD_TYPE)
	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	FORCE)
endif()

#===============================================================================
#= Dependencies
#-------------------------------------------------------------------------------

list(APPEND PKGDEPS libsigrokcxx>=0.3.0)

if(ENABLE_DECODE)
	list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
endif()

if(ANDROID)
	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
endif()

find_package(PkgConfig)
pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})

if(FORCE_QT4)
	set(Qt5Core_FOUND FALSE)
else()
	find_package(Qt5Core QUIET)
endif()

if(Qt5Core_FOUND)
	message("-- Using Qt5")
	find_package(Qt5Widgets REQUIRED)
	find_package(Qt5Gui REQUIRED)
	find_package(Qt5Svg REQUIRED)
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
else()
	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
endif()

if(ENABLE_TESTS)
	find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
else()
	find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
endif()

# Find the platform's thread library (needed for C++11 threads).
# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
find_package(Threads REQUIRED)

#===============================================================================
#= System Introspection
#-------------------------------------------------------------------------------

include(memaccess)
memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)

#===============================================================================
#= Config Header
#-------------------------------------------------------------------------------

set(PV_TITLE PulseView)
set(PV_DESCRIPTION "A GUI for sigrok")

set(PV_VERSION_MAJOR 0)
set(PV_VERSION_MINOR 2)
set(PV_VERSION_MICRO 0)
set(PV_VERSION_STRING
	${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
)

configure_file (
	${PROJECT_SOURCE_DIR}/config.h.in
	${PROJECT_BINARY_DIR}/config.h
)

#===============================================================================
#= Sources
#-------------------------------------------------------------------------------

set(pulseview_SOURCES
	main.cpp
	pv/application.cpp
	pv/devicemanager.cpp
	pv/mainwindow.cpp
	pv/session.cpp
	pv/storesession.cpp
	pv/util.cpp
	pv/data/analog.cpp
	pv/data/analogsegment.cpp
	pv/data/logic.cpp
	pv/data/logicsegment.cpp
	pv/data/signaldata.cpp
	pv/data/segment.cpp
	pv/dialogs/about.cpp
	pv/dialogs/connect.cpp
	pv/dialogs/storeprogress.cpp
	pv/popups/deviceoptions.cpp
	pv/popups/channels.cpp
	pv/prop/bool.cpp
	pv/prop/double.cpp
	pv/prop/enum.cpp
	pv/prop/int.cpp
	pv/prop/property.cpp
	pv/prop/string.cpp
	pv/prop/binding/binding.cpp
	pv/prop/binding/deviceoptions.cpp
	pv/toolbars/mainbar.cpp
	pv/view/analogsignal.cpp
	pv/view/cursor.cpp
	pv/view/cursorpair.cpp
	pv/view/flag.cpp
	pv/view/header.cpp
	pv/view/marginwidget.cpp
	pv/view/logicsignal.cpp
	pv/view/rowitem.cpp
	pv/view/rowitemowner.cpp
	pv/view/ruler.cpp
	pv/view/signal.cpp
	pv/view/timeitem.cpp
	pv/view/timemarker.cpp
	pv/view/trace.cpp
	pv/view/tracegroup.cpp
	pv/view/tracepalette.cpp
	pv/view/view.cpp
	pv/view/viewitem.cpp
	pv/view/viewitempaintparams.cpp
	pv/view/viewport.cpp
	pv/view/viewwidget.cpp
	pv/widgets/colourbutton.cpp
	pv/widgets/colourpopup.cpp
	pv/widgets/devicetoolbutton.cpp
	pv/widgets/hidingmenubar.cpp
	pv/widgets/popup.cpp
	pv/widgets/popuptoolbutton.cpp
	pv/widgets/sweeptimingwidget.cpp
	pv/widgets/wellarray.cpp
)

# This list includes only QObject derived class headers.
set(pulseview_HEADERS
	pv/mainwindow.hpp
	pv/session.hpp
	pv/storesession.hpp
	pv/dialogs/about.hpp
	pv/dialogs/connect.hpp
	pv/dialogs/storeprogress.hpp
	pv/popups/channels.hpp
	pv/popups/deviceoptions.hpp
	pv/prop/bool.hpp
	pv/prop/double.hpp
	pv/prop/enum.hpp
	pv/prop/int.hpp
	pv/prop/property.hpp
	pv/prop/string.hpp
	pv/prop/binding/deviceoptions.hpp
	pv/toolbars/mainbar.hpp
	pv/view/cursor.hpp
	pv/view/flag.hpp
	pv/view/header.hpp
	pv/view/logicsignal.hpp
	pv/view/marginwidget.hpp
	pv/view/rowitem.hpp
	pv/view/ruler.hpp
	pv/view/signal.hpp
	pv/view/timeitem.hpp
	pv/view/timemarker.hpp
	pv/view/trace.hpp
	pv/view/tracegroup.hpp
	pv/view/view.hpp
	pv/view/viewitem.hpp
	pv/view/viewport.hpp
	pv/view/viewwidget.hpp
	pv/widgets/colourbutton.hpp
	pv/widgets/colourpopup.hpp
	pv/widgets/devicetoolbutton.hpp
	pv/widgets/hidingmenubar.hpp
	pv/widgets/popup.hpp
	pv/widgets/popuptoolbutton.hpp
	pv/widgets/sweeptimingwidget.hpp
	pv/widgets/wellarray.hpp
)

set(pulseview_FORMS
	pv/dialogs/about.ui
)

set(pulseview_RESOURCES
	pulseview.qrc
)

if(ENABLE_SIGNALS)
	list(APPEND pulseview_SOURCES signalhandler.cpp)
	list(APPEND pulseview_HEADERS signalhandler.hpp)
endif()

if(ENABLE_DECODE)
	list(APPEND pulseview_SOURCES
		pv/data/decoderstack.cpp
		pv/data/decode/annotation.cpp
		pv/data/decode/decoder.cpp
		pv/data/decode/row.cpp
		pv/data/decode/rowdata.cpp
		pv/prop/binding/decoderoptions.cpp
		pv/view/decodetrace.cpp
		pv/widgets/decodergroupbox.cpp
		pv/widgets/decodermenu.cpp
	)

	list(APPEND pulseview_HEADERS
		pv/data/decoderstack.hpp
		pv/view/decodetrace.hpp
		pv/widgets/decodergroupbox.hpp
		pv/widgets/decodermenu.hpp
	)
endif()

if(WIN32)
	# Use the sigrok icon for the pulseview.exe executable.
	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	enable_language(RC)
	list(APPEND pulseview_SOURCES pulseviewico.rc)
endif()

if(ANDROID)
	list(APPEND pulseview_SOURCES android/loghandler.cpp)
endif()

if(Qt5Core_FOUND)
	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
else()
	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	include(${QT_USE_FILE})
endif()

#===============================================================================
#= Global Definitions
#-------------------------------------------------------------------------------

add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
add_definitions(-D__STDC_LIMIT_MACROS)
add_definitions(-Wall -Wextra)
add_definitions(-std=c++11)

if(ENABLE_DECODE)
	add_definitions(-DENABLE_DECODE)
endif()

if(NOT DISABLE_WERROR)
	add_definitions(-Werror)
endif()

if(ENABLE_SIGNALS)
	add_definitions(-DENABLE_SIGNALS)
endif()

#===============================================================================
#= Global Include Directories
#-------------------------------------------------------------------------------

include_directories(
	${CMAKE_CURRENT_BINARY_DIR}
	${CMAKE_CURRENT_SOURCE_DIR}
	${Boost_INCLUDE_DIRS}
	${QT_INCLUDE_DIRS}
)

if(STATIC_PKGDEPS_LIBS)
	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
else()
	include_directories(${PKGDEPS_INCLUDE_DIRS})
endif()

#===============================================================================
#= Linker Configuration
#-------------------------------------------------------------------------------

link_directories(${Boost_LIBRARY_DIRS})

set(PULSEVIEW_LINK_LIBS
	${Boost_LIBRARIES}
	${QT_LIBRARIES}
	${CMAKE_THREAD_LIBS_INIT}
)

if(STATIC_PKGDEPS_LIBS)
	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
if(WIN32)
	# Workaround for a MinGW linking issue.
	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
endif()
else()
	link_directories(${PKGDEPS_LIBRARY_DIRS})
	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
endif()

if(WIN32)
	# On Windows we need to statically link the libqsvg imageformat
	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	add_definitions(-DQT_STATICPLUGIN)
	link_directories("${QT_PLUGINS_DIR}/imageformats")
	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
endif()

if(ANDROID)
	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
endif()

if(ANDROID)
add_library(${PROJECT_NAME} SHARED
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
else()
add_executable(${PROJECT_NAME}
	${pulseview_SOURCES}
	${pulseview_HEADERS_MOC}
	${pulseview_FORMS_HEADERS}
	${pulseview_RESOURCES_RCC}
)
endif()

target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})

if(WIN32)
	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
endif()

#===============================================================================
#= Installation
#-------------------------------------------------------------------------------

# Install the executable.
install(TARGETS ${PROJECT_NAME} DESTINATION bin/)

# Install the manpage.
install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)

#===============================================================================
#= Packaging (handled by CPack)
#-------------------------------------------------------------------------------

set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
set(CPACK_SOURCE_PACKAGE_FILE_NAME
	"${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
set(CPACK_SOURCE_GENERATOR "TGZ")

include(CPack)

#===============================================================================
#= Tests
#-------------------------------------------------------------------------------

if(ENABLE_TESTS)
	add_subdirectory(test)
	enable_testing()
	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
endif()
Commit	Line	Data
0aad432c	1	##
190fc91a	2	## This file is part of the PulseView project.
68c4a3b3 JH	3	##
68c4a3b3 JH	4	## Copyright (C) 2012 Joel Holdsworth <joel@airwebreathe.org.uk>
3933e8a9	5	## Copyright (C) 2012-2013 Alexandru Gagniuc <mr.nuke.me@gmail.com>
68c4a3b3 JH	6	##
	7	## This program is free software: you can redistribute it and/or modify
	8	## it under the terms of the GNU General Public License as published by
	9	## the Free Software Foundation, either version 2 of the License, or
	10	## (at your option) any later version.
	11	##
	12	## This program is distributed in the hope that it will be useful,
	13	## but WITHOUT ANY WARRANTY; without even the implied warranty of
	14	## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	15	## GNU General Public License for more details.
	16	##
	17	## You should have received a copy of the GNU General Public License
	18	## along with this program. If not, see <http://www.gnu.org/licenses/>.
	19	##
	20
7ba41e7e	21	cmake_minimum_required(VERSION 2.8.6)
0cf9fb24	22
df944399	23	include(FindPkgConfig)
52bbe600	24	include(GNUInstallDirs)
df944399	25
a8d3fb2d	26	project(pulseview)
df944399	27
cf2b5b64 UH	28	list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
cf2b5b64 UH	29
30588653	30	#===============================================================================
506523c1 JH	31	#= User Options
	32	#-------------------------------------------------------------------------------
	33
5f606159	34	option(DISABLE_WERROR "Build without -Werror" FALSE)
140181a4	35	option(ENABLE_SIGNALS "Build with UNIX signals" TRUE)
19f511a4	36	option(ENABLE_DECODE "Build with libsigrokdecode" TRUE)
506523c1	37	option(ENABLE_TESTS "Enable unit tests" FALSE)
61e1e13e	38	option(STATIC_PKGDEPS_LIBS "Statically link to (pkg-config) libraries" FALSE)
9e8e84fc	39	option(FORCE_QT4 "Force use of Qt4 even if Qt5 is available" FALSE)
b04e278d AG	40
b04e278d AG	41	if(WIN32)
7d297a01 UH	42	# On Windows/MinGW we need to statically link to libraries.
7d297a01 UH	43	# This option is user configurable, but enable it by default on win32.
b04e278d	44	set(STATIC_PKGDEPS_LIBS TRUE)
6987ceeb	45
2a21747e UH	46	# For boost-thread we need two additional settings on win32:
	47	set(Boost_USE_STATIC_LIBS ON)
	48	add_definitions(-DBOOST_THREAD_USE_LIB)
	49
e6fd809f UH	50	# On Windows/MinGW we need to use 'thread_win32' instead of 'thread'.
	51	# The library is named libboost_thread_win32* (not libboost_thread*).
	52	set(Boost_THREADAPI win32)
	53
0aad432c	54	# Windows does not support UNIX signals.
140181a4	55	set(ENABLE_SIGNALS FALSE)
b04e278d	56	endif()
506523c1	57
552f686e	58	if(NOT CMAKE_BUILD_TYPE)
7591fe23 UH	59	set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
	60	"Choose the type of build (None, Debug, Release, RelWithDebInfo, MinSizeRel)."
	61	FORCE)
552f686e JH	62	endif()
552f686e JH	63
506523c1	64	#===============================================================================
30588653 AG	65	#= Dependencies
	66	#-------------------------------------------------------------------------------
	67
fe3a1c21	68	list(APPEND PKGDEPS libsigrokcxx>=0.3.0)
df944399	69
269528f5	70	if(ENABLE_DECODE)
ab186d22	71	list(APPEND PKGDEPS libsigrokdecode>=0.3.0)
269528f5 JH	72	endif()
269528f5 JH	73
aff51746 MC	74	if(ANDROID)
	75	list(APPEND PKGDEPS libsigrokandroidutils>=0.1.0)
	76	endif()
	77
d52d8455 JH	78	find_package(PkgConfig)
	79	pkg_check_modules(PKGDEPS REQUIRED ${PKGDEPS})
	80
9e8e84fc MC	81	if(FORCE_QT4)
	82	set(Qt5Core_FOUND FALSE)
	83	else()
	84	find_package(Qt5Core QUIET)
	85	endif()
	86
	87	if(Qt5Core_FOUND)
	88	message("-- Using Qt5")
	89	find_package(Qt5Widgets REQUIRED)
	90	find_package(Qt5Gui REQUIRED)
726ea667	91	find_package(Qt5Svg REQUIRED)
1cd4be22	92	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${Qt5Widgets_EXECUTABLE_COMPILE_FLAGS}")
ea370bc6	93	set(QT_INCLUDE_DIRS ${Qt5Gui_INCLUDE_DIRS} ${Qt5Widgets_INCLUDE_DIRS})
726ea667	94	set(QT_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Svg)
9e8e84fc MC	95	add_definitions(${Qt5Gui_DEFINITIONS} ${Qt5Widgets_DEFINITIONS})
	96	else()
	97	find_program(QT_QMAKE_EXECUTABLE NAMES qmake4 qmake-qt4 qmake-mac)
52f38de6	98	find_package(Qt4 REQUIRED QtCore QtGui QtSvg)
9e8e84fc	99	endif()
2e2946fe	100
226a1527 UH	101	if(ENABLE_TESTS)
226a1527 UH	102	find_package(Boost 1.42 COMPONENTS filesystem system thread unit_test_framework REQUIRED)
2a21747e UH	103	else()
	104	find_package(Boost 1.42 COMPONENTS filesystem system thread REQUIRED)
	105	endif()
df944399	106
858ae630 UH	107	# Find the platform's thread library (needed for C++11 threads).
858ae630 UH	108	# This will set ${CMAKE_THREAD_LIBS_INIT} to the correct, OS-specific value.
2b76309a AJ	109	find_package(Threads REQUIRED)
2b76309a AJ	110
9df8453f MC	111	#===============================================================================
	112	#= System Introspection
	113	#-------------------------------------------------------------------------------
	114
	115	include(memaccess)
	116	memaccess_check_unaligned_le(HAVE_UNALIGNED_LITTLE_ENDIAN_ACCESS)
	117
075fb499 AG	118	#===============================================================================
	119	#= Config Header
	120	#-------------------------------------------------------------------------------
	121
f7951df4	122	set(PV_TITLE PulseView)
d4384c6d	123	set(PV_DESCRIPTION "A GUI for sigrok")
f7951df4	124
075fb499	125	set(PV_VERSION_MAJOR 0)
744905d4	126	set(PV_VERSION_MINOR 2)
075fb499 AG	127	set(PV_VERSION_MICRO 0)
	128	set(PV_VERSION_STRING
	129	${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}
	130	)
	131
	132	configure_file (
	133	${PROJECT_SOURCE_DIR}/config.h.in
	134	${PROJECT_BINARY_DIR}/config.h
	135	)
df944399	136
30588653 AG	137	#===============================================================================
	138	#= Sources
	139	#-------------------------------------------------------------------------------
	140
a8d3fb2d	141	set(pulseview_SOURCES
df944399	142	main.cpp
dac1bb97	143	pv/application.cpp
107ca6d3	144	pv/devicemanager.cpp
51e77110	145	pv/mainwindow.cpp
f65cd27b	146	pv/session.cpp
0fbda3c2	147	pv/storesession.cpp
f0c9f81c	148	pv/util.cpp
1b1ec774	149	pv/data/analog.cpp
f3d66e52	150	pv/data/analogsegment.cpp
1b1ec774	151	pv/data/logic.cpp
f3d66e52	152	pv/data/logicsegment.cpp
1b1ec774	153	pv/data/signaldata.cpp
f3d66e52	154	pv/data/segment.cpp
acda14b8	155	pv/dialogs/about.cpp
9663c82b	156	pv/dialogs/connect.cpp
0fbda3c2	157	pv/dialogs/storeprogress.cpp
51d4a9ab	158	pv/popups/deviceoptions.cpp
6ac6242b	159	pv/popups/channels.cpp
de1d99bb	160	pv/prop/bool.cpp
b912c99c	161	pv/prop/double.cpp
820c3dea	162	pv/prop/enum.cpp
a2b92157	163	pv/prop/int.cpp
c8df6005	164	pv/prop/property.cpp
7112a458	165	pv/prop/string.cpp
c8df6005	166	pv/prop/binding/binding.cpp
3820592a	167	pv/prop/binding/deviceoptions.cpp
7c657094	168	pv/toolbars/mainbar.cpp
aba1dd16	169	pv/view/analogsignal.cpp
cabce982	170	pv/view/cursor.cpp
b42d25c4	171	pv/view/cursorpair.cpp
8914fe79	172	pv/view/flag.cpp
1d8dca91	173	pv/view/header.cpp
c23b29d6	174	pv/view/marginwidget.cpp
8d634081	175	pv/view/logicsignal.cpp
23935421	176	pv/view/rowitem.cpp
18f7104f	177	pv/view/rowitemowner.cpp
ccdd3ef5	178	pv/view/ruler.cpp
8d634081	179	pv/view/signal.cpp
ad341c3a	180	pv/view/timeitem.cpp
cd6c8ee2	181	pv/view/timemarker.cpp
931f20b0	182	pv/view/trace.cpp
722930c1	183	pv/view/tracegroup.cpp
91e8bf08	184	pv/view/tracepalette.cpp
cdf7bea7	185	pv/view/view.cpp
26e3af6b	186	pv/view/viewitem.cpp
5b5fa4da	187	pv/view/viewitempaintparams.cpp
cdf7bea7	188	pv/view/viewport.cpp
40aca27e	189	pv/view/viewwidget.cpp
91e8bf08 JH	190	pv/widgets/colourbutton.cpp
91e8bf08 JH	191	pv/widgets/colourpopup.cpp
079d39ea	192	pv/widgets/devicetoolbutton.cpp
1c4c23b8	193	pv/widgets/hidingmenubar.cpp
6e3f046e	194	pv/widgets/popup.cpp
6a91973f	195	pv/widgets/popuptoolbutton.cpp
1198b887	196	pv/widgets/sweeptimingwidget.cpp
0c0e1888	197	pv/widgets/wellarray.cpp
df944399 JH	198	)
df944399 JH	199
0aad432c	200	# This list includes only QObject derived class headers.
a8d3fb2d	201	set(pulseview_HEADERS
2acdb232	202	pv/mainwindow.hpp
f65cd27b	203	pv/session.hpp
2acdb232 JH	204	pv/storesession.hpp
	205	pv/dialogs/about.hpp
	206	pv/dialogs/connect.hpp
	207	pv/dialogs/storeprogress.hpp
	208	pv/popups/channels.hpp
	209	pv/popups/deviceoptions.hpp
	210	pv/prop/bool.hpp
	211	pv/prop/double.hpp
	212	pv/prop/enum.hpp
	213	pv/prop/int.hpp
	214	pv/prop/property.hpp
	215	pv/prop/string.hpp
	216	pv/prop/binding/deviceoptions.hpp
7c657094	217	pv/toolbars/mainbar.hpp
2acdb232	218	pv/view/cursor.hpp
8914fe79	219	pv/view/flag.hpp
2acdb232 JH	220	pv/view/header.hpp
	221	pv/view/logicsignal.hpp
	222	pv/view/marginwidget.hpp
	223	pv/view/rowitem.hpp
	224	pv/view/ruler.hpp
2acdb232	225	pv/view/signal.hpp
ad341c3a	226	pv/view/timeitem.hpp
2acdb232 JH	227	pv/view/timemarker.hpp
	228	pv/view/trace.hpp
	229	pv/view/tracegroup.hpp
	230	pv/view/view.hpp
26e3af6b	231	pv/view/viewitem.hpp
2acdb232	232	pv/view/viewport.hpp
40aca27e	233	pv/view/viewwidget.hpp
2acdb232 JH	234	pv/widgets/colourbutton.hpp
2acdb232 JH	235	pv/widgets/colourpopup.hpp
079d39ea	236	pv/widgets/devicetoolbutton.hpp
1c4c23b8	237	pv/widgets/hidingmenubar.hpp
2acdb232 JH	238	pv/widgets/popup.hpp
	239	pv/widgets/popuptoolbutton.hpp
	240	pv/widgets/sweeptimingwidget.hpp
	241	pv/widgets/wellarray.hpp
df944399 JH	242	)
df944399 JH	243
a8d3fb2d	244	set(pulseview_FORMS
acda14b8	245	pv/dialogs/about.ui
df944399 JH	246	)
df944399 JH	247
a8d3fb2d JH	248	set(pulseview_RESOURCES
a8d3fb2d JH	249	pulseview.qrc
df944399 JH	250	)
df944399 JH	251
140181a4 JH	252	if(ENABLE_SIGNALS)
140181a4 JH	253	list(APPEND pulseview_SOURCES signalhandler.cpp)
2acdb232	254	list(APPEND pulseview_HEADERS signalhandler.hpp)
140181a4 JH	255	endif()
140181a4 JH	256
269528f5 JH	257	if(ENABLE_DECODE)
	258	list(APPEND pulseview_SOURCES
	259	pv/data/decoderstack.cpp
	260	pv/data/decode/annotation.cpp
	261	pv/data/decode/decoder.cpp
f9101a91 JH	262	pv/data/decode/row.cpp
f9101a91 JH	263	pv/data/decode/rowdata.cpp
269528f5 JH	264	pv/prop/binding/decoderoptions.cpp
	265	pv/view/decodetrace.cpp
	266	pv/widgets/decodergroupbox.cpp
	267	pv/widgets/decodermenu.cpp
269528f5 JH	268	)
	269
	270	list(APPEND pulseview_HEADERS
2acdb232 JH	271	pv/data/decoderstack.hpp
	272	pv/view/decodetrace.hpp
	273	pv/widgets/decodergroupbox.hpp
	274	pv/widgets/decodermenu.hpp
269528f5 JH	275	)
	276	endif()
	277
fe15e0bc UH	278	if(WIN32)
	279	# Use the sigrok icon for the pulseview.exe executable.
	280	set(CMAKE_RC_COMPILE_OBJECT "${CMAKE_RC_COMPILER} -O coff -I${CMAKE_CURRENT_SOURCE_DIR} <SOURCE> <OBJECT>")
	281	enable_language(RC)
61e1e13e	282	list(APPEND pulseview_SOURCES pulseviewico.rc)
fe15e0bc UH	283	endif()
fe15e0bc UH	284
9137928c MC	285	if(ANDROID)
	286	list(APPEND pulseview_SOURCES android/loghandler.cpp)
	287	endif()
	288
9e8e84fc MC	289	if(Qt5Core_FOUND)
	290	qt5_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	291	qt5_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	292	qt5_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	293	else()
	294	qt4_wrap_cpp(pulseview_HEADERS_MOC ${pulseview_HEADERS})
	295	qt4_wrap_ui(pulseview_FORMS_HEADERS ${pulseview_FORMS})
	296	qt4_add_resources(pulseview_RESOURCES_RCC ${pulseview_RESOURCES})
	297	include(${QT_USE_FILE})
	298	endif()
df944399	299
30588653 AG	300	#===============================================================================
	301	#= Global Definitions
	302	#-------------------------------------------------------------------------------
	303
e9213170	304	add_definitions(${QT_DEFINITIONS} -DQT_NO_KEYWORDS)
ac223c1e	305	add_definitions(-D__STDC_LIMIT_MACROS)
a9974171	306	add_definitions(-Wall -Wextra)
95d43108	307	add_definitions(-std=c++11)
5f606159	308
269528f5 JH	309	if(ENABLE_DECODE)
	310	add_definitions(-DENABLE_DECODE)
	311	endif()
	312
5f606159 JH	313	if(NOT DISABLE_WERROR)
	314	add_definitions(-Werror)
	315	endif()
df944399	316
9632990d UH	317	if(ENABLE_SIGNALS)
	318	add_definitions(-DENABLE_SIGNALS)
	319	endif()
	320
30588653 AG	321	#===============================================================================
	322	#= Global Include Directories
	323	#-------------------------------------------------------------------------------
	324
b04e278d AG	325	include_directories(
b04e278d AG	326	${CMAKE_CURRENT_BINARY_DIR}
cef18fc6	327	${CMAKE_CURRENT_SOURCE_DIR}
b04e278d	328	${Boost_INCLUDE_DIRS}
9e8e84fc	329	${QT_INCLUDE_DIRS}
b04e278d AG	330	)
	331
	332	if(STATIC_PKGDEPS_LIBS)
	333	include_directories(${PKGDEPS_STATIC_INCLUDE_DIRS})
	334	else()
	335	include_directories(${PKGDEPS_INCLUDE_DIRS})
	336	endif()
df944399	337
30588653 AG	338	#===============================================================================
	339	#= Linker Configuration
	340	#-------------------------------------------------------------------------------
	341
b04e278d AG	342	link_directories(${Boost_LIBRARY_DIRS})
	343
	344	set(PULSEVIEW_LINK_LIBS
	345	${Boost_LIBRARIES}
	346	${QT_LIBRARIES}
2b76309a	347	${CMAKE_THREAD_LIBS_INIT}
b04e278d AG	348	)
	349
	350	if(STATIC_PKGDEPS_LIBS)
	351	link_directories(${PKGDEPS_STATIC_LIBRARY_DIRS})
	352	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_STATIC_LIBRARIES})
7cfb538d UH	353	if(WIN32)
	354	# Workaround for a MinGW linking issue.
	355	list(APPEND PULSEVIEW_LINK_LIBS "-llzma -llcms2")
	356	endif()
b04e278d AG	357	else()
	358	link_directories(${PKGDEPS_LIBRARY_DIRS})
	359	list(APPEND PULSEVIEW_LINK_LIBS ${PKGDEPS_LIBRARIES})
	360	endif()
df944399	361
11a04e2a UH	362	if(WIN32)
	363	# On Windows we need to statically link the libqsvg imageformat
	364	# plugin (and the QtSvg component) for SVG graphics/icons to work.
	365	add_definitions(-DQT_STATICPLUGIN)
	366	link_directories("${QT_PLUGINS_DIR}/imageformats")
11a04e2a	367	list(APPEND PULSEVIEW_LINK_LIBS "-lqsvg")
52f38de6	368	list(APPEND PULSEVIEW_LINK_LIBS ${QT_QTSVG_LIBRARY})
11a04e2a UH	369	endif()
11a04e2a UH	370
9137928c MC	371	if(ANDROID)
	372	list(APPEND PULSEVIEW_LINK_LIBS "-llog")
	373	endif()
	374
26807061 MC	375	if(ANDROID)
	376	add_library(${PROJECT_NAME} SHARED
	377	${pulseview_SOURCES}
	378	${pulseview_HEADERS_MOC}
	379	${pulseview_FORMS_HEADERS}
	380	${pulseview_RESOURCES_RCC}
	381	)
	382	else()
5a13850b	383	add_executable(${PROJECT_NAME}
a8d3fb2d JH	384	${pulseview_SOURCES}
	385	${pulseview_HEADERS_MOC}
	386	${pulseview_FORMS_HEADERS}
	387	${pulseview_RESOURCES_RCC}
df944399	388	)
26807061	389	endif()
df944399	390
5a13850b	391	target_link_libraries(${PROJECT_NAME} ${PULSEVIEW_LINK_LIBS})
f0fa92c6	392
b0d8c0dc	393	if(WIN32)
61e1e13e UH	394	# Pass -mwindows so that no "DOS box" opens when PulseView is started.
61e1e13e UH	395	set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "-mwindows")
b0d8c0dc UH	396	endif()
b0d8c0dc UH	397
30588653 AG	398	#===============================================================================
	399	#= Installation
	400	#-------------------------------------------------------------------------------
	401
52bbe600	402	# Install the executable.
cd6606c2 AG	403	install(TARGETS ${PROJECT_NAME} DESTINATION bin/)
cd6606c2 AG	404
52bbe600 UH	405	# Install the manpage.
	406	install(FILES doc/pulseview.1 DESTINATION ${CMAKE_INSTALL_MANDIR}/man1 COMPONENT doc)
	407
cd6606c2 AG	408	#===============================================================================
	409	#= Packaging (handled by CPack)
	410	#-------------------------------------------------------------------------------
	411
b02a8cbf JH	412	set(CPACK_PACKAGE_VERSION_MAJOR ${PV_VERSION_MAJOR})
	413	set(CPACK_PACKAGE_VERSION_MINOR ${PV_VERSION_MINOR})
	414	set(CPACK_PACKAGE_VERSION_PATCH ${PV_VERSION_MICRO})
cd6606c2 AG	415	set(CPACK_PACKAGE_DESCRIPTION_FILE ${CMAKE_CURRENT_SOURCE_DIR}/README)
	416	set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/COPYING)
	417	set(CPACK_SOURCE_IGNORE_FILES ${CMAKE_CURRENT_BINARY_DIR} ".gitignore" ".git")
4b413894 JH	418	set(CPACK_SOURCE_PACKAGE_FILE_NAME
4b413894 JH	419	"${CMAKE_PROJECT_NAME}-${PV_VERSION_MAJOR}.${PV_VERSION_MINOR}.${PV_VERSION_MICRO}")
1d2fb87d	420	set(CPACK_SOURCE_GENERATOR "TGZ")
cd6606c2 AG	421
cd6606c2 AG	422	include(CPack)
bc1c1462	423
30588653 AG	424	#===============================================================================
	425	#= Tests
	426	#-------------------------------------------------------------------------------
	427
77e8ac52	428	if(ENABLE_TESTS)
fb746bcc	429	add_subdirectory(test)
951c583c	430	enable_testing()
fb746bcc	431	add_test(test ${CMAKE_CURRENT_BINARY_DIR}/test/pulseview-test)
0aad432c	432	endif()