| | 1 | ## |
| | 2 | ## This file is part of the libsigrok project. |
| | 3 | ## |
| | 4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> |
| | 5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> |
| | 6 | ## |
| | 7 | ## This program is free software: you can redistribute it and/or modify |
| | 8 | ## it under the terms of the GNU General Public License as published by |
| | 9 | ## the Free Software Foundation, either version 3 of the License, or |
| | 10 | ## (at your option) any later version. |
| | 11 | ## |
| | 12 | ## This program is distributed in the hope that it will be useful, |
| | 13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of |
| | 14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| | 15 | ## GNU General Public License for more details. |
| | 16 | ## |
| | 17 | ## You should have received a copy of the GNU General Public License |
| | 18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. |
| | 19 | ## |
| | 20 | |
| | 21 | # We require at least autoconf 2.63 (AC_INIT format changed there). |
| | 22 | AC_PREREQ([2.63]) |
| | 23 | |
| | 24 | AC_INIT([libsigrok], [0.5.1], |
| | 25 | [sigrok-devel@lists.sourceforge.net], |
| | 26 | [libsigrok], [http://www.sigrok.org]) |
| | 27 | AC_CONFIG_MACRO_DIR([m4]) |
| | 28 | AC_CONFIG_AUX_DIR([autostuff]) |
| | 29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) |
| | 30 | |
| | 31 | # We require at least automake 1.11 (needed for 'silent rules'). |
| | 32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) |
| | 33 | AM_SILENT_RULES([yes]) |
| | 34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) |
| | 35 | |
| | 36 | AC_CANONICAL_HOST |
| | 37 | |
| | 38 | # Checks for programs. |
| | 39 | AC_PROG_CC |
| | 40 | AC_PROG_CXX |
| | 41 | AC_PROG_INSTALL |
| | 42 | AC_PROG_LN_S |
| | 43 | |
| | 44 | # Required for per-target flags or subdir-objects with C sources. |
| | 45 | AM_PROG_CC_C_O |
| | 46 | |
| | 47 | # Set the standard the C library headers should conform to. |
| | 48 | AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */ |
| | 49 | #ifndef _POSIX_C_SOURCE |
| | 50 | # define _POSIX_C_SOURCE 200112L |
| | 51 | #endif]) |
| | 52 | |
| | 53 | # Get compiler versions. |
| | 54 | SR_PROG_VERSION([$CC], [sr_cc_version]) |
| | 55 | SR_PROG_VERSION([$CXX], [sr_cxx_version]) |
| | 56 | |
| | 57 | # Check for optional make features. |
| | 58 | SR_PROG_MAKE_ORDER_ONLY |
| | 59 | |
| | 60 | # Initialize libtool. |
| | 61 | LT_INIT |
| | 62 | |
| | 63 | # Set up the libsigrok version defines. |
| | 64 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) |
| | 65 | |
| | 66 | # Library version for libsigrok (NOT the same as the package version). |
| | 67 | # Carefully read the libtool docs before updating these numbers! |
| | 68 | # The algorithm for determining which number to change (and how) is nontrivial! |
| | 69 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info |
| | 70 | # Format: current:revision:age. |
| | 71 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [5:0:1]) |
| | 72 | |
| | 73 | AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"]) |
| | 74 | |
| | 75 | ############################# |
| | 76 | ## Optional dependencies ## |
| | 77 | ############################# |
| | 78 | |
| | 79 | AC_LANG([C]) |
| | 80 | |
| | 81 | # Initialize pkg-config. |
| | 82 | # We require at least 0.22, as "Requires.private" behaviour changed there. |
| | 83 | PKG_PROG_PKG_CONFIG([0.22]) |
| | 84 | |
| | 85 | # Keep track of all checked modules so we can list them at the end. |
| | 86 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) |
| | 87 | |
| | 88 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. |
| | 89 | # These are used to derive the compiler flags and for the "Requires.private" |
| | 90 | # field in the generated libsigrok.pc file. |
| | 91 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) |
| | 92 | SR_PKGLIBS_TESTS= |
| | 93 | SR_PKGLIBS_CXX= |
| | 94 | SR_PKGLIBS_PYTHON= |
| | 95 | SR_PKGLIBS_RUBY= |
| | 96 | SR_EXTRA_LIBS= |
| | 97 | SR_EXTRA_CXX_LIBS= |
| | 98 | |
| | 99 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL], |
| | 100 | [libserialport >= 0.1.1]) |
| | 101 | |
| | 102 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0]) |
| | 103 | |
| | 104 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. |
| | 105 | # This means libusb-1.0 is always available; no need to check for it. |
| | 106 | # On Windows, require the latest version we can get our hands on, |
| | 107 | # until the new generic event handling has seen an official release. |
| | 108 | AS_CASE([$host_os], |
| | 109 | [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes], |
| | 110 | [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'], |
| | 111 | [sr_libusb_req='libusb-1.0 >= 1.0.16']) |
| | 112 | |
| | 113 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], |
| | 114 | [$sr_libusb_req]) |
| | 115 | |
| | 116 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], |
| | 117 | [librevisa >= 0.0.20130412]) |
| | 118 | |
| | 119 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], |
| | 120 | [libgpib]) |
| | 121 | |
| | 122 | SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [ |
| | 123 | sr_save_LIBS=$LIBS |
| | 124 | LIBS="-lieee1284 $LIBS" |
| | 125 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]], |
| | 126 | [[(void) ieee1284_open(0, 0, 0);]])], |
| | 127 | [sr_have_libieee1284=yes], [sr_have_libieee1284=no]) |
| | 128 | LIBS=$sr_save_LIBS |
| | 129 | ]) |
| | 130 | AS_IF([test "x$sr_have_libieee1284" = xyes], |
| | 131 | [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])]) |
| | 132 | |
| | 133 | ###################### |
| | 134 | ## Feature checks ## |
| | 135 | ###################### |
| | 136 | |
| | 137 | # The Check unit testing framework is optional. Disable if not found. |
| | 138 | SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4]) |
| | 139 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) |
| | 140 | |
| | 141 | # Enable the C99 standard if possible, and enforce the use |
| | 142 | # of SR_API to explicitly mark all public API functions. |
| | 143 | SR_EXTRA_CFLAGS= |
| | 144 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) |
| | 145 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) |
| | 146 | |
| | 147 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) |
| | 148 | |
| | 149 | # Check host characteristics. |
| | 150 | AC_SYS_LARGEFILE |
| | 151 | AC_C_BIGENDIAN |
| | 152 | |
| | 153 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) |
| | 154 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) |
| | 155 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) |
| | 156 | |
| | 157 | # We need to link against the Winsock2 library for SCPI over TCP. |
| | 158 | AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])]) |
| | 159 | |
| | 160 | # libm (the standard math library) is always needed. |
| | 161 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) |
| | 162 | |
| | 163 | # RPC is only needed for VXI support. |
| | 164 | AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc], |
| | 165 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( |
| | 166 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], |
| | 167 | [[(void) clnt_create("", 0, 0, "");]])], |
| | 168 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])]) |
| | 169 | AS_IF([test "x$sr_cv_have_rpc" = xyes], |
| | 170 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])]) |
| | 171 | # VXI support is only compiled if RPC support was found. |
| | 172 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) |
| | 173 | |
| | 174 | # Check for compiler support of 128 bit integers |
| | 175 | AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], []) |
| | 176 | |
| | 177 | ######################## |
| | 178 | ## Hardware drivers ## |
| | 179 | ######################## |
| | 180 | |
| | 181 | # Keep track of all drivers so we can list them at the end. |
| | 182 | SR_VAR_SUMMARY([sr_driver_summary]) |
| | 183 | |
| | 184 | # Check whether the sr_deps_avail list contains all of the arguments. |
| | 185 | # Unavailable dependencies are collected in sr_deps_missing. |
| | 186 | sr_check_driver_deps() { |
| | 187 | sr_deps_missing= |
| | 188 | for sr_dep |
| | 189 | do |
| | 190 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, |
| | 191 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) |
| | 192 | done |
| | 193 | test -z "$sr_deps_missing" || return 1 |
| | 194 | } |
| | 195 | |
| | 196 | AC_ARG_ENABLE([all-drivers], |
| | 197 | [AS_HELP_STRING([--enable-all-drivers], |
| | 198 | [enable all drivers by default [default=yes]])], |
| | 199 | [], [enable_all_drivers=yes]) |
| | 200 | |
| | 201 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) |
| | 202 | m4_define([_SR_DRIVER], [ |
| | 203 | AC_ARG_ENABLE([$2], |
| | 204 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], |
| | 205 | [$3=$enableval], [$3=$enable_all_drivers]) |
| | 206 | |
| | 207 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ |
| | 208 | sr_check_driver_deps $4 \ |
| | 209 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" |
| | 210 | ])], [sr_hw_info='no (disabled)']) |
| | 211 | sr_driver_summary_append "$2" "$sr_hw_info" |
| | 212 | |
| | 213 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) |
| | 214 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])]) |
| | 215 | ]) |
| | 216 | |
| | 217 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) |
| | 218 | m4_define([SR_DRIVER], |
| | 219 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) |
| | 220 | |
| | 221 | SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport]) |
| | 222 | SR_DRIVER([Appa 55II], [appa-55ii], [libserialport]) |
| | 223 | SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport]) |
| | 224 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) |
| | 225 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport]) |
| | 226 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) |
| | 227 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) |
| | 228 | SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb]) |
| | 229 | SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport]) |
| | 230 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport]) |
| | 231 | SR_DRIVER([Center 3xx], [center-3xx], [libserialport]) |
| | 232 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi]) |
| | 233 | SR_DRIVER([Colead SLM], [colead-slm], [libserialport]) |
| | 234 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport]) |
| | 235 | SR_DRIVER([demo], [demo]) |
| | 236 | SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb]) |
| | 237 | SR_DRIVER([Fluke 45], [fluke-45]) |
| | 238 | SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport]) |
| | 239 | SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi]) |
| | 240 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) |
| | 241 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport]) |
| | 242 | SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport]) |
| | 243 | SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [libserialport]) |
| | 244 | SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport]) |
| | 245 | SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb]) |
| | 246 | SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb]) |
| | 247 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) |
| | 248 | SR_DRIVER([HP 3457A], [hp-3457a]) |
| | 249 | SR_DRIVER([HP 3478A], [hp-3478a], [libgpib]) |
| | 250 | SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284]) |
| | 251 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) |
| | 252 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) |
| | 253 | SR_DRIVER([IPDBG LA], [ipdbg-la]) |
| | 254 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) |
| | 255 | SR_DRIVER([KERN scale], [kern-scale], [libserialport]) |
| | 256 | SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport]) |
| | 257 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) |
| | 258 | SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb]) |
| | 259 | SR_DRIVER([LeCroy X-Stream], [lecroy-xstream]) |
| | 260 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport]) |
| | 261 | SR_DRIVER([maynuo-m97], [maynuo-m97]) |
| | 262 | SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport]) |
| | 263 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport]) |
| | 264 | SR_DRIVER([Norma DMM], [norma-dmm], [libserialport]) |
| | 265 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport]) |
| | 266 | SR_DRIVER([PCE PCE-322A], [pce-322a], [libserialport]) |
| | 267 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) |
| | 268 | SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [libserialport]) |
| | 269 | SR_DRIVER([Rigol DS], [rigol-ds]) |
| | 270 | SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [libserialport]) |
| | 271 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) |
| | 272 | SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb]) |
| | 273 | SR_DRIVER([SCPI PPS], [scpi-pps]) |
| | 274 | SR_DRIVER([serial DMM], [serial-dmm], [libserialport]) |
| | 275 | SR_DRIVER([serial LCR], [serial-lcr], [libserialport]) |
| | 276 | SR_DRIVER([Siglent SDS], [siglent-sds]) |
| | 277 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) |
| | 278 | SR_DRIVER([Teleinfo], [teleinfo], [libserialport]) |
| | 279 | SR_DRIVER([Testo], [testo], [libusb]) |
| | 280 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport]) |
| | 281 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) |
| | 282 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb]) |
| | 283 | SR_DRIVER([Victor DMM], [victor-dmm], [libusb]) |
| | 284 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) |
| | 285 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) |
| | 286 | SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [libserialport]) |
| | 287 | |
| | 288 | ############################### |
| | 289 | ## Language bindings setup ## |
| | 290 | ############################### |
| | 291 | |
| | 292 | AC_LANG([C++]) |
| | 293 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) |
| | 294 | |
| | 295 | AC_ARG_ENABLE([bindings], |
| | 296 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], |
| | 297 | [], [enable_bindings=yes]) |
| | 298 | |
| | 299 | AC_ARG_ENABLE([cxx], |
| | 300 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], |
| | 301 | [], [enable_cxx=$enable_bindings]) |
| | 302 | |
| | 303 | AC_ARG_ENABLE([python], |
| | 304 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], |
| | 305 | [], [enable_python=$enable_bindings]) |
| | 306 | |
| | 307 | AC_ARG_ENABLE([ruby], |
| | 308 | [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])], |
| | 309 | [], [enable_ruby=$enable_bindings]) |
| | 310 | |
| | 311 | AC_ARG_ENABLE([java], |
| | 312 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], |
| | 313 | [], [enable_java=$enable_bindings]) |
| | 314 | |
| | 315 | #################### |
| | 316 | ## C++ bindings ## |
| | 317 | #################### |
| | 318 | |
| | 319 | sr_cxx_missing= |
| | 320 | |
| | 321 | # Check if the C++ compiler supports the C++11 standard. |
| | 322 | AX_CXX_COMPILE_STDCXX([11], [noext], [optional]) |
| | 323 | AS_IF([test "x$HAVE_CXX11" != x1], |
| | 324 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) |
| | 325 | |
| | 326 | # The C++ bindings need glibmm. |
| | 327 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) |
| | 328 | AS_IF([test "x$sr_have_glibmm" != xyes], |
| | 329 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) |
| | 330 | |
| | 331 | # The C++ bindings use Doxygen to parse libsigrok symbols. |
| | 332 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) |
| | 333 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], |
| | 334 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) |
| | 335 | |
| | 336 | # Link C++ code with gnustl_shared if it exists (Android) |
| | 337 | SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared]) |
| | 338 | |
| | 339 | # Python is needed for the C++ bindings. |
| | 340 | AM_PATH_PYTHON([2.7], |
| | 341 | [HAVE_PYTHON=yes], |
| | 342 | [HAVE_PYTHON=no |
| | 343 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) |
| | 344 | |
| | 345 | AS_IF([test -z "$sr_cxx_missing"], |
| | 346 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) |
| | 347 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) |
| | 348 | |
| | 349 | # C++ bindings want stoi and stod. |
| | 350 | AM_COND_IF([BINDINGS_CXX], [ |
| | 351 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], |
| | 352 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], |
| | 353 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], |
| | 354 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) |
| | 355 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], |
| | 356 | [AC_DEFINE([HAVE_STOI_STOD], [1], |
| | 357 | [Specifies whether we have the stoi and stod functions.])]) |
| | 358 | ]) |
| | 359 | |
| | 360 | ####################### |
| | 361 | ## Python bindings ## |
| | 362 | ####################### |
| | 363 | |
| | 364 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 365 | [sr_python_missing=], |
| | 366 | [sr_python_missing='C++ bindings']) |
| | 367 | |
| | 368 | # Extract major and minor version number of the Python interpreter. |
| | 369 | sr_pymajor=${PYTHON_VERSION%%.*} |
| | 370 | sr_pyminor=${PYTHON_VERSION#*.} |
| | 371 | |
| | 372 | # The Python bindings need Python development files. Check for either |
| | 373 | # Python 3 or Python 2 headers depending on the interpreter version. |
| | 374 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], |
| | 375 | [python = $PYTHON_VERSION], |
| | 376 | [python$sr_pymajor = $PYTHON_VERSION], |
| | 377 | [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION], |
| | 378 | [python-$PYTHON_VERSION = $PYTHON_VERSION]) |
| | 379 | |
| | 380 | AS_IF([test "x$sr_have_python_dev" != xyes], |
| | 381 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) |
| | 382 | |
| | 383 | # PyGObject is needed for the Python bindings. |
| | 384 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) |
| | 385 | AS_IF([test "x$sr_have_pygobject" != xyes], |
| | 386 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) |
| | 387 | |
| | 388 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], |
| | 389 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], |
| | 390 | [Whether last argument to pyg_flags_get_value() is signed.])]) |
| | 391 | |
| | 392 | # The Python bindings need the setuptools and numpy Python modules. |
| | 393 | # We'll let it go through even if the AX macro wasn't found, as the |
| | 394 | # Python modules may still be there. |
| | 395 | m4_ifdef([AX_PYTHON_MODULE], [ |
| | 396 | AX_PYTHON_MODULE([setuptools]) |
| | 397 | AX_PYTHON_MODULE([numpy]) |
| | 398 | ], [ |
| | 399 | HAVE_PYMOD_SETUPTOOLS=yes |
| | 400 | HAVE_PYMOD_NUMPY=yes |
| | 401 | m4_warn([unsupported], |
| | 402 | [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy]) |
| | 403 | ]) |
| | 404 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], |
| | 405 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) |
| | 406 | AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes], |
| | 407 | [SR_APPEND([sr_python_missing], [', '], [numpy])]) |
| | 408 | |
| | 409 | # The Python bindings use SWIG to generate code. |
| | 410 | AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0]) |
| | 411 | AS_IF([test "x$SWIG" != x], |
| | 412 | AC_MSG_CHECKING([for $SWIG version]) |
| | 413 | [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`] |
| | 414 | AC_MSG_RESULT([$SWIG_VERSION])) |
| | 415 | AS_IF([test "x$SWIG" = x], |
| | 416 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) |
| | 417 | |
| | 418 | AS_IF([test -z "$sr_python_missing"], |
| | 419 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) |
| | 420 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) |
| | 421 | |
| | 422 | ##################### |
| | 423 | ## Ruby bindings ## |
| | 424 | ##################### |
| | 425 | |
| | 426 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 427 | [sr_ruby_missing=], |
| | 428 | [sr_ruby_missing='C++ bindings']) |
| | 429 | |
| | 430 | AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], []) |
| | 431 | AS_IF([test "x$RUBY" != x], |
| | 432 | AC_MSG_CHECKING([for Ruby version]) |
| | 433 | [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`] |
| | 434 | AC_MSG_RESULT([$RUBY_VERSION]) |
| | 435 | [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`] |
| | 436 | AC_SUBST(RUBY_DLEXT)) |
| | 437 | |
| | 438 | AS_IF([test "x$RUBY" = x], |
| | 439 | [SR_APPEND([sr_ruby_missing], [', '], [Ruby])]) |
| | 440 | |
| | 441 | # Extract major and minor version number of the Ruby interpreter. |
| | 442 | sr_rbmajor=${RUBY_VERSION%%.*} |
| | 443 | sr_rbminor=${RUBY_VERSION#*.} |
| | 444 | sr_rbminor=${sr_rbminor%%.*} |
| | 445 | |
| | 446 | # The Ruby bindings need Ruby development files. |
| | 447 | SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY], |
| | 448 | [ruby], |
| | 449 | [ruby-$sr_rbmajor.$sr_rbminor]) |
| | 450 | |
| | 451 | AS_IF([test "x$sr_have_ruby_dev" != xyes], |
| | 452 | [SR_APPEND([sr_ruby_missing], [', '], [Headers])]) |
| | 453 | |
| | 454 | # The Ruby bindings use SWIG >= 3.0.8 to generate code. |
| | 455 | AS_IF([test "x$SWIG" = x], |
| | 456 | [SR_APPEND([sr_ruby_missing], [', '], [SWIG])], |
| | 457 | [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8", |
| | 458 | [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])]) |
| | 459 | |
| | 460 | AS_IF([test -z "$sr_ruby_missing"], |
| | 461 | [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no]) |
| | 462 | AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes]) |
| | 463 | |
| | 464 | #################### |
| | 465 | ## Java bindings ## |
| | 466 | #################### |
| | 467 | |
| | 468 | AS_IF([test "x$BINDINGS_CXX" = xyes], |
| | 469 | [sr_java_missing=], |
| | 470 | [sr_java_missing='C++ bindings']) |
| | 471 | |
| | 472 | # The Java bindings use SWIG to generate code. |
| | 473 | AS_IF([test "x$SWIG" = x], |
| | 474 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) |
| | 475 | |
| | 476 | # Find Java compiler and JNI includes for Java bindings. |
| | 477 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) |
| | 478 | AS_IF([test "x$HAVE_JAVAC" = xno], |
| | 479 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) |
| | 480 | |
| | 481 | AC_ARG_WITH([jni-include-path], |
| | 482 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], |
| | 483 | [specify JNI include directories [default=detect]])], |
| | 484 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) |
| | 485 | |
| | 486 | JNI_CPPFLAGS= |
| | 487 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ |
| | 488 | AX_PROG_JAVAC |
| | 489 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ |
| | 490 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: |
| | 491 | ## If we can find jni.h without any special search path, skip |
| | 492 | ## the execution of the broken macro to increase our chances of |
| | 493 | ## success. |
| | 494 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, |
| | 495 | [AX_JNI_INCLUDE_DIR]) |
| | 496 | ]) |
| | 497 | ]) |
| | 498 | for sr_dir in $JNI_INCLUDE_DIRS |
| | 499 | do |
| | 500 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) |
| | 501 | done |
| | 502 | AC_SUBST([JNI_CPPFLAGS]) |
| | 503 | |
| | 504 | sr_save_cppflags=$CPPFLAGS |
| | 505 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) |
| | 506 | AC_CHECK_HEADER([jni.h],, |
| | 507 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) |
| | 508 | CPPFLAGS=$sr_save_cppflags |
| | 509 | |
| | 510 | AS_IF([test -z "$sr_java_missing"], |
| | 511 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) |
| | 512 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) |
| | 513 | |
| | 514 | ############################## |
| | 515 | ## Finalize configuration ## |
| | 516 | ############################## |
| | 517 | |
| | 518 | # Add mandatory dependencies to module list. |
| | 519 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) |
| | 520 | AC_SUBST([SR_PKGLIBS]) |
| | 521 | |
| | 522 | # Retrieve the compile and link flags for all modules combined. |
| | 523 | # Also, bail out at this point if any module dependency is not met. |
| | 524 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) |
| | 525 | PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS]) |
| | 526 | |
| | 527 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when |
| | 528 | # the C++ bindings are enabled. |
| | 529 | AM_COND_IF([BINDINGS_CXX], [ |
| | 530 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) |
| | 531 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) |
| | 532 | PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")]) |
| | 533 | ]) |
| | 534 | |
| | 535 | # Check for specific libusb features, now that we know the CFLAGS. |
| | 536 | AC_LANG([C]) |
| | 537 | sr_save_cflags=$CFLAGS |
| | 538 | sr_save_libs=$LIBS |
| | 539 | CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS" |
| | 540 | LIBS="$LIBSIGROK_LIBS $LIBS" |
| | 541 | AC_CHECK_TYPES([libusb_os_handle], |
| | 542 | [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no], |
| | 543 | [[#include <libusb.h>]]) |
| | 544 | AC_CHECK_FUNCS([zip_discard]) |
| | 545 | LIBS=$sr_save_libs |
| | 546 | CFLAGS=$sr_save_cflags |
| | 547 | |
| | 548 | AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*], |
| | 549 | [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])]) |
| | 550 | |
| | 551 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` |
| | 552 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` |
| | 553 | |
| | 554 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], |
| | 555 | [Build-time version of libzip.]) |
| | 556 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], |
| | 557 | [The canonical host libsigrok will run on.]) |
| | 558 | |
| | 559 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) |
| | 560 | |
| | 561 | AC_OUTPUT |
| | 562 | |
| | 563 | # Prepare bindings report messages. |
| | 564 | m4_define([SR_PREPARE_BINDING_REPORT], [ |
| | 565 | sr_report_$1= |
| | 566 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" |
| | 567 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' |
| | 568 | ]) |
| | 569 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java]) |
| | 570 | |
| | 571 | cat >&AS_MESSAGE_FD <<_EOF |
| | 572 | |
| | 573 | libsigrok configuration summary: |
| | 574 | - Package version................. $SR_PACKAGE_VERSION |
| | 575 | - Library ABI version............. $SR_LIB_VERSION |
| | 576 | - Prefix.......................... $prefix |
| | 577 | - Building on..................... $build |
| | 578 | - Building for.................... $host |
| | 579 | - Building shared / static........ $enable_shared / $enable_static |
| | 580 | |
| | 581 | Compile configuration: |
| | 582 | - C compiler...................... $CC |
| | 583 | - C compiler version.............. $sr_cc_version |
| | 584 | - C compiler flags................ $CFLAGS |
| | 585 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS |
| | 586 | - C compiler warnings............. $SR_WFLAGS |
| | 587 | - C++ compiler.................... $CXX |
| | 588 | - C++ compiler version............ $sr_cxx_version |
| | 589 | - C++ compiler flags.............. $CXXFLAGS |
| | 590 | - C++ compiler warnings........... $SR_WXXFLAGS |
| | 591 | - Linker flags.................... $LDFLAGS |
| | 592 | |
| | 593 | Detected libraries (required): |
| | 594 | - glib-2.0 >= 2.32.0.............. $sr_glib_version |
| | 595 | - libzip >= 0.10.................. $sr_libzip_version |
| | 596 | |
| | 597 | Detected libraries (optional): |
| | 598 | $sr_pkglibs_summary |
| | 599 | Enabled hardware drivers: |
| | 600 | $sr_driver_summary |
| | 601 | Enabled SCPI backends: |
| | 602 | - TCP............................. yes |
| | 603 | - RPC............................. $sr_cv_have_rpc |
| | 604 | - serial.......................... $sr_have_libserialport |
| | 605 | - VISA............................ $sr_have_librevisa |
| | 606 | - GPIB............................ $sr_have_libgpib |
| | 607 | - USBTMC.......................... $sr_have_libusb |
| | 608 | |
| | 609 | Enabled language bindings: |
| | 610 | - C++............................. $BINDINGS_CXX$sr_report_cxx |
| | 611 | - Python.......................... $BINDINGS_PYTHON$sr_report_python |
| | 612 | - Ruby............................ $BINDINGS_RUBY$sr_report_ruby |
| | 613 | - Java............................ $BINDINGS_JAVA$sr_report_java |
| | 614 | |
| | 615 | _EOF |
| | 616 | |
| | 617 | # Emit a warning if the C++ bindings are not being built. |
| | 618 | AM_COND_IF([BINDINGS_CXX], [], [ |
| | 619 | cat >&AS_MESSAGE_FD <<_EOF |
| | 620 | =============================================================================== |
| | 621 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING |
| | 622 | =============================================================================== |
| | 623 | === === |
| | 624 | === The libsigrok C++ bindings are not being built since you === |
| | 625 | === are missing one or more dependencies (see above)! === |
| | 626 | === === |
| | 627 | === This means you won't be able to compile frontends that require === |
| | 628 | === the C++ bindings (such as PulseView)! You also won't be able to build === |
| | 629 | === other bindings and frontends using those (such as sigrok-meter)! === |
| | 630 | === === |
| | 631 | =============================================================================== |
| | 632 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING |
| | 633 | =============================================================================== |
| | 634 | |
| | 635 | _EOF |
| | 636 | ]) |
projects / libsigrok.git / blame_incremental