]>
Commit | Line | Data |
---|---|---|
1 | ## | |
2 | ## This file is part of the PulseView project. | |
3 | ## | |
4 | ## Copyright (C) 2013-2014 Uwe Hermann <uwe@hermann-uwe.de> | |
5 | ## | |
6 | ## This program is free software; you can redistribute it and/or modify | |
7 | ## it under the terms of the GNU General Public License as published by | |
8 | ## the Free Software Foundation; either version 2 of the License, or | |
9 | ## (at your option) any later version. | |
10 | ## | |
11 | ## This program is distributed in the hope that it will be useful, | |
12 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
13 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
14 | ## GNU General Public License for more details. | |
15 | ## | |
16 | ## You should have received a copy of the GNU General Public License | |
17 | ## along with this program; if not, see <http://www.gnu.org/licenses/>. | |
18 | ## | |
19 | ||
20 | # | |
21 | # This file is used to create the PulseView Windows installer via NSIS. | |
22 | # It is meant for use in a cross-compile setup (not for native builds). | |
23 | # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details. | |
24 | # | |
25 | # NSIS documentation: | |
26 | # http://nsis.sourceforge.net/Docs/ | |
27 | # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html | |
28 | # | |
29 | ||
30 | # Include the "Modern UI" header, which gives us the usual Windows look-n-feel. | |
31 | !include "MUI2.nsh" | |
32 | ||
33 | # Include the file association header so that we can register file extensions. | |
34 | !include "FileAssociation.nsh" | |
35 | ||
36 | ||
37 | # --- Global stuff ------------------------------------------------------------ | |
38 | ||
39 | # Installer/product name. | |
40 | Name "PulseView" | |
41 | ||
42 | # Filename of the installer executable. | |
43 | OutFile "pulseview-@PV_VERSION_STRING@-installer.exe" | |
44 | ||
45 | # Where to install the application. | |
46 | InstallDir "$PROGRAMFILES\sigrok\PulseView" | |
47 | ||
48 | # Request admin privileges for Windows Vista and Windows 7. | |
49 | # http://nsis.sourceforge.net/Docs/Chapter4.html | |
50 | RequestExecutionLevel admin | |
51 | ||
52 | # Local helper definitions. | |
53 | !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\PulseView" | |
54 | ||
55 | ||
56 | # --- MUI interface configuration --------------------------------------------- | |
57 | ||
58 | # Use the following icon for the installer EXE file. | |
59 | !define MUI_ICON "@PROJECT_SOURCE_DIR@/icons/pulseview.ico" | |
60 | ||
61 | # Show a nice image at the top of each installer page. | |
62 | !define MUI_HEADERIMAGE | |
63 | ||
64 | # Don't automatically go to the Finish page so the user can check the log. | |
65 | !define MUI_FINISHPAGE_NOAUTOCLOSE | |
66 | ||
67 | # Upon "cancel", ask the user if he really wants to abort the installer. | |
68 | !define MUI_ABORTWARNING | |
69 | ||
70 | # Don't force the user to accept the license, just show it. | |
71 | # Details: http://trac.videolan.org/vlc/ticket/3124 | |
72 | !define MUI_LICENSEPAGE_BUTTON $(^NextBtn) | |
73 | !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue." | |
74 | ||
75 | # Path where the cross-compiled sigrok tools and libraries are located. | |
76 | # Change this to where-ever you installed libsigrok.a and so on. | |
77 | !define CROSS "@CMAKE_INSTALL_PREFIX@" | |
78 | ||
79 | # Defines for WinAPI SHChangeNotify call. | |
80 | !define SHCNE_ASSOCCHANGED 0x8000000 | |
81 | !define SHCNF_IDLIST 0 | |
82 | ||
83 | ||
84 | # --- Functions --------------------------------------------------------------- | |
85 | ||
86 | Function register_sr_files | |
87 | ${registerExtension} "$INSTDIR\pulseview.exe" ".sr" "sigrok session file" | |
88 | ||
89 | # Force Windows to update the icon cache so that the icon for .sr files shows up. | |
90 | System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)' | |
91 | FunctionEnd | |
92 | ||
93 | ||
94 | # --- MUI pages --------------------------------------------------------------- | |
95 | ||
96 | # Show a nice "Welcome to the ... Setup Wizard" page. | |
97 | !insertmacro MUI_PAGE_WELCOME | |
98 | ||
99 | # Show the license of the project. | |
100 | !insertmacro MUI_PAGE_LICENSE "@PROJECT_SOURCE_DIR@/COPYING" | |
101 | ||
102 | # Show a screen which allows the user to select which components to install. | |
103 | !insertmacro MUI_PAGE_COMPONENTS | |
104 | ||
105 | # Allow the user to select a different install directory. | |
106 | !insertmacro MUI_PAGE_DIRECTORY | |
107 | ||
108 | # Perform the actual installation, i.e. install the files. | |
109 | !insertmacro MUI_PAGE_INSTFILES | |
110 | ||
111 | # Insert the "Show Readme" button in the finish dialog. We repurpose it for | |
112 | # registering the .sr file extension. This way, we don't need to add in-depth | |
113 | # modifications to the finish page. | |
114 | !define MUI_FINISHPAGE_SHOWREADME "" | |
115 | !define MUI_FINISHPAGE_SHOWREADME_CHECKED | |
116 | !define MUI_FINISHPAGE_SHOWREADME_TEXT "Register .sr files with PulseView" | |
117 | !define MUI_FINISHPAGE_SHOWREADME_FUNCTION register_sr_files | |
118 | ||
119 | # Show a final "We're done, click Finish to close this wizard" message. | |
120 | !insertmacro MUI_PAGE_FINISH | |
121 | ||
122 | # Pages used for the uninstaller. | |
123 | !insertmacro MUI_UNPAGE_WELCOME | |
124 | !insertmacro MUI_UNPAGE_CONFIRM | |
125 | !insertmacro MUI_UNPAGE_INSTFILES | |
126 | !insertmacro MUI_UNPAGE_FINISH | |
127 | ||
128 | ||
129 | # --- MUI language files ------------------------------------------------------ | |
130 | ||
131 | # Select an installer language (required!). | |
132 | !insertmacro MUI_LANGUAGE "English" | |
133 | ||
134 | ||
135 | # --- Default section --------------------------------------------------------- | |
136 | ||
137 | Section "PulseView (required)" Section1 | |
138 | # This section is gray (can't be disabled) in the component list. | |
139 | SectionIn RO | |
140 | ||
141 | # Install the file(s) specified below into the specified directory. | |
142 | SetOutPath "$INSTDIR" | |
143 | ||
144 | # License file. | |
145 | File "@PROJECT_SOURCE_DIR@/COPYING" | |
146 | ||
147 | # PulseView (statically linked, includes all libs). | |
148 | File "${CROSS}/bin/pulseview.exe" | |
149 | ||
150 | # Zadig (used for installing WinUSB drivers). | |
151 | File "${CROSS}/zadig.exe" | |
152 | File "${CROSS}/zadig_xp.exe" | |
153 | ||
154 | # Python | |
155 | File "${CROSS}/python34.dll" | |
156 | File "${CROSS}/python34.zip" | |
157 | ||
158 | SetOutPath "$INSTDIR\share" | |
159 | ||
160 | # Protocol decoders. | |
161 | File /r /x "__pycache__" /x "*.pyc" "${CROSS}/share/libsigrokdecode" | |
162 | ||
163 | # Firmware files. | |
164 | File /r "${CROSS}/share/sigrok-firmware" | |
165 | ||
166 | # Generate the uninstaller executable. | |
167 | WriteUninstaller "$INSTDIR\Uninstall.exe" | |
168 | ||
169 | # Create a sub-directory in the start menu. | |
170 | CreateDirectory "$SMPROGRAMS\sigrok" | |
171 | CreateDirectory "$SMPROGRAMS\sigrok\PulseView" | |
172 | ||
173 | # Create a shortcut for the PulseView application. | |
174 | SetOutPath "$INSTDIR" | |
175 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" \ | |
176 | "$INSTDIR\pulseview.exe" "" "$INSTDIR\pulseview.exe" \ | |
177 | 0 SW_SHOWNORMAL \ | |
178 | "" "Open-source, portable sigrok GUI" | |
179 | ||
180 | # Create a shortcut for the uninstaller. | |
181 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" \ | |
182 | "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \ | |
183 | SW_SHOWNORMAL "" "Uninstall PulseView" | |
184 | ||
185 | # Create a shortcut for the Zadig executable. | |
186 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" \ | |
187 | "$INSTDIR\zadig.exe" "" "$INSTDIR\zadig.exe" 0 \ | |
188 | SW_SHOWNORMAL "" "Zadig (PulseView)" | |
189 | ||
190 | # Create a shortcut for the Zadig executable (for Win XP). | |
191 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" \ | |
192 | "$INSTDIR\zadig_xp.exe" "" "$INSTDIR\zadig_xp.exe" 0 \ | |
193 | SW_SHOWNORMAL "" "Zadig (PulseView, Win XP)" | |
194 | ||
195 | # Create registry keys for "Add/remove programs" in the control panel. | |
196 | WriteRegStr HKLM "${REGSTR}" "DisplayName" "PulseView" | |
197 | WriteRegStr HKLM "${REGSTR}" "UninstallString" \ | |
198 | "$\"$INSTDIR\Uninstall.exe$\"" | |
199 | WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\"" | |
200 | WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \ | |
201 | "$\"$INSTDIR\pulseview.ico$\"" | |
202 | WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok" | |
203 | WriteRegStr HKLM "${REGSTR}" "HelpLink" \ | |
204 | "http://sigrok.org/wiki/PulseView" | |
205 | WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \ | |
206 | "http://sigrok.org/wiki/Downloads" | |
207 | WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org" | |
208 | WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PV_VERSION_STRING@" | |
209 | WriteRegStr HKLM "${REGSTR}" "Contact" \ | |
210 | "sigrok-devel@lists.sourceforge.org" | |
211 | WriteRegStr HKLM "${REGSTR}" "Comments" \ | |
212 | "This is a Qt based sigrok GUI." | |
213 | ||
214 | # Display "Remove" instead of "Modify/Remove" in the control panel. | |
215 | WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1 | |
216 | WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1 | |
217 | SectionEnd | |
218 | ||
219 | Section /o "Example data" Section2 | |
220 | # Example *.sr files. | |
221 | SetOutPath "$INSTDIR\examples" | |
222 | ||
223 | File "${CROSS}/share/sigrok-dumps/arm_trace/stm32f105/trace_example.sr" | |
224 | File "${CROSS}/share/sigrok-dumps/am230x/am2301/am2301_1mhz.sr" | |
225 | File "${CROSS}/share/sigrok-dumps/avr_isp/atmega88/isp_atmega88_erase_chip.sr" | |
226 | File "${CROSS}/share/sigrok-dumps/can/microchip_mcp2515dm-bm/mcp2515dm-bm-125kbits_msg_222_5bytes.sr" | |
227 | File "${CROSS}/share/sigrok-dumps/dcf77/pollin_dcf1_module/dcf77_120s.sr" | |
228 | File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc02b/hantek_6022be_powerup.sr" | |
229 | File "${CROSS}/share/sigrok-dumps/i2c/eeprom_24xx/microchip_24lc64/sainsmart_dds120_powerup_scl_sda_analog.sr" | |
230 | File "${CROSS}/share/sigrok-dumps/i2c/potentiometer/analog_devices_ad5258/ad5258_read_once_write_continuously_triangle.sr" | |
231 | File "${CROSS}/share/sigrok-dumps/mdio/lan8720a/lan8720a_read_write_read.sr" | |
232 | File "${CROSS}/share/sigrok-dumps/onewire/owfs/ds28ea00.sr" | |
233 | File "${CROSS}/share/sigrok-dumps/sdcard/sd_mode/rcar-h2/cmd23_cmd18.sr" | |
234 | File "${CROSS}/share/sigrok-dumps/spi/mx25l1605d/mx25l1605d_read.sr" | |
235 | File "${CROSS}/share/sigrok-dumps/uart/gps/mtk3339/mtk3339_8n1_9600.sr" | |
236 | File "${CROSS}/share/sigrok-dumps/usb/hid/mouse/olimex_stm32-h103_usb_hid/olimex_stm32-h103_usb_hid.sr" | |
237 | File "${CROSS}/share/sigrok-dumps/z80/kc85/kc85-20mhz.sr" | |
238 | ||
239 | # Create a shortcut for the example data folder. | |
240 | CreateShortCut "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" \ | |
241 | "$INSTDIR\examples" "" "$INSTDIR\examples" 0 \ | |
242 | SW_SHOWNORMAL "" "" | |
243 | SectionEnd | |
244 | ||
245 | ||
246 | # --- Uninstaller section ----------------------------------------------------- | |
247 | ||
248 | Section "Uninstall" | |
249 | # Always delete the uninstaller first (yes, this really works). | |
250 | Delete "$INSTDIR\Uninstall.exe" | |
251 | ||
252 | # Delete the application, the application data, and related libs. | |
253 | Delete "$INSTDIR\COPYING" | |
254 | Delete "$INSTDIR\pulseview.exe" | |
255 | Delete "$INSTDIR\zadig.exe" | |
256 | Delete "$INSTDIR\zadig_xp.exe" | |
257 | Delete "$INSTDIR\python34.dll" | |
258 | Delete "$INSTDIR\python34.zip" | |
259 | ||
260 | # Delete all decoders and everything else in libsigrokdecode/. | |
261 | # There could be *.pyc files or __pycache__ subdirs and so on. | |
262 | RMDir /r "$INSTDIR\share\libsigrokdecode" | |
263 | ||
264 | # Delete the firmware files. | |
265 | RMDir /r "$INSTDIR\share\sigrok-firmware" | |
266 | ||
267 | # Delete the example *.sr files. | |
268 | RMDir /r "$INSTDIR\examples\*" | |
269 | ||
270 | # Delete the install directory and its sub-directories. | |
271 | RMDir "$INSTDIR\share" | |
272 | RMDir "$INSTDIR\examples" | |
273 | RMDir "$INSTDIR" | |
274 | ||
275 | # Delete the links from the start menu. | |
276 | Delete "$SMPROGRAMS\sigrok\PulseView\PulseView.lnk" | |
277 | Delete "$SMPROGRAMS\sigrok\PulseView\Uninstall PulseView.lnk" | |
278 | Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView).lnk" | |
279 | Delete "$SMPROGRAMS\sigrok\PulseView\Zadig (PulseView, Win XP).lnk" | |
280 | Delete "$SMPROGRAMS\sigrok\PulseView\Examples (PulseView).lnk" | |
281 | ||
282 | # Delete the sub-directory in the start menu. | |
283 | RMDir "$SMPROGRAMS\sigrok\PulseView" | |
284 | RMDir "$SMPROGRAMS\sigrok" | |
285 | ||
286 | # Delete the registry key(s). | |
287 | DeleteRegKey HKLM "${REGSTR}" | |
288 | ||
289 | # Unregister any previously registered file extension(s). | |
290 | ${unregisterExtension} ".sr" "sigrok session file" | |
291 | ||
292 | # Force Windows to update the icon cache so that the icon for .sr files is reset. | |
293 | System::Call 'Shell32::SHChangeNotify(i ${SHCNE_ASSOCCHANGED}, i ${SHCNF_IDLIST}, i 0, i 0)' | |
294 | SectionEnd | |
295 | ||
296 | ||
297 | # --- Component selection section descriptions -------------------------------- | |
298 | ||
299 | LangString DESC_Section1 ${LANG_ENGLISH} "This installs the PulseView sigrok GUI, some firmware files, the protocol decoders, and all required libraries." | |
300 | LangString DESC_Section2 ${LANG_ENGLISH} "This installs some example files that you can use to try out the features sigrok has to offer." | |
301 | ||
302 | !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN | |
303 | !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1) | |
304 | !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2) | |
305 | !insertmacro MUI_FUNCTION_DESCRIPTION_END | |
306 |