contrib/sigrok-cli_cross.nsi.in

   1 ##
   2 ## This file is part of the sigrok-cli project.
   3 ##
   4 ## Copyright (C) 2011-2013 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 #
  22 # This file is used to create the sigrok-cli Windows installer via NSIS.
  23 # It is meant for use in a cross-compile setup (not for native builds).
  24 # See the 'sigrok-cross-mingw' script in the sigrok-util repo for details.
  25 #
  26 # NSIS documentation:
  27 # http://nsis.sourceforge.net/Docs/
  28 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
  29 #
  30
  31 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
  32 !include "MUI2.nsh"
  33
  34
  35 # --- Global stuff ------------------------------------------------------------
  36
  37 # Installer/product name.
  38 Name "@PACKAGE_NAME@"
  39
  40 # Filename of the installer executable.
  41 OutFile "@PACKAGE_NAME@-@PACKAGE_VERSION@-installer.exe"
  42
  43 # Where to install the application.
  44 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
  45
  46 # Request admin privileges for Windows Vista and Windows 7.
  47 # http://nsis.sourceforge.net/Docs/Chapter4.html
  48 RequestExecutionLevel admin
  49
  50 # Local helper definitions.
  51 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
  52
  53
  54 # --- MUI interface configuration ---------------------------------------------
  55
  56 # Use the following icon for the installer EXE file.
  57 !define MUI_ICON "sigrok-logo-notext.ico"
  58
  59 # Show a nice image at the top of each installer page.
  60 !define MUI_HEADERIMAGE
  61
  62 # Don't automatically go to the Finish page so the user can check the log.
  63 !define MUI_FINISHPAGE_NOAUTOCLOSE
  64
  65 # Upon "cancel", ask the user if he really wants to abort the installer.
  66 !define MUI_ABORTWARNING
  67
  68 # Don't force the user to accept the license, just show it.
  69 # Details: http://trac.videolan.org/vlc/ticket/3124
  70 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
  71 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
  72
  73 # File name of the Python installer MSI file.
  74 !define PY_INST "python-3.2.3.msi"
  75
  76 # Standard install path of the Python installer (do not change!).
  77 !define PY_BIN "c:\Python32"
  78
  79 # Path where the cross-compiled sigrok tools and libraries are located.
  80 # Change this to where-ever you installed libsigrok.a and so on.
  81 !define CROSS "$%HOME%/sr_mingw"
  82
  83 # Path where the cross-compiled MXE tools and libraries are located.
  84 # Change this to where-ever you installed MXE (and the files it built).
  85 !define MXE "$%HOME%/mxe-git/usr/i686-pc-mingw32"
  86
  87
  88 # --- MUI pages ---------------------------------------------------------------
  89
  90 # Show a nice "Welcome to the ... Setup Wizard" page.
  91 !insertmacro MUI_PAGE_WELCOME
  92
  93 # Show the license of the project.
  94 !insertmacro MUI_PAGE_LICENSE "../COPYING"
  95
  96 # Show a screen which allows the user to select which components to install.
  97 !insertmacro MUI_PAGE_COMPONENTS
  98
  99 # Allow the user to select a different install directory.
 100 !insertmacro MUI_PAGE_DIRECTORY
 101
 102 # Perform the actual installation, i.e. install the files.
 103 !insertmacro MUI_PAGE_INSTFILES
 104
 105 # Show a final "We're done, click Finish to close this wizard" message.
 106 !insertmacro MUI_PAGE_FINISH
 107
 108 # Pages used for the uninstaller.
 109 !insertmacro MUI_UNPAGE_WELCOME
 110 !insertmacro MUI_UNPAGE_CONFIRM
 111 !insertmacro MUI_UNPAGE_INSTFILES
 112 !insertmacro MUI_UNPAGE_FINISH
 113
 114
 115 # --- MUI language files ------------------------------------------------------
 116
 117 # Select an installer language (required!).
 118 !insertmacro MUI_LANGUAGE "English"
 119
 120
 121 # --- Default section ---------------------------------------------------------
 122
 123 Section "@PACKAGE_NAME@ (required)" Section1
 124
 125         # This section is gray (can't be disabled) in the component list.
 126         SectionIn RO
 127
 128         # Install the file(s) specified below into the specified directory.
 129         SetOutPath "$INSTDIR"
 130
 131         # License file
 132         File "../COPYING"
 133
 134         # sigrok-cli
 135         File "${CROSS}/bin/@PACKAGE_NAME@.exe"
 136
 137         # Install the file(s) specified below into the specified directory.
 138         SetOutPath "$INSTDIR\decoders"
 139
 140         # Protocol decoders
 141         File /r /x "__pycache__" "${CROSS}/share/libsigrokdecode/decoders/*"
 142
 143         # Generate the uninstaller executable.
 144         WriteUninstaller "$INSTDIR\Uninstall.exe"
 145
 146         # Create a sub-directory in the start menu.
 147         CreateDirectory "$SMPROGRAMS\sigrok"
 148         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 149
 150         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
 151         # Set the working directory (where the user will be placed into when
 152         # the DOS box starts) to the user's Desktop directory.
 153         SetOutPath "$DESKTOP"
 154         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
 155                 "$SYSDIR\cmd.exe" \
 156                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
 157                 "$SYSDIR\cmd.exe" 0 \
 158                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
 159
 160         # Create a shortcut for the uninstaller.
 161         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
 162                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
 163                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
 164
 165         # Create registry keys for "Add/remove programs" in the control panel.
 166         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
 167         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
 168                 "$\"$INSTDIR\Uninstall.exe$\""
 169         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
 170         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
 171                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
 172         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
 173         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
 174                 "http://sigrok.org/wiki/Sigrok-cli"
 175         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
 176                 "http://sigrok.org/wiki/Downloads"
 177         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
 178         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PACKAGE_VERSION@"
 179         WriteRegStr HKLM "${REGSTR}" "Contact" \
 180                 "sigrok-devel@lists.sourceforge.org"
 181         WriteRegStr HKLM "${REGSTR}" "Comments" \
 182                 "This is the sigrok command-line application."
 183
 184         # Display "Remove" instead of "Modify/Remove" in the control panel.
 185         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
 186         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
 187
 188         # TODO: Add sigrok-cli directory to the PATH env. variable.
 189
 190 SectionEnd
 191
 192
 193 # --- Python installer section ------------------------------------------------
 194
 195 Section "Python" Section2
 196
 197         # Copy the Python installer MSI file into the temporary directory.
 198         SetOutPath "$TEMP"
 199         File "${CROSS}/${PY_INST}"
 200
 201         # Run the Python installer MSI file from within our installer.
 202         ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
 203
 204         # Remove Python installer MSI file again.
 205         Delete "$TEMP\${PY_INST}"
 206
 207 SectionEnd
 208
 209
 210 # --- Uninstaller section -----------------------------------------------------
 211
 212 Section "Uninstall"
 213
 214         # Always delete the uninstaller first (yes, this really works).
 215         Delete "$INSTDIR\Uninstall.exe"
 216
 217         # Delete the application, the application data, and related libs.
 218         Delete "$INSTDIR\COPYING"
 219         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
 220
 221         # Delete all decoders and everything else in decoders/.
 222         # There could be *.pyc files or __pycache__ subdirs and so on.
 223         RMDir /r "$INSTDIR\decoders\*"
 224
 225         # Delete the install directory and its sub-directories.
 226         RMDir "$INSTDIR\decoders"
 227         RMDir "$INSTDIR"
 228
 229         # Delete the links from the start menu.
 230         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
 231         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
 232
 233         # Delete the sub-directory in the start menu.
 234         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
 235         RMDir "$SMPROGRAMS\sigrok"
 236
 237         # Delete the registry key(s).
 238         DeleteRegKey HKLM "${REGSTR}"
 239
 240 SectionEnd
 241
 242
 243 # --- Component selection section descriptions --------------------------------
 244
 245 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, the protocol decoders, and all required libraries."
 246 LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
 247
 248 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 249 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
 250 !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
 251 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 252