show: Sort ALL the things.
[sigrok-cli.git] / contrib / sigrok-cli.nsi.in
1 ##
2 ## This file is part of the sigrok-cli project.
3 ##
4 ## Copyright (C) 2011-2012 Uwe Hermann <uwe@hermann-uwe.de>
5 ##
6 ## This program is free software; you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation; either version 2 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program; if not, write to the Free Software
18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
19 ##
20
21 #
22 # This file is used to create the sigrok-cli Windows installer via NSIS.
23 #
24 # NSIS documentation:
25 # http://nsis.sourceforge.net/Docs/
26 # http://nsis.sourceforge.net/Docs/Modern%20UI%202/Readme.html
27 #
28
29 # Include the "Modern UI" header, which gives us the usual Windows look-n-feel.
30 !include "MUI2.nsh"
31
32
33 # --- Global stuff ------------------------------------------------------------
34
35 # Installer/product name.
36 Name "@PACKAGE_NAME@"
37
38 # Filename of the installer executable.
39 OutFile "@PACKAGE_NAME@-@PACKAGE_VERSION@-installer.exe"
40
41 # Where to install the application.
42 InstallDir "$PROGRAMFILES\sigrok\@PACKAGE_NAME@"
43
44 # Request admin privileges for Windows Vista and Windows 7.
45 # http://nsis.sourceforge.net/Docs/Chapter4.html
46 RequestExecutionLevel admin
47
48 # Local helper definitions.
49 !define REGSTR "Software\Microsoft\Windows\CurrentVersion\Uninstall\@PACKAGE_NAME@"
50
51
52 # --- MUI interface configuration ---------------------------------------------
53
54 # Use the following icon for the installer EXE file.
55 !define MUI_ICON "sigrok-logo-notext.ico"
56
57 # Show a nice image at the top of each installer page.
58 !define MUI_HEADERIMAGE
59
60 # Don't automatically go to the Finish page so the user can check the log.
61 !define MUI_FINISHPAGE_NOAUTOCLOSE
62
63 # Upon "cancel", ask the user if he really wants to abort the installer.
64 !define MUI_ABORTWARNING
65
66 # Don't force the user to accept the license, just show it.
67 # Details: http://trac.videolan.org/vlc/ticket/3124
68 !define MUI_LICENSEPAGE_BUTTON $(^NextBtn)
69 !define MUI_LICENSEPAGE_TEXT_BOTTOM "Click Next to continue."
70
71 # File name of the Python installer MSI file.
72 !define PY_INST "python-3.2.2.msi"
73
74 # Standard install path of the Python installer (do not change!).
75 !define PY_BIN "c:\Python32"
76
77
78 # --- MUI pages ---------------------------------------------------------------
79
80 # Show a nice "Welcome to the ... Setup Wizard" page.
81 !insertmacro MUI_PAGE_WELCOME
82
83 # Show the license of the project.
84 !insertmacro MUI_PAGE_LICENSE "..\COPYING"
85
86 # Show a screen which allows the user to select which components to install.
87 !insertmacro MUI_PAGE_COMPONENTS
88
89 # Allow the user to select a different install directory.
90 !insertmacro MUI_PAGE_DIRECTORY
91
92 # Perform the actual installation, i.e. install the files.
93 !insertmacro MUI_PAGE_INSTFILES
94
95 # Show a final "We're done, click Finish to close this wizard" message.
96 !insertmacro MUI_PAGE_FINISH
97
98 # Pages used for the uninstaller.
99 !insertmacro MUI_UNPAGE_WELCOME
100 !insertmacro MUI_UNPAGE_CONFIRM
101 !insertmacro MUI_UNPAGE_INSTFILES
102 !insertmacro MUI_UNPAGE_FINISH
103
104
105 # --- MUI language files ------------------------------------------------------
106
107 # Select an installer language (required!).
108 !insertmacro MUI_LANGUAGE "English"
109
110
111 # --- Default section ---------------------------------------------------------
112
113 Section "@PACKAGE_NAME@ (required)" Section1
114
115         # This section is gray (can't be disabled) in the component list.
116         SectionIn RO
117
118         # Install the file(s) specified below into the specified directory.
119         SetOutPath "$INSTDIR"
120
121         # License file
122         File "..\COPYING"
123
124         # sigrok libs
125         File "c:\MinGW\msys\1.0\local\lib\libsigrok.a"
126         File "c:\MinGW\msys\1.0\local\lib\libsigrokdecode.a"
127
128         # sigrok-cli
129         File "c:\MinGW\msys\1.0\local\bin\@PACKAGE_NAME@.exe"
130
131         # Icon
132         File "sigrok-logo-notext.ico"
133
134         # MinGW libs
135         File "c:\MinGW\bin\mingwm10.dll"
136         File "c:\MinGW\bin\libgcc_s_dw2-1.dll"
137         File "c:\MinGW\bin\intl.dll"
138         File "c:\MinGW\bin\libiconv-2.dll"
139         File "c:\MinGW\bin\libstdc++-6.dll"
140
141         # MSYS libs.
142         File "c:\MinGW\msys\1.0\bin\msys-1.0.dll"
143         File "c:\MinGW\msys\1.0\bin\msys-z.dll"
144
145         # External libs
146         File "c:\MinGW\msys\1.0\local\bin\libglib-2.0-0.dll"
147         File "c:\MinGW\msys\1.0\local\bin\libgthread-2.0-0.dll"
148         File "c:\MinGW\msys\1.0\local\bin\libusb-1.0.dll"
149         File "c:\MinGW\msys\1.0\local\bin\zlib1.dll"
150         File "c:\MinGW\msys\1.0\local\bin\libzip-2.dll"
151         File "c:\MinGW\msys\1.0\local\bin\libusb0.dll"
152         File "c:\MinGW\msys\1.0\local\bin\libftdi.dll"
153
154         # Install the file(s) specified below into the specified directory.
155         SetOutPath "$INSTDIR\decoders"
156
157         # Protocol decoders
158         File /r /x "__pycache__" \
159                 "c:\MinGW\msys\1.0\local\share\libsigrokdecode\decoders\*"
160
161         # Generate the uninstaller executable.
162         WriteUninstaller "$INSTDIR\Uninstall.exe"
163
164         # Create a sub-directory in the start menu.
165         CreateDirectory "$SMPROGRAMS\sigrok"
166         CreateDirectory "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
167
168         # Create a shortcut for sigrok-cli (this merely opens a "DOS box").
169         # Set the working directory (where the user will be placed into when
170         # the DOS box starts) to the user's Desktop directory.
171         SetOutPath "$DESKTOP"
172         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk" \
173                 "$SYSDIR\cmd.exe" \
174                 "/K echo For instructions run @PACKAGE_NAME@ --help." \
175                 "$SYSDIR\cmd.exe" 0 \
176                 SW_SHOWNORMAL "" "Run @PACKAGE_NAME@"
177
178         # Create a shortcut for the uninstaller.
179         CreateShortCut "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk" \
180                 "$INSTDIR\Uninstall.exe" "" "$INSTDIR\Uninstall.exe" 0 \
181                 SW_SHOWNORMAL "" "Uninstall @PACKAGE_NAME@"
182
183         # Create registry keys for "Add/remove programs" in the control panel.
184         WriteRegStr HKLM "${REGSTR}" "DisplayName" "@PACKAGE_STRING@"
185         WriteRegStr HKLM "${REGSTR}" "UninstallString" \
186                 "$\"$INSTDIR\Uninstall.exe$\""
187         WriteRegStr HKLM "${REGSTR}" "InstallLocation" "$\"$INSTDIR$\""
188         WriteRegStr HKLM "${REGSTR}" "DisplayIcon" \
189                 "$\"$INSTDIR\sigrok-logo-notext.ico$\""
190         WriteRegStr HKLM "${REGSTR}" "Publisher" "sigrok"
191         WriteRegStr HKLM "${REGSTR}" "HelpLink" \
192                 "http://sigrok.org/wiki/Sigrok-cli"
193         WriteRegStr HKLM "${REGSTR}" "URLUpdateInfo" \
194                 "http://sigrok.org/wiki/Downloads"
195         WriteRegStr HKLM "${REGSTR}" "URLInfoAbout" "http://sigrok.org"
196         WriteRegStr HKLM "${REGSTR}" "DisplayVersion" "@PACKAGE_VERSION@"
197         WriteRegStr HKLM "${REGSTR}" "Contact" \
198                 "sigrok-devel@lists.sourceforge.org"
199         WriteRegStr HKLM "${REGSTR}" "Comments" \
200                 "This is the sigrok command-line application."
201
202         # Display "Remove" instead of "Modify/Remove" in the control panel.
203         WriteRegDWORD HKLM "${REGSTR}" "NoModify" 1
204         WriteRegDWORD HKLM "${REGSTR}" "NoRepair" 1
205
206         # TODO: Add sigrok-cli directory to the PATH env. variable.
207
208 SectionEnd
209
210
211 # --- Python installer section ------------------------------------------------
212
213 Section "Python" Section2
214
215         # Copy the Python installer MSI file into the temporary directory.
216         SetOutPath "$TEMP"
217         File "c:\${PY_INST}"
218
219         # Run the Python installer MSI file from within our installer.
220         ExecWait '"msiexec" /i "$TEMP\${PY_INST}" /QB- /passive ALLUSERS=1'
221
222         # Remove Python installer MSI file again.
223         Delete "$TEMP\${PY_INST}"
224
225 SectionEnd
226
227
228 # --- Uninstaller section -----------------------------------------------------
229
230 Section "Uninstall"
231
232         # Always delete the uninstaller first (yes, this really works).
233         Delete "$INSTDIR\Uninstall.exe"
234
235         # Delete the application, the application data, and related libs.
236         Delete "$INSTDIR\COPYING"
237         Delete "$INSTDIR\libsigrok.a"
238         Delete "$INSTDIR\libsigrokdecode.a"
239         Delete "$INSTDIR\@PACKAGE_NAME@.exe"
240         Delete "$INSTDIR\sigrok-logo-notext.ico"
241         Delete "$INSTDIR\mingwm10.dll"
242         Delete "$INSTDIR\libgcc_s_dw2-1.dll"
243         Delete "$INSTDIR\intl.dll"
244         Delete "$INSTDIR\libiconv-2.dll"
245         Delete "$INSTDIR\libstdc++-6.dll"
246         Delete "$INSTDIR\msys-1.0.dll"
247         Delete "$INSTDIR\msys-z.dll"
248         Delete "$INSTDIR\libglib-2.0-0.dll"
249         Delete "$INSTDIR\libgthread-2.0-0.dll"
250         Delete "$INSTDIR\libusb-1.0.dll"
251         Delete "$INSTDIR\zlib1.dll"
252         Delete "$INSTDIR\libzip-2.dll"
253         Delete "$INSTDIR\libusb0.dll"
254         Delete "$INSTDIR\libftdi.dll"
255
256         # Delete all decoders and everything else in decoders/.
257         # There could be *.pyc files or __pycache__ subdirs and so on.
258         RMDir /r "$INSTDIR\decoders\*"
259
260         # Delete the install directory and its sub-directories.
261         RMDir "$INSTDIR\decoders"
262         RMDir "$INSTDIR"
263
264         # Delete the links from the start menu.
265         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\sigrok command-line tool.lnk"
266         Delete "$SMPROGRAMS\sigrok\@PACKAGE_NAME@\Uninstall.lnk"
267
268         # Delete the sub-directory in the start menu.
269         RMDir "$SMPROGRAMS\sigrok\@PACKAGE_NAME@"
270         RMDir "$SMPROGRAMS\sigrok"
271
272         # Delete the registry key(s).
273         DeleteRegKey HKLM "${REGSTR}"
274
275 SectionEnd
276
277
278 # --- Component selection section descriptions --------------------------------
279
280 LangString DESC_Section1 ${LANG_ENGLISH} "This installs the sigrok command-line tool, the protocol decoders, and all required libraries."
281 LangString DESC_Section2 ${LANG_ENGLISH} "This installs Python 3.2 in its default location of c:\Python32. If you already have Python 3.2 installed, you don't need to re-install it."
282
283 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
284 !insertmacro MUI_DESCRIPTION_TEXT ${Section1} $(DESC_Section1)
285 !insertmacro MUI_DESCRIPTION_TEXT ${Section2} $(DESC_Section2)
286 !insertmacro MUI_FUNCTION_DESCRIPTION_END
287