4243c7772b8b1667c48bbea58d8e1d52b7568a37
[libsigrokdecode.git] / configure.ac
1 ##
2 ## This file is part of the libsigrokdecode project.
3 ##
4 ## Copyright (C) 2010 Bert Vermeulen <bert@biot.com>
5 ##
6 ## This program is free software: you can redistribute it and/or modify
7 ## it under the terms of the GNU General Public License as published by
8 ## the Free Software Foundation, either version 3 of the License, or
9 ## (at your option) any later version.
10 ##
11 ## This program is distributed in the hope that it will be useful,
12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 ## GNU General Public License for more details.
15 ##
16 ## You should have received a copy of the GNU General Public License
17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 ##
19
20 # We require at least autoconf 2.63 (AC_INIT format changed there).
21 AC_PREREQ([2.63])
22
23 # libsigrokdecode package version number (NOT the same as shared lib version!).
24 m4_define([srd_package_version_major], [0])
25 m4_define([srd_package_version_minor], [3])
26 m4_define([srd_package_version_micro], [0])
27 m4_define([srd_package_version_suffix], [-git])
28 m4_define([srd_package_version], [srd_package_version_major.srd_package_version_minor.srd_package_version_micro[]srd_package_version_suffix])
29
30 AC_INIT([libsigrokdecode], [srd_package_version],
31         [sigrok-devel@lists.sourceforge.net], [libsigrokdecode],
32         [http://www.sigrok.org])
33 AC_CONFIG_HEADER([config.h])
34 AC_CONFIG_MACRO_DIR([autostuff])
35 AC_CONFIG_AUX_DIR([autostuff])
36
37 # We require at least automake 1.11 (needed for 'silent rules').
38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
41
42 AH_TOP([#ifndef SRD_CONFIG_H
43 #define SRD_CONFIG_H    /* To stop multiple inclusions. */])
44 AH_BOTTOM([#endif /* SRD_CONFIG_H */])
45
46 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
47 # and enforce use of SRD_API to explicitly mark all public API functions.
48 AM_CFLAGS="$AM_CFLAGS -Wall -Wextra -Wmissing-prototypes -fvisibility=hidden"
49
50 # Checks for programs.
51 AC_PROG_CC
52 AC_PROG_CPP
53 AC_PROG_INSTALL
54 AC_PROG_LN_S
55
56 # Required for per-target flags or subdir-objects with C sources.
57 AM_PROG_CC_C_O
58
59 # Initialize libtool.
60 LT_INIT
61
62 # Initialize pkg-config.
63 # We require at least 0.22, as "Requires.private" behaviour changed there.
64 PKG_PROG_PKG_CONFIG([0.22])
65
66 # Library version for libsigrokdecode (NOT the same as the package version).
67 # Carefully read the libtool docs before updating these numbers!
68 # The algorithm for determining which number to change (and how) is nontrivial!
69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
70 SRD_LIB_VERSION_CURRENT=2
71 SRD_LIB_VERSION_REVISION=0
72 SRD_LIB_VERSION_AGE=0
73 SRD_LIB_VERSION="$SRD_LIB_VERSION_CURRENT:$SRD_LIB_VERSION_REVISION:$SRD_LIB_VERSION_AGE"
74 SRD_LIB_LDFLAGS="-version-info $SRD_LIB_VERSION"
75 AC_SUBST(SRD_LIB_VERSION_CURRENT)
76 AC_SUBST(SRD_LIB_VERSION_REVISION)
77 AC_SUBST(SRD_LIB_VERSION_AGE)
78 AC_SUBST(SRD_LIB_VERSION)
79 AC_SUBST(SRD_LIB_LDFLAGS)
80
81 # Checks for libraries.
82
83 # libglib-2.0 is always needed.
84 # Note: glib-2.0 is part of the libsigrokdecode API
85 # (hard pkg-config requirement).
86 AM_PATH_GLIB_2_0([2.24.0],
87         [AM_CFLAGS="$AM_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
88
89 # Python 3 is always needed.
90 # Note: We need to try a few different variants, since some systems have a
91 # python3.pc file, others have a python-3.3.pc file, and so on.
92 # We also export the name of the package so that it can be correctly
93 # added to libsigrokdecode.pc.
94 # See also: http://sigrok.org/wiki/Libsigrokdecode/Python
95 CPPFLAGS_PYTHON=""
96 LDFLAGS_PYTHON=""
97 pyver="none"
98 PKG_CHECK_MODULES([python3], [python3 >= 3.2],
99         [pyver=`$PKG_CONFIG --modversion python3`;
100         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python3_CFLAGS";
101         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python3_LIBS";
102         MODNAME_PYTHON="python3"],
103 [PKG_CHECK_MODULES([python34], [python-3.4 >= 3.4],
104         [pyver=`$PKG_CONFIG --modversion python-3.4`;
105         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python34_CFLAGS";
106         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python34_LIBS";
107         MODNAME_PYTHON="python-3.4"],
108 [PKG_CHECK_MODULES([python33], [python-3.3 >= 3.3],
109         [pyver=`$PKG_CONFIG --modversion python-3.3`;
110         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python33_CFLAGS";
111         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python33_LIBS";
112         MODNAME_PYTHON="python-3.3"],
113 [PKG_CHECK_MODULES([python32], [python-3.2 >= 3.2],
114         [pyver=`$PKG_CONFIG --modversion python-3.2`;
115         CPPFLAGS_PYTHON="$CPPFLAGS_PYTHON $python32_CFLAGS";
116         LDFLAGS_PYTHON="$LDFLAGS_PYTHON $python32_LIBS";
117         MODNAME_PYTHON="python-3.2"],
118 )])])])
119 AC_SUBST(CPPFLAGS_PYTHON)
120 AC_SUBST(LDFLAGS_PYTHON)
121 AC_SUBST(MODNAME_PYTHON)
122
123 # We also need to find the name of the python3 executable (for 'make install').
124 # Some OSes call this python3, some call it python3.2, etc. etc.
125 AC_CHECK_PROGS([PYTHON3], [python3.4 python3.3 python3.2 python3])
126 if test "x$PYTHON3" = "x"; then
127         AC_MSG_ERROR([cannot find python3 executable.])
128 fi
129
130 # Link against libm, this is required (among other things) by Python.
131 AC_SEARCH_LIBS([pow], [m])
132
133 # The Check unit testing framework is optional. Disable if not found.
134 PKG_CHECK_MODULES([check], [check >= 0.9.4],
135         [have_check="yes"], [have_check="no"])
136 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
137
138 # Checks for header files.
139 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
140
141 AC_SUBST(DECODERS_DIR, "$datadir/libsigrokdecode/decoders")
142 AC_SUBST(MAKEFLAGS, '--no-print-directory')
143 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
144
145 SRD_PACKAGE_VERSION_MAJOR=srd_package_version_major
146 SRD_PACKAGE_VERSION_MINOR=srd_package_version_minor
147 SRD_PACKAGE_VERSION_MICRO=srd_package_version_micro
148 SRD_PACKAGE_VERSION=srd_package_version
149
150 AC_SUBST(SRD_PACKAGE_VERSION_MAJOR)
151 AC_SUBST(SRD_PACKAGE_VERSION_MINOR)
152 AC_SUBST(SRD_PACKAGE_VERSION_MICRO)
153 AC_SUBST(SRD_PACKAGE_VERSION)
154
155 AC_SUBST(AM_CFLAGS)
156
157 AC_CONFIG_FILES([Makefile version.h libsigrokdecode.pc])
158
159 AC_OUTPUT
160
161 echo
162 echo "libsigrokdecode configuration summary:"
163 echo
164 echo "  - Package version (major.minor.micro):    $SRD_PACKAGE_VERSION"
165 echo "  - Library version (current:revision:age): $SRD_LIB_VERSION"
166 echo "  - Prefix: $prefix"
167 echo "  - Building on: $build"
168 echo "  - Building for: $host"
169 echo
170 echo "Detected libraries:"
171 echo
172
173 if test "x$pyver" = "xnone"; then
174         echo "  - (REQUIRED) python >= 3.2: no"
175 else
176         echo "  - (REQUIRED) python >= 3.2: yes ($pyver)"
177 fi
178
179 # Note: This only works for libs with pkg-config integration.
180 for lib in "glib-2.0 >= 2.24.0" "check >= 0.9.4"; do
181         optional="OPTIONAL"
182         if test "x$lib" = "xglib-2.0 >= 2.24.0"; then optional="REQUIRED"; fi
183         if `$PKG_CONFIG --exists $lib`; then
184                 ver=`$PKG_CONFIG --modversion $lib`
185                 answer="yes ($ver)"
186         else
187                 answer="no"
188         fi
189         echo "  - ($optional) $lib: $answer"
190 done
191
192 echo
193 echo "Enabled features:"
194 echo
195 echo "  - (OPTIONAL) Library unit test framework support: $have_check"
196 echo
197