m4/sigrok.m4

   1 ## Copyright (c) 2009  Openismus GmbH
   2 ## Copyright (c) 2015  Daniel Elstner <daniel.kitta@gmail.com>
   3 ##
   4 ## This file is part of the sigrok project.
   5 ##
   6 ## sigrok is free software: you can redistribute it and/or modify it
   7 ## under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## sigrok is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with sigrok. If not, see <http://www.gnu.org/licenses/>.
  18
  19 #serial 20150823
  20
  21 ## SR_APPEND(var-name, [list-sep,] element)
  22 ##
  23 ## Append the shell word <element> to the shell variable named <var-name>,
  24 ## prefixed by <list-sep> unless the list was empty before appending. If
  25 ## only two arguments are supplied, <list-sep> defaults to a single space
  26 ## character.
  27 ##
  28 AC_DEFUN([SR_APPEND],
  29 [dnl
  30 m4_assert([$# >= 2])[]dnl
  31 $1=[$]{$1[}]m4_if([$#], [2], [[$]{$1:+' '}$2], [[$]{$1:+$2}$3])[]dnl
  32 ])
  33
  34 ## _SR_PKG_VERSION_SET(var-prefix, pkg-name, tag-prefix, base-version, major, minor, [micro])
  35 ##
  36 m4_define([_SR_PKG_VERSION_SET],
  37 [dnl
  38 m4_assert([$# >= 6])[]dnl
  39 $1=$4
  40 sr_git_deps=
  41 # Check if we can get revision information from git.
  42 sr_head=`git -C "$srcdir" rev-parse --verify --short HEAD 2>&AS_MESSAGE_LOG_FD`
  43
  44 AS_IF([test "$?" = 0 && test "x$sr_head" != x], [dnl
  45         test ! -f "$srcdir/.git/HEAD" \
  46                 || sr_git_deps="$sr_git_deps \$(top_srcdir)/.git/HEAD"
  47
  48         sr_head_name=`git -C "$srcdir" rev-parse --symbolic-full-name HEAD 2>&AS_MESSAGE_LOG_FD`
  49         AS_IF([test "$?" = 0 && test -f "$srcdir/.git/$sr_head_name"],
  50                 [sr_git_deps="$sr_git_deps \$(top_srcdir)/.git/$sr_head_name"])
  51
  52         # Append the revision hash unless we are exactly on a tagged release.
  53         git -C "$srcdir" describe --match "$3$4" \
  54                 --exact-match >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD \
  55                 || $1="[$]$1-git-$sr_head"
  56 ])
  57 # Use $(wildcard) so that things do not break if for whatever
  58 # reason these files do not exist anymore at make time.
  59 AS_IF([test -n "$sr_git_deps"],
  60         [SR_APPEND([CONFIG_STATUS_DEPENDENCIES], ["\$(wildcard$sr_git_deps)"])])
  61 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])[]dnl
  62 AC_SUBST([$1])[]dnl
  63 dnl
  64 AC_DEFINE([$1_MAJOR], [$5], [Major version number of $2.])[]dnl
  65 AC_DEFINE([$1_MINOR], [$6], [Minor version number of $2.])[]dnl
  66 m4_ifval([$7], [AC_DEFINE([$1_MICRO], [$7], [Micro version number of $2.])])[]dnl
  67 AC_DEFINE_UNQUOTED([$1_STRING], ["[$]$1"], [Version of $2.])[]dnl
  68 ])
  69
  70 ## SR_PKG_VERSION_SET(var-prefix, version-triple)
  71 ##
  72 ## Set up substitution variables and macro definitions for the package
  73 ## version components. Derive the version suffix from the repository
  74 ## revision if possible.
  75 ##
  76 ## Substitutions: <var-prefix>
  77 ## Macro defines: <var-prefix>_{MAJOR,MINOR,MICRO,STRING}
  78 ##
  79 AC_DEFUN([SR_PKG_VERSION_SET],
  80 [dnl
  81 m4_assert([$# >= 2])[]dnl
  82 _SR_PKG_VERSION_SET([$1],
  83         m4_defn([AC_PACKAGE_NAME]),
  84         m4_defn([AC_PACKAGE_TARNAME])[-],
  85         m4_expand([$2]),
  86         m4_unquote(m4_split(m4_expand([$2]), [\.])))
  87 ])
  88
  89 ## _SR_LIB_VERSION_SET(var-prefix, pkg-name, abi-triple, current, revision, age)
  90 ##
  91 m4_define([_SR_LIB_VERSION_SET],
  92 [dnl
  93 m4_assert([$# >= 6])[]dnl
  94 $1=$3
  95 AC_SUBST([$1])[]dnl
  96 AC_DEFINE([$1_CURRENT], [$4], [Binary version of $2.])[]dnl
  97 AC_DEFINE([$1_REVISION], [$5], [Binary revision of $2.])[]dnl
  98 AC_DEFINE([$1_AGE], [$6], [Binary age of $2.])[]dnl
  99 AC_DEFINE([$1_STRING], ["$3"], [Binary version triple of $2.])[]dnl
 100 ])
 101
 102 ## SR_LIB_VERSION_SET(var-prefix, abi-triple)
 103 ##
 104 ## Set up substitution variables and macro definitions for a library
 105 ## binary version.
 106 ##
 107 ## Substitutions: <var-prefix>
 108 ## Macro defines: <var-prefix>_{CURRENT,REVISION,AGE,STRING}
 109 ##
 110 AC_DEFUN([SR_LIB_VERSION_SET],
 111 [dnl
 112 m4_assert([$# >= 1])[]dnl
 113 _SR_LIB_VERSION_SET([$1],
 114         m4_defn([AC_PACKAGE_NAME]),
 115         [$2], m4_unquote(m4_split([$2], [:])))
 116 ])
 117
 118 ## _SR_ARG_ENABLE_WARNINGS_ONCE
 119 ##
 120 ## Implementation helper macro of SR_ARG_ENABLE_WARNINGS. Pulled in
 121 ## through AC_REQUIRE so that it is only expanded once.
 122 ##
 123 m4_define([_SR_ARG_ENABLE_WARNINGS_ONCE],
 124 [dnl
 125 AC_PROVIDE([$0])[]dnl
 126 AC_ARG_ENABLE([warnings],
 127                 [AS_HELP_STRING([[--enable-warnings[=min|max|fatal|no]]],
 128                                 [set compile pedantry level [default=max]])],
 129                 [sr_enable_warnings=$enableval],
 130                 [sr_enable_warnings=max])[]dnl
 131 dnl
 132 # Test whether the compiler accepts each flag.  Look at standard output,
 133 # since GCC only shows a warning message if an option is not supported.
 134 sr_check_compile_warning_flags() {
 135         for sr_flag
 136         do
 137                 sr_cc_out=`$sr_cc $sr_warning_flags $sr_flag -c "$sr_conftest" 2>&1 || echo failed`
 138                 AS_IF([test "$?$sr_cc_out" = 0],
 139                         [SR_APPEND([sr_warning_flags], [$sr_flag])],
 140                         [AS_ECHO(["$sr_cc: $sr_cc_out"]) >&AS_MESSAGE_LOG_FD])
 141                 rm -f "conftest.[$]{OBJEXT:-o}"
 142         done
 143 }
 144 ])
 145
 146 ## SR_ARG_ENABLE_WARNINGS(variable, min-flags, max-flags)
 147 ##
 148 ## Provide the --enable-warnings configure argument, set to "min" by default.
 149 ## <min-flags> and <max-flags> should be space-separated lists of compiler
 150 ## warning flags to use with --enable-warnings=min or --enable-warnings=max,
 151 ## respectively. Warning level "fatal" is the same as "max" but in addition
 152 ## enables -Werror mode.
 153 ##
 154 ## In order to determine the warning options to use with the C++ compiler,
 155 ## call AC_LANG([C++]) first to change the current language. If different
 156 ## output variables are used, it is also fine to call SR_ARG_ENABLE_WARNINGS
 157 ## repeatedly, once for each language setting.
 158 ##
 159 AC_DEFUN([SR_ARG_ENABLE_WARNINGS],
 160 [dnl
 161 m4_assert([$# >= 3])[]dnl
 162 AC_REQUIRE([_SR_ARG_ENABLE_WARNINGS_ONCE])[]dnl
 163 dnl
 164 AS_CASE([$ac_compile],
 165         [[*'$CXXFLAGS '*]], [sr_lang='C++' sr_cc=$CXX sr_conftest="conftest.[$]{ac_ext:-cc}"],
 166         [[*'$CFLAGS '*]],   [sr_lang=C sr_cc=$CC sr_conftest="conftest.[$]{ac_ext:-c}"],
 167         [AC_MSG_ERROR([[current language is neither C nor C++]])])
 168 dnl
 169 AC_MSG_CHECKING([which $sr_lang compiler warning flags to use])
 170 sr_warning_flags=
 171 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 172 int main(int argc, char** argv) { return (argv != 0) ? argc : 0; }
 173 ]])])
 174 AS_CASE([$sr_enable_warnings],
 175         [no], [],
 176         [min], [sr_check_compile_warning_flags $2],
 177         [fatal], [sr_check_compile_warning_flags $3 -Werror],
 178         [sr_check_compile_warning_flags $3])
 179 rm -f "$sr_conftest"
 180 AC_SUBST([$1], [$sr_warning_flags])
 181 AC_MSG_RESULT([[$]{sr_warning_flags:-none}])[]dnl
 182 ])