configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrok package version number (NOT the same as shared lib version!).
  24 m4_define([sr_package_version_major], [0])
  25 m4_define([sr_package_version_minor], [2])
  26 m4_define([sr_package_version_micro], [0])
  27 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  28
  29 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  30         [libsigrok], [http://www.sigrok.org])
  31 AC_CONFIG_HEADER([config.h])
  32 AC_CONFIG_MACRO_DIR([autostuff])
  33 AC_CONFIG_AUX_DIR([autostuff])
  34
  35 # We require at least automake 1.11 (needed for 'silent rules').
  36 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  37 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  38 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  39
  40 AH_TOP([#ifndef SR_CONFIG_H
  41 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  42 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  43
  44 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  45 # and enforce use of SR_API to explicitly mark all public API functions.
  46 CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
  47
  48 # Checks for programs.
  49 AC_PROG_CXX
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Initialize libtool.
  56 LT_INIT
  57
  58 # Initialize pkg-config.
  59 # We require at least 0.22, as "Requires.private" behaviour changed there.
  60 PKG_PROG_PKG_CONFIG([0.22])
  61
  62 # Library version for libsigrok (NOT the same as the package version).
  63 # Carefully read the libtool docs before updating these numbers!
  64 # The algorithm for determining which number to change (and how) is nontrivial!
  65 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  66 SR_LIB_VERSION_CURRENT=1
  67 SR_LIB_VERSION_REVISION=0
  68 SR_LIB_VERSION_AGE=0
  69 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  70 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  71 AC_SUBST(SR_LIB_VERSION_CURRENT)
  72 AC_SUBST(SR_LIB_VERSION_REVISION)
  73 AC_SUBST(SR_LIB_VERSION_AGE)
  74 AC_SUBST(SR_LIB_VERSION)
  75 AC_SUBST(SR_LIB_LDFLAGS)
  76
  77 # Logic analyzer hardware support '--enable' options.
  78
  79 # Disabled by default, unfinished.
  80 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  81               [enable ALSA driver support [default=no]]),
  82               [LA_ALSA="$enableval"],
  83               [LA_ALSA=no])
  84 AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
  85 if test "x$LA_ALSA" = "xyes"; then
  86         AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
  87 fi
  88
  89 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  90               [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
  91               [LA_ASIX_SIGMA="$enableval"],
  92               [LA_ASIX_SIGMA=yes])
  93 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
  94 if test "x$LA_ASIX_SIGMA" = "xyes"; then
  95         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
  96 fi
  97
  98 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
  99               [enable ChronoVu LA8 support [default=yes]]),
 100               [LA_CHRONOVU_LA8="$enableval"],
 101               [LA_CHRONOVU_LA8=yes])
 102 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 103 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 104         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 105 fi
 106
 107 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 108               [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 109               [LA_FX2LAFW="$enableval"],
 110               [LA_FX2LAFW=yes])
 111 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 112 if test "x$LA_FX2LAFW" = "xyes"; then
 113         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 114 fi
 115
 116 # Disabled by default for now
 117 AC_ARG_ENABLE(genericdmm, AC_HELP_STRING([--enable-genericdmm],
 118               [enable genericdmm support (for most DMMs). [default=no]]),
 119               [HW_GENERICDMM="$enableval"],
 120               [HW_GENERICDMM=no])
 121 AM_CONDITIONAL(HW_GENERICDMM, test x$HW_GENERICDMM = xyes)
 122 if test "x$HW_GENERICDMM" = "xyes"; then
 123         AC_DEFINE(HAVE_HW_GENERICDMM, 1, [Generic DMM support])
 124 fi
 125
 126 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 127               [enable demo driver support [default=yes]]),
 128               [LA_DEMO="$enableval"],
 129               [LA_DEMO=yes])
 130 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 131 if test "x$LA_DEMO" = "xyes"; then
 132         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 133 fi
 134
 135 # Disabled by default, unfinished.
 136 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 137               [enable Link Instruments MSO-19 support [default=no]]),
 138               [LA_LINK_MSO19="$enableval"],
 139               [LA_LINK_MSO19=no])
 140 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 141 if test "x$LA_LINK_MSO19" = "xyes"; then
 142         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 143 fi
 144
 145 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 146               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 147               [LA_OLS="$enableval"],
 148               [LA_OLS=yes])
 149 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 150 if test "x$LA_OLS" = "xyes"; then
 151         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 152 fi
 153
 154 AC_ARG_ENABLE(zeroplus-logic-cube,
 155               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 156               [enable ZEROPLUS Logic Cube support [default=yes]]),
 157               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 158               [LA_ZEROPLUS_LOGIC_CUBE=yes])
 159 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 160 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 161         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 162 fi
 163
 164 AC_ARG_ENABLE(hantek-dso,
 165               AC_HELP_STRING([--enable-hantek-dso],
 166               [enable Hantek DSO support [default=yes]]),
 167               [HW_HANTEK_DSO="$enableval"],
 168               [HW_HANTEK_DSO=yes])
 169 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 170 if test "x$HW_HANTEK_DSO" = "xyes"; then
 171         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 172 fi
 173
 174 # Checks for libraries.
 175
 176 # This variable collects the pkg-config names of all detected libs.
 177 # It is then used to construct the "Requires.private:" field in the
 178 # libsigrok.pc file.
 179 SR_PKGLIBS=""
 180
 181 # libglib-2.0 is always needed.
 182 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 183 AM_PATH_GLIB_2_0([2.28.0],
 184         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 185
 186 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 187 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 188         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 189         SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
 190
 191 # libusb is only needed for some hardware drivers.
 192 if test "x$LA_ASIX_SIGMA" != xno \
 193    -o "x$LA_CHRONOVU_LA8" != xno \
 194    -o "x$LA_FX2LAFW" != xno \
 195    -o "x$HW_HANTEK_DSO" != xno \
 196    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 197         case "$build" in
 198         *freebsd*)
 199                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 200                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 201                         [Specifies whether we have a libusb.h header.])
 202                 ;;
 203         *)
 204                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.5],
 205                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 206                         LIBS="$LIBS $libusb_LIBS";
 207                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 208                 AC_CHECK_LIB(usb-1.0, libusb_init)
 209                 ;;
 210         esac
 211 fi
 212
 213 # libzip is always needed.
 214 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 215         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 216         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 217
 218 # libftdi is only needed for some hardware drivers.
 219 if test "x$LA_ASIX_SIGMA" != xno \
 220      -o "x$LA_CHRONOVU_LA8" != xno; then
 221         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 222                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 223                 LIBS="$LIBS $libftdi_LIBS";
 224                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 225 fi
 226
 227 # libudev is only needed for some hardware drivers.
 228 if test "x$LA_LINK_MSO19" != xno; then
 229         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 230                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 231                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 232 fi
 233
 234 # ALSA is only needed for some hardware drivers.
 235 if test "x$LA_ALSA" != xno; then
 236         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 237                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 238                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 239 fi
 240
 241 # EZUSB FX2 firmware helpers only needed for some hardware drivers
 242 AM_CONDITIONAL(NEED_EZUSB, \
 243         test "x$LA_FX2LAFW" != xno \
 244         -o "x$HW_HANTEK_DSO" != xno \
 245 )
 246
 247 # Serial port helpers only needed for some hardware drivers
 248 AM_CONDITIONAL(NEED_SERIAL, \
 249         test "x$LA_OLS" != xno \
 250         -o "x$HW_GENERICDMM" != xno \
 251 )
 252
 253 AC_SUBST(SR_PKGLIBS)
 254
 255 # Checks for header files.
 256 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 257 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 258
 259 # Checks for typedefs, structures, and compiler characteristics.
 260 AC_C_INLINE
 261 AC_TYPE_INT8_T
 262 AC_TYPE_INT16_T
 263 AC_TYPE_INT32_T
 264 AC_TYPE_INT64_T
 265 AC_TYPE_UINT8_T
 266 AC_TYPE_UINT16_T
 267 AC_TYPE_UINT32_T
 268 AC_TYPE_UINT64_T
 269 AC_TYPE_SIZE_T
 270
 271 # Checks for library functions.
 272 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 273
 274 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 275 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 276 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 277
 278 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 279 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 280 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 281 SR_PACKAGE_VERSION=sr_package_version
 282
 283 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 284 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 285 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 286 AC_SUBST(SR_PACKAGE_VERSION)
 287
 288 AC_CONFIG_FILES([Makefile
 289                  version.h
 290                  hardware/Makefile
 291                  hardware/alsa/Makefile
 292                  hardware/asix-sigma/Makefile
 293                  hardware/chronovu-la8/Makefile
 294                  hardware/common/Makefile
 295                  hardware/demo/Makefile
 296                  hardware/fx2lafw/Makefile
 297                  hardware/genericdmm/Makefile
 298                  hardware/link-mso19/Makefile
 299                  hardware/openbench-logic-sniffer/Makefile
 300                  hardware/zeroplus-logic-cube/Makefile
 301                  hardware/hantek-dso/Makefile
 302                  input/Makefile
 303                  output/Makefile
 304                  output/text/Makefile
 305                  libsigrok.pc
 306                  contrib/Makefile
 307                 ])
 308
 309 AC_OUTPUT
 310
 311 echo
 312 echo "libsigrok configuration summary:"
 313 echo
 314 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 315 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 316 echo "  - Prefix: $prefix"
 317 echo
 318 echo "Detected libraries:"
 319 echo
 320
 321 # Note: This only works for libs with pkg-config integration.
 322 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
 323         if `$PKG_CONFIG --exists $lib`; then
 324                 ver=`$PKG_CONFIG --modversion $lib`
 325                 answer="yes ($ver)"
 326         else
 327                 answer="no"
 328         fi
 329         echo "  - $lib: $answer"
 330 done
 331
 332 echo
 333 echo "Enabled hardware drivers:"
 334 echo
 335 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 336 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 337 echo "  - Demo driver..................... $LA_DEMO"
 338 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 339 echo "  - Generic DMM..................... $HW_GENERICDMM"
 340 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 341 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 342 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 343 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 344 echo
 345