configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 105         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 106
 107 SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0], [bluetooth >= 4.0])
 108
 109 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 110 # This means libusb-1.0 is always available; no need to check for it.
 111 # On Windows, require the latest version we can get our hands on,
 112 # until the new generic event handling has seen an official release.
 113 AS_CASE([$host_os],
 114         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 115         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 116         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 117
 118 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 119         [$sr_libusb_req])
 120
 121 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 122         [librevisa >= 0.0.20130412])
 123
 124 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 125         [libgpib])
 126
 127 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 128         sr_save_LIBS=$LIBS
 129         LIBS="-lieee1284 $LIBS"
 130         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 131                                 [[(void) ieee1284_open(0, 0, 0);]])],
 132                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 133         LIBS=$sr_save_LIBS
 134 ])
 135 AS_IF([test "x$sr_have_libieee1284" = xyes],
 136         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 137
 138 # See if any of the (potentially platform specific) libs are available
 139 # which provide some means of Bluetooth communication.
 140 AS_IF([test "x$sr_have_libbluez" = xyes],
 141         sr_have_bluetooth=yes, sr_have_bluetooth=no)
 142 AS_IF([test "x$sr_have_bluetooth" = xyes],
 143         [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])])
 144
 145 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes],
 146         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 147 AS_IF([test "x$sr_have_serial_comm" = xyes],
 148         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 149 AS_IF([test "x$sr_have_serial_comm" = xyes],
 150         [SR_APPEND([sr_deps_avail], [serial_comm])])
 151 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 152
 153 ######################
 154 ##  Feature checks  ##
 155 ######################
 156
 157 # The Check unit testing framework is optional. Disable if not found.
 158 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 159 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 160
 161 # Enable the C99 standard if possible, and enforce the use
 162 # of SR_API to explicitly mark all public API functions.
 163 SR_EXTRA_CFLAGS=
 164 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 165 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 166
 167 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 168
 169 # Check host characteristics.
 170 AC_SYS_LARGEFILE
 171 AC_C_BIGENDIAN
 172
 173 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 174 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 175 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 176
 177 # We need to link against the Winsock2 library for SCPI over TCP.
 178 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 179
 180 # libm (the standard math library) is always needed.
 181 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 182
 183 # RPC is only needed for VXI support.
 184 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 185         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 186                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 187                         [[(void) clnt_create("", 0, 0, "");]])],
 188                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 189 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 190         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 191 # VXI support is only compiled if RPC support was found.
 192 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 193
 194 # Check for compiler support of 128 bit integers
 195 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 196
 197 # Availability of bt_put_le16() depends on the bluez library version.
 198 AC_CACHE_CHECK([for bt_put_le16], [sr_cv_have_btputle16],
 199         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 200                         [[#include <bluetooth/bluetooth.h>]],
 201                         [[bt_put_le16(0, (void *)0);]])],
 202                 [sr_cv_have_btputle16=yes], [sr_cv_have_btputle16=no])])
 203 AS_IF([test "x$sr_cv_have_btputle16" = xyes],
 204         [AC_DEFINE([HAVE_BT_PUT_LE16], [1], [Specifies whether we have bt_put_le16().])])
 205
 206 ########################
 207 ##  Hardware drivers  ##
 208 ########################
 209
 210 # Keep track of all drivers so we can list them at the end.
 211 SR_VAR_SUMMARY([sr_driver_summary])
 212
 213 # Check whether the sr_deps_avail list contains all of the arguments.
 214 # Unavailable dependencies are collected in sr_deps_missing.
 215 sr_check_driver_deps() {
 216         sr_deps_missing=
 217         for sr_dep
 218         do
 219                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 220                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 221         done
 222         test -z "$sr_deps_missing" || return 1
 223 }
 224
 225 AC_ARG_ENABLE([all-drivers],
 226         [AS_HELP_STRING([--enable-all-drivers],
 227                         [enable all drivers by default [default=yes]])],
 228         [], [enable_all_drivers=yes])
 229
 230 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 231 m4_define([_SR_DRIVER], [
 232         AC_ARG_ENABLE([$2],
 233                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 234                 [$3=$enableval], [$3=$enable_all_drivers])
 235
 236         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 237                 sr_check_driver_deps $4 \
 238                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 239         ])], [sr_hw_info='no (disabled)'])
 240         sr_driver_summary_append "$2" "$sr_hw_info"
 241
 242         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 243         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 244 ])
 245
 246 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 247 m4_define([SR_DRIVER],
 248         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 249
 250 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 251 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 252 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 253 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 254 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 255 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 256 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 257 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 258 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 259 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 260 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 261 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 262 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 263 SR_DRIVER([demo], [demo])
 264 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 265 SR_DRIVER([Fluke 45], [fluke-45])
 266 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 267 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 268 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 269 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 270 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 271 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 272 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 273 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 274 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 275 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 276 SR_DRIVER([HP 3457A], [hp-3457a])
 277 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 278 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 279 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 280 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 281 SR_DRIVER([IPDBG LA], [ipdbg-la])
 282 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 283 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 284 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 285 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 286 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 287 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 288 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 289 SR_DRIVER([maynuo-m97], [maynuo-m97])
 290 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 291 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 292 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 293 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 294 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 295 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 296 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 297 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 298 SR_DRIVER([Rigol DS], [rigol-ds])
 299 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 300 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 301 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 302 SR_DRIVER([SCPI DMM], [scpi-dmm])
 303 SR_DRIVER([SCPI PPS], [scpi-pps])
 304 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 305 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 306 SR_DRIVER([Siglent SDS], [siglent-sds])
 307 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 308 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 309 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 310 SR_DRIVER([Testo], [testo], [libusb])
 311 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 312 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 313 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 314 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 315 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 316 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 317
 318 ###############################
 319 ##  Language bindings setup  ##
 320 ###############################
 321
 322 AC_LANG([C++])
 323 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 324
 325 AC_ARG_ENABLE([bindings],
 326         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 327         [], [enable_bindings=yes])
 328
 329 AC_ARG_ENABLE([cxx],
 330         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 331         [], [enable_cxx=$enable_bindings])
 332
 333 AC_ARG_ENABLE([python],
 334         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 335         [], [enable_python=$enable_bindings])
 336
 337 AC_ARG_ENABLE([ruby],
 338         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 339         [], [enable_ruby=$enable_bindings])
 340
 341 AC_ARG_ENABLE([java],
 342         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 343         [], [enable_java=$enable_bindings])
 344
 345 ####################
 346 ##  C++ bindings  ##
 347 ####################
 348
 349 sr_cxx_missing=
 350
 351 # Check if the C++ compiler supports the C++11 standard.
 352 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 353 AS_IF([test "x$HAVE_CXX11" != x1],
 354         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 355
 356 # The C++ bindings need glibmm.
 357 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 358 AS_IF([test "x$sr_have_glibmm" != xyes],
 359         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 360
 361 # The C++ bindings use Doxygen to parse libsigrok symbols.
 362 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 363 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 364         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 365
 366 # Link C++ code with gnustl_shared if it exists (Android)
 367 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 368
 369 # Python is needed for the C++ bindings.
 370 AM_PATH_PYTHON([2.7],
 371         [HAVE_PYTHON=yes],
 372         [HAVE_PYTHON=no
 373         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 374
 375 AS_IF([test -z "$sr_cxx_missing"],
 376         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 377 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 378
 379 # C++ bindings want stoi and stod.
 380 AM_COND_IF([BINDINGS_CXX], [
 381         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 382                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 383                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 384                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 385         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 386                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 387                         [Specifies whether we have the stoi and stod functions.])])
 388 ])
 389
 390 #######################
 391 ##  Python bindings  ##
 392 #######################
 393
 394 AS_IF([test "x$BINDINGS_CXX" = xyes],
 395         [sr_python_missing=],
 396         [sr_python_missing='C++ bindings'])
 397
 398 # Extract major and minor version number of the Python interpreter.
 399 sr_pymajor=${PYTHON_VERSION%%.*}
 400 sr_pyminor=${PYTHON_VERSION#*.}
 401
 402 # The Python bindings need Python development files. Check for either
 403 # Python 3 or Python 2 headers depending on the interpreter version.
 404 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 405         [python = $PYTHON_VERSION],
 406         [python$sr_pymajor = $PYTHON_VERSION],
 407         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 408         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 409
 410 AS_IF([test "x$sr_have_python_dev" != xyes],
 411         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 412
 413 # PyGObject is needed for the Python bindings.
 414 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 415 AS_IF([test "x$sr_have_pygobject" != xyes],
 416         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 417
 418 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 419         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 420                 [Whether last argument to pyg_flags_get_value() is signed.])])
 421
 422 # The Python bindings need the setuptools and numpy Python modules.
 423 # We'll let it go through even if the AX macro wasn't found, as the
 424 # Python modules may still be there.
 425 m4_ifdef([AX_PYTHON_MODULE], [
 426         AX_PYTHON_MODULE([setuptools])
 427         AX_PYTHON_MODULE([numpy])
 428 ], [
 429         HAVE_PYMOD_SETUPTOOLS=yes
 430         HAVE_PYMOD_NUMPY=yes
 431         m4_warn([unsupported],
 432                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 433 ])
 434 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 435         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 436 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 437         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 438
 439 # The Python bindings use SWIG to generate code.
 440 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 441 AS_IF([test "x$SWIG" != x],
 442     AC_MSG_CHECKING([for $SWIG version])
 443     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 444     AC_MSG_RESULT([$SWIG_VERSION]))
 445 AS_IF([test "x$SWIG" = x],
 446         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 447
 448 AS_IF([test -z "$sr_python_missing"],
 449         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 450 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 451
 452 #####################
 453 ##  Ruby bindings  ##
 454 #####################
 455
 456 AS_IF([test "x$BINDINGS_CXX" = xyes],
 457         [sr_ruby_missing=],
 458         [sr_ruby_missing='C++ bindings'])
 459
 460 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 461 AS_IF([test "x$RUBY" != x],
 462         AC_MSG_CHECKING([for Ruby version])
 463     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 464     AC_MSG_RESULT([$RUBY_VERSION])
 465     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 466     AC_SUBST(RUBY_DLEXT))
 467
 468 AS_IF([test "x$RUBY" = x],
 469         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 470
 471 # Extract major and minor version number of the Ruby interpreter.
 472 sr_rbmajor=${RUBY_VERSION%%.*}
 473 sr_rbminor=${RUBY_VERSION#*.}
 474 sr_rbminor=${sr_rbminor%%.*}
 475
 476 # The Ruby bindings need Ruby development files.
 477 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 478         [ruby],
 479         [ruby-$sr_rbmajor.$sr_rbminor])
 480
 481 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 482         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 483
 484 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 485 AS_IF([test "x$SWIG" = x],
 486         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 487         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 488                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 489
 490 AS_IF([test -z "$sr_ruby_missing"],
 491         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 492 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 493
 494 ####################
 495 ##  Java bindings ##
 496 ####################
 497
 498 AS_IF([test "x$BINDINGS_CXX" = xyes],
 499         [sr_java_missing=],
 500         [sr_java_missing='C++ bindings'])
 501
 502 # The Java bindings use SWIG to generate code.
 503 AS_IF([test "x$SWIG" = x],
 504         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 505
 506 # Find Java compiler and JNI includes for Java bindings.
 507 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 508 AS_IF([test "x$HAVE_JAVAC" = xno],
 509         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 510
 511 AC_ARG_WITH([jni-include-path],
 512         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 513                 [specify JNI include directories [default=detect]])],
 514         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 515
 516 JNI_CPPFLAGS=
 517 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 518         AX_PROG_JAVAC
 519         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 520                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 521                 ## If we can find jni.h without any special search path, skip
 522                 ## the execution of the broken macro to increase our chances of
 523                 ## success.
 524                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 525                         [AX_JNI_INCLUDE_DIR])
 526         ])
 527 ])
 528 for sr_dir in $JNI_INCLUDE_DIRS
 529 do
 530         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 531 done
 532 AC_SUBST([JNI_CPPFLAGS])
 533
 534 sr_save_cppflags=$CPPFLAGS
 535 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 536 AC_CHECK_HEADER([jni.h],,
 537         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 538 CPPFLAGS=$sr_save_cppflags
 539
 540 AS_IF([test -z "$sr_java_missing"],
 541         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 542 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 543
 544 ##############################
 545 ##  Finalize configuration  ##
 546 ##############################
 547
 548 # Add mandatory dependencies to module list.
 549 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 550 AC_SUBST([SR_PKGLIBS])
 551
 552 # Retrieve the compile and link flags for all modules combined.
 553 # Also, bail out at this point if any module dependency is not met.
 554 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 555 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 556
 557 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 558 # the C++ bindings are enabled.
 559 AM_COND_IF([BINDINGS_CXX], [
 560         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 561         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 562         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 563 ])
 564
 565 # Check for specific libusb features, now that we know the CFLAGS.
 566 AC_LANG([C])
 567 sr_save_cflags=$CFLAGS
 568 sr_save_libs=$LIBS
 569 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 570 LIBS="$LIBSIGROK_LIBS $LIBS"
 571 AC_CHECK_TYPES([libusb_os_handle],
 572         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 573         [[#include <libusb.h>]])
 574 AC_CHECK_FUNCS([zip_discard])
 575 LIBS=$sr_save_libs
 576 CFLAGS=$sr_save_cflags
 577
 578 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 579         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 580
 581 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 582 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 583
 584 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 585         [Build-time version of libzip.])
 586 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 587         [The canonical host libsigrok will run on.])
 588
 589 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 590
 591 AC_OUTPUT
 592
 593 # Prepare bindings report messages.
 594 m4_define([SR_PREPARE_BINDING_REPORT], [
 595         sr_report_$1=
 596         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 597         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 598 ])
 599 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 600
 601 cat >&AS_MESSAGE_FD <<_EOF
 602
 603 libsigrok configuration summary:
 604  - Package version................. $SR_PACKAGE_VERSION
 605  - Library ABI version............. $SR_LIB_VERSION
 606  - Prefix.......................... $prefix
 607  - Building on..................... $build
 608  - Building for.................... $host
 609  - Building shared / static........ $enable_shared / $enable_static
 610
 611 Compile configuration:
 612  - C compiler...................... $CC
 613  - C compiler version.............. $sr_cc_version
 614  - C compiler flags................ $CFLAGS
 615  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 616  - C compiler warnings............. $SR_WFLAGS
 617  - C++ compiler.................... $CXX
 618  - C++ compiler version............ $sr_cxx_version
 619  - C++ compiler flags.............. $CXXFLAGS
 620  - C++ compiler warnings........... $SR_WXXFLAGS
 621  - Linker flags.................... $LDFLAGS
 622
 623 Detected libraries (required):
 624  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 625  - libzip >= 0.10.................. $sr_libzip_version
 626
 627 Detected libraries (optional):
 628 $sr_pkglibs_summary
 629 Enabled hardware drivers:
 630 $sr_driver_summary
 631 Enabled serial communication transports:
 632   - serial comm ................... $sr_have_serial_comm
 633   - libserialport ................. $sr_have_libserialport
 634   - hidapi ........................ $sr_have_libhidapi
 635   - bluetooth ..................... $sr_have_bluetooth
 636   - bluez ......................... $sr_have_libbluez
 637
 638 Enabled SCPI backends:
 639  - TCP............................. yes
 640  - RPC............................. $sr_cv_have_rpc
 641  - serial.......................... $sr_have_serial_comm
 642  - VISA............................ $sr_have_librevisa
 643  - GPIB............................ $sr_have_libgpib
 644  - USBTMC.......................... $sr_have_libusb
 645
 646 Enabled language bindings:
 647  - C++............................. $BINDINGS_CXX$sr_report_cxx
 648  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 649  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 650  - Java............................ $BINDINGS_JAVA$sr_report_java
 651
 652 _EOF
 653
 654 # Emit a warning if the C++ bindings are not being built.
 655 AM_COND_IF([BINDINGS_CXX], [], [
 656 cat >&AS_MESSAGE_FD <<_EOF
 657 ===============================================================================
 658 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 659 ===============================================================================
 660 ===                                                                         ===
 661 ===         The libsigrok C++ bindings are not being built since you        ===
 662 ===             are missing one or more dependencies (see above)!           ===
 663 ===                                                                         ===
 664 ===      This means you won't be able to compile frontends that require     ===
 665 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 666 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 667 ===                                                                         ===
 668 ===============================================================================
 669 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 670 ===============================================================================
 671
 672 _EOF
 673 ])