configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CXX
  51 AC_PROG_CC
  52 AC_PROG_CPP
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55
  56 # Initialize libtool.
  57 LT_INIT
  58
  59 # Initialize pkg-config.
  60 # We require at least 0.22, as "Requires.private" behaviour changed there.
  61 PKG_PROG_PKG_CONFIG([0.22])
  62
  63 # Library version for libsigrok (NOT the same as the package version).
  64 # Carefully read the libtool docs before updating these numbers!
  65 # The algorithm for determining which number to change (and how) is nontrivial!
  66 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  67 SR_LIB_VERSION_CURRENT=2
  68 SR_LIB_VERSION_REVISION=0
  69 SR_LIB_VERSION_AGE=0
  70 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  71 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  72 AC_SUBST(SR_LIB_VERSION_CURRENT)
  73 AC_SUBST(SR_LIB_VERSION_REVISION)
  74 AC_SUBST(SR_LIB_VERSION_AGE)
  75 AC_SUBST(SR_LIB_VERSION)
  76 AC_SUBST(SR_LIB_LDFLAGS)
  77
  78 # Hardware support '--enable' options.
  79
  80 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  81         [enable all drivers by default [default=yes]]),
  82         [HW_ENABLED_DEFAULT="$enableval"],
  83         [HW_ENABLED_DEFAULT="yes"])
  84
  85 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  86               [enable Agilent DMM support [default=yes]]),
  87               [HW_AGILENT_DMM="$enableval"],
  88               [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  89 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
  90 if test "x$HW_AGILENT_DMM" = "xyes"; then
  91         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
  92 fi
  93
  94 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  95               [enable ALSA driver support [default=yes]]),
  96               [HW_ALSA="$enableval"],
  97               [HW_ALSA=$HW_ENABLED_DEFAULT])
  98 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
  99 if test "x$HW_ALSA" = "xyes"; then
 100         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 101 fi
 102
 103 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
 104               [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
 105               [LA_ASIX_SIGMA="$enableval"],
 106               [LA_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 107 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 108 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 109         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 110 fi
 111
 112 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 113               [enable ChronoVu LA8 support [default=yes]]),
 114               [LA_CHRONOVU_LA8="$enableval"],
 115               [LA_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 116 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 117 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 118         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 119 fi
 120
 121 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 122         [enable Colead SLM support [default=yes]]),
 123         [HW_COLEAD_SLM="$enableval"],
 124         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 125 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 126 if test "x$HW_COLEAD_SLM" = "xyes"; then
 127         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 128 fi
 129
 130 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 131               [enable demo driver support [default=yes]]),
 132               [LA_DEMO="$enableval"],
 133               [LA_DEMO=$HW_ENABLED_DEFAULT])
 134 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 135 if test "x$LA_DEMO" = "xyes"; then
 136         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 137 fi
 138
 139 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 140               [enable Fluke DMM support [default=yes]]),
 141               [HW_FLUKE_DMM="$enableval"],
 142               [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 143 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 144 if test "x$HW_FLUKE_DMM" = "xyes"; then
 145         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 146 fi
 147
 148 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 149               [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 150               [LA_FX2LAFW="$enableval"],
 151               [LA_FX2LAFW=$HW_ENABLED_DEFAULT])
 152 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 153 if test "x$LA_FX2LAFW" = "xyes"; then
 154         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 155 fi
 156
 157 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 158               [enable Hantek DSO support [default=yes]]),
 159               [HW_HANTEK_DSO="$enableval"],
 160               [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 161 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 162 if test "x$HW_HANTEK_DSO" = "xyes"; then
 163         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 164 fi
 165
 166 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 167         [enable Lascar EL-USB support [default=yes]]),
 168         [HW_LASCAR_EL_USB="$enableval"],
 169         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 170 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 171 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 172         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 173 fi
 174
 175 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 176               [enable Link Instruments MSO-19 support [default=yes]]),
 177               [LA_LINK_MSO19="$enableval"],
 178               [LA_LINK_MSO19=$HW_ENABLED_DEFAULT])
 179 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 180 if test "x$LA_LINK_MSO19" = "xyes"; then
 181         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 182 fi
 183
 184 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 185         [enable Nexus Osciprime support [default=yes]]),
 186         [HW_NEXUS_OSCIPRIME="$enableval"],
 187         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 188 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 189 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 190         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 191 fi
 192
 193 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 194               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 195               [LA_OLS="$enableval"],
 196               [LA_OLS=$HW_ENABLED_DEFAULT])
 197 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 198 if test "x$LA_OLS" = "xyes"; then
 199         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 200 fi
 201
 202 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 203         [enable Rigol DS1xx2 support [default=yes]]),
 204         [HW_RIGOL_DS1XX2="$enableval"],
 205         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 206 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 207 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 208         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 209 fi
 210
 211 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 212               [enable serial DMM support [default=yes]]),
 213               [HW_SERIAL_DMM="$enableval"],
 214               [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 215 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 216 if test "x$HW_SERIAL_DMM" = "xyes"; then
 217         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 218 fi
 219
 220 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 221         [enable Tondaj SL-814 support [default=yes]]),
 222         [HW_TONDAJ_SL_814="$enableval"],
 223         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 224 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 225 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 226         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 227 fi
 228
 229 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 230               [enable UNI-T DMM support [default=yes]]),
 231               [HW_UNI_T_DMM="$enableval"],
 232               [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 233 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 234 if test "x$HW_UNI_T_DMM" = "xyes"; then
 235         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 236 fi
 237
 238 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 239         [enable victor-dmm support [default=yes]]),
 240         [HW_VICTOR_DMM="$enableval"],
 241         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 242 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 243 if test "x$HW_VICTOR_DMM" = "xyes"; then
 244         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [victor-dmm support])
 245 fi
 246
 247 AC_ARG_ENABLE(zeroplus-logic-cube,
 248               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 249               [enable ZEROPLUS Logic Cube support [default=yes]]),
 250               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 251               [LA_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 252 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 253 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 254         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 255 fi
 256
 257 # Checks for libraries.
 258
 259 # This variable collects the pkg-config names of all detected libs.
 260 # It is then used to construct the "Requires.private:" field in the
 261 # libsigrok.pc file.
 262 SR_PKGLIBS=""
 263
 264 # libglib-2.0 is always needed.
 265 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 266 AM_PATH_GLIB_2_0([2.28.0],
 267         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 268
 269 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 270 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 271         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 272         SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
 273
 274 # libusb-1.0 is only needed for some hardware drivers.
 275 if test "x$LA_ASIX_SIGMA" != xno \
 276    -o "x$LA_CHRONOVU_LA8" != xno \
 277    -o "x$LA_FX2LAFW" != xno \
 278    -o "x$HW_HANTEK_DSO" != xno \
 279    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 280         case "$build" in
 281         *freebsd*)
 282                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 283                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 284                         [Specifies whether we have a libusb.h header.])
 285                 ;;
 286         *)
 287                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 288                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 289                         LIBS="$LIBS $libusb_LIBS";
 290                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 291                 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 292                 if test "x$libusb_CFLAGS" != "x"; then
 293                         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 294                                 [Specifies whether we have a libusb.h header.])
 295                 fi
 296                 ;;
 297         esac
 298 fi
 299
 300 # libzip is always needed.
 301 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 302         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 303         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 304
 305 # libftdi is only needed for some hardware drivers.
 306 if test "x$LA_ASIX_SIGMA" != xno \
 307      -o "x$LA_CHRONOVU_LA8" != xno; then
 308         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 309                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 310                 LIBS="$LIBS $libftdi_LIBS";
 311                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 312 fi
 313
 314 # libudev is only needed for some hardware drivers.
 315 if test "x$LA_LINK_MSO19" != xno; then
 316         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 317                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 318                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 319 fi
 320
 321 # ALSA is only needed for some hardware drivers.
 322 if test "x$HW_ALSA" != xno; then
 323         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 324                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 325                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 326 fi
 327
 328 # EZUSB FX2 firmware helper code is only needed for some hardware drivers.
 329 AM_CONDITIONAL(NEED_EZUSB, \
 330         test "x$LA_FX2LAFW" != xno \
 331         -o "x$HW_HANTEK_DSO" != xno \
 332 )
 333
 334 # Serial port helper code is only needed for some hardware drivers.
 335 AM_CONDITIONAL(NEED_SERIAL, \
 336         test "x$HW_AGILENT_DMM" != xno \
 337         -o "x$HW_COLEAD_SLM" != xno \
 338         -o "x$HW_FLUKE_DMM" != xno \
 339         -o "x$LA_LINK_MSO19" != xno \
 340         -o "x$LA_OLS" != xno \
 341         -o "x$HW_SERIAL_DMM" != xno \
 342         -o "x$HW_TONDAJ_SL_814" != xno \
 343 )
 344
 345 AC_SUBST(SR_PKGLIBS)
 346
 347 # Checks for header files.
 348 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 349 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 350
 351 # Checks for typedefs, structures, and compiler characteristics.
 352 AC_C_INLINE
 353 AC_TYPE_INT8_T
 354 AC_TYPE_INT16_T
 355 AC_TYPE_INT32_T
 356 AC_TYPE_INT64_T
 357 AC_TYPE_UINT8_T
 358 AC_TYPE_UINT16_T
 359 AC_TYPE_UINT32_T
 360 AC_TYPE_UINT64_T
 361 AC_TYPE_SIZE_T
 362
 363 # Checks for library functions.
 364 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 365
 366 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 367 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 368 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 369
 370 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 371 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 372 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 373 SR_PACKAGE_VERSION=sr_package_version
 374
 375 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 376 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 377 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 378 AC_SUBST(SR_PACKAGE_VERSION)
 379
 380 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 381                  hardware/agilent-dmm/Makefile
 382                  hardware/alsa/Makefile
 383                  hardware/asix-sigma/Makefile
 384                  hardware/chronovu-la8/Makefile
 385                  hardware/colead-slm/Makefile
 386                  hardware/common/Makefile
 387                  hardware/lascar-el-usb/Makefile
 388                  hardware/nexus-osciprime/Makefile
 389                  hardware/rigol-ds1xx2/Makefile
 390                  hardware/tondaj-sl-814/Makefile
 391                  hardware/victor-dmm/Makefile
 392                  hardware/common/dmm/Makefile
 393                  hardware/demo/Makefile
 394                  hardware/fluke-dmm/Makefile
 395                  hardware/fx2lafw/Makefile
 396                  hardware/hantek-dso/Makefile
 397                  hardware/link-mso19/Makefile
 398                  hardware/openbench-logic-sniffer/Makefile
 399                  hardware/serial-dmm/Makefile
 400                  hardware/uni-t-dmm/Makefile
 401                  hardware/zeroplus-logic-cube/Makefile
 402                  input/Makefile
 403                  output/Makefile
 404                  output/text/Makefile
 405                  libsigrok.pc
 406                  contrib/Makefile
 407                 ])
 408
 409 AC_OUTPUT
 410
 411 echo
 412 echo "libsigrok configuration summary:"
 413 echo
 414 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 415 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 416 echo "  - Prefix: $prefix"
 417 echo
 418 echo "Detected libraries:"
 419 echo
 420
 421 # Note: This only works for libs with pkg-config integration.
 422 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
 423         if `$PKG_CONFIG --exists $lib`; then
 424                 ver=`$PKG_CONFIG --modversion $lib`
 425                 answer="yes ($ver)"
 426         else
 427                 answer="no"
 428         fi
 429         echo "  - $lib: $answer"
 430 done
 431
 432 echo -e "\nEnabled hardware drivers:\n"
 433 echo "  - Agilent DMM..................... $HW_AGILENT_DMM"
 434 echo "  - ALSA............................ $HW_ALSA"
 435 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 436 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 437 echo "  - Colead SLM...................... $HW_COLEAD_SLM"
 438 echo "  - Demo driver..................... $LA_DEMO"
 439 echo "  - Fluke DMM....................... $HW_FLUKE_DMM"
 440 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 441 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 442 echo "  - Lascar EL-USB................... $HW_LASCAR_EL_USB"
 443 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 444 echo "  - Nexus Osciprime................. $HW_NEXUS_OSCIPRIME"
 445 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 446 echo "  - Rigol DS1xx2.................... $HW_RIGOL_DS1XX2"
 447 echo "  - Serial DMM...................... $HW_SERIAL_DMM"
 448 echo "  - Tondaj SL-814................... $HW_TONDAJ_SL_814"
 449 echo "  - UNI-T DMM....................... $HW_UNI_T_DMM"
 450 echo "  - Victor DMM...................... $HW_VICTOR_DMM"
 451 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 452 echo
 453