configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 AC_CANONICAL_HOST
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_INSTALL
  46 AC_PROG_LN_S
  47
  48 # Required for per-target flags or subdir-objects with C sources.
  49 AM_PROG_CC_C_O
  50
  51 # Get compiler versions.
  52 SR_PROG_VERSION([$CC], [sr_cc_version])
  53 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  54
  55 # Check for optional make features.
  56 SR_PROG_MAKE_ORDER_ONLY
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Set up the libsigrok version defines.
  62 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  63
  64 # Library version for libsigrok (NOT the same as the package version).
  65 # Carefully read the libtool docs before updating these numbers!
  66 # The algorithm for determining which number to change (and how) is nontrivial!
  67 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  68 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  69
  70 #############################
  71 ##  Optional dependencies  ##
  72 #############################
  73
  74 AC_LANG([C])
  75
  76 # Initialize pkg-config.
  77 # We require at least 0.22, as "Requires.private" behaviour changed there.
  78 PKG_PROG_PKG_CONFIG([0.22])
  79
  80 # Keep track of all checked modules so we can list them at the end.
  81 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  82
  83 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  84 # These are used to derive the compiler flags and for the "Requires.private"
  85 # field in the generated libsigrok.pc file.
  86 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  87 SR_PKGLIBS_TESTS=
  88 SR_PKGLIBS_CXX=
  89 SR_PKGLIBS_PYTHON=
  90 SR_EXTRA_LIBS=
  91
  92 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  93         [libserialport >= 0.1.1])
  94
  95 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  96         [libftdi1 >= 1.0], [libftdi >= 0.16])
  97
  98 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  99 # This means libusb-1.0 is always available; no need to check for it.
 100 # On Windows, require the latest version we can get our hands on,
 101 # until the new generic event handling has seen an official release.
 102 AS_CASE([$host_os],
 103         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 104         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 105         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 106
 107 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 108         [$sr_libusb_req])
 109
 110 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 111         [librevisa >= 0.0.20130412])
 112
 113 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 114         [libgpib])
 115
 116 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 117         sr_save_LIBS=$LIBS
 118         LIBS="-lieee1284 $LIBS"
 119         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 120                                 [[(void) ieee1284_open(0, 0, 0);]])],
 121                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 122         LIBS=$sr_save_LIBS
 123 ])
 124 AS_IF([test "x$sr_have_libieee1284" = xyes],
 125         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 126
 127 ######################
 128 ##  Feature checks  ##
 129 ######################
 130
 131 # The Check unit testing framework is optional. Disable if not found.
 132 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 133 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 134
 135 # Enable the C99 standard if possible, and enforce the use
 136 # of SR_API to explicitly mark all public API functions.
 137 SR_EXTRA_CFLAGS=
 138 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 139 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 140
 141 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 142
 143 # Check host characteristics.
 144 AC_SYS_LARGEFILE
 145 AC_C_BIGENDIAN
 146
 147 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 148 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 149 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 150
 151 # We need to link against the Winsock2 library for SCPI over TCP.
 152 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 153
 154 # libm (the standard math library) is always needed.
 155 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 156
 157 # RPC is only needed for VXI support.
 158 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 159         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 160                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 161                         [[(void) clnt_create("", 0, 0, "");]])],
 162                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 163 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 164         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 165 # VXI support is only compiled if RPC support was found.
 166 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 167
 168 ########################
 169 ##  Hardware drivers  ##
 170 ########################
 171
 172 # Keep track of all drivers so we can list them at the end.
 173 SR_VAR_SUMMARY([sr_driver_summary])
 174
 175 # Check whether the sr_deps_avail list contains all of the arguments.
 176 # Unavailable dependencies are collected in sr_deps_missing.
 177 sr_check_driver_deps() {
 178         sr_deps_missing=
 179         for sr_dep
 180         do
 181                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 182                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 183         done
 184         test -z "$sr_deps_missing" || return 1
 185 }
 186
 187 AC_ARG_ENABLE([all-drivers],
 188         [AS_HELP_STRING([--enable-all-drivers],
 189                         [enable all drivers by default [default=yes]])],
 190         [], [enable_all_drivers=yes])
 191
 192 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 193 m4_define([_SR_DRIVER], [
 194         AC_ARG_ENABLE([$2],
 195                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 196                 [$3=$enableval], [$3=$enable_all_drivers])
 197
 198         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 199                 sr_check_driver_deps $4 \
 200                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 201         ])], [sr_hw_info='no (disabled)'])
 202         sr_driver_summary_append "$2" "$sr_hw_info"
 203
 204         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 205         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 206 ])
 207
 208 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 209 m4_define([SR_DRIVER],
 210         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 211
 212 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 213 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 214 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 215 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 216 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 217 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 218 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 219 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 220 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 221 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 222 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 223 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 224 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 225 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 226 SR_DRIVER([demo], [demo])
 227 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 228 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 229 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 230 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 231 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 232 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 233 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 234 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 235 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 236 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 237 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 238 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 239 SR_DRIVER([maynuo-m97], [maynuo-m97])
 240 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 241 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 242 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 243 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 244 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 245 SR_DRIVER([Rigol DS], [rigol-ds])
 246 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 247 SR_DRIVER([SCPI PPS], [scpi-pps])
 248 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 249 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 250 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 251 SR_DRIVER([Testo], [testo], [libusb])
 252 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 253 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 254 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 255 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 256 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 257 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 258
 259 ###############################
 260 ##  Language bindings setup  ##
 261 ###############################
 262
 263 AC_LANG([C++])
 264 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 265
 266 AC_ARG_ENABLE([bindings],
 267         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 268         [], [enable_bindings=yes])
 269
 270 AC_ARG_ENABLE([cxx],
 271         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 272         [], [enable_cxx=$enable_bindings])
 273
 274 AC_ARG_ENABLE([python],
 275         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 276         [], [enable_python=$enable_bindings])
 277
 278 AC_ARG_ENABLE([java],
 279         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 280         [], [enable_java=$enable_bindings])
 281
 282 ####################
 283 ##  C++ bindings  ##
 284 ####################
 285
 286 sr_cxx_missing=
 287
 288 # Check if the C++ compiler supports the C++11 standard.
 289 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 290 AS_IF([test "x$HAVE_CXX11" != x1],
 291         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 292
 293 # The C++ bindings need glibmm.
 294 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 295 AS_IF([test "x$sr_have_glibmm" != xyes],
 296         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 297
 298 # The C++ bindings use Doxygen to parse libsigrok symbols.
 299 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 300 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 301         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 302
 303 # Python is needed for the C++ bindings.
 304 AM_PATH_PYTHON([2.7],
 305         [HAVE_PYTHON=yes],
 306         [HAVE_PYTHON=no
 307         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 308
 309 AS_IF([test -z "$sr_cxx_missing"],
 310         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 311 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 312
 313 # C++ bindings want stoi and stod.
 314 AM_COND_IF([BINDINGS_CXX], [
 315         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 316                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 317                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 318                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 319         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 320                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 321                         [Specifies whether we have the stoi and stod functions.])])
 322 ])
 323
 324 #######################
 325 ##  Python bindings  ##
 326 #######################
 327
 328 AS_IF([test "x$BINDINGS_CXX" = xyes],
 329         [sr_python_missing=],
 330         [sr_python_missing='C++ bindings'])
 331
 332 # The Python bindings need Python development files.
 333 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 334         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 335 AS_IF([test "x$sr_have_python_dev" != xyes],
 336         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 337
 338 # PyGObject is needed for the Python bindings.
 339 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 340 AS_IF([test "x$sr_have_pygobject" != xyes],
 341         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 342
 343 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 344         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 345                 [Whether last argument to pyg_flags_get_value() is signed.])])
 346
 347 # The Python bindings need the setuptools Python module.
 348 # We'll let it go through even if the AX macro wasn't found,
 349 # as the Python module may still be there.
 350 HAVE_PYMOD_SETUPTOOLS=yes
 351 m4_ifdef([AX_PYTHON_MODULE],
 352         [AX_PYTHON_MODULE([setuptools])],
 353         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 354 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 355         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 356
 357 # The Python bindings use SWIG to generate code.
 358 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 359 AS_IF([test "x$SWIG" = x],
 360         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 361
 362 AS_IF([test -z "$sr_python_missing"],
 363         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 364 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 365
 366 ####################
 367 ##  Java bindings ##
 368 ####################
 369
 370 AS_IF([test "x$BINDINGS_CXX" = xyes],
 371         [sr_java_missing=],
 372         [sr_java_missing='C++ bindings'])
 373
 374 # The Java bindings use SWIG to generate code.
 375 AS_IF([test "x$SWIG" = x],
 376         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 377
 378 # Find Java compiler and JNI includes for Java bindings.
 379 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 380 AS_IF([test "x$HAVE_JAVAC" = xno],
 381         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 382
 383 AC_ARG_WITH([jni-include-path],
 384         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 385                 [specify JNI include directories [default=detect]])],
 386         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 387
 388 JNI_CPPFLAGS=
 389 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 390         AX_PROG_JAVAC
 391         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 392                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 393                 ## If we can find jni.h without any special search path, skip
 394                 ## the execution of the broken macro to increase our chances of
 395                 ## success.
 396                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 397                         [AX_JNI_INCLUDE_DIR])
 398         ])
 399 ])
 400 for sr_dir in $JNI_INCLUDE_DIRS
 401 do
 402         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 403 done
 404 AC_SUBST([JNI_CPPFLAGS])
 405
 406 sr_save_cppflags=$CPPFLAGS
 407 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 408 AC_CHECK_HEADER([jni.h],,
 409         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 410 CPPFLAGS=$sr_save_cppflags
 411
 412 AS_IF([test -z "$sr_java_missing"],
 413         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 414 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 415
 416 ##############################
 417 ##  Finalize configuration  ##
 418 ##############################
 419
 420 # Add mandatory dependencies to module list.
 421 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 422 AC_SUBST([SR_PKGLIBS])
 423
 424 # Retrieve the compile and link flags for all modules combined.
 425 # Also, bail out at this point if any module dependency is not met.
 426 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 427 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 428
 429 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 430 # the C++ bindings are enabled.
 431 AM_COND_IF([BINDINGS_CXX], [
 432         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 433         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 434 ])
 435
 436 # Check for specific libusb features, now that we know the CFLAGS.
 437 AC_LANG([C])
 438 sr_save_cflags=$CFLAGS
 439 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 440 AC_CHECK_TYPES([libusb_os_handle],
 441         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 442         [[#include <libusb.h>]])
 443 CFLAGS=$sr_save_cflags
 444 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 445         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 446
 447 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 448 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 449
 450 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 451         [Build-time version of libzip.])
 452 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 453         [The canonical host libsigrok will run on.])
 454
 455 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 456
 457 AC_OUTPUT
 458
 459 # Prepare bindings report messages.
 460 m4_define([SR_PREPARE_BINDING_REPORT], [
 461         sr_report_$1=
 462         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 463         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 464 ])
 465 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 466
 467 cat >&AS_MESSAGE_FD <<_EOF
 468
 469 libsigrok configuration summary:
 470  - Package version................. $SR_PACKAGE_VERSION
 471  - Library ABI version............. $SR_LIB_VERSION
 472  - Prefix.......................... $prefix
 473  - Building on..................... $build
 474  - Building for.................... $host
 475
 476 Compile configuration:
 477  - C compiler...................... $CC
 478  - C compiler version.............. $sr_cc_version
 479  - C compiler flags................ $CFLAGS
 480  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 481  - C compiler warnings............. $SR_WFLAGS
 482  - C++ compiler.................... $CXX
 483  - C++ compiler version............ $sr_cxx_version
 484  - C++ compiler flags.............. $CXXFLAGS
 485  - C++ compiler warnings........... $SR_WXXFLAGS
 486
 487 Detected libraries (required):
 488  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 489  - libzip >= 0.10.................. $sr_libzip_version
 490
 491 Detected libraries (optional):
 492 $sr_pkglibs_summary
 493 Enabled hardware drivers:
 494 $sr_driver_summary
 495 Enabled SCPI backends:
 496  - TCP............................. yes
 497  - RPC............................. $sr_cv_have_rpc
 498  - serial.......................... $sr_have_libserialport
 499  - VISA............................ $sr_have_librevisa
 500  - GPIB............................ $sr_have_libgpib
 501  - USBTMC.......................... $sr_have_libusb
 502
 503 Enabled language bindings:
 504  - C++............................. $BINDINGS_CXX$sr_report_cxx
 505  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 506  - Java............................ $BINDINGS_JAVA$sr_report_java
 507
 508 _EOF