configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BeagleLogic], [beaglelogic])
 110 DRIVER([Brymen BM86x], [brymen-bm86x])
 111 DRIVER([Brymen DMM], [brymen-dmm])
 112 DRIVER([CEM DT-885x], [cem-dt-885x])
 113 DRIVER([Center 3xx], [center-3xx])
 114 DRIVER([ChronoVu LA], [chronovu-la])
 115 DRIVER([Colead SLM], [colead-slm])
 116 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 117 DRIVER([demo], [demo])
 118 DRIVER([Fluke DMM], [fluke-dmm])
 119 DRIVER([fx2lafw], [fx2lafw])
 120 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 121 DRIVER([Hameg HMO], [hameg-hmo])
 122 DRIVER([Hantek DSO], [hantek-dso])
 123 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 124 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 125 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 126 DRIVER([Lascar EL-USB], [lascar-el-usb])
 127 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 128 DRIVER([MIC 985xx], [mic-985xx])
 129 DRIVER([Motech LPS 30x], [motech-lps-30x])
 130 DRIVER([Norma DMM], [norma-dmm])
 131 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 132 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([SCPI PPS], [scpi-pps])
 136 DRIVER([serial DMM], [serial-dmm])
 137 DRIVER([Sysclk LWLA], [sysclk-lwla])
 138 DRIVER([Teleinfo], [teleinfo])
 139 DRIVER([Testo], [testo])
 140 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 141 DRIVER([UNI-T DMM], [uni-t-dmm])
 142 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 143 DRIVER([Victor DMM], [victor-dmm])
 144 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 145 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 146
 147 AC_ARG_ENABLE(libserialport,
 148         AC_HELP_STRING([--disable-libserialport],
 149         [disable libserialport support [default=detect]]))
 150
 151 AC_ARG_ENABLE(libftdi,
 152         AC_HELP_STRING([--disable-libftdi],
 153         [disable libftdi support [default=detect]]))
 154
 155 AC_ARG_ENABLE(libusb,
 156         AC_HELP_STRING([--disable-libusb],
 157         [disable libusb support [default=detect]]))
 158
 159 # Language binding '--enable' options:
 160
 161 AC_ARG_ENABLE(bindings,
 162         AC_HELP_STRING([--enable-bindings],
 163         [build language bindings [default=yes]]),
 164         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 165
 166 AC_ARG_ENABLE(cxx,
 167         AC_HELP_STRING([--enable-cxx],
 168         [build C++ bindings [default=yes]]),
 169         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 170
 171 AC_ARG_ENABLE(python,
 172         AC_HELP_STRING([--enable-python],
 173         [build Python bindings [default=yes]]),
 174         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 175
 176 AC_ARG_ENABLE(java,
 177         AC_HELP_STRING([--enable-java],
 178         [build Java bindings [default=yes]]),
 179         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 180
 181 AC_ARG_WITH(jni-include-path,
 182         AC_HELP_STRING([--with-jni-include-path=path],
 183         [specify include path for JNI [default=autodetect]]),
 184         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 185
 186 # Check if the C++ compiler supports the C++11 standard.
 187
 188 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 189         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 190
 191 if test "x$HAVE_CXX11" != "x1"; then
 192         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 193 fi
 194
 195 # The C++ bindings use Doxygen to parse libsigrok symbols.
 196 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 197 if test "x$HAVE_DOXYGEN" != "xyes"; then
 198         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 199 fi
 200
 201 # Python is needed for the C++ bindings.
 202 AC_CHECK_PROG([HAVE_PYTHON], [python], [yes])
 203 if test "x$HAVE_PYTHON" != "xyes"; then
 204         BINDINGS_CXX="no"; cxx_msg="Python required"
 205 fi
 206
 207 # The Python bindings need Python development files.
 208 PKG_CHECK_MODULES([python], [python >= 2.7],
 209         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 210         CXXLIBS="$CXXLIBS $python_LIBS"],
 211 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 212         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 213         CXXLIBS="$CXXLIBS $python27_LIBS"],
 214                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 215
 216 # The Python bindings need the setuptools Python module.
 217 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 218         # We'll let it go through even if the macro wasn't found, the Python
 219         # module may still be there.
 220         [HAVE_PYTHON_SETUPTOOLS="yes";
 221                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 222 )
 223 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 224         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 225 fi
 226
 227 # The Python and Java bindings use SWIG to generate code.
 228 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 229 if test "x$HAVE_SWIG" != "xyes"; then
 230         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 231         BINDINGS_JAVA="no"; java_msg="SWIG required"
 232 fi
 233
 234 # Checks for libraries.
 235
 236 case "$host" in
 237 *mingw*)
 238         # We need to link against the Winsock2 library for SCPI over TCP.
 239         LIBS="$LIBS -lws2_32";;
 240 esac
 241
 242 # This variable collects the pkg-config names of all detected libs.
 243 # It is then used to construct the "Requires.private:" field in the
 244 # libsigrok.pc file.
 245 SR_PKGLIBS=""
 246
 247 # libm (the standard math library) is always needed.
 248 AC_SEARCH_LIBS([pow], [m])
 249
 250 # RPC is only needed for VXI support.
 251 AC_MSG_CHECKING([for RPC support])
 252 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 253                         [CLIENT *rpc_test(void)],
 254                         [{ return clnt_create("", 0, 0, ""); }])],
 255                 [AC_MSG_RESULT([yes]); have_rpc=1],
 256                 [AC_MSG_RESULT([no]);  have_rpc=0])
 257 # Define HAVE_RPC in config.h if we found RPC support.
 258 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 259 # VXI support is only compiled if RPC support was found.
 260 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 261
 262 # libglib-2.0 is always needed. Abort if it's not found.
 263 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 264 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 265 AM_PATH_GLIB_2_0([2.32.0],
 266         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 267
 268 # libzip is always needed. Abort if it's not found.
 269 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 270         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 271         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 272
 273 # libserialport is only needed for some hardware drivers. Disable the
 274 # respective drivers if it is not found.
 275 if test "x$enable_libserialport" != "xno"; then
 276         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 277                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 278                 LIBS="$LIBS $libserialport_LIBS";
 279                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 280                 [have_libserialport="no"])
 281         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 282                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 283         fi
 284 else
 285         have_libserialport="no"
 286 fi
 287 if test "x$have_libserialport" = "xno"; then
 288         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 289         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 290         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 291         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 292         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 293         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 294         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 295 else
 296         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 297         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 298                 [Specifies whether we have libserialport.])
 299 fi
 300
 301 # Serial port helper code is only compiled in if libserialport was found.
 302 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 303
 304 # The VISA SCPI backend is only compiled in if librevisa was found.
 305 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 306         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 307         LIBS="$LIBS $librevisa_LIBS";
 308         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 309         [have_librevisa="no"])
 310 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 311 if test "x$have_librevisa" != "xno"; then
 312         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 313         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 314                 [Specifies whether we have librevisa.])
 315 fi
 316
 317 # The GPIB SCPI backend is only compiled in if libgpib is found.
 318 PKG_CHECK_MODULES([libgpib], [libgpib],
 319         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 320         LIBS="$LIBS $libgpib_LIBS";
 321         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 322         [have_libgpib="no"])
 323 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 324 if test "x$have_libgpib" != "xno"; then
 325         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 326         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 327                 [Specifies whether we have libgpib.])
 328 fi
 329
 330 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 331 # drivers if it is not found.
 332 if test "x$enable_libusb" != "xno"; then
 333         case "$host" in
 334         *freebsd*)
 335                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 336                 # This means libusb-1.0 is always available, no need to check for it,
 337                 # and no need to (potentially) disable any drivers if it's not found.
 338                 have_libusb1_0="yes"
 339                 ;;
 340         *)
 341                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 342                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 343                         LIBS="$LIBS $libusb_LIBS";
 344                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 345                         [have_libusb1_0="no"])
 346                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 347                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 348                 fi
 349                 ;;
 350         esac
 351 else
 352         have_libusb1_0="no"
 353 fi
 354 if test "x$have_libusb1_0" = "xno"; then
 355         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 356         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 357         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 358         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 359         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 360         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 361 else
 362         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 363         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 364                 [Specifies whether we have libusb-1.0.])
 365 fi
 366
 367 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 368 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 369
 370 # libftdi is only needed for some hardware drivers. Disable them if not found.
 371 if test "x$enable_libftdi" != "xno"; then
 372         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 373                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 374                 LIBS="$LIBS $libftdi_LIBS";
 375                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 376                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 377                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 378                         LIBS="$LIBS $libftdi1_LIBS";
 379                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 380                         [have_libftdi="no"])])
 381         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 382                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 383         fi
 384 else
 385         have_libftdi="no"
 386 fi
 387 if test "x$have_libftdi" = "xno"; then
 388         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 389         HW_PIPISTRELLO_OLS="no";
 390 fi
 391
 392 # glibmm-2.4 is needed for the C++ bindings.
 393 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 394         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 395         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 396         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 397
 398 # C++ bindings want stoi and stod.
 399 if test "x$BINDINGS_CXX" == "xyes"; then
 400         AC_LANG_PUSH([C++])
 401         AC_MSG_CHECKING([for stoi and stod])
 402         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 403                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 404                 [AC_MSG_RESULT([yes]);
 405                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 406                 [Specifies whether we have the stoi and stod functions.])],
 407                 [AC_MSG_RESULT([no])])
 408         AC_LANG_POP([C++])
 409 fi
 410
 411 # PyGObject is needed for the Python bindings.
 412 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 413         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 414         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 415         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 416                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 417         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 418                 [Whether last argument to pyg_flags_get_value() is signed.])],
 419         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 420
 421 # The Check unit testing framework is optional. Disable if not found.
 422 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 423         [have_check="yes"], [have_check="no"])
 424 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 425
 426 # The OLS driver uses serial port file descriptors directly, and therefore
 427 # will not currently work on Windows.
 428 case "$host" in
 429 *mingw*)
 430         HW_OPENBENCH_LOGIC_SNIFFER="no"
 431         ;;
 432 esac
 433
 434 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 435 # build it if these headers aren't available.
 436 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 437
 438 AC_SUBST(SR_PKGLIBS)
 439
 440 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 441 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrok -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 442
 443 # Find Java compiler and JNI includes for Java bindings.
 444 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 445 if test "x$HAVE_JAVAC" = "xyes"; then
 446         AX_PROG_JAVAC
 447         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 448                 if test "x$cross_compiling" = "xyes"; then
 449                         JNI_INCLUDE_DIRS=
 450                 else
 451                         AX_JNI_INCLUDE_DIR
 452                 fi
 453         fi
 454         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 455                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 456         done
 457         AC_LANG_PUSH([C++])
 458         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 459         AC_LANG_POP([C++])
 460 else
 461         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 462 fi
 463
 464 # Python and Java bindings depend on C++ bindings.
 465 if test "x$BINDINGS_CXX" != "xyes"; then
 466         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 467         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 468 fi
 469
 470 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 471
 472 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 473 if test "x$HW_AGILENT_DMM" = "xyes"; then
 474         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 475 fi
 476
 477 AM_CONDITIONAL(HW_APPA_55II, test x$HW_APPA_55II = xyes)
 478 if test "x$HW_APPA_55II" = "xyes"; then
 479         AC_DEFINE(HAVE_HW_APPA_55II, 1, [APPA 55II support])
 480 fi
 481
 482 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 483 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 484         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 485 fi
 486
 487 AM_CONDITIONAL(HW_ATTEN_PPS3XXX, test x$HW_ATTEN_PPS3XXX = xyes)
 488 if test "x$HW_ATTEN_PPS3XXX" = "xyes"; then
 489         AC_DEFINE(HAVE_HW_ATTEN_PPS3XXX, 1, [Atten PPS3xxx support])
 490 fi
 491
 492 AM_CONDITIONAL(HW_BEAGLELOGIC, test x$HW_BEAGLELOGIC = xyes)
 493 if test "x$HW_BEAGLELOGIC" = "xyes"; then
 494         AC_DEFINE(HAVE_HW_BEAGLELOGIC, 1, [BeagleLogic support])
 495 fi
 496
 497 AM_CONDITIONAL(HW_BRYMEN_BM86X, test x$HW_BRYMEN_BM86X = xyes)
 498 if test "x$HW_BRYMEN_BM86X" = "xyes"; then
 499         AC_DEFINE(HAVE_HW_BRYMEN_BM86X, 1, [Brymen BM86X support])
 500 fi
 501
 502 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 503 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 504         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 505 fi
 506
 507 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 508 if test "x$HW_CEM_DT_885X" = "xyes"; then
 509         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 510 fi
 511
 512 AM_CONDITIONAL(HW_CENTER_3XX, test x$HW_CENTER_3XX = xyes)
 513 if test "x$HW_CENTER_3XX" = "xyes"; then
 514         AC_DEFINE(HAVE_HW_CENTER_3XX, 1, [Center 3xx support])
 515 fi
 516
 517 AM_CONDITIONAL(HW_CHRONOVU_LA, test x$HW_CHRONOVU_LA = xyes)
 518 if test "x$HW_CHRONOVU_LA" = "xyes"; then
 519         AC_DEFINE(HAVE_HW_CHRONOVU_LA, 1, [ChronoVu LA support])
 520 fi
 521
 522 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 523 if test "x$HW_COLEAD_SLM" = "xyes"; then
 524         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 525 fi
 526
 527 AM_CONDITIONAL(HW_CONRAD_DIGI_35_CPU, test x$HW_CONRAD_DIGI_35_CPU = xyes)
 528 if test "x$HW_CONRAD_DIGI_35_CPU" = "xyes"; then
 529         AC_DEFINE(HAVE_HW_CONRAD_DIGI_35_CPU, 1, [Conrad DIGI 35 CPU support])
 530 fi
 531
 532 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 533 if test "x$HW_DEMO" = "xyes"; then
 534         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 535 fi
 536
 537 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 538 if test "x$HW_FLUKE_DMM" = "xyes"; then
 539         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 540 fi
 541
 542 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 543 if test "x$HW_FX2LAFW" = "xyes"; then
 544         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 545 fi
 546
 547 AM_CONDITIONAL(HW_GMC_MH_1X_2X, test x$HW_GMC_MH_1X_2X = xyes)
 548 if test "x$HW_GMC_MH_1X_2X" = "xyes"; then
 549         AC_DEFINE(HAVE_HW_GMC_MH_1X_2X, 1, [gmc-mh-1x-2x support])
 550 fi
 551
 552 AM_CONDITIONAL(HW_HAMEG_HMO, test x$HW_HAMEG_HMO = xyes)
 553 if test "x$HW_HAMEG_HMO" = "xyes"; then
 554         AC_DEFINE(HAVE_HW_HAMEG_HMO, 1, [Hameg HMO support])
 555 fi
 556
 557 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 558 if test "x$HW_HANTEK_DSO" = "xyes"; then
 559         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 560 fi
 561
 562 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 563 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 564         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic-2 support])
 565 fi
 566
 567 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 568 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 569         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [IKALOGIC ScanaPLUS support])
 570 fi
 571
 572 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 573 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 574         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 575 fi
 576
 577 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 578 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 579         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 580 fi
 581
 582 AM_CONDITIONAL(HW_MANSON_HCS_3XXX, test x$HW_MANSON_HCS_3XXX = xyes)
 583 if test "x$HW_MANSON_HCS_3XXX" = "xyes"; then
 584         AC_DEFINE(HAVE_HW_MANSON_HCS_3XXX, 1, [Manson HCS-3xxx support])
 585 fi
 586
 587 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 588 if test "x$HW_MIC_985XX" = "xyes"; then
 589         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 590 fi
 591
 592 AM_CONDITIONAL(HW_MOTECH_LPS_30X, test x$HW_MOTECH_LPS_30X = xyes)
 593 if test "x$HW_MOTECH_LPS_30X" = "xyes"; then
 594         AC_DEFINE(HAVE_HW_MOTECH_LPS_30X, 1, [motech-lps-30x support])
 595 fi
 596
 597 AM_CONDITIONAL(HW_NORMA_DMM, test x$HW_NORMA_DMM = xyes)
 598 if test "x$HW_NORMA_DMM" = "xyes"; then
 599         AC_DEFINE(HAVE_HW_NORMA_DMM, 1, [Norma DMM support])
 600 fi
 601
 602 AM_CONDITIONAL(HW_OPENBENCH_LOGIC_SNIFFER, test x$HW_OPENBENCH_LOGIC_SNIFFER = xyes)
 603 if test "x$HW_OPENBENCH_LOGIC_SNIFFER" = "xyes"; then
 604         AC_DEFINE(HAVE_HW_OPENBENCH_LOGIC_SNIFFER, 1, [OpenBench Logic Sniffer (OLS) support])
 605 fi
 606
 607 AM_CONDITIONAL(HW_PIPISTRELLO_OLS, test x$HW_PIPISTRELLO_OLS = xyes)
 608 if test "x$HW_PIPISTRELLO_OLS" = "xyes"; then
 609         AC_DEFINE(HAVE_HW_PIPISTRELLO_OLS, 1, [Pipistrello OLS support])
 610 fi
 611
 612 AM_CONDITIONAL(HW_RIGOL_DS, test x$HW_RIGOL_DS = xyes)
 613 if test "x$HW_RIGOL_DS" = "xyes"; then
 614         AC_DEFINE(HAVE_HW_RIGOL_DS, 1, [Rigol DS support])
 615 fi
 616
 617 AM_CONDITIONAL(HW_SALEAE_LOGIC16, test x$HW_SALEAE_LOGIC16 = xyes)
 618 if test "x$HW_SALEAE_LOGIC16" = "xyes"; then
 619         AC_DEFINE(HAVE_HW_SALEAE_LOGIC16, 1, [Saleae Logic16 support])
 620 fi
 621
 622 AM_CONDITIONAL(HW_SCPI_PPS, test x$HW_SCPI_PPS = xyes)
 623 if test "x$HW_SCPI_PPS" = "xyes"; then
 624         AC_DEFINE(HAVE_HW_SCPI_PPS, 1, [SCPI PPS support])
 625 fi
 626
 627 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 628 if test "x$HW_SERIAL_DMM" = "xyes"; then
 629         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 630 fi
 631
 632 AM_CONDITIONAL(HW_SYSCLK_LWLA, test x$HW_SYSCLK_LWLA = xyes)
 633 if test "x$HW_SYSCLK_LWLA" = "xyes"; then
 634         AC_DEFINE(HAVE_HW_SYSCLK_LWLA, 1, [Sysclk LWLA support])
 635 fi
 636
 637 AM_CONDITIONAL(HW_TELEINFO, test x$HW_TELEINFO = xyes)
 638 if test "x$HW_TELEINFO" = "xyes"; then
 639         AC_DEFINE(HAVE_HW_TELEINFO, 1, [Teleinfo support])
 640 fi
 641
 642 AM_CONDITIONAL(HW_TESTO, test x$HW_TESTO = xyes)
 643 if test "x$HW_TESTO" = "xyes"; then
 644         AC_DEFINE(HAVE_HW_TESTO, 1, [Testo support])
 645 fi
 646
 647 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 648 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 649         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 650 fi
 651
 652 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 653 if test "x$HW_UNI_T_DMM" = "xyes"; then
 654         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 655 fi
 656
 657 AM_CONDITIONAL(HW_UNI_T_UT32X, test x$HW_UNI_T_UT32X = xyes)
 658 if test "x$HW_UNI_T_UT32X" = "xyes"; then
 659         AC_DEFINE(HAVE_HW_UNI_T_UT32X, 1, [UNI-T UT32x support])
 660 fi
 661
 662 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 663 if test "x$HW_VICTOR_DMM" = "xyes"; then
 664         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 665 fi
 666
 667 AM_CONDITIONAL(HW_YOKOGAWA_DLM, test x$HW_YOKOGAWA_DLM = xyes)
 668 if test "x$HW_YOKOGAWA_DLM" = "xyes"; then
 669         AC_DEFINE(HAVE_HW_YOKOGAWA_DLM, 1, [Yokogawa DL/DLM support])
 670 fi
 671
 672 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 673 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 674         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 675 fi
 676
 677 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 678
 679 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 680
 681 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 682
 683 # Checks for header files.
 684 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 685 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 686
 687 # Checks for typedefs, structures, and compiler characteristics.
 688 AC_C_BIGENDIAN
 689
 690 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 691 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 692 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 693
 694 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 695 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 696 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 697 SR_PACKAGE_VERSION=sr_package_version
 698
 699 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 700 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 701 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 702 AC_SUBST(SR_PACKAGE_VERSION)
 703
 704 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 705         bindings/cxx/libsigrokxx.pc])
 706
 707 AC_OUTPUT
 708
 709 echo
 710 echo "libsigrok configuration summary:"
 711 echo
 712 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 713 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 714 echo "  - Prefix: $prefix"
 715 echo "  - Building on: $build"
 716 echo "  - Building for: $host"
 717 echo
 718 echo "Detected libraries:"
 719 echo
 720
 721 # Note: This only works for libs with pkg-config integration.
 722 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.2.0" \
 723         "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 724         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 725         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 726 do
 727         optional="OPTIONAL"
 728         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 729         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 730         if `$PKG_CONFIG --exists $lib`; then
 731                 ver=`$PKG_CONFIG --modversion $lib`
 732                 answer="yes ($ver)"
 733         else
 734                 answer="no"
 735         fi
 736         echo "  - ($optional) $lib: $answer"
 737 done
 738
 739 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 740
 741 # Prepare final bindings report messages.
 742 final_cxx=""
 743 final_python=""
 744 final_java=""
 745 if test "$enable_bindings" = "no"; then
 746         final_cxx=" (disabled)"
 747         final_python=" (disabled)"
 748         final_java=" (disabled)"
 749 else
 750         if test "$enable_cxx" = "no"; then
 751                 final_cxx=" (disabled)"
 752         elif test "$BINDINGS_CXX" = "no"; then
 753                 final_cxx=" ($cxx_msg)"
 754         fi
 755         if test "$enable_python" = "no"; then
 756                 final_python=" (disabled)"
 757         elif test "$BINDINGS_PYTHON" = "no"; then
 758                 final_python=" ($python_msg)"
 759         fi
 760         if test "$enable_java" = "no"; then
 761                 final_java=" (disabled)"
 762         elif test "$BINDINGS_JAVA" = "no"; then
 763                 final_java=" ($java_msg)"
 764         fi
 765 fi
 766
 767 echo "Enabled SCPI backends:"
 768 echo " - TCP............................. yes"
 769 if test "x$have_rpc" = "x0"; then
 770 echo " - RPC............................. no"
 771 else
 772 echo " - RPC............................. yes"
 773 fi
 774 echo " - serial.......................... $have_libserialport"
 775 echo " - VISA............................ $have_librevisa"
 776 echo " - GPIB............................ $have_libgpib"
 777 echo " - USBTMC.......................... $have_libusb1_0"
 778 echo
 779
 780 echo "Enabled language bindings:"
 781 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 782 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 783 echo " - Java............................ $BINDINGS_JAVA$final_java"
 784 echo