configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrok package version number (NOT the same as shared lib version!).
  24 m4_define([sr_package_version_major], [0])
  25 m4_define([sr_package_version_minor], [1])
  26 m4_define([sr_package_version_micro], [0])
  27 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  28
  29 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  30         [libsigrok], [http://www.sigrok.org])
  31 AC_CONFIG_HEADER([config.h])
  32 AC_CONFIG_MACRO_DIR([autostuff])
  33 AC_CONFIG_AUX_DIR([autostuff])
  34
  35 # We require at least automake 1.11 (needed for 'silent rules').
  36 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  37 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  38
  39 AH_TOP([#ifndef SR_CONFIG_H
  40 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  41 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  42
  43 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  44 # and enforce use of SR_API to explicitly mark all public API functions.
  45 CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
  46
  47 # Checks for programs.
  48 AC_PROG_CXX
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Initialize libtool.
  55 LT_INIT
  56
  57 # Initialize pkg-config.
  58 # We require at least 0.22, as "Requires.private" behaviour changed there.
  59 PKG_PROG_PKG_CONFIG([0.22])
  60
  61 # Library version for libsigrok (NOT the same as the package version).
  62 # Carefully read the libtool docs before updating these numbers!
  63 # The algorithm for determining which number to change (and how) is nontrivial!
  64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  65 SR_LIB_VERSION_CURRENT=0
  66 SR_LIB_VERSION_REVISION=0
  67 SR_LIB_VERSION_AGE=0
  68 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  69 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  70 AC_SUBST(SR_LIB_VERSION_CURRENT)
  71 AC_SUBST(SR_LIB_VERSION_REVISION)
  72 AC_SUBST(SR_LIB_VERSION_AGE)
  73 AC_SUBST(SR_LIB_VERSION)
  74 AC_SUBST(SR_LIB_LDFLAGS)
  75
  76 # Logic analyzer hardware support '--enable' options.
  77
  78 # Disabled by default, unfinished.
  79 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  80               [enable ALSA driver support [default=no]]),
  81               [LA_ALSA="$enableval"],
  82               [LA_ALSA=no])
  83 AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
  84 if test "x$LA_ALSA" = "xyes"; then
  85         AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
  86 fi
  87
  88 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  89               [enable ASIX Sigma support [default=yes]]),
  90               [LA_ASIX_SIGMA="$enableval"],
  91               [LA_ASIX_SIGMA=yes])
  92 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
  93 if test "x$LA_ASIX_SIGMA" = "xyes"; then
  94         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX Sigma support])
  95 fi
  96
  97 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
  98               [enable ChronoVu LA8 support [default=yes]]),
  99               [LA_CHRONOVU_LA8="$enableval"],
 100               [LA_CHRONOVU_LA8=yes])
 101 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 102 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 103         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 104 fi
 105
 106 # Disabled per default for now, will be enabled when it's tested some more.
 107 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 108               [enable fx2lafw support (for FX2 LAs). [default=no]]),
 109               [LA_FX2LAFW="$enableval"],
 110               [LA_FX2LAFW=yes])
 111 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 112 if test "x$LA_FX2LAFW" = "xyes"; then
 113         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 114 fi
 115
 116 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 117               [enable demo driver support [default=yes]]),
 118               [LA_DEMO="$enableval"],
 119               [LA_DEMO=yes])
 120 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 121 if test "x$LA_DEMO" = "xyes"; then
 122         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 123 fi
 124
 125 # Disabled by default, unfinished.
 126 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 127               [enable Link Instruments MSO-19 support [default=no]]),
 128               [LA_LINK_MSO19="$enableval"],
 129               [LA_LINK_MSO19=no])
 130 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 131 if test "x$LA_LINK_MSO19" = "xyes"; then
 132         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 133 fi
 134
 135 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 136               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 137               [LA_OLS="$enableval"],
 138               [LA_OLS=yes])
 139 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 140 if test "x$LA_OLS" = "xyes"; then
 141         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 142 fi
 143
 144 AC_ARG_ENABLE(zeroplus-logic-cube,
 145               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 146               [enable Zeroplus Logic Cube support [default=yes]]),
 147               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 148               [LA_ZEROPLUS_LOGIC_CUBE=yes])
 149 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 150 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 151         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [Zeroplus Logic Cube support])
 152 fi
 153
 154 # Checks for libraries.
 155
 156 # This variable collects the pkg-config names of all detected libs.
 157 # It is then used to construct the "Requires.private:" field in the
 158 # libsigrok.pc file.
 159 SR_PKGLIBS=""
 160
 161 # libglib-2.0 is always needed.
 162 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 163 AM_PATH_GLIB_2_0([2.22.0],
 164         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 165
 166 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 167 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 168         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 169         SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
 170
 171 # libusb is only needed for some hardware drivers.
 172 if test "x$LA_ASIX_SIGMA" != xno \
 173    -o "x$LA_CHRONOVU_LA8" != xno \
 174    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno \
 175    -o "x$LA_FX2LAFW" != xno; then
 176         case "$build" in
 177         *freebsd*)
 178                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 179                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 180                         [Specifies whether we have a libusb.h header.])
 181                 ;;
 182         *)
 183                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.5],
 184                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 185                         LIBS="$LIBS $libusb_LIBS";
 186                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 187                 AC_CHECK_LIB(usb-1.0, libusb_init)
 188                 ;;
 189         esac
 190 fi
 191
 192 # libzip is always needed.
 193 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 194         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 195         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 196
 197 # zlib is only needed for some hardware drivers.
 198 if test "x$LA_ASIX_SIGMA" != xno; then
 199         case "$build" in
 200         *freebsd*)
 201                 # FreeBSD has zlib, but no pkg-config file for it.
 202                 # Check manually, and do NOT add it to SR_PKGLIBS.
 203                 AC_CHECK_LIB(z, uncompress)
 204                 ;;
 205         *)
 206                 PKG_CHECK_MODULES([zlib], [zlib >= 1.2.3.1],
 207                         [CFLAGS="$CFLAGS $zlib_CFLAGS"; LIBS="$LIBS $zlib_LIBS";
 208                         SR_PKGLIBS="$SR_PKGLIBS zlib"])
 209                 ;;
 210         esac
 211 fi
 212
 213 # libftdi is only needed for some hardware drivers.
 214 if test "x$LA_ASIX_SIGMA" != xno \
 215      -o "x$LA_CHRONOVU_LA8" != xno; then
 216         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 217                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 218                 LIBS="$LIBS $libftdi_LIBS";
 219                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 220 fi
 221
 222 # libudev is only needed for some hardware drivers.
 223 if test "x$LA_LINK_MSO19" != xno; then
 224         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 225                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 226                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 227 fi
 228
 229 # ALSA is only needed for some hardware drivers.
 230 if test "x$LA_ALSA" != xno; then
 231         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 232                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 233                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 234 fi
 235
 236 AC_SUBST(SR_PKGLIBS)
 237
 238 # Checks for header files.
 239 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 240 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 241
 242 # Checks for typedefs, structures, and compiler characteristics.
 243 AC_C_INLINE
 244 AC_TYPE_INT8_T
 245 AC_TYPE_INT16_T
 246 AC_TYPE_INT32_T
 247 AC_TYPE_INT64_T
 248 AC_TYPE_UINT8_T
 249 AC_TYPE_UINT16_T
 250 AC_TYPE_UINT32_T
 251 AC_TYPE_UINT64_T
 252 AC_TYPE_SIZE_T
 253
 254 # Checks for library functions.
 255 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 256
 257 AC_SUBST(FIRMWARE_DIR, "$datadir/libsigrok/firmware")
 258 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 259 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 260
 261 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 262 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 263 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 264 SR_PACKAGE_VERSION=sr_package_version
 265
 266 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 267 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 268 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 269 AC_SUBST(SR_PACKAGE_VERSION)
 270
 271 AC_CONFIG_FILES([Makefile
 272                  sigrok.h
 273                  firmware/Makefile
 274                  hardware/Makefile
 275                  hardware/alsa/Makefile
 276                  hardware/asix-sigma/Makefile
 277                  hardware/chronovu-la8/Makefile
 278                  hardware/common/Makefile
 279                  hardware/demo/Makefile
 280                  hardware/fx2lafw/Makefile
 281                  hardware/link-mso19/Makefile
 282                  hardware/openbench-logic-sniffer/Makefile
 283                  hardware/zeroplus-logic-cube/Makefile
 284                  input/Makefile
 285                  output/Makefile
 286                  output/text/Makefile
 287                  libsigrok.pc
 288                  contrib/Makefile
 289                 ])
 290
 291 AC_OUTPUT
 292
 293 echo
 294 echo "libsigrok configuration summary:"
 295 echo
 296 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 297 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 298 echo "  - Prefix: $prefix"
 299 echo
 300 echo "Detected libraries:"
 301 echo
 302
 303 # Note: This only works for libs with pkg-config integration.
 304 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "zlib" "libftdi" "libudev" "alsa"; do
 305         if `$PKG_CONFIG --exists $lib`; then
 306                 ver=`$PKG_CONFIG --modversion $lib`
 307                 answer="yes ($ver)"
 308         else
 309                 answer="no"
 310         fi
 311         echo "  - $lib: $answer"
 312 done
 313
 314 echo
 315 echo "Enabled hardware drivers:"
 316 echo
 317 echo "  - ASIX SIGMA...................... $LA_ASIX_SIGMA"
 318 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 319 echo "  - Demo driver..................... $LA_DEMO"
 320 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 321 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 322 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 323 echo "  - Zeroplus Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 324 echo
 325