configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Initialize libtool.
  56 LT_INIT
  57
  58 # Initialize pkg-config.
  59 # We require at least 0.22, as "Requires.private" behaviour changed there.
  60 PKG_PROG_PKG_CONFIG([0.22])
  61
  62 # Library version for libsigrok (NOT the same as the package version).
  63 # Carefully read the libtool docs before updating these numbers!
  64 # The algorithm for determining which number to change (and how) is nontrivial!
  65 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  66 SR_LIB_VERSION_CURRENT=2
  67 SR_LIB_VERSION_REVISION=0
  68 SR_LIB_VERSION_AGE=0
  69 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  70 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  71 AC_SUBST(SR_LIB_VERSION_CURRENT)
  72 AC_SUBST(SR_LIB_VERSION_REVISION)
  73 AC_SUBST(SR_LIB_VERSION_AGE)
  74 AC_SUBST(SR_LIB_VERSION)
  75 AC_SUBST(SR_LIB_LDFLAGS)
  76
  77 # Hardware support '--enable' options.
  78
  79 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  80         [enable all drivers by default [default=yes]]),
  81         [HW_ENABLED_DEFAULT="$enableval"],
  82         [HW_ENABLED_DEFAULT="yes"])
  83
  84 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  85         [enable Agilent DMM support [default=yes]]),
  86         [HW_AGILENT_DMM="$enableval"],
  87         [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  88 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
  89 if test "x$HW_AGILENT_DMM" = "xyes"; then
  90         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
  91 fi
  92
  93 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  94         [enable ALSA driver support [default=yes]]),
  95         [HW_ALSA="$enableval"],
  96         [HW_ALSA=$HW_ENABLED_DEFAULT])
  97 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
  98 if test "x$HW_ALSA" = "xyes"; then
  99         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 100 fi
 101
 102 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
 103         [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
 104         [LA_ASIX_SIGMA="$enableval"],
 105         [LA_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 106 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 107 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 108         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 109 fi
 110
 111 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 112         [enable ChronoVu LA8 support [default=yes]]),
 113         [LA_CHRONOVU_LA8="$enableval"],
 114         [LA_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 115 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 116 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 117         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 118 fi
 119
 120 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 121         [enable Colead SLM support [default=yes]]),
 122         [HW_COLEAD_SLM="$enableval"],
 123         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 124 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 125 if test "x$HW_COLEAD_SLM" = "xyes"; then
 126         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 127 fi
 128
 129 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 130         [enable demo driver support [default=yes]]),
 131         [LA_DEMO="$enableval"],
 132         [LA_DEMO=$HW_ENABLED_DEFAULT])
 133 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 134 if test "x$LA_DEMO" = "xyes"; then
 135         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 136 fi
 137
 138 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 139         [enable Fluke DMM support [default=yes]]),
 140         [HW_FLUKE_DMM="$enableval"],
 141         [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 142 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 143 if test "x$HW_FLUKE_DMM" = "xyes"; then
 144         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 145 fi
 146
 147 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 148         [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 149         [LA_FX2LAFW="$enableval"],
 150         [LA_FX2LAFW=$HW_ENABLED_DEFAULT])
 151 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 152 if test "x$LA_FX2LAFW" = "xyes"; then
 153         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 154 fi
 155
 156 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 157         [enable Hantek DSO support [default=yes]]),
 158         [HW_HANTEK_DSO="$enableval"],
 159         [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 160 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 161 if test "x$HW_HANTEK_DSO" = "xyes"; then
 162         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 163 fi
 164
 165 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 166         [enable Lascar EL-USB support [default=yes]]),
 167         [HW_LASCAR_EL_USB="$enableval"],
 168         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 169 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 170 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 171         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 172 fi
 173
 174 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 175         [enable Link Instruments MSO-19 support [default=yes]]),
 176         [LA_LINK_MSO19="$enableval"],
 177         [LA_LINK_MSO19=$HW_ENABLED_DEFAULT])
 178 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 179 if test "x$LA_LINK_MSO19" = "xyes"; then
 180         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 181 fi
 182
 183 AC_ARG_ENABLE(mic-985xx, AC_HELP_STRING([--enable-mic-985xx],
 184         [enable MIC 985xx support [default=yes]]),
 185         [HW_MIC_985XX="$enableval"],
 186         [HW_MIC_985XX=yes])
 187 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 188 if test "x$HW_MIC_985XX" = "xyes"; then
 189         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 190 fi
 191
 192 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 193         [enable Nexus Osciprime support [default=yes]]),
 194         [HW_NEXUS_OSCIPRIME="$enableval"],
 195         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 196 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 197 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 198         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 199 fi
 200
 201 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 202         [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 203         [LA_OLS="$enableval"],
 204         [LA_OLS=$HW_ENABLED_DEFAULT])
 205 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 206 if test "x$LA_OLS" = "xyes"; then
 207         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 208 fi
 209
 210 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 211         [enable Rigol DS1xx2 support [default=yes]]),
 212         [HW_RIGOL_DS1XX2="$enableval"],
 213         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 214 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 215 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 216         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 217 fi
 218
 219 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 220         [enable serial DMM support [default=yes]]),
 221         [HW_SERIAL_DMM="$enableval"],
 222         [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 223 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 224 if test "x$HW_SERIAL_DMM" = "xyes"; then
 225         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 226 fi
 227
 228 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 229         [enable Tondaj SL-814 support [default=yes]]),
 230         [HW_TONDAJ_SL_814="$enableval"],
 231         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 232 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 233 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 234         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 235 fi
 236
 237 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 238         [enable UNI-T DMM support [default=yes]]),
 239         [HW_UNI_T_DMM="$enableval"],
 240         [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 241 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 242 if test "x$HW_UNI_T_DMM" = "xyes"; then
 243         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 244 fi
 245
 246 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 247         [enable victor-dmm support [default=yes]]),
 248         [HW_VICTOR_DMM="$enableval"],
 249         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 250 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 251 if test "x$HW_VICTOR_DMM" = "xyes"; then
 252         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [victor-dmm support])
 253 fi
 254
 255 AC_ARG_ENABLE(zeroplus-logic-cube,
 256         AC_HELP_STRING([--enable-zeroplus-logic-cube],
 257         [enable ZEROPLUS Logic Cube support [default=yes]]),
 258         [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 259         [LA_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 260 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 261 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 262         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 263 fi
 264
 265 # Checks for libraries.
 266
 267 # This variable collects the pkg-config names of all detected libs.
 268 # It is then used to construct the "Requires.private:" field in the
 269 # libsigrok.pc file.
 270 SR_PKGLIBS=""
 271
 272 # libglib-2.0 is always needed.
 273 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 274 AM_PATH_GLIB_2_0([2.28.0],
 275         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 276
 277 # libusb-1.0 is only needed for some hardware drivers.
 278 if test "x$LA_ASIX_SIGMA" != xno \
 279    -o "x$LA_CHRONOVU_LA8" != xno \
 280    -o "x$LA_FX2LAFW" != xno \
 281    -o "x$HW_HANTEK_DSO" != xno \
 282    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 283         case "$build" in
 284         *freebsd*)
 285                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 286                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 287                         [Specifies whether we have a libusb.h header.])
 288                 ;;
 289         *)
 290                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 291                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 292                         LIBS="$LIBS $libusb_LIBS";
 293                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 294                 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 295                 if test "x$libusb_CFLAGS" != "x"; then
 296                         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 297                                 [Specifies whether we have a libusb.h header.])
 298                 fi
 299                 ;;
 300         esac
 301 fi
 302
 303 # libzip is always needed.
 304 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 305         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 306         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 307
 308 # libftdi is only needed for some hardware drivers.
 309 if test "x$LA_ASIX_SIGMA" != xno \
 310      -o "x$LA_CHRONOVU_LA8" != xno; then
 311         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 312                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 313                 LIBS="$LIBS $libftdi_LIBS";
 314                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 315 fi
 316
 317 # libudev is only needed for some hardware drivers.
 318 if test "x$LA_LINK_MSO19" != xno; then
 319         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 320                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 321                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 322 fi
 323
 324 # ALSA is only needed for some hardware drivers.
 325 if test "x$HW_ALSA" != xno; then
 326         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 327                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 328                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 329 fi
 330
 331 # EZUSB FX2 firmware helper code is only needed for some hardware drivers.
 332 AM_CONDITIONAL(NEED_EZUSB, \
 333         test "x$LA_FX2LAFW" != xno \
 334         -o "x$HW_HANTEK_DSO" != xno \
 335 )
 336
 337 # Serial port helper code is only needed for some hardware drivers.
 338 AM_CONDITIONAL(NEED_SERIAL, \
 339         test "x$HW_AGILENT_DMM" != xno \
 340         -o "x$HW_COLEAD_SLM" != xno \
 341         -o "x$HW_FLUKE_DMM" != xno \
 342         -o "x$LA_LINK_MSO19" != xno \
 343         -o "x$LA_OLS" != xno \
 344         -o "x$HW_SERIAL_DMM" != xno \
 345         -o "x$HW_TONDAJ_SL_814" != xno \
 346 )
 347
 348 AC_SUBST(SR_PKGLIBS)
 349
 350 # Checks for header files.
 351 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 352 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 353
 354 # Checks for typedefs, structures, and compiler characteristics.
 355 AC_C_INLINE
 356 AC_TYPE_INT8_T
 357 AC_TYPE_INT16_T
 358 AC_TYPE_INT32_T
 359 AC_TYPE_INT64_T
 360 AC_TYPE_UINT8_T
 361 AC_TYPE_UINT16_T
 362 AC_TYPE_UINT32_T
 363 AC_TYPE_UINT64_T
 364 AC_TYPE_SIZE_T
 365
 366 # Checks for library functions.
 367 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 368
 369 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 370 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 371 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 372
 373 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 374 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 375 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 376 SR_PACKAGE_VERSION=sr_package_version
 377
 378 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 379 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 380 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 381 AC_SUBST(SR_PACKAGE_VERSION)
 382
 383 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 384                  hardware/agilent-dmm/Makefile
 385                  hardware/alsa/Makefile
 386                  hardware/asix-sigma/Makefile
 387                  hardware/chronovu-la8/Makefile
 388                  hardware/colead-slm/Makefile
 389                  hardware/common/Makefile
 390                  hardware/lascar-el-usb/Makefile
 391                  hardware/mic-985xx/Makefile
 392                  hardware/nexus-osciprime/Makefile
 393                  hardware/rigol-ds1xx2/Makefile
 394                  hardware/tondaj-sl-814/Makefile
 395                  hardware/victor-dmm/Makefile
 396                  hardware/common/dmm/Makefile
 397                  hardware/demo/Makefile
 398                  hardware/fluke-dmm/Makefile
 399                  hardware/fx2lafw/Makefile
 400                  hardware/hantek-dso/Makefile
 401                  hardware/link-mso19/Makefile
 402                  hardware/openbench-logic-sniffer/Makefile
 403                  hardware/serial-dmm/Makefile
 404                  hardware/uni-t-dmm/Makefile
 405                  hardware/zeroplus-logic-cube/Makefile
 406                  input/Makefile
 407                  output/Makefile
 408                  output/text/Makefile
 409                  libsigrok.pc
 410                  contrib/Makefile
 411                 ])
 412
 413 AC_OUTPUT
 414
 415 echo
 416 echo "libsigrok configuration summary:"
 417 echo
 418 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 419 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 420 echo "  - Prefix: $prefix"
 421 echo
 422 echo "Detected libraries:"
 423 echo
 424
 425 # Note: This only works for libs with pkg-config integration.
 426 for lib in "glib-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
 427         if `$PKG_CONFIG --exists $lib`; then
 428                 ver=`$PKG_CONFIG --modversion $lib`
 429                 answer="yes ($ver)"
 430         else
 431                 answer="no"
 432         fi
 433         echo "  - $lib: $answer"
 434 done
 435
 436 echo -e "\nEnabled hardware drivers:\n"
 437 echo "  - Agilent DMM..................... $HW_AGILENT_DMM"
 438 echo "  - ALSA............................ $HW_ALSA"
 439 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 440 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 441 echo "  - Colead SLM...................... $HW_COLEAD_SLM"
 442 echo "  - Demo driver..................... $LA_DEMO"
 443 echo "  - Fluke DMM....................... $HW_FLUKE_DMM"
 444 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 445 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 446 echo "  - Lascar EL-USB................... $HW_LASCAR_EL_USB"
 447 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 448 echo "  - MIC 985xx....................... $HW_MIC_985XX"
 449 echo "  - Nexus Osciprime................. $HW_NEXUS_OSCIPRIME"
 450 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 451 echo "  - Rigol DS1xx2.................... $HW_RIGOL_DS1XX2"
 452 echo "  - Serial DMM...................... $HW_SERIAL_DMM"
 453 echo "  - Tondaj SL-814................... $HW_TONDAJ_SL_814"
 454 echo "  - UNI-T DMM....................... $HW_UNI_T_DMM"
 455 echo "  - Victor DMM...................... $HW_VICTOR_DMM"
 456 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 457 echo
 458