configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  71
  72 #############################
  73 ##  Optional dependencies  ##
  74 #############################
  75
  76 AC_LANG([C])
  77
  78 # Initialize pkg-config.
  79 # We require at least 0.22, as "Requires.private" behaviour changed there.
  80 PKG_PROG_PKG_CONFIG([0.22])
  81
  82 # Keep track of all checked modules so we can list them at the end.
  83 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  84
  85 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  86 # These are used to derive the compiler flags and for the "Requires.private"
  87 # field in the generated libsigrok.pc file.
  88 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  89 SR_PKGLIBS_TESTS=
  90 SR_PKGLIBS_CXX=
  91 SR_PKGLIBS_PYTHON=
  92 SR_EXTRA_LIBS=
  93
  94 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  95         [libserialport >= 0.1.1])
  96
  97 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  98         [libftdi1 >= 1.0], [libftdi >= 0.16])
  99
 100 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 101 # This means libusb-1.0 is always available; no need to check for it.
 102 # On Windows, require the latest version we can get our hands on,
 103 # until the new generic event handling has seen an official release.
 104 AS_CASE([$host_os],
 105         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 106         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 107         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 108
 109 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 110         [$sr_libusb_req])
 111
 112 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 113         [librevisa >= 0.0.20130412])
 114
 115 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 116         [libgpib])
 117
 118 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 119         sr_save_LIBS=$LIBS
 120         LIBS="-lieee1284 $LIBS"
 121         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 122                                 [[(void) ieee1284_open(0, 0, 0);]])],
 123                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 124         LIBS=$sr_save_LIBS
 125 ])
 126 AS_IF([test "x$sr_have_libieee1284" = xyes],
 127         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 128
 129 ######################
 130 ##  Feature checks  ##
 131 ######################
 132
 133 # The Check unit testing framework is optional. Disable if not found.
 134 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 135 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 136
 137 # Enable the C99 standard if possible, and enforce the use
 138 # of SR_API to explicitly mark all public API functions.
 139 SR_EXTRA_CFLAGS=
 140 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 141 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 142
 143 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 144
 145 # Check host characteristics.
 146 AC_SYS_LARGEFILE
 147 AC_C_BIGENDIAN
 148
 149 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 150 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 151 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 152
 153 # We need to link against the Winsock2 library for SCPI over TCP.
 154 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 155
 156 # libm (the standard math library) is always needed.
 157 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 158
 159 # RPC is only needed for VXI support.
 160 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 161         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 162                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 163                         [[(void) clnt_create("", 0, 0, "");]])],
 164                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 165 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 166         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 167 # VXI support is only compiled if RPC support was found.
 168 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 169
 170 ########################
 171 ##  Hardware drivers  ##
 172 ########################
 173
 174 # Keep track of all drivers so we can list them at the end.
 175 SR_VAR_SUMMARY([sr_driver_summary])
 176
 177 # Check whether the sr_deps_avail list contains all of the arguments.
 178 # Unavailable dependencies are collected in sr_deps_missing.
 179 sr_check_driver_deps() {
 180         sr_deps_missing=
 181         for sr_dep
 182         do
 183                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 184                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 185         done
 186         test -z "$sr_deps_missing" || return 1
 187 }
 188
 189 AC_ARG_ENABLE([all-drivers],
 190         [AS_HELP_STRING([--enable-all-drivers],
 191                         [enable all drivers by default [default=yes]])],
 192         [], [enable_all_drivers=yes])
 193
 194 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 195 m4_define([_SR_DRIVER], [
 196         AC_ARG_ENABLE([$2],
 197                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 198                 [$3=$enableval], [$3=$enable_all_drivers])
 199
 200         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 201                 sr_check_driver_deps $4 \
 202                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 203         ])], [sr_hw_info='no (disabled)'])
 204         sr_driver_summary_append "$2" "$sr_hw_info"
 205
 206         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 207         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 208 ])
 209
 210 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 211 m4_define([SR_DRIVER],
 212         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 213
 214 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 215 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 216 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 217 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 218 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 219 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 220 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 221 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 222 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 223 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 224 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 225 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 226 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 227 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 228 SR_DRIVER([demo], [demo])
 229 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 230 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 231 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 232 SR_DRIVER([gwinstek gds-800], [gwinstek-gds-800], [libserialport])
 233 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 234 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 235 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 236 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 237 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 238 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 239 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 240 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 241 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 242 SR_DRIVER([maynuo-m97], [maynuo-m97])
 243 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 244 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 245 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 246 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 247 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 248 SR_DRIVER([Rigol DS], [rigol-ds])
 249 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 250 SR_DRIVER([SCPI PPS], [scpi-pps])
 251 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 252 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 253 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 254 SR_DRIVER([Testo], [testo], [libusb])
 255 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 256 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 257 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 258 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 259 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 260 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 261
 262 ###############################
 263 ##  Language bindings setup  ##
 264 ###############################
 265
 266 AC_LANG([C++])
 267 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 268
 269 AC_ARG_ENABLE([bindings],
 270         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 271         [], [enable_bindings=yes])
 272
 273 AC_ARG_ENABLE([cxx],
 274         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 275         [], [enable_cxx=$enable_bindings])
 276
 277 AC_ARG_ENABLE([python],
 278         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 279         [], [enable_python=$enable_bindings])
 280
 281 AC_ARG_ENABLE([java],
 282         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 283         [], [enable_java=$enable_bindings])
 284
 285 ####################
 286 ##  C++ bindings  ##
 287 ####################
 288
 289 sr_cxx_missing=
 290
 291 # Check if the C++ compiler supports the C++11 standard.
 292 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 293 AS_IF([test "x$HAVE_CXX11" != x1],
 294         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 295
 296 # The C++ bindings need glibmm.
 297 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 298 AS_IF([test "x$sr_have_glibmm" != xyes],
 299         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 300
 301 # The C++ bindings use Doxygen to parse libsigrok symbols.
 302 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 303 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 304         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 305
 306 # Python is needed for the C++ bindings.
 307 AM_PATH_PYTHON([2.7],
 308         [HAVE_PYTHON=yes],
 309         [HAVE_PYTHON=no
 310         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 311
 312 AS_IF([test -z "$sr_cxx_missing"],
 313         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 314 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 315
 316 # C++ bindings want stoi and stod.
 317 AM_COND_IF([BINDINGS_CXX], [
 318         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 319                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 320                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 321                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 322         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 323                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 324                         [Specifies whether we have the stoi and stod functions.])])
 325 ])
 326
 327 #######################
 328 ##  Python bindings  ##
 329 #######################
 330
 331 AS_IF([test "x$BINDINGS_CXX" = xyes],
 332         [sr_python_missing=],
 333         [sr_python_missing='C++ bindings'])
 334
 335 # The Python bindings need Python development files.
 336 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 337         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 338 AS_IF([test "x$sr_have_python_dev" != xyes],
 339         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 340
 341 # PyGObject is needed for the Python bindings.
 342 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 343 AS_IF([test "x$sr_have_pygobject" != xyes],
 344         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 345
 346 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 347         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 348                 [Whether last argument to pyg_flags_get_value() is signed.])])
 349
 350 # The Python bindings need the setuptools and numpy Python modules.
 351 # We'll let it go through even if the AX macro wasn't found, as the
 352 # Python modules may still be there.
 353 m4_ifdef([AX_PYTHON_MODULE], [
 354         AX_PYTHON_MODULE([setuptools])
 355         AX_PYTHON_MODULE([numpy])
 356 ], [
 357         HAVE_PYMOD_SETUPTOOLS=yes
 358         HAVE_PYMOD_NUMPY=yes
 359         m4_warn([unsupported],
 360                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 361 ])
 362 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 363         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 364 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 365         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 366
 367 # The Python bindings use SWIG to generate code.
 368 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 369 AS_IF([test "x$SWIG" = x],
 370         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 371
 372 AS_IF([test -z "$sr_python_missing"],
 373         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 374 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 375
 376 ####################
 377 ##  Java bindings ##
 378 ####################
 379
 380 AS_IF([test "x$BINDINGS_CXX" = xyes],
 381         [sr_java_missing=],
 382         [sr_java_missing='C++ bindings'])
 383
 384 # The Java bindings use SWIG to generate code.
 385 AS_IF([test "x$SWIG" = x],
 386         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 387
 388 # Find Java compiler and JNI includes for Java bindings.
 389 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 390 AS_IF([test "x$HAVE_JAVAC" = xno],
 391         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 392
 393 AC_ARG_WITH([jni-include-path],
 394         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 395                 [specify JNI include directories [default=detect]])],
 396         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 397
 398 JNI_CPPFLAGS=
 399 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 400         AX_PROG_JAVAC
 401         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 402                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 403                 ## If we can find jni.h without any special search path, skip
 404                 ## the execution of the broken macro to increase our chances of
 405                 ## success.
 406                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 407                         [AX_JNI_INCLUDE_DIR])
 408         ])
 409 ])
 410 for sr_dir in $JNI_INCLUDE_DIRS
 411 do
 412         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 413 done
 414 AC_SUBST([JNI_CPPFLAGS])
 415
 416 sr_save_cppflags=$CPPFLAGS
 417 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 418 AC_CHECK_HEADER([jni.h],,
 419         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 420 CPPFLAGS=$sr_save_cppflags
 421
 422 AS_IF([test -z "$sr_java_missing"],
 423         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 424 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 425
 426 ##############################
 427 ##  Finalize configuration  ##
 428 ##############################
 429
 430 # Add mandatory dependencies to module list.
 431 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 432 AC_SUBST([SR_PKGLIBS])
 433
 434 # Retrieve the compile and link flags for all modules combined.
 435 # Also, bail out at this point if any module dependency is not met.
 436 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 437 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 438
 439 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 440 # the C++ bindings are enabled.
 441 AM_COND_IF([BINDINGS_CXX], [
 442         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 443         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 444 ])
 445
 446 # Check for specific libusb features, now that we know the CFLAGS.
 447 AC_LANG([C])
 448 sr_save_cflags=$CFLAGS
 449 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 450 AC_CHECK_TYPES([libusb_os_handle],
 451         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 452         [[#include <libusb.h>]])
 453 CFLAGS=$sr_save_cflags
 454 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 455         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 456
 457 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 458 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 459
 460 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 461         [Build-time version of libzip.])
 462 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 463         [The canonical host libsigrok will run on.])
 464
 465 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 466
 467 AC_OUTPUT
 468
 469 # Prepare bindings report messages.
 470 m4_define([SR_PREPARE_BINDING_REPORT], [
 471         sr_report_$1=
 472         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 473         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 474 ])
 475 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 476
 477 cat >&AS_MESSAGE_FD <<_EOF
 478
 479 libsigrok configuration summary:
 480  - Package version................. $SR_PACKAGE_VERSION
 481  - Library ABI version............. $SR_LIB_VERSION
 482  - Prefix.......................... $prefix
 483  - Building on..................... $build
 484  - Building for.................... $host
 485
 486 Compile configuration:
 487  - C compiler...................... $CC
 488  - C compiler version.............. $sr_cc_version
 489  - C compiler flags................ $CFLAGS
 490  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 491  - C compiler warnings............. $SR_WFLAGS
 492  - C++ compiler.................... $CXX
 493  - C++ compiler version............ $sr_cxx_version
 494  - C++ compiler flags.............. $CXXFLAGS
 495  - C++ compiler warnings........... $SR_WXXFLAGS
 496
 497 Detected libraries (required):
 498  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 499  - libzip >= 0.10.................. $sr_libzip_version
 500
 501 Detected libraries (optional):
 502 $sr_pkglibs_summary
 503 Enabled hardware drivers:
 504 $sr_driver_summary
 505 Enabled SCPI backends:
 506  - TCP............................. yes
 507  - RPC............................. $sr_cv_have_rpc
 508  - serial.......................... $sr_have_libserialport
 509  - VISA............................ $sr_have_librevisa
 510  - GPIB............................ $sr_have_libgpib
 511  - USBTMC.......................... $sr_have_libusb
 512
 513 Enabled language bindings:
 514  - C++............................. $BINDINGS_CXX$sr_report_cxx
 515  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 516  - Java............................ $BINDINGS_JAVA$sr_report_java
 517
 518 _EOF