2 ## This file is part of the libsigrok project.
4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
7 ## This program is free software: you can redistribute it and/or modify
8 ## it under the terms of the GNU General Public License as published by
9 ## the Free Software Foundation, either version 3 of the License, or
10 ## (at your option) any later version.
12 ## This program is distributed in the hope that it will be useful,
13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15 ## GNU General Public License for more details.
17 ## You should have received a copy of the GNU General Public License
18 ## along with this program. If not, see <http://www.gnu.org/licenses/>.
21 # We require at least autoconf 2.63 (AC_INIT format changed there).
24 AC_INIT([libsigrok], [0.4.0],
25 [sigrok-devel@lists.sourceforge.net],
26 [libsigrok], [http://www.sigrok.org])
27 AC_CONFIG_MACRO_DIR([m4])
28 AC_CONFIG_AUX_DIR([autostuff])
29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
31 # We require at least automake 1.11 (needed for 'silent rules').
32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
33 AM_SILENT_RULES([yes])
34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
38 # Checks for programs.
44 # Required for per-target flags or subdir-objects with C sources.
47 # Get compiler versions.
48 SR_PROG_VERSION([$CC], [sr_cc_version])
49 SR_PROG_VERSION([$CXX], [sr_cxx_version])
51 # Check for optional make features.
52 SR_PROG_MAKE_ORDER_ONLY
57 # Set up the libsigrok version defines.
58 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
60 # Library version for libsigrok (NOT the same as the package version).
61 # Carefully read the libtool docs before updating these numbers!
62 # The algorithm for determining which number to change (and how) is nontrivial!
63 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
64 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
66 #############################
67 ## Optional dependencies ##
68 #############################
72 # Initialize pkg-config.
73 # We require at least 0.22, as "Requires.private" behaviour changed there.
74 PKG_PROG_PKG_CONFIG([0.22])
76 # Keep track of all checked modules so we can list them at the end.
77 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
79 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
80 # These are used to derive the compiler flags and for the "Requires.private"
81 # field in the generated libsigrok.pc file.
82 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
88 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
89 [libserialport >= 0.1.1])
91 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
92 [libftdi1 >= 1.0], [libftdi >= 0.16])
94 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
95 # This means libusb-1.0 is always available; no need to check for it.
96 # On Windows, require the latest version we can get our hands on,
97 # until the new generic event handling has seen an official release.
99 [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
100 [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
101 [sr_libusb_req='libusb-1.0 >= 1.0.16'])
103 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
106 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
107 [librevisa >= 0.0.20130412])
109 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
112 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
114 LIBS="-lieee1284 $LIBS"
115 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
116 [[(void) ieee1284_open(0, 0, 0);]])],
117 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
120 AS_IF([test "x$sr_have_libieee1284" = xyes],
121 [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
123 ######################
125 ######################
127 # The Check unit testing framework is optional. Disable if not found.
128 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
129 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
131 # Enable the C99 standard if possible, and enforce the use
132 # of SR_API to explicitly mark all public API functions.
134 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
135 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
137 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
139 # Check host characteristics.
143 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
144 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
145 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
147 # We need to link against the Winsock2 library for SCPI over TCP.
148 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
150 # libm (the standard math library) is always needed.
151 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
153 # RPC is only needed for VXI support.
154 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
155 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
156 [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
157 [[(void) clnt_create("", 0, 0, "");]])],
158 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
159 AS_IF([test "x$sr_cv_have_rpc" = xyes],
160 [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
161 # VXI support is only compiled if RPC support was found.
162 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
164 ########################
165 ## Hardware drivers ##
166 ########################
168 # Keep track of all drivers so we can list them at the end.
169 SR_VAR_SUMMARY([sr_driver_summary])
171 # Check whether the sr_deps_avail list contains all of the arguments.
172 # Unavailable dependencies are collected in sr_deps_missing.
173 sr_check_driver_deps() {
177 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
178 [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
180 test -z "$sr_deps_missing" || return 1
183 AC_ARG_ENABLE([all-drivers],
184 [AS_HELP_STRING([--enable-all-drivers],
185 [enable all drivers by default [default=yes]])],
186 [], [enable_all_drivers=yes])
188 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
189 m4_define([_SR_DRIVER], [
191 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
192 [$3=$enableval], [$3=$enable_all_drivers])
194 AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
195 sr_check_driver_deps $4 \
196 || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
197 ])], [sr_hw_info='no (disabled)'])
198 sr_driver_summary_append "$2" "$sr_hw_info"
200 AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
201 AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
204 ## SR_DRIVER(Device name, driver-name, [dependencies...])
205 m4_define([SR_DRIVER],
206 [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
208 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
209 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
210 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
211 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
212 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
213 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
214 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
215 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
216 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
217 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
218 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
219 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
220 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
221 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
222 SR_DRIVER([demo], [demo])
223 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
224 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
225 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
226 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
227 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
228 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
229 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
230 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
231 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
232 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
233 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
234 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
235 SR_DRIVER([maynuo-m97], [maynuo-m97])
236 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
237 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
238 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
239 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
240 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
241 SR_DRIVER([Rigol DS], [rigol-ds])
242 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
243 SR_DRIVER([SCPI PPS], [scpi-pps])
244 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
245 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
246 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
247 SR_DRIVER([Testo], [testo], [libusb])
248 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
249 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
250 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
251 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
252 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
253 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
255 ###############################
256 ## Language bindings setup ##
257 ###############################
260 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
262 AC_ARG_ENABLE([bindings],
263 [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
264 [], [enable_bindings=yes])
267 [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
268 [], [enable_cxx=$enable_bindings])
270 AC_ARG_ENABLE([python],
271 [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
272 [], [enable_python=$enable_bindings])
274 AC_ARG_ENABLE([java],
275 [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
276 [], [enable_java=$enable_bindings])
284 # Check if the C++ compiler supports the C++11 standard.
285 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
286 AS_IF([test "x$HAVE_CXX11" != x1],
287 [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
289 # The C++ bindings need glibmm.
290 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
291 AS_IF([test "x$sr_have_glibmm" != xyes],
292 [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
294 # The C++ bindings use Doxygen to parse libsigrok symbols.
295 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
296 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
297 [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
299 # Python is needed for the C++ bindings.
300 AM_PATH_PYTHON([2.7],
303 SR_APPEND([sr_cxx_missing], [', '], [Python])])
305 AS_IF([test -z "$sr_cxx_missing"],
306 [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
307 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
309 # C++ bindings want stoi and stod.
310 AM_COND_IF([BINDINGS_CXX], [
311 AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
312 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
313 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
314 [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
315 AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
316 [AC_DEFINE([HAVE_STOI_STOD], [1],
317 [Specifies whether we have the stoi and stod functions.])])
320 #######################
321 ## Python bindings ##
322 #######################
324 AS_IF([test "x$BINDINGS_CXX" = xyes],
325 [sr_python_missing=],
326 [sr_python_missing='C++ bindings'])
328 # The Python bindings need Python development files.
329 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
330 [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
331 AS_IF([test "x$sr_have_python_dev" != xyes],
332 [SR_APPEND([sr_python_missing], [', '], [Headers])])
334 # PyGObject is needed for the Python bindings.
335 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
336 AS_IF([test "x$sr_have_pygobject" != xyes],
337 [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
339 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
340 [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
341 [Whether last argument to pyg_flags_get_value() is signed.])])
343 # The Python bindings need the setuptools Python module.
344 # We'll let it go through even if the AX macro wasn't found,
345 # as the Python module may still be there.
346 HAVE_PYMOD_SETUPTOOLS=yes
347 m4_ifdef([AX_PYTHON_MODULE],
348 [AX_PYTHON_MODULE([setuptools])],
349 [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
350 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
351 [SR_APPEND([sr_python_missing], [', '], [setuptools])])
353 # The Python bindings use SWIG to generate code.
354 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
355 AS_IF([test "x$SWIG" = x],
356 [SR_APPEND([sr_python_missing], [', '], [SWIG])])
358 AS_IF([test -z "$sr_python_missing"],
359 [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
360 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
366 AS_IF([test "x$BINDINGS_CXX" = xyes],
368 [sr_java_missing='C++ bindings'])
370 # The Java bindings use SWIG to generate code.
371 AS_IF([test "x$SWIG" = x],
372 [SR_APPEND([sr_java_missing], [', '], [SWIG])])
374 # Find Java compiler and JNI includes for Java bindings.
375 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
376 AS_IF([test "x$HAVE_JAVAC" = xno],
377 [SR_APPEND([sr_java_missing], [', '], [JavaC])])
379 AC_ARG_WITH([jni-include-path],
380 [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
381 [specify JNI include directories [default=detect]])],
382 [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
385 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
387 AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
388 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
389 ## If we can find jni.h without any special search path, skip
390 ## the execution of the broken macro to increase our chances of
392 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
393 [AX_JNI_INCLUDE_DIR])
396 for sr_dir in $JNI_INCLUDE_DIRS
398 SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
400 AC_SUBST([JNI_CPPFLAGS])
402 sr_save_cppflags=$CPPFLAGS
403 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
404 AC_CHECK_HEADER([jni.h],,
405 [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
406 CPPFLAGS=$sr_save_cppflags
408 AS_IF([test -z "$sr_java_missing"],
409 [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
410 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
412 ##############################
413 ## Finalize configuration ##
414 ##############################
416 # Add mandatory dependencies to module list.
417 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
418 AC_SUBST([SR_PKGLIBS])
420 # Retrieve the compile and link flags for all modules combined.
421 # Also, bail out at this point if any module dependency is not met.
422 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
423 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
425 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
426 # the C++ bindings are enabled.
427 AM_COND_IF([BINDINGS_CXX], [
428 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
429 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
432 # Check for specific libusb features, now that we know the CFLAGS.
434 sr_save_cflags=$CFLAGS
435 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
436 AC_CHECK_TYPES([libusb_os_handle],
437 [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
438 [[#include <libusb.h>]])
439 CFLAGS=$sr_save_cflags
440 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
441 [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
443 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
444 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
446 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
447 [Build-time version of libzip.])
448 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
449 [The canonical host libsigrok will run on.])
451 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
455 # Prepare bindings report messages.
456 m4_define([SR_PREPARE_BINDING_REPORT], [
458 test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
459 test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
461 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
463 cat >&AS_MESSAGE_FD <<_EOF
465 libsigrok configuration summary:
466 - Package version................. $SR_PACKAGE_VERSION
467 - Library ABI version............. $SR_LIB_VERSION
468 - Prefix.......................... $prefix
469 - Building on..................... $build
470 - Building for.................... $host
472 Compile configuration:
473 - C compiler...................... $CC
474 - C compiler version.............. $sr_cc_version
475 - C compiler flags................ $CFLAGS
476 - Additional C compiler flags..... $SR_EXTRA_CFLAGS
477 - C compiler warnings............. $SR_WFLAGS
478 - C++ compiler.................... $CXX
479 - C++ compiler version............ $sr_cxx_version
480 - C++ compiler flags.............. $CXXFLAGS
481 - C++ compiler warnings........... $SR_WXXFLAGS
483 Detected libraries (required):
484 - glib-2.0 >= 2.32.0.............. $sr_glib_version
485 - libzip >= 0.10.................. $sr_libzip_version
487 Detected libraries (optional):
489 Enabled hardware drivers:
491 Enabled SCPI backends:
492 - TCP............................. yes
493 - RPC............................. $sr_cv_have_rpc
494 - serial.......................... $sr_have_libserialport
495 - VISA............................ $sr_have_librevisa
496 - GPIB............................ $sr_have_libgpib
497 - USBTMC.......................... $sr_have_libusb
499 Enabled language bindings:
500 - C++............................. $BINDINGS_CXX$sr_report_cxx
501 - Python.......................... $BINDINGS_PYTHON$sr_report_python
502 - Java............................ $BINDINGS_JAVA$sr_report_java