configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  71
  72 #############################
  73 ##  Optional dependencies  ##
  74 #############################
  75
  76 AC_LANG([C])
  77
  78 # Initialize pkg-config.
  79 # We require at least 0.22, as "Requires.private" behaviour changed there.
  80 PKG_PROG_PKG_CONFIG([0.22])
  81
  82 # Keep track of all checked modules so we can list them at the end.
  83 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  84
  85 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  86 # These are used to derive the compiler flags and for the "Requires.private"
  87 # field in the generated libsigrok.pc file.
  88 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  89 SR_PKGLIBS_TESTS=
  90 SR_PKGLIBS_CXX=
  91 SR_PKGLIBS_PYTHON=
  92 SR_EXTRA_LIBS=
  93
  94 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  95         [libserialport >= 0.1.1])
  96
  97 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  98         [libftdi1 >= 1.0], [libftdi >= 0.16])
  99
 100 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 101 # This means libusb-1.0 is always available; no need to check for it.
 102 # On Windows, require the latest version we can get our hands on,
 103 # until the new generic event handling has seen an official release.
 104 AS_CASE([$host_os],
 105         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 106         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 107         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 108
 109 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 110         [$sr_libusb_req])
 111
 112 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 113         [librevisa >= 0.0.20130412])
 114
 115 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 116         [libgpib])
 117
 118 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 119         sr_save_LIBS=$LIBS
 120         LIBS="-lieee1284 $LIBS"
 121         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 122                                 [[(void) ieee1284_open(0, 0, 0);]])],
 123                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 124         LIBS=$sr_save_LIBS
 125 ])
 126 AS_IF([test "x$sr_have_libieee1284" = xyes],
 127         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 128
 129 ######################
 130 ##  Feature checks  ##
 131 ######################
 132
 133 # The Check unit testing framework is optional. Disable if not found.
 134 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 135 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 136
 137 # Enable the C99 standard if possible, and enforce the use
 138 # of SR_API to explicitly mark all public API functions.
 139 SR_EXTRA_CFLAGS=
 140 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 141 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 142
 143 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 144
 145 # Check host characteristics.
 146 AC_SYS_LARGEFILE
 147 AC_C_BIGENDIAN
 148
 149 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 150 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 151 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 152
 153 # We need to link against the Winsock2 library for SCPI over TCP.
 154 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 155
 156 # libm (the standard math library) is always needed.
 157 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 158
 159 # RPC is only needed for VXI support.
 160 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 161         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 162                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 163                         [[(void) clnt_create("", 0, 0, "");]])],
 164                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 165 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 166         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 167 # VXI support is only compiled if RPC support was found.
 168 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 169
 170 ########################
 171 ##  Hardware drivers  ##
 172 ########################
 173
 174 # Keep track of all drivers so we can list them at the end.
 175 SR_VAR_SUMMARY([sr_driver_summary])
 176
 177 # Check whether the sr_deps_avail list contains all of the arguments.
 178 # Unavailable dependencies are collected in sr_deps_missing.
 179 sr_check_driver_deps() {
 180         sr_deps_missing=
 181         for sr_dep
 182         do
 183                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 184                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 185         done
 186         test -z "$sr_deps_missing" || return 1
 187 }
 188
 189 AC_ARG_ENABLE([all-drivers],
 190         [AS_HELP_STRING([--enable-all-drivers],
 191                         [enable all drivers by default [default=yes]])],
 192         [], [enable_all_drivers=yes])
 193
 194 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 195 m4_define([_SR_DRIVER], [
 196         AC_ARG_ENABLE([$2],
 197                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 198                 [$3=$enableval], [$3=$enable_all_drivers])
 199
 200         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 201                 sr_check_driver_deps $4 \
 202                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 203         ])], [sr_hw_info='no (disabled)'])
 204         sr_driver_summary_append "$2" "$sr_hw_info"
 205
 206         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 207         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 208 ])
 209
 210 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 211 m4_define([SR_DRIVER],
 212         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 213
 214 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 215 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 216 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 217 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 218 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 219 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 220 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 221 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 222 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 223 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 224 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 225 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 226 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 227 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 228 SR_DRIVER([demo], [demo])
 229 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 230 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 231 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 232 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 233 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 234 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 235 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 236 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 237 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 238 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 239 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 240 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 241 SR_DRIVER([maynuo-m97], [maynuo-m97])
 242 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 243 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 244 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 245 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 246 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 247 SR_DRIVER([Rigol DS], [rigol-ds])
 248 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 249 SR_DRIVER([SCPI PPS], [scpi-pps])
 250 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 251 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 252 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 253 SR_DRIVER([Testo], [testo], [libusb])
 254 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 255 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 256 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 257 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 258 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 259 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 260
 261 ###############################
 262 ##  Language bindings setup  ##
 263 ###############################
 264
 265 AC_LANG([C++])
 266 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 267
 268 AC_ARG_ENABLE([bindings],
 269         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 270         [], [enable_bindings=yes])
 271
 272 AC_ARG_ENABLE([cxx],
 273         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 274         [], [enable_cxx=$enable_bindings])
 275
 276 AC_ARG_ENABLE([python],
 277         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 278         [], [enable_python=$enable_bindings])
 279
 280 AC_ARG_ENABLE([java],
 281         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 282         [], [enable_java=$enable_bindings])
 283
 284 ####################
 285 ##  C++ bindings  ##
 286 ####################
 287
 288 sr_cxx_missing=
 289
 290 # Check if the C++ compiler supports the C++11 standard.
 291 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 292 AS_IF([test "x$HAVE_CXX11" != x1],
 293         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 294
 295 # The C++ bindings need glibmm.
 296 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 297 AS_IF([test "x$sr_have_glibmm" != xyes],
 298         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 299
 300 # The C++ bindings use Doxygen to parse libsigrok symbols.
 301 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 302 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 303         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 304
 305 # Python is needed for the C++ bindings.
 306 AM_PATH_PYTHON([2.7],
 307         [HAVE_PYTHON=yes],
 308         [HAVE_PYTHON=no
 309         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 310
 311 AS_IF([test -z "$sr_cxx_missing"],
 312         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 313 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 314
 315 # C++ bindings want stoi and stod.
 316 AM_COND_IF([BINDINGS_CXX], [
 317         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 318                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 319                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 320                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 321         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 322                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 323                         [Specifies whether we have the stoi and stod functions.])])
 324 ])
 325
 326 #######################
 327 ##  Python bindings  ##
 328 #######################
 329
 330 AS_IF([test "x$BINDINGS_CXX" = xyes],
 331         [sr_python_missing=],
 332         [sr_python_missing='C++ bindings'])
 333
 334 # The Python bindings need Python development files.
 335 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 336         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 337 AS_IF([test "x$sr_have_python_dev" != xyes],
 338         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 339
 340 # PyGObject is needed for the Python bindings.
 341 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 342 AS_IF([test "x$sr_have_pygobject" != xyes],
 343         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 344
 345 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 346         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 347                 [Whether last argument to pyg_flags_get_value() is signed.])])
 348
 349 # The Python bindings need the setuptools Python module.
 350 # We'll let it go through even if the AX macro wasn't found,
 351 # as the Python module may still be there.
 352 HAVE_PYMOD_SETUPTOOLS=yes
 353 m4_ifdef([AX_PYTHON_MODULE],
 354         [AX_PYTHON_MODULE([setuptools])],
 355         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 356 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 357         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 358
 359 # The Python bindings use SWIG to generate code.
 360 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 361 AS_IF([test "x$SWIG" = x],
 362         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 363
 364 AS_IF([test -z "$sr_python_missing"],
 365         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 366 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 367
 368 ####################
 369 ##  Java bindings ##
 370 ####################
 371
 372 AS_IF([test "x$BINDINGS_CXX" = xyes],
 373         [sr_java_missing=],
 374         [sr_java_missing='C++ bindings'])
 375
 376 # The Java bindings use SWIG to generate code.
 377 AS_IF([test "x$SWIG" = x],
 378         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 379
 380 # Find Java compiler and JNI includes for Java bindings.
 381 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 382 AS_IF([test "x$HAVE_JAVAC" = xno],
 383         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 384
 385 AC_ARG_WITH([jni-include-path],
 386         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 387                 [specify JNI include directories [default=detect]])],
 388         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 389
 390 JNI_CPPFLAGS=
 391 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 392         AX_PROG_JAVAC
 393         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 394                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 395                 ## If we can find jni.h without any special search path, skip
 396                 ## the execution of the broken macro to increase our chances of
 397                 ## success.
 398                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 399                         [AX_JNI_INCLUDE_DIR])
 400         ])
 401 ])
 402 for sr_dir in $JNI_INCLUDE_DIRS
 403 do
 404         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 405 done
 406 AC_SUBST([JNI_CPPFLAGS])
 407
 408 sr_save_cppflags=$CPPFLAGS
 409 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 410 AC_CHECK_HEADER([jni.h],,
 411         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 412 CPPFLAGS=$sr_save_cppflags
 413
 414 AS_IF([test -z "$sr_java_missing"],
 415         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 416 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 417
 418 ##############################
 419 ##  Finalize configuration  ##
 420 ##############################
 421
 422 # Add mandatory dependencies to module list.
 423 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 424 AC_SUBST([SR_PKGLIBS])
 425
 426 # Retrieve the compile and link flags for all modules combined.
 427 # Also, bail out at this point if any module dependency is not met.
 428 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 429 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 430
 431 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 432 # the C++ bindings are enabled.
 433 AM_COND_IF([BINDINGS_CXX], [
 434         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 435         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 436 ])
 437
 438 # Check for specific libusb features, now that we know the CFLAGS.
 439 AC_LANG([C])
 440 sr_save_cflags=$CFLAGS
 441 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 442 AC_CHECK_TYPES([libusb_os_handle],
 443         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 444         [[#include <libusb.h>]])
 445 CFLAGS=$sr_save_cflags
 446 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 447         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 448
 449 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 450 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 451
 452 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 453         [Build-time version of libzip.])
 454 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 455         [The canonical host libsigrok will run on.])
 456
 457 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 458
 459 AC_OUTPUT
 460
 461 # Prepare bindings report messages.
 462 m4_define([SR_PREPARE_BINDING_REPORT], [
 463         sr_report_$1=
 464         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 465         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 466 ])
 467 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 468
 469 cat >&AS_MESSAGE_FD <<_EOF
 470
 471 libsigrok configuration summary:
 472  - Package version................. $SR_PACKAGE_VERSION
 473  - Library ABI version............. $SR_LIB_VERSION
 474  - Prefix.......................... $prefix
 475  - Building on..................... $build
 476  - Building for.................... $host
 477
 478 Compile configuration:
 479  - C compiler...................... $CC
 480  - C compiler version.............. $sr_cc_version
 481  - C compiler flags................ $CFLAGS
 482  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 483  - C compiler warnings............. $SR_WFLAGS
 484  - C++ compiler.................... $CXX
 485  - C++ compiler version............ $sr_cxx_version
 486  - C++ compiler flags.............. $CXXFLAGS
 487  - C++ compiler warnings........... $SR_WXXFLAGS
 488
 489 Detected libraries (required):
 490  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 491  - libzip >= 0.10.................. $sr_libzip_version
 492
 493 Detected libraries (optional):
 494 $sr_pkglibs_summary
 495 Enabled hardware drivers:
 496 $sr_driver_summary
 497 Enabled SCPI backends:
 498  - TCP............................. yes
 499  - RPC............................. $sr_cv_have_rpc
 500  - serial.......................... $sr_have_libserialport
 501  - VISA............................ $sr_have_librevisa
 502  - GPIB............................ $sr_have_libgpib
 503  - USBTMC.......................... $sr_have_libusb
 504
 505 Enabled language bindings:
 506  - C++............................. $BINDINGS_CXX$sr_report_cxx
 507  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 508  - Java............................ $BINDINGS_JAVA$sr_report_java
 509
 510 _EOF