configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45
  46 # Required for per-target flags or subdir-objects with C sources.
  47 AM_PROG_CC_C_O
  48
  49 # Get compiler versions.
  50 SR_PROG_VERSION([$CC], [sr_cc_version])
  51 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  52
  53 # Check for optional make features.
  54 SR_PROG_MAKE_NO_PRINT_DIRECTORY
  55 SR_PROG_MAKE_ORDER_ONLY
  56
  57 # Initialize libtool.
  58 LT_INIT
  59
  60 # Set up the libsigrok version defines.
  61 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  62
  63 # Library version for libsigrok (NOT the same as the package version).
  64 # Carefully read the libtool docs before updating these numbers!
  65 # The algorithm for determining which number to change (and how) is nontrivial!
  66 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  67 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  68
  69 #############################
  70 ##  Optional dependencies  ##
  71 #############################
  72
  73 AC_LANG([C])
  74
  75 # Initialize pkg-config.
  76 # We require at least 0.22, as "Requires.private" behaviour changed there.
  77 PKG_PROG_PKG_CONFIG([0.22])
  78
  79 # Keep track of all checked modules so we can list them at the end.
  80 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  81
  82 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  83 # These are used to derive the compiler flags and for the "Requires.private"
  84 # field in the generated libsigrok.pc file.
  85 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  86 SR_PKGLIBS_TESTS=
  87 SR_PKGLIBS_CXX=
  88 SR_PKGLIBS_PYTHON=
  89 SR_EXTRA_LIBS=
  90
  91 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  92         [libserialport >= 0.1.1])
  93
  94 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  95         [libftdi1 >= 1.0], [libftdi >= 0.16])
  96
  97 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  98 # This means libusb-1.0 is always available; no need to check for it.
  99 # On Windows, require the latest version we can get our hands on,
 100 # until the new generic event handling has seen an official release.
 101 AS_CASE([$host_os],
 102         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 103         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 104         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 105
 106 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 107         [$sr_libusb_req])
 108
 109 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 110         [librevisa >= 0.0.20130412])
 111
 112 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 113         [libgpib])
 114
 115 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 116         sr_save_LIBS=$LIBS
 117         LIBS="-lieee1284 $LIBS"
 118         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 119                                 [[(void) ieee1284_open(0, 0, 0);]])],
 120                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 121         LIBS=$sr_save_LIBS
 122 ])
 123 AS_IF([test "x$sr_have_libieee1284" = xyes],
 124         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 125
 126 ######################
 127 ##  Feature checks  ##
 128 ######################
 129
 130 # The Check unit testing framework is optional. Disable if not found.
 131 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 132 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 133
 134 # Enable the C99 standard if possible, and enforce the use
 135 # of SR_API to explicitly mark all public API functions.
 136 SR_EXTRA_CFLAGS=
 137 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 138 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 139
 140 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 141
 142 # Check host characteristics.
 143 AC_SYS_LARGEFILE
 144 AC_C_BIGENDIAN
 145
 146 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 147 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 148 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 149
 150 # We need to link against the Winsock2 library for SCPI over TCP.
 151 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 152
 153 # libm (the standard math library) is always needed.
 154 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 155
 156 # RPC is only needed for VXI support.
 157 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 158         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 159                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 160                         [[(void) clnt_create("", 0, 0, "");]])],
 161                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 162 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 163         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 164 # VXI support is only compiled if RPC support was found.
 165 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 166
 167 ########################
 168 ##  Hardware drivers  ##
 169 ########################
 170
 171 # Keep track of all drivers so we can list them at the end.
 172 SR_VAR_SUMMARY([sr_driver_summary])
 173
 174 # Check whether the sr_deps_avail list contains all of the arguments.
 175 # Unavailable dependencies are collected in sr_deps_missing.
 176 sr_check_driver_deps() {
 177         sr_deps_missing=
 178         for sr_dep
 179         do
 180                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 181                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 182         done
 183         test -z "$sr_deps_missing" || return 1
 184 }
 185
 186 AC_ARG_ENABLE([all-drivers],
 187         [AS_HELP_STRING([--enable-all-drivers],
 188                         [enable all drivers by default [default=yes]])],
 189         [], [enable_all_drivers=yes])
 190
 191 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 192 m4_define([_SR_DRIVER], [
 193         AC_ARG_ENABLE([$2],
 194                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 195                 [$3=$enableval], [$3=$enable_all_drivers])
 196
 197         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 198                 sr_check_driver_deps $4 \
 199                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 200         ])], [sr_hw_info='no (disabled)'])
 201         sr_driver_summary_append "$2" "$sr_hw_info"
 202
 203         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 204         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 205 ])
 206
 207 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 208 m4_define([SR_DRIVER],
 209         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 210
 211 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 212 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 213 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 214 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 215 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 216 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 217 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 218 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 219 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 220 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 221 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 222 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 223 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 224 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 225 SR_DRIVER([demo], [demo])
 226 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 227 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 228 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 229 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 230 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 231 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 232 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 233 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 234 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 235 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 236 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 237 SR_DRIVER([maynuo-m97], [maynuo-m97])
 238 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 239 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 240 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 241 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 242 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 243 SR_DRIVER([Rigol DS], [rigol-ds])
 244 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 245 SR_DRIVER([SCPI PPS], [scpi-pps])
 246 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 247 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 248 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 249 SR_DRIVER([Testo], [testo], [libusb])
 250 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 251 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 252 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 253 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 254 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 255 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 256
 257 ###############################
 258 ##  Language bindings setup  ##
 259 ###############################
 260
 261 AC_LANG([C++])
 262 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 263
 264 AC_ARG_ENABLE([bindings],
 265         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 266         [], [enable_bindings=yes])
 267
 268 AC_ARG_ENABLE([cxx],
 269         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 270         [], [enable_cxx=$enable_bindings])
 271
 272 AC_ARG_ENABLE([python],
 273         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 274         [], [enable_python=$enable_bindings])
 275
 276 AC_ARG_ENABLE([java],
 277         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 278         [], [enable_java=$enable_bindings])
 279
 280 ####################
 281 ##  C++ bindings  ##
 282 ####################
 283
 284 sr_cxx_missing=
 285
 286 # Check if the C++ compiler supports the C++11 standard.
 287 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 288 AS_IF([test "x$HAVE_CXX11" != x1],
 289         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 290
 291 # The C++ bindings need glibmm.
 292 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 293 AS_IF([test "x$sr_have_glibmm" != xyes],
 294         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 295
 296 # The C++ bindings use Doxygen to parse libsigrok symbols.
 297 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 298 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 299         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 300
 301 # Python is needed for the C++ bindings.
 302 AM_PATH_PYTHON([2.7],
 303         [HAVE_PYTHON=yes],
 304         [HAVE_PYTHON=no
 305         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 306
 307 AS_IF([test -z "$sr_cxx_missing"],
 308         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 309 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 310
 311 # C++ bindings want stoi and stod.
 312 AM_COND_IF([BINDINGS_CXX], [
 313         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 314                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 315                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 316                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 317         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 318                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 319                         [Specifies whether we have the stoi and stod functions.])])
 320 ])
 321
 322 #######################
 323 ##  Python bindings  ##
 324 #######################
 325
 326 AS_IF([test "x$BINDINGS_CXX" = xyes],
 327         [sr_python_missing=],
 328         [sr_python_missing='C++ bindings'])
 329
 330 # The Python bindings need Python development files.
 331 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 332         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 333 AS_IF([test "x$sr_have_python_dev" != xyes],
 334         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 335
 336 # PyGObject is needed for the Python bindings.
 337 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 338 AS_IF([test "x$sr_have_pygobject" != xyes],
 339         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 340
 341 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 342         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 343                 [Whether last argument to pyg_flags_get_value() is signed.])])
 344
 345 # The Python bindings need the setuptools Python module.
 346 # We'll let it go through even if the AX macro wasn't found,
 347 # as the Python module may still be there.
 348 HAVE_PYMOD_SETUPTOOLS=yes
 349 m4_ifdef([AX_PYTHON_MODULE],
 350         [AX_PYTHON_MODULE([setuptools])],
 351         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 352 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 353         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 354
 355 # The Python bindings use SWIG to generate code.
 356 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 357 AS_IF([test "x$SWIG" = x],
 358         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 359
 360 AS_IF([test -z "$sr_python_missing"],
 361         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 362 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 363
 364 ####################
 365 ##  Java bindings ##
 366 ####################
 367
 368 AS_IF([test "x$BINDINGS_CXX" = xyes],
 369         [sr_java_missing=],
 370         [sr_java_missing='C++ bindings'])
 371
 372 # The Java bindings use SWIG to generate code.
 373 AS_IF([test "x$SWIG" = x],
 374         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 375
 376 # Find Java compiler and JNI includes for Java bindings.
 377 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 378 AS_IF([test "x$HAVE_JAVAC" = xno],
 379         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 380
 381 AC_ARG_WITH([jni-include-path],
 382         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 383                 [specify JNI include directories [default=detect]])],
 384         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 385
 386 JNI_CPPFLAGS=
 387 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 388         AX_PROG_JAVAC
 389         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 390                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 391                 ## If we can find jni.h without any special search path, skip
 392                 ## the execution of the broken macro to increase our chances of
 393                 ## success.
 394                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 395                         [AX_JNI_INCLUDE_DIR])
 396         ])
 397 ])
 398 for sr_dir in $JNI_INCLUDE_DIRS
 399 do
 400         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 401 done
 402 AC_SUBST([JNI_CPPFLAGS])
 403
 404 sr_save_cppflags=$CPPFLAGS
 405 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 406 AC_CHECK_HEADER([jni.h],,
 407         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 408 CPPFLAGS=$sr_save_cppflags
 409
 410 AS_IF([test -z "$sr_java_missing"],
 411         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 412 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 413
 414 ##############################
 415 ##  Finalize configuration  ##
 416 ##############################
 417
 418 # Add mandatory dependencies to module list.
 419 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 420 AC_SUBST([SR_PKGLIBS])
 421
 422 # Retrieve the compile and link flags for all modules combined.
 423 # Also, bail out at this point if any module dependency is not met.
 424 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 425 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 426
 427 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 428 # the C++ bindings are enabled.
 429 AM_COND_IF([BINDINGS_CXX], [
 430         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 431         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 432 ])
 433
 434 # Check for specific libusb features, now that we know the CFLAGS.
 435 AC_LANG([C])
 436 sr_save_cflags=$CFLAGS
 437 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 438 AC_CHECK_TYPES([libusb_os_handle],
 439         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 440         [[#include <libusb.h>]])
 441 CFLAGS=$sr_save_cflags
 442 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 443         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 444
 445 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 446 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 447
 448 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 449         [Build-time version of libzip.])
 450 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 451         [The canonical host libsigrok will run on.])
 452
 453 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 454
 455 AC_OUTPUT
 456
 457 # Prepare bindings report messages.
 458 m4_define([SR_PREPARE_BINDING_REPORT], [
 459         sr_report_$1=
 460         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 461         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 462 ])
 463 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 464
 465 cat >&AS_MESSAGE_FD <<_EOF
 466
 467 libsigrok configuration summary:
 468  - Package version................. $SR_PACKAGE_VERSION
 469  - Library ABI version............. $SR_LIB_VERSION
 470  - Prefix.......................... $prefix
 471  - Building on..................... $build
 472  - Building for.................... $host
 473
 474 Compile configuration:
 475  - C compiler...................... $CC
 476  - C compiler version.............. $sr_cc_version
 477  - C compiler flags................ $CFLAGS
 478  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 479  - C compiler warnings............. $SR_WFLAGS
 480  - C++ compiler.................... $CXX
 481  - C++ compiler version............ $sr_cxx_version
 482  - C++ compiler flags.............. $CXXFLAGS
 483  - C++ compiler warnings........... $SR_WXXFLAGS
 484
 485 Detected libraries (required):
 486  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 487  - libzip >= 0.10.................. $sr_libzip_version
 488
 489 Detected libraries (optional):
 490 $sr_pkglibs_summary
 491 Enabled hardware drivers:
 492 $sr_driver_summary
 493 Enabled SCPI backends:
 494  - TCP............................. yes
 495  - RPC............................. $sr_cv_have_rpc
 496  - serial.......................... $sr_have_libserialport
 497  - VISA............................ $sr_have_librevisa
 498  - GPIB............................ $sr_have_libgpib
 499  - USBTMC.......................... $sr_have_libusb
 500
 501 Enabled language bindings:
 502  - C++............................. $BINDINGS_CXX$sr_report_cxx
 503  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 504  - Java............................ $BINDINGS_JAVA$sr_report_java
 505
 506 _EOF