configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45
  46 # Required for per-target flags or subdir-objects with C sources.
  47 AM_PROG_CC_C_O
  48
  49 # Check for optional make features.
  50 SR_PROG_MAKE_NO_PRINT_DIRECTORY
  51 SR_PROG_MAKE_ORDER_ONLY
  52
  53 # Initialize libtool.
  54 LT_INIT
  55
  56 # Set up the libsigrok version defines.
  57 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  58
  59 # Library version for libsigrok (NOT the same as the package version).
  60 # Carefully read the libtool docs before updating these numbers!
  61 # The algorithm for determining which number to change (and how) is nontrivial!
  62 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  63 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  64
  65 #############################
  66 ##  Optional dependencies  ##
  67 #############################
  68
  69 AC_LANG([C])
  70
  71 # Initialize pkg-config.
  72 # We require at least 0.22, as "Requires.private" behaviour changed there.
  73 PKG_PROG_PKG_CONFIG([0.22])
  74
  75 # Keep track of all checked modules so we can list them at the end.
  76 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  77
  78 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  79 # These are used to derive the compiler flags and for the "Requires.private"
  80 # field in the generated libsigrok.pc file.
  81 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  82 SR_PKGLIBS_TESTS=
  83 SR_PKGLIBS_CXX=
  84 SR_PKGLIBS_PYTHON=
  85 SR_EXTRA_LIBS=
  86
  87 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  88         [libserialport >= 0.1.1])
  89
  90 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  91         [libftdi1 >= 1.0], [libftdi >= 0.16])
  92
  93 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  94 # This means libusb-1.0 is always available; no need to check for it.
  95 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
  96
  97 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
  98         [libusb-1.0 >= 1.0.16])
  99
 100 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 101         [librevisa >= 0.0.20130412])
 102
 103 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 104         [libgpib])
 105
 106 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 107         sr_save_LIBS=$LIBS
 108         LIBS="-lieee1284 $LIBS"
 109         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 110                                 [[(void) ieee1284_open(0, 0, 0);]])],
 111                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 112         sr_save_LIBS=$LIBS
 113 ])
 114 AS_IF([test "x$sr_have_libieee1284" = xyes],
 115         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 116
 117 ######################
 118 ##  Feature checks  ##
 119 ######################
 120
 121 # The Check unit testing framework is optional. Disable if not found.
 122 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 123 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 124
 125 # Enable the C99 standard if possible, and enforce the use
 126 # of SR_API to explicitly mark all public API functions.
 127 SR_EXTRA_CFLAGS=
 128 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 129 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 130
 131 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 132
 133 # Check host characteristics.
 134 AC_SYS_LARGEFILE
 135 AC_C_BIGENDIAN
 136
 137 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 138 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 139 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 140
 141 # We need to link against the Winsock2 library for SCPI over TCP.
 142 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 143
 144 # libm (the standard math library) is always needed.
 145 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 146
 147 # RPC is only needed for VXI support.
 148 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 149         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 150                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 151                         [[(void) clnt_create("", 0, 0, "");]])],
 152                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 153 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 154         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 155 # VXI support is only compiled if RPC support was found.
 156 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 157
 158 ########################
 159 ##  Hardware drivers  ##
 160 ########################
 161
 162 # Keep track of all drivers so we can list them at the end.
 163 SR_VAR_SUMMARY([sr_driver_summary])
 164
 165 # Check whether the sr_deps_avail list contains all of the arguments.
 166 # Unavailable dependencies are collected in sr_deps_missing.
 167 sr_check_driver_deps() {
 168         sr_deps_missing=
 169         for sr_dep
 170         do
 171                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 172                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 173         done
 174         test -z "$sr_deps_missing" || return 1
 175 }
 176
 177 AC_ARG_ENABLE([all-drivers],
 178         [AS_HELP_STRING([--enable-all-drivers],
 179                         [enable all drivers by default [default=yes]])],
 180         [], [enable_all_drivers=yes])
 181
 182 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 183 m4_define([_SR_DRIVER], [
 184         AC_ARG_ENABLE([$2],
 185                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 186                 [$3=$enableval], [$3=$enable_all_drivers])
 187
 188         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 189                 sr_check_driver_deps $4 \
 190                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 191         ])], [sr_hw_info='no (disabled)'])
 192         sr_driver_summary_append "$2" "$sr_hw_info"
 193
 194         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 195         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 196 ])
 197
 198 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 199 m4_define([SR_DRIVER],
 200         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 201
 202 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 203 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 204 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 205 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 206 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 207 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 208 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 209 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 210 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 211 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 212 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 213 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 214 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 215 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 216 SR_DRIVER([demo], [demo])
 217 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 218 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 219 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 220 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 221 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 222 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 223 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 224 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 225 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 226 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 227 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 228 SR_DRIVER([maynuo-m97], [maynuo-m97])
 229 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 230 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 231 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 232 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 233 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 234 SR_DRIVER([Rigol DS], [rigol-ds])
 235 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 236 SR_DRIVER([SCPI PPS], [scpi-pps])
 237 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 238 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 239 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 240 SR_DRIVER([Testo], [testo], [libusb])
 241 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 242 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 243 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 244 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 245 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 246 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 247
 248 ###############################
 249 ##  Language bindings setup  ##
 250 ###############################
 251
 252 AC_LANG([C++])
 253 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 254
 255 AC_ARG_ENABLE([bindings],
 256         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 257         [], [enable_bindings=yes])
 258
 259 AC_ARG_ENABLE([cxx],
 260         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 261         [], [enable_cxx=$enable_bindings])
 262
 263 AC_ARG_ENABLE([python],
 264         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 265         [], [enable_python=$enable_bindings])
 266
 267 AC_ARG_ENABLE([java],
 268         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 269         [], [enable_java=$enable_bindings])
 270
 271 ####################
 272 ##  C++ bindings  ##
 273 ####################
 274
 275 sr_cxx_missing=
 276
 277 # Check if the C++ compiler supports the C++11 standard.
 278 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 279 AS_IF([test "x$HAVE_CXX11" != x1],
 280         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 281
 282 # The C++ bindings need glibmm.
 283 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 284 AS_IF([test "x$sr_have_glibmm" != xyes],
 285         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 286
 287 # The C++ bindings use Doxygen to parse libsigrok symbols.
 288 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 289 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 290         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 291
 292 # Python is needed for the C++ bindings.
 293 AM_PATH_PYTHON([2.7],
 294         [HAVE_PYTHON=yes],
 295         [HAVE_PYTHON=no
 296         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 297
 298 AS_IF([test -z "$sr_cxx_missing"],
 299         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 300 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 301
 302 # C++ bindings want stoi and stod.
 303 AM_COND_IF([BINDINGS_CXX], [
 304         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 305                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 306                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 307                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 308         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 309                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 310                         [Specifies whether we have the stoi and stod functions.])])
 311 ])
 312
 313 #######################
 314 ##  Python bindings  ##
 315 #######################
 316
 317 AS_IF([test "x$BINDINGS_CXX" = xyes],
 318         [sr_python_missing=],
 319         [sr_python_missing='C++ bindings'])
 320
 321 # The Python bindings need Python development files.
 322 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 323         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 324 AS_IF([test "x$sr_have_python_dev" != xyes],
 325         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 326
 327 # PyGObject is needed for the Python bindings.
 328 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 329 AS_IF([test "x$sr_have_pygobject" != xyes],
 330         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 331
 332 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 333         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 334                 [Whether last argument to pyg_flags_get_value() is signed.])])
 335
 336 # The Python bindings need the setuptools Python module.
 337 # We'll let it go through even if the AX macro wasn't found,
 338 # as the Python module may still be there.
 339 HAVE_PYMOD_SETUPTOOLS=yes
 340 m4_ifdef([AX_PYTHON_MODULE],
 341         [AX_PYTHON_MODULE([setuptools])],
 342         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 343 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 344         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 345
 346 # The Python bindings use SWIG to generate code.
 347 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 348 AS_IF([test "x$SWIG" = x],
 349         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 350
 351 AS_IF([test -z "$sr_python_missing"],
 352         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 353 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 354
 355 ####################
 356 ##  Java bindings ##
 357 ####################
 358
 359 AS_IF([test "x$BINDINGS_CXX" = xyes],
 360         [sr_java_missing=],
 361         [sr_java_missing='C++ bindings'])
 362
 363 # The Java bindings use SWIG to generate code.
 364 AS_IF([test "x$SWIG" = x],
 365         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 366
 367 # Find Java compiler and JNI includes for Java bindings.
 368 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 369 AS_IF([test "x$HAVE_JAVAC" = xno],
 370         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 371
 372 AC_ARG_WITH([jni-include-path],
 373         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 374                 [specify JNI include directories [default=detect]])],
 375         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 376
 377 JNI_CPPFLAGS=
 378 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 379         AX_PROG_JAVAC
 380         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 381                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 382                 ## If we can find jni.h without any special search path, skip
 383                 ## the execution of the broken macro to increase our chances of
 384                 ## success.
 385                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 386                         [AX_JNI_INCLUDE_DIR])
 387         ])
 388 ])
 389 for sr_dir in $JNI_INCLUDE_DIRS
 390 do
 391         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 392 done
 393 AC_SUBST([JNI_CPPFLAGS])
 394
 395 sr_save_cppflags=$CPPFLAGS
 396 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 397 AC_CHECK_HEADER([jni.h],,
 398         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 399 CPPFLAGS=$sr_save_cppflags
 400
 401 AS_IF([test -z "$sr_java_missing"],
 402         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 403 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 404
 405 ##############################
 406 ##  Finalize configuration  ##
 407 ##############################
 408
 409 # Add mandatory dependencies to module list.
 410 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 411 AC_SUBST([SR_PKGLIBS])
 412
 413 # Retrieve the compile and link flags for all modules combined.
 414 # Also, bail out at this point if any module dependency is not met.
 415 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 416 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 417
 418 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 419 # the C++ bindings are enabled.
 420 AM_COND_IF([BINDINGS_CXX], [
 421         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 422         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 423 ])
 424 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 425 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 426
 427 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 428         [Build-time version of libzip.])
 429 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 430         [The canonical host libsigrok will run on.])
 431
 432 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 433
 434 AC_OUTPUT
 435
 436 # Prepare bindings report messages.
 437 m4_define([SR_PREPARE_BINDING_REPORT], [
 438         sr_report_$1=
 439         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 440         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 441 ])
 442 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 443
 444 cat >&AS_MESSAGE_FD <<_EOF
 445
 446 libsigrok configuration summary:
 447  - Package version................. $SR_PACKAGE_VERSION
 448  - Library ABI version............. $SR_LIB_VERSION
 449  - Prefix.......................... $prefix
 450  - Building on..................... $build
 451  - Building for.................... $host
 452  - C compiler...................... $CC
 453  - C compiler flags................ $CFLAGS
 454  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 455  - C compiler warnings............. $SR_WFLAGS
 456  - C++ compiler.................... $CXX
 457  - C++ compiler flags.............. $CXXFLAGS
 458  - C++ compiler warnings........... $SR_WXXFLAGS
 459
 460 Detected libraries (required):
 461  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 462  - libzip >= 0.10.................. $sr_libzip_version
 463
 464 Detected libraries (optional):
 465 $sr_pkglibs_summary
 466 Enabled hardware drivers:
 467 $sr_driver_summary
 468 Enabled SCPI backends:
 469  - TCP............................. yes
 470  - RPC............................. $sr_cv_have_rpc
 471  - serial.......................... $sr_have_libserialport
 472  - VISA............................ $sr_have_librevisa
 473  - GPIB............................ $sr_have_libgpib
 474  - USBTMC.......................... $sr_have_libusb
 475
 476 Enabled language bindings:
 477  - C++............................. $BINDINGS_CXX$sr_report_cxx
 478  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 479  - Java............................ $BINDINGS_JAVA$sr_report_java
 480
 481 _EOF