configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrok (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SR_LIB_VERSION_CURRENT=1
  70 SR_LIB_VERSION_REVISION=0
  71 SR_LIB_VERSION_AGE=0
  72 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  73 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  74 AC_SUBST(SR_LIB_VERSION_CURRENT)
  75 AC_SUBST(SR_LIB_VERSION_REVISION)
  76 AC_SUBST(SR_LIB_VERSION_AGE)
  77 AC_SUBST(SR_LIB_VERSION)
  78 AC_SUBST(SR_LIB_LDFLAGS)
  79
  80 # Hardware support '--enable' options.
  81
  82 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  83         [enable all drivers by default [default=yes]]),
  84         [HW_ENABLED_DEFAULT="$enableval"],
  85         [HW_ENABLED_DEFAULT="yes"])
  86
  87 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  88         [enable Agilent DMM support [default=yes]]),
  89         [HW_AGILENT_DMM="$enableval"],
  90         [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  91
  92 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  93         [enable ALSA driver support [default=yes]]),
  94         [HW_ALSA="$enableval"],
  95         [HW_ALSA=$HW_ENABLED_DEFAULT])
  96
  97 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  98         [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
  99         [HW_ASIX_SIGMA="$enableval"],
 100         [HW_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 101
 102 AC_ARG_ENABLE(brymen-dmm, AC_HELP_STRING([--enable-brymen-dmm],
 103         [enable Brymen DMM support [default=yes]]),
 104         [HW_BRYMEN_DMM="$enableval"],
 105         [HW_BRYMEN_DMM=$HW_ENABLED_DEFAULT])
 106
 107 AC_ARG_ENABLE(cem-dt-885x, AC_HELP_STRING([--enable-cem-dt-885x],
 108         [enable CEM DT-885x support [default=yes]]),
 109         [HW_CEM_DT_885X="$enableval"],
 110         [HW_CEM_DT_885X=yes])
 111 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 112 if test "x$HW_CEM_DT_885X" = "xyes"; then
 113         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 114 fi
 115
 116 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 117         [enable ChronoVu LA8 support [default=yes]]),
 118         [HW_CHRONOVU_LA8="$enableval"],
 119         [HW_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 120
 121 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 122         [enable Colead SLM support [default=yes]]),
 123         [HW_COLEAD_SLM="$enableval"],
 124         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 125
 126 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 127         [enable demo driver support [default=yes]]),
 128         [HW_DEMO="$enableval"],
 129         [HW_DEMO=$HW_ENABLED_DEFAULT])
 130
 131 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 132         [enable Fluke DMM support [default=yes]]),
 133         [HW_FLUKE_DMM="$enableval"],
 134         [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 135
 136 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 137         [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 138         [HW_FX2LAFW="$enableval"],
 139         [HW_FX2LAFW=$HW_ENABLED_DEFAULT])
 140
 141 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 142         [enable Hantek DSO support [default=yes]]),
 143         [HW_HANTEK_DSO="$enableval"],
 144         [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 145
 146 AC_ARG_ENABLE(ikalogic-scanalogic2, AC_HELP_STRING([--enable-ikalogic-scanalogic2],
 147         [enable IKALOGIC Scanalogic2 support [default=yes]]),
 148         [HW_IKALOGIC_SCANALOGIC2="$enableval"],
 149         [HW_IKALOGIC_SCANALOGIC2=yes])
 150
 151 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 152         [enable Lascar EL-USB support [default=yes]]),
 153         [HW_LASCAR_EL_USB="$enableval"],
 154         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 155
 156 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 157         [enable Link Instruments MSO-19 support [default=yes]]),
 158         [HW_LINK_MSO19="$enableval"],
 159         [HW_LINK_MSO19=$HW_ENABLED_DEFAULT])
 160
 161 AC_ARG_ENABLE(mic-985xx, AC_HELP_STRING([--enable-mic-985xx],
 162         [enable MIC 985xx support [default=yes]]),
 163         [HW_MIC_985XX="$enableval"],
 164         [HW_MIC_985XX=$HW_ENABLED_DEFAULT])
 165
 166 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 167         [enable Nexus Osciprime support [default=yes]]),
 168         [HW_NEXUS_OSCIPRIME="$enableval"],
 169         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 170
 171 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 172         [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 173         [HW_OLS="$enableval"],
 174         [HW_OLS=$HW_ENABLED_DEFAULT])
 175
 176 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 177         [enable Rigol DS1xx2 support [default=yes]]),
 178         [HW_RIGOL_DS1XX2="$enableval"],
 179         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 180
 181 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 182         [enable serial DMM support [default=yes]]),
 183         [HW_SERIAL_DMM="$enableval"],
 184         [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 185
 186 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 187         [enable Tondaj SL-814 support [default=yes]]),
 188         [HW_TONDAJ_SL_814="$enableval"],
 189         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 190
 191 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 192         [enable UNI-T DMM support [default=yes]]),
 193         [HW_UNI_T_DMM="$enableval"],
 194         [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 195
 196 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 197         [enable victor-dmm support [default=yes]]),
 198         [HW_VICTOR_DMM="$enableval"],
 199         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 200
 201 AC_ARG_ENABLE(zeroplus-logic-cube,
 202         AC_HELP_STRING([--enable-zeroplus-logic-cube],
 203         [enable ZEROPLUS Logic Cube support [default=yes]]),
 204         [HW_ZEROPLUS_LOGIC_CUBE="$enableval"],
 205         [HW_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 206
 207 # Checks for libraries.
 208
 209 # This variable collects the pkg-config names of all detected libs.
 210 # It is then used to construct the "Requires.private:" field in the
 211 # libsigrok.pc file.
 212 SR_PKGLIBS=""
 213
 214 # libm (the standard math library) is always needed.
 215 AC_SEARCH_LIBS([pow], [m])
 216
 217 # libglib-2.0 is always needed. Abort if it's not found.
 218 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 219 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 220 AM_PATH_GLIB_2_0([2.32.0],
 221         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 222
 223 # libzip is always needed. Abort if it's not found.
 224 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 225         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 226         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 227
 228 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 229 # drivers if it is not found.
 230 case "$host" in
 231 *freebsd*)
 232         # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 233         # This means libusb-1.0 is always available, no need to check for it,
 234         # and no need to (potentially) disable any drivers if it's not found.
 235         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 236                 [Specifies whether we have a libusb.h header.])
 237         ;;
 238 *)
 239         PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 240                 [have_libusb1_0="yes"; CFLAGS="$CFLAGS $libusb_CFLAGS";
 241                 LIBS="$LIBS $libusb_LIBS";
 242                 SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 243                 [have_libusb1_0="no"; HW_FX2LAFW="no"; HW_HANTEK_DSO="no";
 244                 HW_IKALOGIC_SCANALOGIC2="no"; HW_LASCAR_EL_USB="no";
 245                 HW_NEXUS_OSCIPRIME="no"; HW_UNI_T_DMM="no"; HW_VICTOR_DMM="no";
 246                 HW_ZEROPLUS_LOGIC_CUBE="no"])
 247
 248         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 249         if test "x$have_libusb1_0" != "xno"; then
 250                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 251                         [Specifies whether we have a libusb.h header.])
 252         fi
 253         ;;
 254 esac
 255
 256 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 257 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 258
 259 # libftdi is only needed for some hardware drivers. Disable them if not found.
 260 PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 261         [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 262         LIBS="$LIBS $libftdi_LIBS";
 263         SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 264         [HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA8="no"])
 265
 266 # libudev is only needed for some hardware drivers. Disable them if not found.
 267 PKG_CHECK_MODULES([libudev], [libudev >= 151],
 268         [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 269         SR_PKGLIBS="$SR_PKGLIBS libudev"],
 270         [HW_LINK_MSO19="no"])
 271
 272 # ALSA is only needed for some hardware drivers. Disable them if not found.
 273 PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 274         [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 275         SR_PKGLIBS="$SR_PKGLIBS alsa"],
 276         [HW_ALSA="no"])
 277
 278 # The Check unit testing framework is optional. Disable if not found.
 279 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 280         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
 281         LIBS="$LIBS $check_LIBS"], [have_check="no"])
 282 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 283
 284 # The Rigol DS1xx2 driver currently uses the Linux kernel usbtmc module
 285 # (though it is planned to rewrite the driver to be portable later).
 286 # Thus, it will be disabled for non-Linux builds for now.
 287 case "$host" in
 288 *linux*)
 289         # Do nothing. Whether the driver is enabled is determined by the
 290         # previous --enable-all-drivers/--disable-all-drivers and/or any
 291         # --enable-rigol-ds1xx2/--disable-rigol-ds1xx2 options.
 292         ;;
 293 *)
 294         # Disable the driver for builds that don't target Linux.
 295         HW_RIGOL_DS1XX2="no"
 296         ;;
 297 esac
 298
 299 AC_SUBST(SR_PKGLIBS)
 300
 301 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 302
 303 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 304 if test "x$HW_AGILENT_DMM" = "xyes"; then
 305         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 306 fi
 307
 308 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
 309 if test "x$HW_ALSA" = "xyes"; then
 310         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 311 fi
 312
 313 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 314 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 315         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 316 fi
 317
 318 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 319 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 320         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 321 fi
 322
 323 AM_CONDITIONAL(HW_CHRONOVU_LA8, test x$HW_CHRONOVU_LA8 = xyes)
 324 if test "x$HW_CHRONOVU_LA8" = "xyes"; then
 325         AC_DEFINE(HAVE_HW_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 326 fi
 327
 328 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 329 if test "x$HW_COLEAD_SLM" = "xyes"; then
 330         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 331 fi
 332
 333 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 334 if test "x$HW_DEMO" = "xyes"; then
 335         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 336 fi
 337
 338 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 339 if test "x$HW_FLUKE_DMM" = "xyes"; then
 340         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 341 fi
 342
 343 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 344 if test "x$HW_FX2LAFW" = "xyes"; then
 345         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 346 fi
 347
 348 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 349 if test "x$HW_HANTEK_DSO" = "xyes"; then
 350         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 351 fi
 352
 353 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 354 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 355         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic2 support])
 356 fi
 357
 358 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 359 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 360         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 361 fi
 362
 363 AM_CONDITIONAL(HW_LINK_MSO19, test x$HW_LINK_MSO19 = xyes)
 364 if test "x$HW_LINK_MSO19" = "xyes"; then
 365         AC_DEFINE(HAVE_HW_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 366 fi
 367
 368 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 369 if test "x$HW_MIC_985XX" = "xyes"; then
 370         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 371 fi
 372
 373 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 374 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 375         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 376 fi
 377
 378 AM_CONDITIONAL(HW_OLS, test x$HW_OLS = xyes)
 379 if test "x$HW_OLS" = "xyes"; then
 380         AC_DEFINE(HAVE_HW_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 381 fi
 382
 383 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 384 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 385         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 386 fi
 387
 388 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 389 if test "x$HW_SERIAL_DMM" = "xyes"; then
 390         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 391 fi
 392
 393 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 394 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 395         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 396 fi
 397
 398 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 399 if test "x$HW_UNI_T_DMM" = "xyes"; then
 400         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 401 fi
 402
 403 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 404 if test "x$HW_VICTOR_DMM" = "xyes"; then
 405         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 406 fi
 407
 408 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 409 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 410         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 411 fi
 412
 413 # Checks for header files.
 414 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 415 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 416
 417 # Checks for typedefs, structures, and compiler characteristics.
 418 AC_C_INLINE
 419 AC_TYPE_INT8_T
 420 AC_TYPE_INT16_T
 421 AC_TYPE_INT32_T
 422 AC_TYPE_INT64_T
 423 AC_TYPE_UINT8_T
 424 AC_TYPE_UINT16_T
 425 AC_TYPE_UINT32_T
 426 AC_TYPE_UINT64_T
 427 AC_TYPE_SIZE_T
 428
 429 # Checks for library functions.
 430 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 431
 432 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 433 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 434 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 435
 436 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 437 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 438 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 439 SR_PACKAGE_VERSION=sr_package_version
 440
 441 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 442 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 443 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 444 AC_SUBST(SR_PACKAGE_VERSION)
 445
 446 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 447                  hardware/agilent-dmm/Makefile
 448                  hardware/alsa/Makefile
 449                  hardware/asix-sigma/Makefile
 450                  hardware/brymen-dmm/Makefile
 451                  hardware/cem-dt-885x/Makefile
 452                  hardware/chronovu-la8/Makefile
 453                  hardware/colead-slm/Makefile
 454                  hardware/common/Makefile
 455                  hardware/ikalogic-scanalogic2/Makefile
 456                  hardware/lascar-el-usb/Makefile
 457                  hardware/mic-985xx/Makefile
 458                  hardware/nexus-osciprime/Makefile
 459                  hardware/rigol-ds1xx2/Makefile
 460                  hardware/tondaj-sl-814/Makefile
 461                  hardware/victor-dmm/Makefile
 462                  hardware/common/dmm/Makefile
 463                  hardware/demo/Makefile
 464                  hardware/fluke-dmm/Makefile
 465                  hardware/fx2lafw/Makefile
 466                  hardware/hantek-dso/Makefile
 467                  hardware/link-mso19/Makefile
 468                  hardware/openbench-logic-sniffer/Makefile
 469                  hardware/serial-dmm/Makefile
 470                  hardware/uni-t-dmm/Makefile
 471                  hardware/zeroplus-logic-cube/Makefile
 472                  input/Makefile
 473                  output/Makefile
 474                  output/text/Makefile
 475                  libsigrok.pc
 476                  contrib/Makefile
 477                  tests/Makefile
 478                 ])
 479
 480 AC_OUTPUT
 481
 482 echo
 483 echo "libsigrok configuration summary:"
 484 echo
 485 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 486 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 487 echo "  - Prefix: $prefix"
 488 echo "  - Building on: $build"
 489 echo "  - Building for: $host"
 490 echo
 491 echo "Detected libraries:"
 492 echo
 493
 494 # Note: This only works for libs with pkg-config integration.
 495 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.8" "libusb-1.0 >= 1.0.9" "libftdi >= 0.16" "libudev >= 151" "alsa >= 1.0" "check >= 0.9.4"; do
 496         if `$PKG_CONFIG --exists $lib`; then
 497                 ver=`$PKG_CONFIG --modversion $lib`
 498                 answer="yes ($ver)"
 499         else
 500                 answer="no"
 501         fi
 502         echo "  - $lib: $answer"
 503 done
 504
 505 echo -e "\nEnabled hardware drivers:\n"
 506 echo "  - agilent-dmm..................... $HW_AGILENT_DMM"
 507 echo "  - alsa............................ $HW_ALSA"
 508 echo "  - asix-sigma...................... $HW_ASIX_SIGMA"
 509 echo "  - brymen-dmm...................... $HW_BRYMEN_DMM"
 510 echo "  - cem-dt-885x..................... $HW_CEM_DT_885X"
 511 echo "  - chronovu-la8.................... $HW_CHRONOVU_LA8"
 512 echo "  - colead-slm...................... $HW_COLEAD_SLM"
 513 echo "  - demo............................ $HW_DEMO"
 514 echo "  - fluke-dmm....................... $HW_FLUKE_DMM"
 515 echo "  - fx2lafw......................... $HW_FX2LAFW"
 516 echo "  - hantek-dso...................... $HW_HANTEK_DSO"
 517 echo "  - ikalogic-scanalogic2............ $HW_IKALOGIC_SCANALOGIC2"
 518 echo "  - lascar-el-usb................... $HW_LASCAR_EL_USB"
 519 echo "  - link-mso19...................... $HW_LINK_MSO19"
 520 echo "  - mic-985xx....................... $HW_MIC_985XX"
 521 echo "  - nexus-osciprime................. $HW_NEXUS_OSCIPRIME"
 522 echo "  - openbench-logic-sniffer......... $HW_OLS"
 523 echo "  - rigol-ds1xx2.................... $HW_RIGOL_DS1XX2"
 524 echo "  - serial-dmm...................... $HW_SERIAL_DMM"
 525 echo "  - tondaj-sl-814................... $HW_TONDAJ_SL_814"
 526 echo "  - uni-t-dmm....................... $HW_UNI_T_DMM"
 527 echo "  - victor-dmm...................... $HW_VICTOR_DMM"
 528 echo "  - zeroplus-logic-cube............. $HW_ZEROPLUS_LOGIC_CUBE"
 529 echo
 530