configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 105 # This means libusb-1.0 is always available; no need to check for it.
 106 # On Windows, require the latest version we can get our hands on,
 107 # until the new generic event handling has seen an official release.
 108 AS_CASE([$host_os],
 109         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 110         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 111         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 112
 113 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 114         [$sr_libusb_req])
 115
 116 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 117         [librevisa >= 0.0.20130412])
 118
 119 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 120         [libgpib])
 121
 122 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 123         sr_save_LIBS=$LIBS
 124         LIBS="-lieee1284 $LIBS"
 125         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 126                                 [[(void) ieee1284_open(0, 0, 0);]])],
 127                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 128         LIBS=$sr_save_LIBS
 129 ])
 130 AS_IF([test "x$sr_have_libieee1284" = xyes],
 131         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 132
 133 AS_IF([test "x$sr_have_libserialport" = xyes],
 134         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 135 AS_IF([test "x$sr_have_serial_comm" = xyes],
 136         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 137 AS_IF([test "x$sr_have_serial_comm" = xyes],
 138         [SR_APPEND([sr_deps_avail], [serial_comm])])
 139 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 140
 141 ######################
 142 ##  Feature checks  ##
 143 ######################
 144
 145 # The Check unit testing framework is optional. Disable if not found.
 146 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 147 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 148
 149 # Enable the C99 standard if possible, and enforce the use
 150 # of SR_API to explicitly mark all public API functions.
 151 SR_EXTRA_CFLAGS=
 152 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 153 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 154
 155 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 156
 157 # Check host characteristics.
 158 AC_SYS_LARGEFILE
 159 AC_C_BIGENDIAN
 160
 161 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 162 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 163 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 164
 165 # We need to link against the Winsock2 library for SCPI over TCP.
 166 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 167
 168 # libm (the standard math library) is always needed.
 169 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 170
 171 # RPC is only needed for VXI support.
 172 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 173         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 174                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 175                         [[(void) clnt_create("", 0, 0, "");]])],
 176                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 177 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 178         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 179 # VXI support is only compiled if RPC support was found.
 180 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 181
 182 # Check for compiler support of 128 bit integers
 183 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 184
 185 ########################
 186 ##  Hardware drivers  ##
 187 ########################
 188
 189 # Keep track of all drivers so we can list them at the end.
 190 SR_VAR_SUMMARY([sr_driver_summary])
 191
 192 # Check whether the sr_deps_avail list contains all of the arguments.
 193 # Unavailable dependencies are collected in sr_deps_missing.
 194 sr_check_driver_deps() {
 195         sr_deps_missing=
 196         for sr_dep
 197         do
 198                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 199                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 200         done
 201         test -z "$sr_deps_missing" || return 1
 202 }
 203
 204 AC_ARG_ENABLE([all-drivers],
 205         [AS_HELP_STRING([--enable-all-drivers],
 206                         [enable all drivers by default [default=yes]])],
 207         [], [enable_all_drivers=yes])
 208
 209 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 210 m4_define([_SR_DRIVER], [
 211         AC_ARG_ENABLE([$2],
 212                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 213                 [$3=$enableval], [$3=$enable_all_drivers])
 214
 215         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 216                 sr_check_driver_deps $4 \
 217                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 218         ])], [sr_hw_info='no (disabled)'])
 219         sr_driver_summary_append "$2" "$sr_hw_info"
 220
 221         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 222         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 223 ])
 224
 225 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 226 m4_define([SR_DRIVER],
 227         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 228
 229 # TODO
 230 # Make device drivers depend on the more generic HAVE_SERIAL_COMM
 231 # feature flag instead of the specific libserialport, which no longer
 232 # is the exclusive provider of serial communication support.
 233
 234 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 235 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 236 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [libserialport])
 237 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 238 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 239 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 240 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 241 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 242 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 243 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 244 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 245 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 246 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 247 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 248 SR_DRIVER([demo], [demo])
 249 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 250 SR_DRIVER([Fluke 45], [fluke-45])
 251 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 252 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 253 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 254 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 255 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 256 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [libserialport])
 257 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 258 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 259 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 260 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 261 SR_DRIVER([HP 3457A], [hp-3457a])
 262 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 263 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 264 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 265 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 266 SR_DRIVER([IPDBG LA], [ipdbg-la])
 267 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 268 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 269 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [libserialport])
 270 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 271 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 272 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 273 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 274 SR_DRIVER([maynuo-m97], [maynuo-m97])
 275 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 276 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 277 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 278 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 279 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 280 SR_DRIVER([PCE PCE-322A], [pce-322a], [libserialport])
 281 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 282 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [libserialport])
 283 SR_DRIVER([Rigol DS], [rigol-ds])
 284 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [libserialport])
 285 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 286 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 287 SR_DRIVER([SCPI DMM], [scpi-dmm])
 288 SR_DRIVER([SCPI PPS], [scpi-pps])
 289 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 290 SR_DRIVER([serial LCR], [serial-lcr], [libserialport])
 291 SR_DRIVER([Siglent SDS], [siglent-sds])
 292 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 293 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 294 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 295 SR_DRIVER([Testo], [testo], [libusb])
 296 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 297 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 298 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 299 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 300 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 301 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 302 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [libserialport])
 303
 304 ###############################
 305 ##  Language bindings setup  ##
 306 ###############################
 307
 308 AC_LANG([C++])
 309 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 310
 311 AC_ARG_ENABLE([bindings],
 312         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 313         [], [enable_bindings=yes])
 314
 315 AC_ARG_ENABLE([cxx],
 316         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 317         [], [enable_cxx=$enable_bindings])
 318
 319 AC_ARG_ENABLE([python],
 320         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 321         [], [enable_python=$enable_bindings])
 322
 323 AC_ARG_ENABLE([ruby],
 324         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 325         [], [enable_ruby=$enable_bindings])
 326
 327 AC_ARG_ENABLE([java],
 328         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 329         [], [enable_java=$enable_bindings])
 330
 331 ####################
 332 ##  C++ bindings  ##
 333 ####################
 334
 335 sr_cxx_missing=
 336
 337 # Check if the C++ compiler supports the C++11 standard.
 338 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 339 AS_IF([test "x$HAVE_CXX11" != x1],
 340         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 341
 342 # The C++ bindings need glibmm.
 343 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 344 AS_IF([test "x$sr_have_glibmm" != xyes],
 345         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 346
 347 # The C++ bindings use Doxygen to parse libsigrok symbols.
 348 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 349 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 350         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 351
 352 # Link C++ code with gnustl_shared if it exists (Android)
 353 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 354
 355 # Python is needed for the C++ bindings.
 356 AM_PATH_PYTHON([2.7],
 357         [HAVE_PYTHON=yes],
 358         [HAVE_PYTHON=no
 359         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 360
 361 AS_IF([test -z "$sr_cxx_missing"],
 362         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 363 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 364
 365 # C++ bindings want stoi and stod.
 366 AM_COND_IF([BINDINGS_CXX], [
 367         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 368                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 369                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 370                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 371         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 372                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 373                         [Specifies whether we have the stoi and stod functions.])])
 374 ])
 375
 376 #######################
 377 ##  Python bindings  ##
 378 #######################
 379
 380 AS_IF([test "x$BINDINGS_CXX" = xyes],
 381         [sr_python_missing=],
 382         [sr_python_missing='C++ bindings'])
 383
 384 # Extract major and minor version number of the Python interpreter.
 385 sr_pymajor=${PYTHON_VERSION%%.*}
 386 sr_pyminor=${PYTHON_VERSION#*.}
 387
 388 # The Python bindings need Python development files. Check for either
 389 # Python 3 or Python 2 headers depending on the interpreter version.
 390 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 391         [python = $PYTHON_VERSION],
 392         [python$sr_pymajor = $PYTHON_VERSION],
 393         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 394         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 395
 396 AS_IF([test "x$sr_have_python_dev" != xyes],
 397         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 398
 399 # PyGObject is needed for the Python bindings.
 400 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 401 AS_IF([test "x$sr_have_pygobject" != xyes],
 402         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 403
 404 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 405         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 406                 [Whether last argument to pyg_flags_get_value() is signed.])])
 407
 408 # The Python bindings need the setuptools and numpy Python modules.
 409 # We'll let it go through even if the AX macro wasn't found, as the
 410 # Python modules may still be there.
 411 m4_ifdef([AX_PYTHON_MODULE], [
 412         AX_PYTHON_MODULE([setuptools])
 413         AX_PYTHON_MODULE([numpy])
 414 ], [
 415         HAVE_PYMOD_SETUPTOOLS=yes
 416         HAVE_PYMOD_NUMPY=yes
 417         m4_warn([unsupported],
 418                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 419 ])
 420 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 421         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 422 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 423         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 424
 425 # The Python bindings use SWIG to generate code.
 426 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 427 AS_IF([test "x$SWIG" != x],
 428     AC_MSG_CHECKING([for $SWIG version])
 429     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 430     AC_MSG_RESULT([$SWIG_VERSION]))
 431 AS_IF([test "x$SWIG" = x],
 432         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 433
 434 AS_IF([test -z "$sr_python_missing"],
 435         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 436 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 437
 438 #####################
 439 ##  Ruby bindings  ##
 440 #####################
 441
 442 AS_IF([test "x$BINDINGS_CXX" = xyes],
 443         [sr_ruby_missing=],
 444         [sr_ruby_missing='C++ bindings'])
 445
 446 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 447 AS_IF([test "x$RUBY" != x],
 448         AC_MSG_CHECKING([for Ruby version])
 449     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 450     AC_MSG_RESULT([$RUBY_VERSION])
 451     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 452     AC_SUBST(RUBY_DLEXT))
 453
 454 AS_IF([test "x$RUBY" = x],
 455         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 456
 457 # Extract major and minor version number of the Ruby interpreter.
 458 sr_rbmajor=${RUBY_VERSION%%.*}
 459 sr_rbminor=${RUBY_VERSION#*.}
 460 sr_rbminor=${sr_rbminor%%.*}
 461
 462 # The Ruby bindings need Ruby development files.
 463 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 464         [ruby],
 465         [ruby-$sr_rbmajor.$sr_rbminor])
 466
 467 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 468         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 469
 470 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 471 AS_IF([test "x$SWIG" = x],
 472         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 473         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 474                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 475
 476 AS_IF([test -z "$sr_ruby_missing"],
 477         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 478 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 479
 480 ####################
 481 ##  Java bindings ##
 482 ####################
 483
 484 AS_IF([test "x$BINDINGS_CXX" = xyes],
 485         [sr_java_missing=],
 486         [sr_java_missing='C++ bindings'])
 487
 488 # The Java bindings use SWIG to generate code.
 489 AS_IF([test "x$SWIG" = x],
 490         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 491
 492 # Find Java compiler and JNI includes for Java bindings.
 493 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 494 AS_IF([test "x$HAVE_JAVAC" = xno],
 495         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 496
 497 AC_ARG_WITH([jni-include-path],
 498         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 499                 [specify JNI include directories [default=detect]])],
 500         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 501
 502 JNI_CPPFLAGS=
 503 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 504         AX_PROG_JAVAC
 505         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 506                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 507                 ## If we can find jni.h without any special search path, skip
 508                 ## the execution of the broken macro to increase our chances of
 509                 ## success.
 510                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 511                         [AX_JNI_INCLUDE_DIR])
 512         ])
 513 ])
 514 for sr_dir in $JNI_INCLUDE_DIRS
 515 do
 516         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 517 done
 518 AC_SUBST([JNI_CPPFLAGS])
 519
 520 sr_save_cppflags=$CPPFLAGS
 521 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 522 AC_CHECK_HEADER([jni.h],,
 523         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 524 CPPFLAGS=$sr_save_cppflags
 525
 526 AS_IF([test -z "$sr_java_missing"],
 527         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 528 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 529
 530 ##############################
 531 ##  Finalize configuration  ##
 532 ##############################
 533
 534 # Add mandatory dependencies to module list.
 535 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 536 AC_SUBST([SR_PKGLIBS])
 537
 538 # Retrieve the compile and link flags for all modules combined.
 539 # Also, bail out at this point if any module dependency is not met.
 540 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 541 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 542
 543 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 544 # the C++ bindings are enabled.
 545 AM_COND_IF([BINDINGS_CXX], [
 546         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 547         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 548         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 549 ])
 550
 551 # Check for specific libusb features, now that we know the CFLAGS.
 552 AC_LANG([C])
 553 sr_save_cflags=$CFLAGS
 554 sr_save_libs=$LIBS
 555 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 556 LIBS="$LIBSIGROK_LIBS $LIBS"
 557 AC_CHECK_TYPES([libusb_os_handle],
 558         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 559         [[#include <libusb.h>]])
 560 AC_CHECK_FUNCS([zip_discard])
 561 LIBS=$sr_save_libs
 562 CFLAGS=$sr_save_cflags
 563
 564 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 565         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 566
 567 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 568 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 569
 570 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 571         [Build-time version of libzip.])
 572 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 573         [The canonical host libsigrok will run on.])
 574
 575 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 576
 577 AC_OUTPUT
 578
 579 # Prepare bindings report messages.
 580 m4_define([SR_PREPARE_BINDING_REPORT], [
 581         sr_report_$1=
 582         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 583         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 584 ])
 585 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 586
 587 cat >&AS_MESSAGE_FD <<_EOF
 588
 589 libsigrok configuration summary:
 590  - Package version................. $SR_PACKAGE_VERSION
 591  - Library ABI version............. $SR_LIB_VERSION
 592  - Prefix.......................... $prefix
 593  - Building on..................... $build
 594  - Building for.................... $host
 595  - Building shared / static........ $enable_shared / $enable_static
 596
 597 Compile configuration:
 598  - C compiler...................... $CC
 599  - C compiler version.............. $sr_cc_version
 600  - C compiler flags................ $CFLAGS
 601  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 602  - C compiler warnings............. $SR_WFLAGS
 603  - C++ compiler.................... $CXX
 604  - C++ compiler version............ $sr_cxx_version
 605  - C++ compiler flags.............. $CXXFLAGS
 606  - C++ compiler warnings........... $SR_WXXFLAGS
 607  - Linker flags.................... $LDFLAGS
 608
 609 Detected libraries (required):
 610  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 611  - libzip >= 0.10.................. $sr_libzip_version
 612
 613 Detected libraries (optional):
 614 $sr_pkglibs_summary
 615 Enabled hardware drivers:
 616 $sr_driver_summary
 617 Enabled serial communication transports:
 618   - serial comm ................... $sr_have_serial_comm
 619   - libserialport ................. $sr_have_libserialport
 620
 621 Enabled SCPI backends:
 622  - TCP............................. yes
 623  - RPC............................. $sr_cv_have_rpc
 624  - serial.......................... $sr_have_serial_comm
 625  - VISA............................ $sr_have_librevisa
 626  - GPIB............................ $sr_have_libgpib
 627  - USBTMC.......................... $sr_have_libusb
 628
 629 Enabled language bindings:
 630  - C++............................. $BINDINGS_CXX$sr_report_cxx
 631  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 632  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 633  - Java............................ $BINDINGS_JAVA$sr_report_java
 634
 635 _EOF
 636
 637 # Emit a warning if the C++ bindings are not being built.
 638 AM_COND_IF([BINDINGS_CXX], [], [
 639 cat >&AS_MESSAGE_FD <<_EOF
 640 ===============================================================================
 641 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 642 ===============================================================================
 643 ===                                                                         ===
 644 ===         The libsigrok C++ bindings are not being built since you        ===
 645 ===             are missing one or more dependencies (see above)!           ===
 646 ===                                                                         ===
 647 ===      This means you won't be able to compile frontends that require     ===
 648 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 649 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 650 ===                                                                         ===
 651 ===============================================================================
 652 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 653 ===============================================================================
 654
 655 _EOF
 656 ])