configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CXX
  51 AC_PROG_CC
  52 AC_PROG_CPP
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55
  56 # Initialize libtool.
  57 LT_INIT
  58
  59 # Initialize pkg-config.
  60 # We require at least 0.22, as "Requires.private" behaviour changed there.
  61 PKG_PROG_PKG_CONFIG([0.22])
  62
  63 # Library version for libsigrok (NOT the same as the package version).
  64 # Carefully read the libtool docs before updating these numbers!
  65 # The algorithm for determining which number to change (and how) is nontrivial!
  66 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  67 SR_LIB_VERSION_CURRENT=2
  68 SR_LIB_VERSION_REVISION=0
  69 SR_LIB_VERSION_AGE=0
  70 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  71 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  72 AC_SUBST(SR_LIB_VERSION_CURRENT)
  73 AC_SUBST(SR_LIB_VERSION_REVISION)
  74 AC_SUBST(SR_LIB_VERSION_AGE)
  75 AC_SUBST(SR_LIB_VERSION)
  76 AC_SUBST(SR_LIB_LDFLAGS)
  77
  78 # Hardware support '--enable' options.
  79
  80 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  81               [enable Agilent DMM support [default=yes]]),
  82               [HW_AGILENT_DMM="$enableval"],
  83               [HW_AGILENT_DMM=yes])
  84 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
  85 if test "x$HW_AGILENT_DMM" = "xyes"; then
  86         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
  87 fi
  88
  89 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  90               [enable ALSA driver support [default=yes]]),
  91               [HW_ALSA="$enableval"],
  92               [HW_ALSA=yes])
  93 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
  94 if test "x$HW_ALSA" = "xyes"; then
  95         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
  96 fi
  97
  98 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  99               [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
 100               [LA_ASIX_SIGMA="$enableval"],
 101               [LA_ASIX_SIGMA=yes])
 102 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 103 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 104         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 105 fi
 106
 107 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 108               [enable ChronoVu LA8 support [default=yes]]),
 109               [LA_CHRONOVU_LA8="$enableval"],
 110               [LA_CHRONOVU_LA8=yes])
 111 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 112 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 113         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 114 fi
 115
 116 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 117         [enable Colead SLM support [default=yes]]),
 118         [HW_COLEAD_SLM="$enableval"],
 119         [HW_COLEAD_SLM=yes])
 120 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 121 if test "x$HW_COLEAD_SLM" = "xyes"; then
 122         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 123 fi
 124
 125 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 126               [enable demo driver support [default=yes]]),
 127               [LA_DEMO="$enableval"],
 128               [LA_DEMO=yes])
 129 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 130 if test "x$LA_DEMO" = "xyes"; then
 131         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 132 fi
 133
 134 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 135               [enable Fluke DMM support [default=yes]]),
 136               [HW_FLUKE_DMM="$enableval"],
 137               [HW_FLUKE_DMM=yes])
 138 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 139 if test "x$HW_FLUKE_DMM" = "xyes"; then
 140         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 141 fi
 142
 143 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 144               [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 145               [LA_FX2LAFW="$enableval"],
 146               [LA_FX2LAFW=yes])
 147 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 148 if test "x$LA_FX2LAFW" = "xyes"; then
 149         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 150 fi
 151
 152 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 153               [enable Hantek DSO support [default=yes]]),
 154               [HW_HANTEK_DSO="$enableval"],
 155               [HW_HANTEK_DSO=yes])
 156 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 157 if test "x$HW_HANTEK_DSO" = "xyes"; then
 158         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 159 fi
 160
 161 # Disabled by default, unfinished.
 162 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 163         [enable Lascar EL-USB support [default=yes]]),
 164         [HW_LASCAR_EL_USB="$enableval"],
 165         [HW_LASCAR_EL_USB=yes])
 166 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 167 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 168         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 169 fi
 170
 171 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 172               [enable Link Instruments MSO-19 support [default=no]]),
 173               [LA_LINK_MSO19="$enableval"],
 174               [LA_LINK_MSO19=no])
 175 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 176 if test "x$LA_LINK_MSO19" = "xyes"; then
 177         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 178 fi
 179
 180 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 181               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 182               [LA_OLS="$enableval"],
 183               [LA_OLS=yes])
 184 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 185 if test "x$LA_OLS" = "xyes"; then
 186         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 187 fi
 188
 189 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 190               [enable serial DMM support [default=yes]]),
 191               [HW_SERIAL_DMM="$enableval"],
 192               [HW_SERIAL_DMM=yes])
 193 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 194 if test "x$HW_SERIAL_DMM" = "xyes"; then
 195         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 196 fi
 197
 198 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 199         [enable Tondaj SL-814 support [default=yes]]),
 200         [HW_TONDAJ_SL_814="$enableval"],
 201         [HW_TONDAJ_SL_814=yes])
 202 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 203 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 204         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 205 fi
 206
 207 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 208               [enable UNI-T DMM support [default=yes]]),
 209               [HW_UNI_T_DMM="$enableval"],
 210               [HW_UNI_T_DMM=yes])
 211 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 212 if test "x$HW_UNI_T_DMM" = "xyes"; then
 213         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 214 fi
 215
 216 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 217         [enable victor-dmm support [default=yes]]),
 218         [HW_VICTOR_DMM="$enableval"],
 219         [HW_VICTOR_DMM=yes])
 220 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 221 if test "x$HW_VICTOR_DMM" = "xyes"; then
 222         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [victor-dmm support])
 223 fi
 224
 225 AC_ARG_ENABLE(zeroplus-logic-cube,
 226               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 227               [enable ZEROPLUS Logic Cube support [default=yes]]),
 228               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 229               [LA_ZEROPLUS_LOGIC_CUBE=yes])
 230 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 231 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 232         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 233 fi
 234
 235 # Checks for libraries.
 236
 237 # This variable collects the pkg-config names of all detected libs.
 238 # It is then used to construct the "Requires.private:" field in the
 239 # libsigrok.pc file.
 240 SR_PKGLIBS=""
 241
 242 # libglib-2.0 is always needed.
 243 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 244 AM_PATH_GLIB_2_0([2.28.0],
 245         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 246
 247 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 248 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 249         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 250         SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
 251
 252 # libusb-1.0 is only needed for some hardware drivers.
 253 if test "x$LA_ASIX_SIGMA" != xno \
 254    -o "x$LA_CHRONOVU_LA8" != xno \
 255    -o "x$LA_FX2LAFW" != xno \
 256    -o "x$HW_HANTEK_DSO" != xno \
 257    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 258         case "$build" in
 259         *freebsd*)
 260                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 261                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 262                         [Specifies whether we have a libusb.h header.])
 263                 ;;
 264         *)
 265                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 266                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 267                         LIBS="$LIBS $libusb_LIBS";
 268                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 269                 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 270                 if test "x$libusb_CFLAGS" != "x"; then
 271                         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 272                                 [Specifies whether we have a libusb.h header.])
 273                 fi
 274                 ;;
 275         esac
 276 fi
 277
 278 # libzip is always needed.
 279 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 280         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 281         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 282
 283 # libftdi is only needed for some hardware drivers.
 284 if test "x$LA_ASIX_SIGMA" != xno \
 285      -o "x$LA_CHRONOVU_LA8" != xno; then
 286         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 287                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 288                 LIBS="$LIBS $libftdi_LIBS";
 289                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 290 fi
 291
 292 # libudev is only needed for some hardware drivers.
 293 if test "x$LA_LINK_MSO19" != xno; then
 294         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 295                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 296                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 297 fi
 298
 299 # ALSA is only needed for some hardware drivers.
 300 if test "x$HW_ALSA" != xno; then
 301         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 302                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 303                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 304 fi
 305
 306 # EZUSB FX2 firmware helper code is only needed for some hardware drivers.
 307 AM_CONDITIONAL(NEED_EZUSB, \
 308         test "x$LA_FX2LAFW" != xno \
 309         -o "x$HW_HANTEK_DSO" != xno \
 310 )
 311
 312 # Serial port helper code is only needed for some hardware drivers.
 313 AM_CONDITIONAL(NEED_SERIAL, \
 314         test "x$HW_AGILENT_DMM" != xno \
 315         -o "x$HW_COLEAD_SLM" != xno \
 316         -o "x$HW_FLUKE_DMM" != xno \
 317         -o "x$LA_LINK_MSO19" != xno \
 318         -o "x$LA_OLS" != xno \
 319         -o "x$HW_SERIAL_DMM" != xno \
 320         -o "x$HW_TONDAJ_SL_814" != xno \
 321 )
 322
 323 AC_SUBST(SR_PKGLIBS)
 324
 325 # Checks for header files.
 326 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 327 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 328
 329 # Checks for typedefs, structures, and compiler characteristics.
 330 AC_C_INLINE
 331 AC_TYPE_INT8_T
 332 AC_TYPE_INT16_T
 333 AC_TYPE_INT32_T
 334 AC_TYPE_INT64_T
 335 AC_TYPE_UINT8_T
 336 AC_TYPE_UINT16_T
 337 AC_TYPE_UINT32_T
 338 AC_TYPE_UINT64_T
 339 AC_TYPE_SIZE_T
 340
 341 # Checks for library functions.
 342 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 343
 344 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 345 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 346 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 347
 348 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 349 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 350 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 351 SR_PACKAGE_VERSION=sr_package_version
 352
 353 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 354 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 355 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 356 AC_SUBST(SR_PACKAGE_VERSION)
 357
 358 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 359                  hardware/agilent-dmm/Makefile
 360                  hardware/alsa/Makefile
 361                  hardware/asix-sigma/Makefile
 362                  hardware/chronovu-la8/Makefile
 363                  hardware/colead-slm/Makefile
 364                  hardware/common/Makefile
 365                  hardware/lascar-el-usb/Makefile
 366                  hardware/tondaj-sl-814/Makefile
 367                  hardware/victor-dmm/Makefile
 368                  hardware/common/dmm/Makefile
 369                  hardware/demo/Makefile
 370                  hardware/fluke-dmm/Makefile
 371                  hardware/fx2lafw/Makefile
 372                  hardware/hantek-dso/Makefile
 373                  hardware/link-mso19/Makefile
 374                  hardware/openbench-logic-sniffer/Makefile
 375                  hardware/serial-dmm/Makefile
 376                  hardware/uni-t-dmm/Makefile
 377                  hardware/zeroplus-logic-cube/Makefile
 378                  input/Makefile
 379                  output/Makefile
 380                  output/text/Makefile
 381                  libsigrok.pc
 382                  contrib/Makefile
 383                 ])
 384
 385 AC_OUTPUT
 386
 387 echo
 388 echo "libsigrok configuration summary:"
 389 echo
 390 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 391 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 392 echo "  - Prefix: $prefix"
 393 echo
 394 echo "Detected libraries:"
 395 echo
 396
 397 # Note: This only works for libs with pkg-config integration.
 398 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
 399         if `$PKG_CONFIG --exists $lib`; then
 400                 ver=`$PKG_CONFIG --modversion $lib`
 401                 answer="yes ($ver)"
 402         else
 403                 answer="no"
 404         fi
 405         echo "  - $lib: $answer"
 406 done
 407
 408 echo -e "\nEnabled hardware drivers:\n"
 409 echo "  - Agilent DMM..................... $HW_AGILENT_DMM"
 410 echo "  - ALSA............................ $HW_ALSA"
 411 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 412 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 413 echo "  - Colead SLM...................... $HW_COLEAD_SLM"
 414 echo "  - Demo driver..................... $LA_DEMO"
 415 echo "  - Fluke DMM....................... $HW_FLUKE_DMM"
 416 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 417 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 418 echo "  - Lascar EL-USB................... $HW_LASCAR_EL_USB"
 419 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 420 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 421 echo "  - Serial DMM...................... $HW_SERIAL_DMM"
 422 echo "  - Tondaj SL-814................... $HW_TONDAJ_SL_814"
 423 echo "  - UNI-T DMM....................... $HW_UNI_T_DMM"
 424 echo "  - Victor DMM...................... $HW_VICTOR_DMM"
 425 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 426 echo
 427