configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.6.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 # Format: current:revision:age.
  71 SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0])
  72
  73 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  74
  75 #############################
  76 ##  Optional dependencies  ##
  77 #############################
  78
  79 AC_LANG([C])
  80
  81 # Initialize pkg-config.
  82 # We require at least 0.22, as "Requires.private" behaviour changed there.
  83 PKG_PROG_PKG_CONFIG([0.22])
  84
  85 # Keep track of all checked modules so we can list them at the end.
  86 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  87
  88 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  89 # These are used to derive the compiler flags and for the "Requires.private"
  90 # field in the generated libsigrok.pc file.
  91 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  92 SR_PKGLIBS_TESTS=
  93 SR_PKGLIBS_CXX=
  94 SR_PKGLIBS_PYTHON=
  95 SR_PKGLIBS_RUBY=
  96 SR_EXTRA_LIBS=
  97 SR_EXTRA_CXX_LIBS=
  98
  99 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], ,
 100         [libserialport >= 0.1.1])
 101
 102 SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0])
 103
 104 SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], ,
 105         [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0])
 106
 107 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 108 # This means libusb-1.0 is always available; no need to check for it.
 109 # On Windows, require the latest version we can get our hands on,
 110 # until the new generic event handling has seen an official release.
 111 AS_CASE([$host_os],
 112         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 113         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 114         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 115
 116 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 117         [$sr_libusb_req])
 118
 119 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 120         [librevisa >= 0.0.20130412])
 121
 122 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 123         [libgpib])
 124
 125 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 126         sr_save_LIBS=$LIBS
 127         LIBS="-lieee1284 $LIBS"
 128         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 129                                 [[(void) ieee1284_open(0, 0, 0);]])],
 130                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 131         LIBS=$sr_save_LIBS
 132 ])
 133 AS_IF([test "x$sr_have_libieee1284" = xyes],
 134         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 135
 136 AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes],
 137         sr_have_serial_comm=yes, sr_have_serial_comm=no)
 138 AS_IF([test "x$sr_have_serial_comm" = xyes],
 139         [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])])
 140 AS_IF([test "x$sr_have_serial_comm" = xyes],
 141         [SR_APPEND([sr_deps_avail], [serial_comm])])
 142 AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes])
 143
 144 ######################
 145 ##  Feature checks  ##
 146 ######################
 147
 148 # The Check unit testing framework is optional. Disable if not found.
 149 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 150 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 151
 152 # Enable the C99 standard if possible, and enforce the use
 153 # of SR_API to explicitly mark all public API functions.
 154 SR_EXTRA_CFLAGS=
 155 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 156 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 157
 158 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 159
 160 # Check host characteristics.
 161 AC_SYS_LARGEFILE
 162 AC_C_BIGENDIAN
 163
 164 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 165 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 166 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 167
 168 # We need to link against the Winsock2 library for SCPI over TCP.
 169 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 170
 171 # libm (the standard math library) is always needed.
 172 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 173
 174 # RPC is only needed for VXI support.
 175 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 176         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 177                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 178                         [[(void) clnt_create("", 0, 0, "");]])],
 179                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 180 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 181         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 182 # VXI support is only compiled if RPC support was found.
 183 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 184
 185 # Check for compiler support of 128 bit integers
 186 AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], [])
 187
 188 ########################
 189 ##  Hardware drivers  ##
 190 ########################
 191
 192 # Keep track of all drivers so we can list them at the end.
 193 SR_VAR_SUMMARY([sr_driver_summary])
 194
 195 # Check whether the sr_deps_avail list contains all of the arguments.
 196 # Unavailable dependencies are collected in sr_deps_missing.
 197 sr_check_driver_deps() {
 198         sr_deps_missing=
 199         for sr_dep
 200         do
 201                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 202                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 203         done
 204         test -z "$sr_deps_missing" || return 1
 205 }
 206
 207 AC_ARG_ENABLE([all-drivers],
 208         [AS_HELP_STRING([--enable-all-drivers],
 209                         [enable all drivers by default [default=yes]])],
 210         [], [enable_all_drivers=yes])
 211
 212 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 213 m4_define([_SR_DRIVER], [
 214         AC_ARG_ENABLE([$2],
 215                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 216                 [$3=$enableval], [$3=$enable_all_drivers])
 217
 218         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 219                 sr_check_driver_deps $4 \
 220                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 221         ])], [sr_hw_info='no (disabled)'])
 222         sr_driver_summary_append "$2" "$sr_hw_info"
 223
 224         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 225         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])])
 226 ])
 227
 228 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 229 m4_define([SR_DRIVER],
 230         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 231
 232 SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm])
 233 SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm])
 234 SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm])
 235 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 236 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm])
 237 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 238 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 239 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 240 SR_DRIVER([Brymen DMM], [brymen-dmm], [serial_comm])
 241 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm])
 242 SR_DRIVER([Center 3xx], [center-3xx], [serial_comm])
 243 SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi])
 244 SR_DRIVER([Colead SLM], [colead-slm], [serial_comm])
 245 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm])
 246 SR_DRIVER([demo], [demo])
 247 SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb])
 248 SR_DRIVER([Fluke 45], [fluke-45])
 249 SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm])
 250 SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi])
 251 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 252 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm])
 253 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm])
 254 SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm])
 255 SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm])
 256 SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb])
 257 SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb])
 258 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 259 SR_DRIVER([HP 3457A], [hp-3457a])
 260 SR_DRIVER([HP 3478A], [hp-3478a], [libgpib])
 261 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 262 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 263 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 264 SR_DRIVER([IPDBG LA], [ipdbg-la])
 265 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 266 SR_DRIVER([KERN scale], [kern-scale], [serial_comm])
 267 SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm])
 268 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 269 SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb])
 270 SR_DRIVER([LeCroy X-Stream], [lecroy-xstream])
 271 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm])
 272 SR_DRIVER([maynuo-m97], [maynuo-m97])
 273 SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm])
 274 SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb])
 275 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm])
 276 SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm])
 277 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm])
 278 SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm])
 279 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 280 SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm])
 281 SR_DRIVER([Rigol DS], [rigol-ds])
 282 SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm])
 283 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 284 SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb])
 285 SR_DRIVER([SCPI DMM], [scpi-dmm])
 286 SR_DRIVER([SCPI PPS], [scpi-pps])
 287 SR_DRIVER([serial DMM], [serial-dmm], [serial_comm])
 288 SR_DRIVER([serial LCR], [serial-lcr], [serial_comm])
 289 SR_DRIVER([Siglent SDS], [siglent-sds])
 290 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 291 SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb])
 292 SR_DRIVER([Teleinfo], [teleinfo], [serial_comm])
 293 SR_DRIVER([Testo], [testo], [libusb])
 294 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm])
 295 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 296 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm])
 297 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 298 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 299 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 300 SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm])
 301
 302 ###############################
 303 ##  Language bindings setup  ##
 304 ###############################
 305
 306 AC_LANG([C++])
 307 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 308
 309 AC_ARG_ENABLE([bindings],
 310         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 311         [], [enable_bindings=yes])
 312
 313 AC_ARG_ENABLE([cxx],
 314         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 315         [], [enable_cxx=$enable_bindings])
 316
 317 AC_ARG_ENABLE([python],
 318         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 319         [], [enable_python=$enable_bindings])
 320
 321 AC_ARG_ENABLE([ruby],
 322         [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])],
 323         [], [enable_ruby=$enable_bindings])
 324
 325 AC_ARG_ENABLE([java],
 326         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 327         [], [enable_java=$enable_bindings])
 328
 329 ####################
 330 ##  C++ bindings  ##
 331 ####################
 332
 333 sr_cxx_missing=
 334
 335 # Check if the C++ compiler supports the C++11 standard.
 336 AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
 337 AS_IF([test "x$HAVE_CXX11" != x1],
 338         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 339
 340 # The C++ bindings need glibmm.
 341 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 342 AS_IF([test "x$sr_have_glibmm" != xyes],
 343         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 344
 345 # The C++ bindings use Doxygen to parse libsigrok symbols.
 346 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 347 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 348         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 349
 350 # Link C++ code with gnustl_shared if it exists (Android)
 351 SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared])
 352
 353 # Python is needed for the C++ bindings.
 354 AM_PATH_PYTHON([2.7],
 355         [HAVE_PYTHON=yes],
 356         [HAVE_PYTHON=no
 357         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 358
 359 AS_IF([test -z "$sr_cxx_missing"],
 360         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 361 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 362
 363 # C++ bindings want stoi and stod.
 364 AM_COND_IF([BINDINGS_CXX], [
 365         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 366                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 367                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 368                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 369         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 370                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 371                         [Specifies whether we have the stoi and stod functions.])])
 372 ])
 373
 374 #######################
 375 ##  Python bindings  ##
 376 #######################
 377
 378 AS_IF([test "x$BINDINGS_CXX" = xyes],
 379         [sr_python_missing=],
 380         [sr_python_missing='C++ bindings'])
 381
 382 # Extract major and minor version number of the Python interpreter.
 383 sr_pymajor=${PYTHON_VERSION%%.*}
 384 sr_pyminor=${PYTHON_VERSION#*.}
 385
 386 # The Python bindings need Python development files. Check for either
 387 # Python 3 or Python 2 headers depending on the interpreter version.
 388 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 389         [python = $PYTHON_VERSION],
 390         [python$sr_pymajor = $PYTHON_VERSION],
 391         [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION],
 392         [python-$PYTHON_VERSION = $PYTHON_VERSION])
 393
 394 AS_IF([test "x$sr_have_python_dev" != xyes],
 395         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 396
 397 # PyGObject is needed for the Python bindings.
 398 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 399 AS_IF([test "x$sr_have_pygobject" != xyes],
 400         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 401
 402 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 403         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 404                 [Whether last argument to pyg_flags_get_value() is signed.])])
 405
 406 # The Python bindings need the setuptools and numpy Python modules.
 407 # We'll let it go through even if the AX macro wasn't found, as the
 408 # Python modules may still be there.
 409 m4_ifdef([AX_PYTHON_MODULE], [
 410         AX_PYTHON_MODULE([setuptools])
 411         AX_PYTHON_MODULE([numpy])
 412 ], [
 413         HAVE_PYMOD_SETUPTOOLS=yes
 414         HAVE_PYMOD_NUMPY=yes
 415         m4_warn([unsupported],
 416                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 417 ])
 418 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 419         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 420 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 421         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 422
 423 # The Python bindings use SWIG to generate code.
 424 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 425 AS_IF([test "x$SWIG" != x],
 426     AC_MSG_CHECKING([for $SWIG version])
 427     [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`]
 428     AC_MSG_RESULT([$SWIG_VERSION]))
 429 AS_IF([test "x$SWIG" = x],
 430         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 431
 432 AS_IF([test -z "$sr_python_missing"],
 433         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 434 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 435
 436 #####################
 437 ##  Ruby bindings  ##
 438 #####################
 439
 440 AS_IF([test "x$BINDINGS_CXX" = xyes],
 441         [sr_ruby_missing=],
 442         [sr_ruby_missing='C++ bindings'])
 443
 444 AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], [])
 445 AS_IF([test "x$RUBY" != x],
 446         AC_MSG_CHECKING([for Ruby version])
 447     [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`]
 448     AC_MSG_RESULT([$RUBY_VERSION])
 449     [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`]
 450     AC_SUBST(RUBY_DLEXT))
 451
 452 AS_IF([test "x$RUBY" = x],
 453         [SR_APPEND([sr_ruby_missing], [', '], [Ruby])])
 454
 455 # Extract major and minor version number of the Ruby interpreter.
 456 sr_rbmajor=${RUBY_VERSION%%.*}
 457 sr_rbminor=${RUBY_VERSION#*.}
 458 sr_rbminor=${sr_rbminor%%.*}
 459
 460 # The Ruby bindings need Ruby development files.
 461 SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY],
 462         [ruby],
 463         [ruby-$sr_rbmajor.$sr_rbminor])
 464
 465 AS_IF([test "x$sr_have_ruby_dev" != xyes],
 466         [SR_APPEND([sr_ruby_missing], [', '], [Headers])])
 467
 468 # The Ruby bindings use SWIG >= 3.0.8 to generate code.
 469 AS_IF([test "x$SWIG" = x],
 470         [SR_APPEND([sr_ruby_missing], [', '], [SWIG])],
 471         [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8",
 472                 [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])])
 473
 474 AS_IF([test -z "$sr_ruby_missing"],
 475         [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no])
 476 AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes])
 477
 478 ####################
 479 ##  Java bindings ##
 480 ####################
 481
 482 AS_IF([test "x$BINDINGS_CXX" = xyes],
 483         [sr_java_missing=],
 484         [sr_java_missing='C++ bindings'])
 485
 486 # The Java bindings use SWIG to generate code.
 487 AS_IF([test "x$SWIG" = x],
 488         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 489
 490 # Find Java compiler and JNI includes for Java bindings.
 491 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 492 AS_IF([test "x$HAVE_JAVAC" = xno],
 493         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 494
 495 AC_ARG_WITH([jni-include-path],
 496         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 497                 [specify JNI include directories [default=detect]])],
 498         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 499
 500 JNI_CPPFLAGS=
 501 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 502         AX_PROG_JAVAC
 503         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 504                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 505                 ## If we can find jni.h without any special search path, skip
 506                 ## the execution of the broken macro to increase our chances of
 507                 ## success.
 508                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 509                         [AX_JNI_INCLUDE_DIR])
 510         ])
 511 ])
 512 for sr_dir in $JNI_INCLUDE_DIRS
 513 do
 514         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 515 done
 516 AC_SUBST([JNI_CPPFLAGS])
 517
 518 sr_save_cppflags=$CPPFLAGS
 519 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 520 AC_CHECK_HEADER([jni.h],,
 521         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 522 CPPFLAGS=$sr_save_cppflags
 523
 524 AS_IF([test -z "$sr_java_missing"],
 525         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 526 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 527
 528 ##############################
 529 ##  Finalize configuration  ##
 530 ##############################
 531
 532 # Add mandatory dependencies to module list.
 533 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 534 AC_SUBST([SR_PKGLIBS])
 535
 536 # Retrieve the compile and link flags for all modules combined.
 537 # Also, bail out at this point if any module dependency is not met.
 538 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 539 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 540
 541 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 542 # the C++ bindings are enabled.
 543 AM_COND_IF([BINDINGS_CXX], [
 544         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 545         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 546         PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")])
 547 ])
 548
 549 # Check for specific libusb features, now that we know the CFLAGS.
 550 AC_LANG([C])
 551 sr_save_cflags=$CFLAGS
 552 sr_save_libs=$LIBS
 553 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 554 LIBS="$LIBSIGROK_LIBS $LIBS"
 555 AC_CHECK_TYPES([libusb_os_handle],
 556         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 557         [[#include <libusb.h>]])
 558 AC_CHECK_FUNCS([zip_discard])
 559 LIBS=$sr_save_libs
 560 CFLAGS=$sr_save_cflags
 561
 562 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 563         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 564
 565 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 566 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 567
 568 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 569         [Build-time version of libzip.])
 570 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 571         [The canonical host libsigrok will run on.])
 572
 573 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 574
 575 AC_OUTPUT
 576
 577 # Prepare bindings report messages.
 578 m4_define([SR_PREPARE_BINDING_REPORT], [
 579         sr_report_$1=
 580         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 581         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 582 ])
 583 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java])
 584
 585 cat >&AS_MESSAGE_FD <<_EOF
 586
 587 libsigrok configuration summary:
 588  - Package version................. $SR_PACKAGE_VERSION
 589  - Library ABI version............. $SR_LIB_VERSION
 590  - Prefix.......................... $prefix
 591  - Building on..................... $build
 592  - Building for.................... $host
 593  - Building shared / static........ $enable_shared / $enable_static
 594
 595 Compile configuration:
 596  - C compiler...................... $CC
 597  - C compiler version.............. $sr_cc_version
 598  - C compiler flags................ $CFLAGS
 599  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 600  - C compiler warnings............. $SR_WFLAGS
 601  - C++ compiler.................... $CXX
 602  - C++ compiler version............ $sr_cxx_version
 603  - C++ compiler flags.............. $CXXFLAGS
 604  - C++ compiler warnings........... $SR_WXXFLAGS
 605  - Linker flags.................... $LDFLAGS
 606
 607 Detected libraries (required):
 608  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 609  - libzip >= 0.10.................. $sr_libzip_version
 610
 611 Detected libraries (optional):
 612 $sr_pkglibs_summary
 613 Enabled hardware drivers:
 614 $sr_driver_summary
 615 Enabled serial communication transports:
 616   - serial comm ................... $sr_have_serial_comm
 617   - libserialport ................. $sr_have_libserialport
 618   - hidapi ........................ $sr_have_libhidapi
 619
 620 Enabled SCPI backends:
 621  - TCP............................. yes
 622  - RPC............................. $sr_cv_have_rpc
 623  - serial.......................... $sr_have_serial_comm
 624  - VISA............................ $sr_have_librevisa
 625  - GPIB............................ $sr_have_libgpib
 626  - USBTMC.......................... $sr_have_libusb
 627
 628 Enabled language bindings:
 629  - C++............................. $BINDINGS_CXX$sr_report_cxx
 630  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 631  - Ruby............................ $BINDINGS_RUBY$sr_report_ruby
 632  - Java............................ $BINDINGS_JAVA$sr_report_java
 633
 634 _EOF
 635
 636 # Emit a warning if the C++ bindings are not being built.
 637 AM_COND_IF([BINDINGS_CXX], [], [
 638 cat >&AS_MESSAGE_FD <<_EOF
 639 ===============================================================================
 640 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 641 ===============================================================================
 642 ===                                                                         ===
 643 ===         The libsigrok C++ bindings are not being built since you        ===
 644 ===             are missing one or more dependencies (see above)!           ===
 645 ===                                                                         ===
 646 ===      This means you won't be able to compile frontends that require     ===
 647 ===  the C++ bindings (such as PulseView)! You also won't be able to build  ===
 648 ===     other bindings and frontends using those (such as sigrok-meter)!    ===
 649 ===                                                                         ===
 650 ===============================================================================
 651 WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING
 652 ===============================================================================
 653
 654 _EOF
 655 ])