configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CXX
  51 AC_PROG_CC
  52 AC_PROG_CPP
  53 AC_PROG_INSTALL
  54 AC_PROG_LN_S
  55
  56 # Initialize libtool.
  57 LT_INIT
  58
  59 # Initialize pkg-config.
  60 # We require at least 0.22, as "Requires.private" behaviour changed there.
  61 PKG_PROG_PKG_CONFIG([0.22])
  62
  63 # Library version for libsigrok (NOT the same as the package version).
  64 # Carefully read the libtool docs before updating these numbers!
  65 # The algorithm for determining which number to change (and how) is nontrivial!
  66 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  67 SR_LIB_VERSION_CURRENT=1
  68 SR_LIB_VERSION_REVISION=0
  69 SR_LIB_VERSION_AGE=0
  70 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  71 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  72 AC_SUBST(SR_LIB_VERSION_CURRENT)
  73 AC_SUBST(SR_LIB_VERSION_REVISION)
  74 AC_SUBST(SR_LIB_VERSION_AGE)
  75 AC_SUBST(SR_LIB_VERSION)
  76 AC_SUBST(SR_LIB_LDFLAGS)
  77
  78 # Hardware support '--enable' options.
  79
  80 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  81               [enable Agilent DMM support [default=yes]]),
  82               [HW_AGILENT_DMM="$enableval"],
  83               [HW_AGILENT_DMM=yes])
  84 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
  85 if test "x$HW_AGILENT_DMM" = "xyes"; then
  86         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
  87 fi
  88
  89 # Disabled by default, unfinished.
  90 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  91               [enable ALSA driver support [default=no]]),
  92               [LA_ALSA="$enableval"],
  93               [LA_ALSA=no])
  94 AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
  95 if test "x$LA_ALSA" = "xyes"; then
  96         AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
  97 fi
  98
  99 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
 100               [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
 101               [LA_ASIX_SIGMA="$enableval"],
 102               [LA_ASIX_SIGMA=yes])
 103 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 104 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 105         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 106 fi
 107
 108 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 109               [enable ChronoVu LA8 support [default=yes]]),
 110               [LA_CHRONOVU_LA8="$enableval"],
 111               [LA_CHRONOVU_LA8=yes])
 112 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 113 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 114         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 115 fi
 116
 117 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 118         [enable Colead SLM support [default=yes]]),
 119         [HW_COLEAD_SLM="$enableval"],
 120         [HW_COLEAD_SLM=yes])
 121 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 122 if test "x$HW_COLEAD_SLM" = "xyes"; then
 123         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 124 fi
 125
 126 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 127               [enable demo driver support [default=yes]]),
 128               [LA_DEMO="$enableval"],
 129               [LA_DEMO=yes])
 130 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 131 if test "x$LA_DEMO" = "xyes"; then
 132         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 133 fi
 134
 135 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 136               [enable Fluke DMM support [default=yes]]),
 137               [HW_FLUKE_DMM="$enableval"],
 138               [HW_FLUKE_DMM=yes])
 139 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 140 if test "x$HW_FLUKE_DMM" = "xyes"; then
 141         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 142 fi
 143
 144 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 145               [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 146               [LA_FX2LAFW="$enableval"],
 147               [LA_FX2LAFW=yes])
 148 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 149 if test "x$LA_FX2LAFW" = "xyes"; then
 150         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 151 fi
 152
 153 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 154               [enable Hantek DSO support [default=yes]]),
 155               [HW_HANTEK_DSO="$enableval"],
 156               [HW_HANTEK_DSO=yes])
 157 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 158 if test "x$HW_HANTEK_DSO" = "xyes"; then
 159         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 160 fi
 161
 162 # Disabled by default, unfinished.
 163 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 164               [enable Link Instruments MSO-19 support [default=no]]),
 165               [LA_LINK_MSO19="$enableval"],
 166               [LA_LINK_MSO19=no])
 167 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 168 if test "x$LA_LINK_MSO19" = "xyes"; then
 169         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 170 fi
 171
 172 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 173               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 174               [LA_OLS="$enableval"],
 175               [LA_OLS=yes])
 176 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 177 if test "x$LA_OLS" = "xyes"; then
 178         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 179 fi
 180
 181 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 182               [enable serial DMM support [default=yes]]),
 183               [HW_SERIAL_DMM="$enableval"],
 184               [HW_SERIAL_DMM=yes])
 185 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 186 if test "x$HW_SERIAL_DMM" = "xyes"; then
 187         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 188 fi
 189
 190 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 191         [enable Tondaj SL-814 support [default=yes]]),
 192         [HW_TONDAJ_SL_814="$enableval"],
 193         [HW_TONDAJ_SL_814=yes])
 194 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 195 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 196         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 197 fi
 198
 199 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 200               [enable UNI-T DMM support [default=yes]]),
 201               [HW_UNI_T_DMM="$enableval"],
 202               [HW_UNI_T_DMM=yes])
 203 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 204 if test "x$HW_UNI_T_DMM" = "xyes"; then
 205         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 206 fi
 207
 208 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 209         [enable victor-dmm support [default=yes]]),
 210         [HW_VICTOR_DMM="$enableval"],
 211         [HW_VICTOR_DMM=yes])
 212 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 213 if test "x$HW_VICTOR_DMM" = "xyes"; then
 214         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [victor-dmm support])
 215 fi
 216
 217 AC_ARG_ENABLE(zeroplus-logic-cube,
 218               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 219               [enable ZEROPLUS Logic Cube support [default=yes]]),
 220               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 221               [LA_ZEROPLUS_LOGIC_CUBE=yes])
 222 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 223 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 224         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 225 fi
 226
 227 # Checks for libraries.
 228
 229 # This variable collects the pkg-config names of all detected libs.
 230 # It is then used to construct the "Requires.private:" field in the
 231 # libsigrok.pc file.
 232 SR_PKGLIBS=""
 233
 234 # libglib-2.0 is always needed.
 235 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 236 AM_PATH_GLIB_2_0([2.28.0],
 237         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 238
 239 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 240 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 241         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 242         SR_PKGLIBS="$SR_PKGLIBS gthread-2.0"])
 243
 244 # libusb is only needed for some hardware drivers.
 245 if test "x$LA_ASIX_SIGMA" != xno \
 246    -o "x$LA_CHRONOVU_LA8" != xno \
 247    -o "x$LA_FX2LAFW" != xno \
 248    -o "x$HW_HANTEK_DSO" != xno \
 249    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 250         case "$build" in
 251         *freebsd*)
 252                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 253                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 254                         [Specifies whether we have a libusb.h header.])
 255                 ;;
 256         *)
 257                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 258                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 259                         LIBS="$LIBS $libusb_LIBS";
 260                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 261                 AC_CHECK_LIB(usb-1.0, libusb_init)
 262                 ;;
 263         esac
 264 fi
 265
 266 # libzip is always needed.
 267 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 268         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 269         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 270
 271 # libftdi is only needed for some hardware drivers.
 272 if test "x$LA_ASIX_SIGMA" != xno \
 273      -o "x$LA_CHRONOVU_LA8" != xno; then
 274         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 275                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 276                 LIBS="$LIBS $libftdi_LIBS";
 277                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 278 fi
 279
 280 # libudev is only needed for some hardware drivers.
 281 if test "x$LA_LINK_MSO19" != xno; then
 282         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 283                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 284                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 285 fi
 286
 287 # ALSA is only needed for some hardware drivers.
 288 if test "x$LA_ALSA" != xno; then
 289         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 290                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 291                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 292 fi
 293
 294 # EZUSB FX2 firmware helper code is only needed for some hardware drivers.
 295 AM_CONDITIONAL(NEED_EZUSB, \
 296         test "x$LA_FX2LAFW" != xno \
 297         -o "x$HW_HANTEK_DSO" != xno \
 298 )
 299
 300 # Serial port helper code is only needed for some hardware drivers.
 301 AM_CONDITIONAL(NEED_SERIAL, \
 302         test "x$HW_AGILENT_DMM" != xno \
 303         -o "x$HW_COLEAD_SLM" != xno \
 304         -o "x$HW_FLUKE_DMM" != xno \
 305         -o "x$LA_LINK_MSO19" != xno \
 306         -o "x$LA_OLS" != xno \
 307         -o "x$HW_SERIAL_DMM" != xno \
 308         -o "x$HW_TONDAJ_SL_814" != xno \
 309 )
 310
 311 AC_SUBST(SR_PKGLIBS)
 312
 313 # Checks for header files.
 314 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 315 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 316
 317 # Checks for typedefs, structures, and compiler characteristics.
 318 AC_C_INLINE
 319 AC_TYPE_INT8_T
 320 AC_TYPE_INT16_T
 321 AC_TYPE_INT32_T
 322 AC_TYPE_INT64_T
 323 AC_TYPE_UINT8_T
 324 AC_TYPE_UINT16_T
 325 AC_TYPE_UINT32_T
 326 AC_TYPE_UINT64_T
 327 AC_TYPE_SIZE_T
 328
 329 # Checks for library functions.
 330 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 331
 332 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 333 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 334 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 335
 336 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 337 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 338 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 339 SR_PACKAGE_VERSION=sr_package_version
 340
 341 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 342 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 343 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 344 AC_SUBST(SR_PACKAGE_VERSION)
 345
 346 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 347                  hardware/agilent-dmm/Makefile
 348                  hardware/alsa/Makefile
 349                  hardware/asix-sigma/Makefile
 350                  hardware/chronovu-la8/Makefile
 351                  hardware/colead-slm/Makefile
 352                  hardware/common/Makefile
 353                  hardware/tondaj-sl-814/Makefile
 354                  hardware/victor-dmm/Makefile
 355                  hardware/common/dmm/Makefile
 356                  hardware/demo/Makefile
 357                  hardware/fluke-dmm/Makefile
 358                  hardware/fx2lafw/Makefile
 359                  hardware/hantek-dso/Makefile
 360                  hardware/link-mso19/Makefile
 361                  hardware/openbench-logic-sniffer/Makefile
 362                  hardware/serial-dmm/Makefile
 363                  hardware/uni-t-dmm/Makefile
 364                  hardware/zeroplus-logic-cube/Makefile
 365                  input/Makefile
 366                  output/Makefile
 367                  output/text/Makefile
 368                  libsigrok.pc
 369                  contrib/Makefile
 370                 ])
 371
 372 AC_OUTPUT
 373
 374 echo
 375 echo "libsigrok configuration summary:"
 376 echo
 377 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 378 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 379 echo "  - Prefix: $prefix"
 380 echo
 381 echo "Detected libraries:"
 382 echo
 383
 384 # Note: This only works for libs with pkg-config integration.
 385 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa"; do
 386         if `$PKG_CONFIG --exists $lib`; then
 387                 ver=`$PKG_CONFIG --modversion $lib`
 388                 answer="yes ($ver)"
 389         else
 390                 answer="no"
 391         fi
 392         echo "  - $lib: $answer"
 393 done
 394
 395 echo -e "\nEnabled hardware drivers:\n"
 396 echo "  - Agilent DMM..................... $HW_AGILENT_DMM"
 397 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 398 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 399 echo "  - Colead SLM...................... $HW_COLEAD_SLM"
 400 echo "  - Demo driver..................... $LA_DEMO"
 401 echo "  - Fluke DMM....................... $HW_FLUKE_DMM"
 402 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 403 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 404 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 405 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 406 echo "  - Serial DMM...................... $HW_SERIAL_DMM"
 407 echo "  - Tondaj SL-814................... $HW_TONDAJ_SL_814"
 408 echo "  - UNI-T DMM....................... $HW_UNI_T_DMM"
 409 echo "  - victor-dmm...................... $HW_VICTOR_DMM"
 410 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 411 echo
 412