configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 # Hardware support '--enable' options.
  84
  85 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  86         [enable all drivers by default [default=yes]]),
  87         [HW_ENABLED_DEFAULT="$enableval"],
  88         [HW_ENABLED_DEFAULT="yes"])
  89
  90 # Usage: DRIVER([Device name], [driver-name])
  91 # An optional third argument [no] disables that driver.
  92 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  93 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  94 AC_DEFUN([DRIVER], [
  95         if test -z "$3"; then
  96                 default=$HW_ENABLED_DEFAULT
  97         else
  98                 default="$3"
  99         fi
 100         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 101                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 102                 [m4_join([], [HW_], upperize([$2]))=$default])
 103         dots=$(expr substr ".............................." 1 $(expr 32 - length $2))
 104         driver_summary="${driver_summary}  - $2${dots} ${m4_join([], [HW_], upperize([$2]))}\n"
 105 ])
 106
 107 DRIVER([Agilent DMM], [agilent-dmm])
 108 DRIVER([Appa 55II], [appa-55ii])
 109 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 110 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 111 DRIVER([Brymen BM86x], [brymen-bm86x])
 112 DRIVER([Brymen DMM], [brymen-dmm])
 113 DRIVER([CEM DT-885x], [cem-dt-885x])
 114 DRIVER([Center 3xx], [center-3xx])
 115 DRIVER([ChronoVu LA], [chronovu-la])
 116 DRIVER([Colead SLM], [colead-slm])
 117 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 118 DRIVER([demo], [demo])
 119 DRIVER([Fluke DMM], [fluke-dmm])
 120 DRIVER([fx2lafw], [fx2lafw])
 121 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 122 DRIVER([Hameg HMO], [hameg-hmo])
 123 DRIVER([Hantek DSO], [hantek-dso])
 124 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 125 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 126 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 127 DRIVER([Lascar EL-USB], [lascar-el-usb])
 128 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 129 DRIVER([MIC 985xx], [mic-985xx])
 130 DRIVER([Motech LPS 30x], [motech-lps-30x])
 131 DRIVER([Norma DMM], [norma-dmm])
 132 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([serial DMM], [serial-dmm])
 136 DRIVER([Sysclk LWLA], [sysclk-lwla])
 137 DRIVER([Teleinfo], [teleinfo])
 138 DRIVER([Testo], [testo])
 139 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 140 DRIVER([UNI-T DMM], [uni-t-dmm])
 141 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 142 DRIVER([Victor DMM], [victor-dmm])
 143 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 144
 145 AC_ARG_ENABLE(libserialport,
 146         AC_HELP_STRING([--disable-libserialport],
 147         [disable libserialport support [default=detect]]))
 148
 149 AC_ARG_ENABLE(libftdi,
 150         AC_HELP_STRING([--disable-libftdi],
 151         [disable libftdi support [default=detect]]))
 152
 153 AC_ARG_ENABLE(libusb,
 154         AC_HELP_STRING([--disable-libusb],
 155         [disable libusb support [default=detect]]))
 156
 157 # Language binding '--enable' options
 158
 159 AC_ARG_ENABLE(c++,
 160         AC_HELP_STRING([--enable-cxx],
 161         [build C++ bindings [default=yes]]),
 162         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX="yes"])
 163
 164 AC_ARG_ENABLE(python,
 165         AC_HELP_STRING([--enable-python],
 166         [build Python bindings [default=yes]]),
 167         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON="yes"])
 168
 169 AC_ARG_ENABLE(java,
 170         AC_HELP_STRING([--enable-java],
 171         [build Java bindings [default=yes]]),
 172         [BINDINGS_PYTHON="$enableval"], [BINDINGS_JAVA="yes"])
 173
 174 # Check if the C++ compiler supports the C++11 standard.
 175
 176 AX_CXX_COMPILE_STDCXX_11(,[optional])
 177
 178 if test "x$HAVE_CXX11" != "x1"; then
 179         BINDINGS_CXX="no"
 180 fi
 181
 182 # Python and Java bindings depend on C++ bindings.
 183
 184 if test "x$BINDINGS_CXX" != "xyes"; then
 185         BINDINGS_PYTHON="no"
 186         BINDINGS_JAVA="no"
 187 fi
 188
 189 # Checks for libraries.
 190
 191 case "$host" in
 192 *mingw*)
 193         # We need to link against the Winsock2 library for SCPI over TCP.
 194         LIBS="$LIBS -lws2_32";;
 195 esac
 196
 197 # This variable collects the pkg-config names of all detected libs.
 198 # It is then used to construct the "Requires.private:" field in the
 199 # libsigrok.pc file.
 200 SR_PKGLIBS=""
 201
 202 # libm (the standard math library) is always needed.
 203 AC_SEARCH_LIBS([pow], [m])
 204
 205 # RPC is only needed for VXI support.
 206 AC_MSG_CHECKING([for RPC support])
 207 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 208                                 [CLIENT *rpc_test(void)],
 209                                 [{ return clnt_create("", 0, 0, ""); }])],
 210                [AC_MSG_RESULT([yes]); have_rpc=1],
 211                [AC_MSG_RESULT([no]);  have_rpc=0])
 212 # Define HAVE_RPC in config.h if we found RPC support.
 213 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 214 # VXI support is only compiled if RPC support was found.
 215 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 216
 217 # libglib-2.0 is always needed. Abort if it's not found.
 218 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 219 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 220 AM_PATH_GLIB_2_0([2.32.0],
 221         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 222
 223 # libzip is always needed. Abort if it's not found.
 224 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 225         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 226         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 227
 228 # libserialport is only needed for some hardware drivers. Disable the
 229 # respective drivers if it is not found.
 230 if test "x$enable_libserialport" != "xno"; then
 231         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.0],
 232                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 233                 LIBS="$LIBS $libserialport_LIBS";
 234                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 235                 [have_libserialport="no"])
 236         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 237                 AC_MSG_ERROR([libserialport support requested, but it was not found])
 238         fi
 239 else
 240         have_libserialport="no"
 241 fi
 242
 243 # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 244 if test "x$have_libserialport" = "xno"; then
 245         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 246         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 247         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 248         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 249         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 250         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 251         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 252 else
 253         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 254                 [Specifies whether we have libserialport.])
 255 fi
 256
 257 # Serial port helper code is only compiled in if libserialport was found.
 258 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 259
 260 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 261         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 262         LIBS="$LIBS $librevisa_LIBS";
 263         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 264         [have_librevisa="no"])
 265
 266 # VISA SCPI backend is only compiled in if librevisa was found.
 267 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 268
 269 # Define HAVE_LIBREVISA in config.h if we found librevisa.
 270 if test "x$have_librevisa" != "xno"; then
 271         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 272                 [Specifies whether we have librevisa.])
 273 fi
 274
 275 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 276 # drivers if it is not found.
 277 if test "x$enable_libusb" != "xno"; then
 278         case "$host" in
 279         *freebsd*)
 280                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 281                 # This means libusb-1.0 is always available, no need to check for it,
 282                 # and no need to (potentially) disable any drivers if it's not found.
 283                 have_libusb1_0="yes"
 284                 ;;
 285         *)
 286                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 287                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 288                         LIBS="$LIBS $libusb_LIBS";
 289                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 290                         [have_libusb1_0="no"])
 291                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 292                         AC_MSG_ERROR([libusb support requested, but it was not found])
 293                 fi
 294                 ;;
 295         esac
 296 else
 297         have_libusb1_0="no"
 298 fi
 299
 300 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 301 if test "x$have_libusb1_0" = "xno"; then
 302         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 303         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 304         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 305         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 306         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 307         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 308 else
 309         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 310                 [Specifies whether we have a libusb.h header.])
 311 fi
 312
 313 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 314 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 315
 316 # libftdi is only needed for some hardware drivers. Disable them if not found.
 317 if test "x$enable_libftdi" != "xno"; then
 318         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 319                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 320                 LIBS="$LIBS $libftdi_LIBS";
 321                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 322                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 323                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 324                         LIBS="$LIBS $libftdi1_LIBS";
 325                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 326                         [have_libftdi="no"])])
 327         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 328                 AC_MSG_ERROR([libftdi support requested, but it was not found])
 329         fi
 330 else
 331         have_libftdi="no"
 332 fi
 333
 334 if test "x$have_libftdi" = "xno"; then
 335         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 336 fi
 337
 338 # glibmm-2.4 is needed for the C++ bindings.
 339 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 340         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 341         CXXLIBS="$CXXLIBS $glibmm_LIBS"], [BINDINGS_CXX="no"])
 342
 343 # Python is needed for the Python bindings.
 344 PKG_CHECK_MODULES([python], [python3 >= 2.7],
 345         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 346         CXXLIBS="$CXXLIBS $python_LIBS"], [BINDINGS_PYTHON="no"])
 347
 348 # PyGObject is needed for the Python bindings.
 349 PKG_CHECK_MODULES([pygobject], [pygobject-3.0],
 350         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 351         CXXLIBS="$CXXLIBS $pygobject_LIBS"], [BINDINGS_PYTHON="no"])
 352
 353 # The Check unit testing framework is optional. Disable if not found.
 354 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 355         [have_check="yes"], [have_check="no"])
 356 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 357
 358 # The OLS driver uses serial port file descriptors directly, and therefore
 359 # will not currently work on Windows.
 360 case "$host" in
 361 *mingw*)
 362         HW_OPENBENCH_LOGIC_SNIFFER="no"
 363         ;;
 364 esac
 365
 366 AC_SUBST(SR_PKGLIBS)
 367
 368 CFLAGS="$CFLAGS -I./include/libsigrok $LIB_CFLAGS"
 369 CXXFLAGS="$CXXFLAGS -I./include -I./bindings/cxx/include $LIB_CFLAGS"
 370
 371 # Find Java compiler and JNI includes for Java bindings.
 372
 373 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 374
 375 if test "x$HAVE_JAVAC" = "xyes"; then
 376         AX_PROG_JAVAC
 377         AX_JNI_INCLUDE_DIR
 378         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 379                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 380         done
 381 else
 382         BINDINGS_JAVA="no"
 383 fi
 384
 385 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 386
 387 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 388 if test "x$HW_AGILENT_DMM" = "xyes"; then
 389         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 390 fi
 391
 392 AM_CONDITIONAL(HW_APPA_55II, test x$HW_APPA_55II = xyes)
 393 if test "x$HW_APPA_55II" = "xyes"; then
 394         AC_DEFINE(HAVE_HW_APPA_55II, 1, [APPA 55II support])
 395 fi
 396
 397 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 398 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 399         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 400 fi
 401
 402 AM_CONDITIONAL(HW_ATTEN_PPS3XXX, test x$HW_ATTEN_PPS3XXX = xyes)
 403 if test "x$HW_ATTEN_PPS3XXX" = "xyes"; then
 404         AC_DEFINE(HAVE_HW_ATTEN_PPS3XXX, 1, [Atten PPS3xxx support])
 405 fi
 406
 407 AM_CONDITIONAL(HW_BRYMEN_BM86X, test x$HW_BRYMEN_BM86X = xyes)
 408 if test "x$HW_BRYMEN_BM86X" = "xyes"; then
 409         AC_DEFINE(HAVE_HW_BRYMEN_BM86X, 1, [Brymen BM86X support])
 410 fi
 411
 412 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 413 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 414         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 415 fi
 416
 417 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 418 if test "x$HW_CEM_DT_885X" = "xyes"; then
 419         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 420 fi
 421
 422 AM_CONDITIONAL(HW_CENTER_3XX, test x$HW_CENTER_3XX = xyes)
 423 if test "x$HW_CENTER_3XX" = "xyes"; then
 424         AC_DEFINE(HAVE_HW_CENTER_3XX, 1, [Center 3xx support])
 425 fi
 426
 427 AM_CONDITIONAL(HW_CHRONOVU_LA, test x$HW_CHRONOVU_LA = xyes)
 428 if test "x$HW_CHRONOVU_LA" = "xyes"; then
 429         AC_DEFINE(HAVE_HW_CHRONOVU_LA, 1, [ChronoVu LA support])
 430 fi
 431
 432 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 433 if test "x$HW_COLEAD_SLM" = "xyes"; then
 434         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 435 fi
 436
 437 AM_CONDITIONAL(HW_CONRAD_DIGI_35_CPU, test x$HW_CONRAD_DIGI_35_CPU = xyes)
 438 if test "x$HW_CONRAD_DIGI_35_CPU" = "xyes"; then
 439         AC_DEFINE(HAVE_HW_CONRAD_DIGI_35_CPU, 1, [Conrad DIGI 35 CPU support])
 440 fi
 441
 442 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 443 if test "x$HW_DEMO" = "xyes"; then
 444         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 445 fi
 446
 447 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 448 if test "x$HW_FLUKE_DMM" = "xyes"; then
 449         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 450 fi
 451
 452 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 453 if test "x$HW_FX2LAFW" = "xyes"; then
 454         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 455 fi
 456
 457 AM_CONDITIONAL(HW_GMC_MH_1X_2X, test x$HW_GMC_MH_1X_2X = xyes)
 458 if test "x$HW_GMC_MH_1X_2X" = "xyes"; then
 459         AC_DEFINE(HAVE_HW_GMC_MH_1X_2X, 1, [gmc-mh-1x-2x support])
 460 fi
 461
 462 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 463 if test "x$HW_HANTEK_DSO" = "xyes"; then
 464         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 465 fi
 466
 467 AM_CONDITIONAL(HW_HAMEG_HMO, test x$HW_HAMEG_HMO = xyes)
 468 if test "x$HW_HAMEG_HMO" = "xyes"; then
 469         AC_DEFINE(HAVE_HW_HAMEG_HMO, 1, [Hameg HMO support])
 470 fi
 471
 472 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 473 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 474         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic-2 support])
 475 fi
 476
 477 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 478 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 479         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [IKALOGIC ScanaPLUS support])
 480 fi
 481
 482 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 483 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 484         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 485 fi
 486
 487 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 488 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 489         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 490 fi
 491
 492 AM_CONDITIONAL(HW_MANSON_HCS_3XXX, test x$HW_MANSON_HCS_3XXX = xyes)
 493 if test "x$HW_MANSON_HCS_3XXX" = "xyes"; then
 494         AC_DEFINE(HAVE_HW_MANSON_HCS_3XXX, 1, [Manson HCS-3xxx support])
 495 fi
 496
 497 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 498 if test "x$HW_MIC_985XX" = "xyes"; then
 499         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 500 fi
 501
 502 AM_CONDITIONAL(HW_MOTECH_LPS_30X, test x$HW_MOTECH_LPS_30X = xyes)
 503 if test "x$HW_MOTECH_LPS_30X" = "xyes"; then
 504         AC_DEFINE(HAVE_HW_MOTECH_LPS_30X, 1, [motech-lps-30x support])
 505 fi
 506
 507 AM_CONDITIONAL(HW_NORMA_DMM, test x$HW_NORMA_DMM = xyes)
 508 if test "x$HW_NORMA_DMM" = "xyes"; then
 509         AC_DEFINE(HAVE_HW_NORMA_DMM, 1, [Norma DMM support])
 510 fi
 511
 512 AM_CONDITIONAL(HW_OPENBENCH_LOGIC_SNIFFER, test x$HW_OPENBENCH_LOGIC_SNIFFER = xyes)
 513 if test "x$HW_OPENBENCH_LOGIC_SNIFFER" = "xyes"; then
 514         AC_DEFINE(HAVE_HW_OPENBENCH_LOGIC_SNIFFER, 1, [OpenBench Logic Sniffer (OLS) support])
 515 fi
 516
 517 AM_CONDITIONAL(HW_RIGOL_DS, test x$HW_RIGOL_DS = xyes)
 518 if test "x$HW_RIGOL_DS" = "xyes"; then
 519         AC_DEFINE(HAVE_HW_RIGOL_DS, 1, [Rigol DS support])
 520 fi
 521
 522 AM_CONDITIONAL(HW_SALEAE_LOGIC16, test x$HW_SALEAE_LOGIC16 = xyes)
 523 if test "x$HW_SALEAE_LOGIC16" = "xyes"; then
 524         AC_DEFINE(HAVE_HW_SALEAE_LOGIC16, 1, [Saleae Logic16 support])
 525 fi
 526
 527 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 528 if test "x$HW_SERIAL_DMM" = "xyes"; then
 529         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 530 fi
 531
 532 AM_CONDITIONAL(HW_SYSCLK_LWLA, test x$HW_SYSCLK_LWLA = xyes)
 533 if test "x$HW_SYSCLK_LWLA" = "xyes"; then
 534         AC_DEFINE(HAVE_HW_SYSCLK_LWLA, 1, [Sysclk LWLA support])
 535 fi
 536
 537 AM_CONDITIONAL(HW_TELEINFO, test x$HW_TELEINFO = xyes)
 538 if test "x$HW_TELEINFO" = "xyes"; then
 539         AC_DEFINE(HAVE_HW_TELEINFO, 1, [Teleinfo support])
 540 fi
 541
 542 AM_CONDITIONAL(HW_TESTO, test x$HW_TESTO = xyes)
 543 if test "x$HW_TESTO" = "xyes"; then
 544         AC_DEFINE(HAVE_HW_TESTO, 1, [Testo support])
 545 fi
 546
 547 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 548 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 549         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 550 fi
 551
 552 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 553 if test "x$HW_UNI_T_DMM" = "xyes"; then
 554         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 555 fi
 556
 557 AM_CONDITIONAL(HW_UNI_T_UT32X, test x$HW_UNI_T_UT32X = xyes)
 558 if test "x$HW_UNI_T_UT32X" = "xyes"; then
 559         AC_DEFINE(HAVE_HW_UNI_T_UT32X, 1, [UNI-T UT32x support])
 560 fi
 561
 562 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 563 if test "x$HW_VICTOR_DMM" = "xyes"; then
 564         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 565 fi
 566
 567 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 568 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 569         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 570 fi
 571
 572 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 573
 574 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 575
 576 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 577
 578 # Checks for header files.
 579 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 580
 581 # Checks for typedefs, structures, and compiler characteristics.
 582 AC_C_BIGENDIAN
 583
 584 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 585 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 586 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 587
 588 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 589 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 590 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 591 SR_PACKAGE_VERSION=sr_package_version
 592
 593 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 594 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 595 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 596 AC_SUBST(SR_PACKAGE_VERSION)
 597
 598 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 599         bindings/cxx/libsigrokxx.pc])
 600
 601 AC_OUTPUT
 602
 603 echo
 604 echo "libsigrok configuration summary:"
 605 echo
 606 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 607 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 608 echo "  - Prefix: $prefix"
 609 echo "  - Building on: $build"
 610 echo "  - Building for: $host"
 611 echo
 612 echo "Detected libraries:"
 613 echo
 614
 615 # Note: This only works for libs with pkg-config integration.
 616 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.0" "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" "libftdi1 >= 1.0" "check >= 0.9.4"; do
 617         optional="OPTIONAL"
 618         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 619         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 620         if `$PKG_CONFIG --exists $lib`; then
 621                 ver=`$PKG_CONFIG --modversion $lib`
 622                 answer="yes ($ver)"
 623         else
 624                 answer="no"
 625         fi
 626         echo "  - ($optional) $lib: $answer"
 627 done
 628
 629 echo -e "\nEnabled hardware drivers:\n${driver_summary}"
 630
 631 echo -e "\nEnabled language bindings:\n"
 632 echo "  - C++............................. $BINDINGS_CXX"
 633 echo "  - Python.......................... $BINDINGS_PYTHON"
 634 echo "  - Java............................ $BINDINGS_JAVA"
 635 echo