configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [3])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 # Library version for libsigrok (NOT the same as the package version).
  69 # Carefully read the libtool docs before updating these numbers!
  70 # The algorithm for determining which number to change (and how) is nontrivial!
  71 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  72 SR_LIB_VERSION_CURRENT=2
  73 SR_LIB_VERSION_REVISION=0
  74 SR_LIB_VERSION_AGE=0
  75 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  76 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  77 AC_SUBST(SR_LIB_VERSION_CURRENT)
  78 AC_SUBST(SR_LIB_VERSION_REVISION)
  79 AC_SUBST(SR_LIB_VERSION_AGE)
  80 AC_SUBST(SR_LIB_VERSION)
  81 AC_SUBST(SR_LIB_LDFLAGS)
  82
  83 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  84         [enable all drivers by default [default=yes]]),
  85         [HW_ENABLED_DEFAULT="$enableval"],
  86         [HW_ENABLED_DEFAULT="yes"])
  87
  88 # Usage: DRIVER([Device name], [driver-name])
  89 # An optional third argument [no] disables that driver.
  90 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
  91 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
  92 AC_DEFUN([DRIVER], [
  93         if test -z "$3"; then
  94                 default=$HW_ENABLED_DEFAULT
  95         else
  96                 default="$3"
  97         fi
  98         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
  99                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 100                 [m4_join([], [HW_], upperize([$2]))=$default])
 101         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 102         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 103 ])
 104
 105 DRIVER([Agilent DMM], [agilent-dmm])
 106 DRIVER([Appa 55II], [appa-55ii])
 107 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 108 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 109 DRIVER([BeagleLogic], [beaglelogic])
 110 DRIVER([Brymen BM86x], [brymen-bm86x])
 111 DRIVER([Brymen DMM], [brymen-dmm])
 112 DRIVER([CEM DT-885x], [cem-dt-885x])
 113 DRIVER([Center 3xx], [center-3xx])
 114 DRIVER([ChronoVu LA], [chronovu-la])
 115 DRIVER([Colead SLM], [colead-slm])
 116 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 117 DRIVER([demo], [demo])
 118 DRIVER([Fluke DMM], [fluke-dmm])
 119 DRIVER([fx2lafw], [fx2lafw])
 120 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 121 DRIVER([Hameg HMO], [hameg-hmo])
 122 DRIVER([Hantek DSO], [hantek-dso])
 123 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 124 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 125 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 126 DRIVER([Lascar EL-USB], [lascar-el-usb])
 127 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 128 DRIVER([MIC 985xx], [mic-985xx])
 129 DRIVER([Motech LPS 30x], [motech-lps-30x])
 130 DRIVER([Norma DMM], [norma-dmm])
 131 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 132 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 133 DRIVER([Rigol DS], [rigol-ds])
 134 DRIVER([Saleae Logic16], [saleae-logic16])
 135 DRIVER([serial DMM], [serial-dmm])
 136 DRIVER([Sysclk LWLA], [sysclk-lwla])
 137 DRIVER([Teleinfo], [teleinfo])
 138 DRIVER([Testo], [testo])
 139 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 140 DRIVER([UNI-T DMM], [uni-t-dmm])
 141 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 142 DRIVER([Victor DMM], [victor-dmm])
 143 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 144
 145 AC_ARG_ENABLE(libserialport,
 146         AC_HELP_STRING([--disable-libserialport],
 147         [disable libserialport support [default=detect]]))
 148
 149 AC_ARG_ENABLE(libftdi,
 150         AC_HELP_STRING([--disable-libftdi],
 151         [disable libftdi support [default=detect]]))
 152
 153 AC_ARG_ENABLE(libusb,
 154         AC_HELP_STRING([--disable-libusb],
 155         [disable libusb support [default=detect]]))
 156
 157 # Language binding '--enable' options
 158
 159 AC_ARG_ENABLE(bindings,
 160         AC_HELP_STRING([--enable-bindings],
 161         [build language bindings [default=yes]]),
 162         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 163
 164 AC_ARG_ENABLE(cxx,
 165         AC_HELP_STRING([--enable-cxx],
 166         [build C++ bindings [default=yes]]),
 167         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 168
 169 AC_ARG_ENABLE(python,
 170         AC_HELP_STRING([--enable-python],
 171         [build Python bindings [default=yes]]),
 172         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 173
 174 AC_ARG_ENABLE(java,
 175         AC_HELP_STRING([--enable-java],
 176         [build Java bindings [default=yes]]),
 177         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 178
 179 AC_ARG_WITH(jni-include-path,
 180         AC_HELP_STRING([--with-jni-include-path=path],
 181         [specify include path for JNI [default=autodetect]]),
 182         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 183
 184 # Check if the C++ compiler supports the C++11 standard.
 185
 186 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 187         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 188
 189 if test "x$HAVE_CXX11" != "x1"; then
 190         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 191 fi
 192
 193 # The C++ bindings use doxygen to parse libsigrok symbols.
 194 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 195 if test "x$HAVE_DOXYGEN" != "xyes"; then
 196         BINDINGS_CXX="no"; cxx_msg="doxygen required"
 197 fi
 198
 199 # Python is needed for the C++ bindings.
 200 AC_CHECK_PROG([HAVE_PYTHON], [python], [yes])
 201 if test "x$HAVE_PYTHON" != "xyes"; then
 202         BINDINGS_CXX="no"; cxx_msg="Python required"
 203 fi
 204
 205 # The Python bindings need Python development files
 206 PKG_CHECK_MODULES([python], [python >= 2.7],
 207         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 208         CXXLIBS="$CXXLIBS $python_LIBS"],
 209 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 210         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 211         CXXLIBS="$CXXLIBS $python27_LIBS"],
 212                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 213
 214 # The Python bindings need the setuptools Python module.
 215 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 216         # We'll let it go through even if the macro wasn't found, the python
 217         # module may still be there.
 218         [HAVE_PYTHON_SETUPTOOLS="yes";
 219                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 220 )
 221 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 222         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 223 fi
 224
 225 # The Python and Java bindings use swig to generate code.
 226 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 227 if test "x$HAVE_SWIG" != "xyes"; then
 228         BINDINGS_PYTHON="no"; python_msg="swig required"
 229         BINDINGS_JAVA="no"; java_msg="swig required"
 230 fi
 231
 232 # Checks for libraries.
 233
 234 case "$host" in
 235 *mingw*)
 236         # We need to link against the Winsock2 library for SCPI over TCP.
 237         LIBS="$LIBS -lws2_32";;
 238 esac
 239
 240 # This variable collects the pkg-config names of all detected libs.
 241 # It is then used to construct the "Requires.private:" field in the
 242 # libsigrok.pc file.
 243 SR_PKGLIBS=""
 244
 245 # libm (the standard math library) is always needed.
 246 AC_SEARCH_LIBS([pow], [m])
 247
 248 # RPC is only needed for VXI support.
 249 AC_MSG_CHECKING([for RPC support])
 250 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 251                                 [CLIENT *rpc_test(void)],
 252                                 [{ return clnt_create("", 0, 0, ""); }])],
 253                [AC_MSG_RESULT([yes]); have_rpc=1],
 254                [AC_MSG_RESULT([no]);  have_rpc=0])
 255 # Define HAVE_RPC in config.h if we found RPC support.
 256 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 257 # VXI support is only compiled if RPC support was found.
 258 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 259
 260 # libglib-2.0 is always needed. Abort if it's not found.
 261 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 262 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 263 AM_PATH_GLIB_2_0([2.32.0],
 264         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 265
 266 # libzip is always needed. Abort if it's not found.
 267 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 268         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 269         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 270
 271 # libserialport is only needed for some hardware drivers. Disable the
 272 # respective drivers if it is not found.
 273 if test "x$enable_libserialport" != "xno"; then
 274         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.2.0],
 275                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 276                 LIBS="$LIBS $libserialport_LIBS";
 277                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 278                 [have_libserialport="no"])
 279         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 280                 AC_MSG_ERROR([libserialport support requested, but it was not found])
 281         fi
 282 else
 283         have_libserialport="no"
 284 fi
 285
 286 # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 287 if test "x$have_libserialport" = "xno"; then
 288         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 289         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 290         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 291         HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no"; HW_HAMEG_HMO="no";
 292         HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no"; HW_MOTECH_LPS_30X="no";
 293         HW_NORMA_DMM="no"; HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 294         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 295 else
 296         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 297                 [Specifies whether we have libserialport.])
 298 fi
 299
 300 # Serial port helper code is only compiled in if libserialport was found.
 301 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 302
 303 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130812],
 304         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 305         LIBS="$LIBS $librevisa_LIBS";
 306         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 307         [have_librevisa="no"])
 308
 309 # VISA SCPI backend is only compiled in if librevisa was found.
 310 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 311
 312 # Define HAVE_LIBREVISA in config.h if we found librevisa.
 313 if test "x$have_librevisa" != "xno"; then
 314         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 315                 [Specifies whether we have librevisa.])
 316 fi
 317
 318 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 319 # drivers if it is not found.
 320 if test "x$enable_libusb" != "xno"; then
 321         case "$host" in
 322         *freebsd*)
 323                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 324                 # This means libusb-1.0 is always available, no need to check for it,
 325                 # and no need to (potentially) disable any drivers if it's not found.
 326                 have_libusb1_0="yes"
 327                 ;;
 328         *)
 329                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 330                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 331                         LIBS="$LIBS $libusb_LIBS";
 332                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 333                         [have_libusb1_0="no"])
 334                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 335                         AC_MSG_ERROR([libusb support requested, but it was not found])
 336                 fi
 337                 ;;
 338         esac
 339 else
 340         have_libusb1_0="no"
 341 fi
 342
 343 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 344 if test "x$have_libusb1_0" = "xno"; then
 345         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 346         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 347         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 348         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 349         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 350         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 351 else
 352         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 353                 [Specifies whether we have a libusb.h header.])
 354 fi
 355
 356 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 357 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 358
 359 # libftdi is only needed for some hardware drivers. Disable them if not found.
 360 if test "x$enable_libftdi" != "xno"; then
 361         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 362                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 363                 LIBS="$LIBS $libftdi_LIBS";
 364                 SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 365                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 366                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 367                         LIBS="$LIBS $libftdi1_LIBS";
 368                         SR_PKGLIBS="$SR_PKGLIBS libftdi1"],
 369                         [have_libftdi="no"])])
 370         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 371                 AC_MSG_ERROR([libftdi support requested, but it was not found])
 372         fi
 373 else
 374         have_libftdi="no"
 375 fi
 376
 377 if test "x$have_libftdi" = "xno"; then
 378         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 379         HW_PIPISTRELLO_OLS="no";
 380 fi
 381
 382 # glibmm-2.4 is needed for the C++ bindings.
 383 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 384         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 385         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 386         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 387
 388 # PyGObject is needed for the Python bindings.
 389 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 390         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 391         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 392         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 393                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 394         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 395                 [Whether last argument to pyg_flags_get_value() is signed])],
 396         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 397
 398 # The Check unit testing framework is optional. Disable if not found.
 399 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 400         [have_check="yes"], [have_check="no"])
 401 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 402
 403 # The OLS driver uses serial port file descriptors directly, and therefore
 404 # will not currently work on Windows.
 405 case "$host" in
 406 *mingw*)
 407         HW_OPENBENCH_LOGIC_SNIFFER="no"
 408         ;;
 409 esac
 410
 411 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 412 # build it if these headers aren't available.
 413 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 414
 415 AC_SUBST(SR_PKGLIBS)
 416
 417 CFLAGS="$CFLAGS -Iinclude/libsigrok -I${srcdir}/include/libsigrok $LIB_CFLAGS"
 418 CXXFLAGS="$CXXFLAGS -Iinclude/libsigrok -I${srcdir}/include -Ibindings/cxx -Ibindings/cxx/include/libsigrok -I${srcdir}/bindings/cxx/include $LIB_CFLAGS"
 419
 420 # Find Java compiler and JNI includes for Java bindings.
 421
 422 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 423
 424 if test "x$HAVE_JAVAC" = "xyes"; then
 425         AX_PROG_JAVAC
 426         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 427                 if test "x$cross_compiling" = "xyes"; then
 428                         JNI_INCLUDE_DIRS=
 429                 else
 430                         AX_JNI_INCLUDE_DIR
 431                 fi
 432         fi
 433         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 434                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 435         done
 436         AC_LANG_PUSH([C++])
 437         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 438         AC_LANG_POP([C++])
 439 else
 440         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 441 fi
 442
 443 # Python and Java bindings depend on C++ bindings.
 444 if test "x$BINDINGS_CXX" != "xyes"; then
 445         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 446         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 447 fi
 448
 449 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 450
 451 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 452 if test "x$HW_AGILENT_DMM" = "xyes"; then
 453         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 454 fi
 455
 456 AM_CONDITIONAL(HW_APPA_55II, test x$HW_APPA_55II = xyes)
 457 if test "x$HW_APPA_55II" = "xyes"; then
 458         AC_DEFINE(HAVE_HW_APPA_55II, 1, [APPA 55II support])
 459 fi
 460
 461 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 462 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 463         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 464 fi
 465
 466 AM_CONDITIONAL(HW_ATTEN_PPS3XXX, test x$HW_ATTEN_PPS3XXX = xyes)
 467 if test "x$HW_ATTEN_PPS3XXX" = "xyes"; then
 468         AC_DEFINE(HAVE_HW_ATTEN_PPS3XXX, 1, [Atten PPS3xxx support])
 469 fi
 470
 471 AM_CONDITIONAL(HW_BEAGLELOGIC, test x$HW_BEAGLELOGIC = xyes)
 472 if test "x$HW_BEAGLELOGIC" = "xyes"; then
 473         AC_DEFINE(HAVE_HW_BEAGLELOGIC, 1, [BeagleLogic support])
 474 fi
 475
 476 AM_CONDITIONAL(HW_BRYMEN_BM86X, test x$HW_BRYMEN_BM86X = xyes)
 477 if test "x$HW_BRYMEN_BM86X" = "xyes"; then
 478         AC_DEFINE(HAVE_HW_BRYMEN_BM86X, 1, [Brymen BM86X support])
 479 fi
 480
 481 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 482 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 483         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 484 fi
 485
 486 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 487 if test "x$HW_CEM_DT_885X" = "xyes"; then
 488         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 489 fi
 490
 491 AM_CONDITIONAL(HW_CENTER_3XX, test x$HW_CENTER_3XX = xyes)
 492 if test "x$HW_CENTER_3XX" = "xyes"; then
 493         AC_DEFINE(HAVE_HW_CENTER_3XX, 1, [Center 3xx support])
 494 fi
 495
 496 AM_CONDITIONAL(HW_CHRONOVU_LA, test x$HW_CHRONOVU_LA = xyes)
 497 if test "x$HW_CHRONOVU_LA" = "xyes"; then
 498         AC_DEFINE(HAVE_HW_CHRONOVU_LA, 1, [ChronoVu LA support])
 499 fi
 500
 501 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 502 if test "x$HW_COLEAD_SLM" = "xyes"; then
 503         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 504 fi
 505
 506 AM_CONDITIONAL(HW_CONRAD_DIGI_35_CPU, test x$HW_CONRAD_DIGI_35_CPU = xyes)
 507 if test "x$HW_CONRAD_DIGI_35_CPU" = "xyes"; then
 508         AC_DEFINE(HAVE_HW_CONRAD_DIGI_35_CPU, 1, [Conrad DIGI 35 CPU support])
 509 fi
 510
 511 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 512 if test "x$HW_DEMO" = "xyes"; then
 513         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 514 fi
 515
 516 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 517 if test "x$HW_FLUKE_DMM" = "xyes"; then
 518         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 519 fi
 520
 521 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 522 if test "x$HW_FX2LAFW" = "xyes"; then
 523         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 524 fi
 525
 526 AM_CONDITIONAL(HW_GMC_MH_1X_2X, test x$HW_GMC_MH_1X_2X = xyes)
 527 if test "x$HW_GMC_MH_1X_2X" = "xyes"; then
 528         AC_DEFINE(HAVE_HW_GMC_MH_1X_2X, 1, [gmc-mh-1x-2x support])
 529 fi
 530
 531 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 532 if test "x$HW_HANTEK_DSO" = "xyes"; then
 533         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 534 fi
 535
 536 AM_CONDITIONAL(HW_HAMEG_HMO, test x$HW_HAMEG_HMO = xyes)
 537 if test "x$HW_HAMEG_HMO" = "xyes"; then
 538         AC_DEFINE(HAVE_HW_HAMEG_HMO, 1, [Hameg HMO support])
 539 fi
 540
 541 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 542 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 543         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic-2 support])
 544 fi
 545
 546 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 547 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 548         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [IKALOGIC ScanaPLUS support])
 549 fi
 550
 551 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 552 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 553         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 554 fi
 555
 556 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 557 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 558         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 559 fi
 560
 561 AM_CONDITIONAL(HW_MANSON_HCS_3XXX, test x$HW_MANSON_HCS_3XXX = xyes)
 562 if test "x$HW_MANSON_HCS_3XXX" = "xyes"; then
 563         AC_DEFINE(HAVE_HW_MANSON_HCS_3XXX, 1, [Manson HCS-3xxx support])
 564 fi
 565
 566 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 567 if test "x$HW_MIC_985XX" = "xyes"; then
 568         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 569 fi
 570
 571 AM_CONDITIONAL(HW_MOTECH_LPS_30X, test x$HW_MOTECH_LPS_30X = xyes)
 572 if test "x$HW_MOTECH_LPS_30X" = "xyes"; then
 573         AC_DEFINE(HAVE_HW_MOTECH_LPS_30X, 1, [motech-lps-30x support])
 574 fi
 575
 576 AM_CONDITIONAL(HW_NORMA_DMM, test x$HW_NORMA_DMM = xyes)
 577 if test "x$HW_NORMA_DMM" = "xyes"; then
 578         AC_DEFINE(HAVE_HW_NORMA_DMM, 1, [Norma DMM support])
 579 fi
 580
 581 AM_CONDITIONAL(HW_OPENBENCH_LOGIC_SNIFFER, test x$HW_OPENBENCH_LOGIC_SNIFFER = xyes)
 582 if test "x$HW_OPENBENCH_LOGIC_SNIFFER" = "xyes"; then
 583         AC_DEFINE(HAVE_HW_OPENBENCH_LOGIC_SNIFFER, 1, [OpenBench Logic Sniffer (OLS) support])
 584 fi
 585
 586 AM_CONDITIONAL(HW_PIPISTRELLO_OLS, test x$HW_PIPISTRELLO_OLS = xyes)
 587 if test "x$HW_PIPISTRELLO_OLS" = "xyes"; then
 588         AC_DEFINE(HAVE_HW_PIPISTRELLO_OLS, 1, [Pipistrello OLS support])
 589 fi
 590
 591 AM_CONDITIONAL(HW_RIGOL_DS, test x$HW_RIGOL_DS = xyes)
 592 if test "x$HW_RIGOL_DS" = "xyes"; then
 593         AC_DEFINE(HAVE_HW_RIGOL_DS, 1, [Rigol DS support])
 594 fi
 595
 596 AM_CONDITIONAL(HW_SALEAE_LOGIC16, test x$HW_SALEAE_LOGIC16 = xyes)
 597 if test "x$HW_SALEAE_LOGIC16" = "xyes"; then
 598         AC_DEFINE(HAVE_HW_SALEAE_LOGIC16, 1, [Saleae Logic16 support])
 599 fi
 600
 601 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 602 if test "x$HW_SERIAL_DMM" = "xyes"; then
 603         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 604 fi
 605
 606 AM_CONDITIONAL(HW_SYSCLK_LWLA, test x$HW_SYSCLK_LWLA = xyes)
 607 if test "x$HW_SYSCLK_LWLA" = "xyes"; then
 608         AC_DEFINE(HAVE_HW_SYSCLK_LWLA, 1, [Sysclk LWLA support])
 609 fi
 610
 611 AM_CONDITIONAL(HW_TELEINFO, test x$HW_TELEINFO = xyes)
 612 if test "x$HW_TELEINFO" = "xyes"; then
 613         AC_DEFINE(HAVE_HW_TELEINFO, 1, [Teleinfo support])
 614 fi
 615
 616 AM_CONDITIONAL(HW_TESTO, test x$HW_TESTO = xyes)
 617 if test "x$HW_TESTO" = "xyes"; then
 618         AC_DEFINE(HAVE_HW_TESTO, 1, [Testo support])
 619 fi
 620
 621 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 622 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 623         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 624 fi
 625
 626 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 627 if test "x$HW_UNI_T_DMM" = "xyes"; then
 628         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 629 fi
 630
 631 AM_CONDITIONAL(HW_UNI_T_UT32X, test x$HW_UNI_T_UT32X = xyes)
 632 if test "x$HW_UNI_T_UT32X" = "xyes"; then
 633         AC_DEFINE(HAVE_HW_UNI_T_UT32X, 1, [UNI-T UT32x support])
 634 fi
 635
 636 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 637 if test "x$HW_VICTOR_DMM" = "xyes"; then
 638         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 639 fi
 640
 641 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 642 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 643         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 644 fi
 645
 646 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 647
 648 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 649
 650 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 651
 652 # Checks for header files.
 653 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 654 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 655
 656 # Checks for typedefs, structures, and compiler characteristics.
 657 AC_C_BIGENDIAN
 658
 659 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 660 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 661 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 662
 663 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 664 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 665 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 666 SR_PACKAGE_VERSION=sr_package_version
 667
 668 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 669 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 670 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 671 AC_SUBST(SR_PACKAGE_VERSION)
 672
 673 AC_CONFIG_FILES([Makefile include/libsigrok/version.h libsigrok.pc
 674         bindings/cxx/libsigrokxx.pc])
 675
 676 AC_OUTPUT
 677
 678 echo
 679 echo "libsigrok configuration summary:"
 680 echo
 681 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 682 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 683 echo "  - Prefix: $prefix"
 684 echo "  - Building on: $build"
 685 echo "  - Building for: $host"
 686 echo
 687 echo "Detected libraries:"
 688 echo
 689
 690 # Note: This only works for libs with pkg-config integration.
 691 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.2.0" "librevisa >= 0.0.20130812" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" "libftdi1 >= 1.0" "glibmm-2.4 >= 2.32.0" "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"; do
 692         optional="OPTIONAL"
 693         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 694         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 695         if `$PKG_CONFIG --exists $lib`; then
 696                 ver=`$PKG_CONFIG --modversion $lib`
 697                 answer="yes ($ver)"
 698         else
 699                 answer="no"
 700         fi
 701         echo "  - ($optional) $lib: $answer"
 702 done
 703
 704 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 705
 706 # Prepare final bindings report messages
 707 final_cxx=""
 708 final_python=""
 709 final_java=""
 710 if test "$enable_bindings" = "no"; then
 711         final_cxx=" (disabled)"
 712         final_python=" (disabled)"
 713         final_java=" (disabled)"
 714 else
 715         if test "$enable_cxx" = "no"; then
 716                 final_cxx=" (disabled)"
 717         elif test "$BINDINGS_CXX" = "no"; then
 718                 final_cxx=" ($cxx_msg)"
 719         fi
 720         if test "$enable_python" = "no"; then
 721                 final_python=" (disabled)"
 722         elif test "$BINDINGS_PYTHON" = "no"; then
 723                 final_python=" ($python_msg)"
 724         fi
 725         if test "$enable_java" = "no"; then
 726                 final_java=" (disabled)"
 727         elif test "$BINDINGS_JAVA" = "no"; then
 728                 final_java=" ($java_msg)"
 729         fi
 730 fi
 731
 732 echo -e "Enabled language bindings:\n"
 733 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 734 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 735 echo " - Java............................ $BINDINGS_JAVA$final_java"
 736 echo