configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 3 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 # libsigrok package version number (NOT the same as shared lib version!).
  24 m4_define([libsigrok_major_version], [0])
  25 m4_define([libsigrok_minor_version], [2])
  26 m4_define([libsigrok_micro_version], [0])
  27 m4_define([libsigrok_version], [libsigrok_major_version.libsigrok_minor_version.libsigrok_micro_version])
  28
  29 AC_INIT([libsigrok], [libsigrok_version], [sigrok-devel@lists.sourceforge.net],
  30         [libsigrok], [http://www.sigrok.org])
  31 AC_CONFIG_HEADER([config.h])
  32 AC_CONFIG_MACRO_DIR([autostuff])
  33 AC_CONFIG_AUX_DIR([autostuff])
  34
  35 # We require at least automake 1.11 (needed for 'silent rules').
  36 AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign std-options])
  37 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  38
  39 AH_TOP([#ifndef LIBSIGROK_CONFIG_H
  40 #define LIBSIGROK_CONFIG_H    /* To stop multiple inclusions. */])
  41 AH_BOTTOM([#endif /* LIBSIGROK_CONFIG_H */])
  42
  43 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  44 # and enforce use of SR_API to explicitly mark all public API functions.
  45 CFLAGS="-g -Wall -Wextra -fvisibility=hidden"
  46
  47 # Checks for programs.
  48 AC_PROG_CXX
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Initialize libtool.
  55 LT_INIT
  56
  57 # Initialize pkg-config.
  58 # We require at least 0.22, as "Requires.private" behaviour changed there.
  59 PKG_PROG_PKG_CONFIG([0.22])
  60
  61 # Library version for libsigrok (NOT the same as the package version).
  62 # Carefully read the libtool docs before updating these numbers!
  63 # The algorithm for determining which number to change (and how) is nontrivial!
  64 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  65 LIBSIGROK_LT_CURRENT=0
  66 LIBSIGROK_LT_REVISION=0
  67 LIBSIGROK_LT_AGE=0
  68 LIBSIGROK_LT_VERSION="$LIBSIGROK_LT_CURRENT:$LIBSIGROK_LT_REVISION:$LIBSIGROK_LT_AGE"
  69 LIBSIGROK_LT_LDFLAGS="-version-info $LIBSIGROK_LT_VERSION"
  70 AC_SUBST(LIBSIGROK_LT_LDFLAGS)
  71
  72 # Logic analyzer hardware support '--enable' options.
  73
  74 # Disabled by default, unfinished.
  75 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  76               [enable ALSA driver support [default=no]]),
  77               [LA_ALSA="$enableval"],
  78               [LA_ALSA=no])
  79 AM_CONDITIONAL(LA_ALSA, test x$LA_ALSA = xyes)
  80 if test "x$LA_ALSA" = "xyes"; then
  81         AC_DEFINE(HAVE_LA_ALSA, 1, [ALSA driver support])
  82 fi
  83
  84 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  85               [enable ASIX Sigma support [default=yes]]),
  86               [LA_ASIX_SIGMA="$enableval"],
  87               [LA_ASIX_SIGMA=yes])
  88 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
  89 if test "x$LA_ASIX_SIGMA" = "xyes"; then
  90         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX Sigma support])
  91 fi
  92
  93 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
  94               [enable ChronoVu LA8 support [default=yes]]),
  95               [LA_CHRONOVU_LA8="$enableval"],
  96               [LA_CHRONOVU_LA8=yes])
  97 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
  98 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
  99         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 100 fi
 101
 102 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 103               [enable demo driver support [default=yes]]),
 104               [LA_DEMO="$enableval"],
 105               [LA_DEMO=yes])
 106 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 107 if test "x$LA_DEMO" = "xyes"; then
 108         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 109 fi
 110
 111 # Disabled by default, unfinished.
 112 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 113               [enable Link Instruments MSO-19 support [default=no]]),
 114               [LA_LINK_MSO19="$enableval"],
 115               [LA_LINK_MSO19=no])
 116 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 117 if test "x$LA_LINK_MSO19" = "xyes"; then
 118         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 119 fi
 120
 121 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 122               [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 123               [LA_OLS="$enableval"],
 124               [LA_OLS=yes])
 125 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 126 if test "x$LA_OLS" = "xyes"; then
 127         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 128 fi
 129
 130 AC_ARG_ENABLE(saleae-logic, AC_HELP_STRING([--enable-saleae-logic],
 131               [enable Saleae Logic support [default=yes]]),
 132               [LA_SALEAE_LOGIC="$enableval"],
 133               [LA_SALEAE_LOGIC=yes])
 134 AM_CONDITIONAL(LA_SALEAE_LOGIC, test x$LA_SALEAE_LOGIC = xyes)
 135 if test "x$LA_SALEAE_LOGIC" = "xyes"; then
 136         AC_DEFINE(HAVE_LA_SALEAE_LOGIC, 1, [Saleae Logic support])
 137 fi
 138
 139 AC_ARG_ENABLE(zeroplus-logic-cube,
 140               AC_HELP_STRING([--enable-zeroplus-logic-cube],
 141               [enable Zeroplus Logic Cube support [default=yes]]),
 142               [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 143               [LA_ZEROPLUS_LOGIC_CUBE=yes])
 144 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 145 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 146         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [Zeroplus Logic Cube support])
 147 fi
 148
 149 # Checks for libraries.
 150
 151 # This variable collects the pkg-config names of all detected libs.
 152 # It is then used to construct the "Requires.private:" field in the
 153 # libsigrok.pc file.
 154 LIBSIGROK_PKGLIBS=""
 155
 156 # libglib-2.0 is always needed.
 157 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 158 AM_PATH_GLIB_2_0([2.22.0],
 159         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 160
 161 # libgthread-2.0 is always needed (e.g. for the demo hardware driver).
 162 PKG_CHECK_MODULES([gthread], [gthread-2.0 >= 2.22.0],
 163         [CFLAGS="$CFLAGS $gthread_CFLAGS"; LIBS="$LIBS $gthread_LIBS";
 164         LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS gthread-2.0"])
 165
 166 # libusb is only needed for some hardware drivers.
 167 if test "x$LA_SALEAE_LOGIC" != xno \
 168    -o "x$LA_ASIX_SIGMA" != xno \
 169    -o "x$LA_CHRONOVU_LA8" != xno \
 170    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 171         case "$build" in
 172         *freebsd*)
 173                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 174                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 175                         [Specifies whether we have a libusb.h header.])
 176                 ;;
 177         *)
 178                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.5],
 179                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 180                         LIBS="$LIBS $libusb_LIBS";
 181                         LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS libusb-1.0"])
 182                 AC_CHECK_LIB(usb-1.0, libusb_init)
 183                 ;;
 184         esac
 185 fi
 186
 187 # libzip is always needed.
 188 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 189         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 190         LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS libzip"])
 191
 192 # zlib is only needed for some hardware drivers.
 193 if test "x$LA_ASIX_SIGMA" != xno; then
 194         case "$build" in
 195         *freebsd*)
 196                 # FreeBSD has zlib, but no pkg-config file for it.
 197                 # Check manually, and do NOT add it to LIBSIGROK_PKGLIBS.
 198                 AC_CHECK_LIB(z, uncompress)
 199                 ;;
 200         *)
 201                 PKG_CHECK_MODULES([zlib], [zlib >= 1.2.3.1],
 202                         [CFLAGS="$CFLAGS $zlib_CFLAGS"; LIBS="$LIBS $zlib_LIBS";
 203                         LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS zlib"])
 204                 ;;
 205         esac
 206 fi
 207
 208 # libftdi is only needed for some hardware drivers.
 209 if test "x$LA_ASIX_SIGMA" != xno \
 210      -o "x$LA_CHRONOVU_LA8" != xno; then
 211         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 212                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 213                 LIBS="$LIBS $libftdi_LIBS";
 214                 LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS libftdi"])
 215 fi
 216
 217 # libudev is only needed for some hardware drivers.
 218 if test "x$LA_LINK_MSO19" != xno; then
 219         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 220                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 221                 LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS libudev"])
 222 fi
 223
 224 # ALSA is only needed for some hardware drivers.
 225 if test "x$LA_ALSA" != xno; then
 226         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 227                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 228                 LIBSIGROK_PKGLIBS="$LIBSIGROK_PKGLIBS alsa"])
 229 fi
 230
 231 AC_SUBST(LIBSIGROK_PKGLIBS)
 232
 233 # Checks for header files.
 234 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 235 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 236
 237 # Checks for typedefs, structures, and compiler characteristics.
 238 AC_C_INLINE
 239 AC_TYPE_INT8_T
 240 AC_TYPE_INT16_T
 241 AC_TYPE_INT32_T
 242 AC_TYPE_INT64_T
 243 AC_TYPE_UINT8_T
 244 AC_TYPE_UINT16_T
 245 AC_TYPE_UINT32_T
 246 AC_TYPE_UINT64_T
 247 AC_TYPE_SIZE_T
 248
 249 # Checks for library functions.
 250 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 251
 252 AC_SUBST(FIRMWARE_DIR, "$datadir/libsigrok/firmware")
 253 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 254 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 255
 256 LIBSIGROK_MAJOR_VERSION=libsigrok_major_version
 257 LIBSIGROK_MINOR_VERSION=libsigrok_minor_version
 258 LIBSIGROK_MICRO_VERSION=libsigrok_micro_version
 259 LIBSIGROK_VERSION=libsigrok_version
 260
 261 AC_SUBST(LIBSIGROK_MAJOR_VERSION)
 262 AC_SUBST(LIBSIGROK_MINOR_VERSION)
 263 AC_SUBST(LIBSIGROK_MICRO_VERSION)
 264 AC_SUBST(LIBSIGROK_VERSION)
 265
 266 AC_DEFINE(LIBSIGROK_MAJOR_VERSION, [libsigrok_major_version],
 267           [Define to the libsigrok major package version])
 268 AC_DEFINE(LIBSIGROK_MINOR_VERSION, [libsigrok_minor_version],
 269           [Define to the libsigrok minor package version])
 270 AC_DEFINE(LIBSIGROK_MICRO_VERSION, [libsigrok_micro_version],
 271           [Define to the libsigrok micro package version])
 272 AC_DEFINE(LIBSIGROK_VERSION, [libsigrok_version],
 273           [Define to the libsigrok package version])
 274
 275 AC_CONFIG_FILES([Makefile
 276                  firmware/Makefile
 277                  hardware/Makefile
 278                  hardware/alsa/Makefile
 279                  hardware/asix-sigma/Makefile
 280                  hardware/chronovu-la8/Makefile
 281                  hardware/common/Makefile
 282                  hardware/demo/Makefile
 283                  hardware/link-mso19/Makefile
 284                  hardware/openbench-logic-sniffer/Makefile
 285                  hardware/saleae-logic/Makefile
 286                  hardware/zeroplus-logic-cube/Makefile
 287                  input/Makefile
 288                  output/Makefile
 289                  output/text/Makefile
 290                  libsigrok.pc
 291                  contrib/Makefile
 292                 ])
 293
 294 AC_OUTPUT
 295
 296 echo
 297 echo "libsigrok configuration summary:"
 298 echo
 299 echo "  - Package version (major.minor.micro):    $LIBSIGROK_VERSION"
 300 echo "  - Library version (current:revision:age): $LIBSIGROK_LT_VERSION"
 301 echo "  - Prefix: $prefix"
 302 echo
 303 echo "Detected libraries:"
 304 echo
 305
 306 # Note: This only works for libs with pkg-config integration.
 307 for lib in "glib-2.0" "gthread-2.0" "libusb-1.0" "libzip" "zlib" "libftdi" "libudev" "alsa"; do
 308         if `$PKG_CONFIG --exists $lib`; then
 309                 ver=`$PKG_CONFIG --modversion $lib`
 310                 answer="yes ($ver)"
 311         else
 312                 answer="no"
 313         fi
 314         echo "  - $lib: $answer"
 315 done
 316
 317 echo
 318 echo "Enabled hardware drivers:"
 319 echo
 320 echo "  - ASIX SIGMA...................... $LA_ASIX_SIGMA"
 321 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 322 echo "  - Demo driver..................... $LA_DEMO"
 323 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 324 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 325 echo "  - Saleae Logic.................... $LA_SALEAE_LOGIC"
 326 echo "  - Zeroplus Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 327 echo
 328