configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45
  46 # Required for per-target flags or subdir-objects with C sources.
  47 AM_PROG_CC_C_O
  48
  49 # Initialize libtool.
  50 LT_INIT
  51
  52 # Set up the libsigrok version defines.
  53 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  54
  55 # Library version for libsigrok (NOT the same as the package version).
  56 # Carefully read the libtool docs before updating these numbers!
  57 # The algorithm for determining which number to change (and how) is nontrivial!
  58 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  59 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  60
  61 #############################
  62 ##  Optional dependencies  ##
  63 #############################
  64
  65 # Initialize pkg-config.
  66 # We require at least 0.22, as "Requires.private" behaviour changed there.
  67 PKG_PROG_PKG_CONFIG([0.22])
  68
  69 # Keep track of all checked modules so we can list them at the end.
  70 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  71
  72 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  73 # These are used to derive the compiler flags and for the "Requires.private"
  74 # field in the generated libsigrok.pc file.
  75 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  76 SR_PKGLIBS_TESTS=
  77 SR_PKGLIBS_CXX=
  78 SR_PKGLIBS_PYTHON=
  79
  80 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  81         [libserialport >= 0.1.1])
  82
  83 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  84         [libftdi1 >= 1.0], [libftdi >= 0.16])
  85
  86 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  87 # This means libusb-1.0 is always available; no need to check for it.
  88 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
  89
  90 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
  91         [libusb-1.0 >= 1.0.16])
  92
  93 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
  94         [librevisa >= 0.0.20130412])
  95
  96 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
  97         [libgpib])
  98
  99 ######################
 100 ##  Feature checks  ##
 101 ######################
 102
 103 # The Check unit testing framework is optional. Disable if not found.
 104 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 105 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 106
 107 AC_LANG([C])
 108
 109 # Enable the C99 standard if possible, and enforce the use
 110 # of SR_API to explicitly mark all public API functions.
 111 SR_EXTRA_CFLAGS=
 112 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 113 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 114
 115 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 116
 117 # Check host characteristics.
 118 AC_SYS_LARGEFILE
 119 AC_C_BIGENDIAN
 120
 121 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 122 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 123 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 124
 125 # We need to link against the Winsock2 library for SCPI over TCP.
 126 AS_CASE([$host], [*-mingw*], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=])
 127
 128 # libm (the standard math library) is always needed.
 129 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 130
 131 # RPC is only needed for VXI support.
 132 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 133         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 134                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 135                         [[(void) clnt_create("", 0, 0, "");]])],
 136                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 137 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 138         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 139 # VXI support is only compiled if RPC support was found.
 140 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 141
 142 ########################
 143 ##  Hardware drivers  ##
 144 ########################
 145
 146 # Keep track of all drivers so we can list them at the end.
 147 SR_VAR_SUMMARY([sr_driver_summary])
 148
 149 # Check whether the sr_deps_avail list contains all of the arguments.
 150 # Unavailable dependencies are collected in sr_deps_missing.
 151 sr_check_driver_deps() {
 152         sr_deps_missing=
 153         for sr_dep
 154         do
 155                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 156                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 157         done
 158         test -z "$sr_deps_missing" || return 1
 159 }
 160
 161 AC_ARG_ENABLE([all-drivers],
 162         [AS_HELP_STRING([--enable-all-drivers],
 163                         [enable all drivers by default [default=yes]])],
 164         [], [enable_all_drivers=yes])
 165
 166 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 167 m4_define([_SR_DRIVER], [
 168         AC_ARG_ENABLE([$2],
 169                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 170                 [$3=$enableval], [$3=$enable_all_drivers])
 171
 172         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 173                 sr_check_driver_deps $4 \
 174                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 175         ])], [sr_hw_info='no (disabled)'])
 176         sr_driver_summary_append "$2" "$sr_hw_info"
 177
 178         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 179         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 180 ])
 181
 182 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 183 m4_define([SR_DRIVER],
 184         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 185
 186 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 187 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 188 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 189 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 190 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 191 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 192 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 193 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 194 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 195 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 196 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 197 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 198 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 199 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 200 SR_DRIVER([demo], [demo])
 201 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 202 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 203 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 204 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 205 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 206 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 207 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 208 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 209 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 210 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 211 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 212 SR_DRIVER([maynuo-m97], [maynuo-m97])
 213 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 214 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 215 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 216 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 217 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 218 SR_DRIVER([Rigol DS], [rigol-ds])
 219 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 220 SR_DRIVER([SCPI PPS], [scpi-pps])
 221 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 222 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 223 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 224 SR_DRIVER([Testo], [testo], [libusb])
 225 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 226 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 227 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 228 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 229 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 230 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 231
 232 ###############################
 233 ##  Language bindings setup  ##
 234 ###############################
 235
 236 AC_LANG([C++])
 237 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 238
 239 AC_ARG_ENABLE([bindings],
 240         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 241         [], [enable_bindings=yes])
 242
 243 AC_ARG_ENABLE([cxx],
 244         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 245         [], [enable_cxx=$enable_bindings])
 246
 247 AC_ARG_ENABLE([python],
 248         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 249         [], [enable_python=$enable_bindings])
 250
 251 AC_ARG_ENABLE([java],
 252         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 253         [], [enable_java=$enable_bindings])
 254
 255 ####################
 256 ##  C++ bindings  ##
 257 ####################
 258
 259 sr_cxx_missing=
 260
 261 # Check if the C++ compiler supports the C++11 standard.
 262 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 263 AS_IF([test "x$HAVE_CXX11" != x1],
 264         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 265
 266 # The C++ bindings need glibmm.
 267 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 268 AS_IF([test "x$sr_have_glibmm" != xyes],
 269         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 270
 271 # The C++ bindings use Doxygen to parse libsigrok symbols.
 272 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 273 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 274         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 275
 276 # Python is needed for the C++ bindings.
 277 AM_PATH_PYTHON([2.7],
 278         [HAVE_PYTHON=yes],
 279         [HAVE_PYTHON=no
 280         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 281
 282 AS_IF([test -z "$sr_cxx_missing"],
 283         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 284 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 285
 286 # C++ bindings want stoi and stod.
 287 AM_COND_IF([BINDINGS_CXX], [
 288         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 289                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 290                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 291                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 292         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 293                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 294                         [Specifies whether we have the stoi and stod functions.])])
 295 ])
 296
 297 #######################
 298 ##  Python bindings  ##
 299 #######################
 300
 301 AS_IF([test "x$BINDINGS_CXX" = xyes],
 302         [sr_python_missing=],
 303         [sr_python_missing='C++ bindings'])
 304
 305 # The Python bindings need Python development files.
 306 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 307         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 308 AS_IF([test "x$sr_have_python_dev" != xyes],
 309         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 310
 311 # PyGObject is needed for the Python bindings.
 312 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 313 AS_IF([test "x$sr_have_pygobject" != xyes],
 314         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 315
 316 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 317         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 318                 [Whether last argument to pyg_flags_get_value() is signed.])])
 319
 320 # The Python bindings need the setuptools Python module.
 321 # We'll let it go through even if the AX macro wasn't found,
 322 # as the Python module may still be there.
 323 HAVE_PYMOD_SETUPTOOLS=yes
 324 m4_ifdef([AX_PYTHON_MODULE],
 325         [AX_PYTHON_MODULE([setuptools])],
 326         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 327 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 328         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 329
 330 # The Python bindings use SWIG to generate code.
 331 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 332 AS_IF([test "x$SWIG" = x],
 333         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 334
 335 AS_IF([test -z "$sr_python_missing"],
 336         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 337 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 338
 339 ####################
 340 ##  Java bindings ##
 341 ####################
 342
 343 AS_IF([test "x$BINDINGS_CXX" = xyes],
 344         [sr_java_missing=],
 345         [sr_java_missing='C++ bindings'])
 346
 347 # The Java bindings use SWIG to generate code.
 348 AS_IF([test "x$SWIG" = x],
 349         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 350
 351 # Find Java compiler and JNI includes for Java bindings.
 352 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 353 AS_IF([test "x$HAVE_JAVAC" = xno],
 354         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 355
 356 AC_ARG_WITH([jni-include-path],
 357         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 358                 [specify JNI include directories [default=detect]])],
 359         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 360
 361 JNI_CPPFLAGS=
 362 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 363         AX_PROG_JAVAC
 364         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 365                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 366                 ## If we can find jni.h without any special search path, skip
 367                 ## the execution of the broken macro to increase our chances of
 368                 ## success.
 369                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 370                         [AX_JNI_INCLUDE_DIR])
 371         ])
 372 ])
 373 for sr_dir in $JNI_INCLUDE_DIRS
 374 do
 375         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 376 done
 377 AC_SUBST([JNI_CPPFLAGS])
 378
 379 sr_save_cppflags=$CPPFLAGS
 380 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 381 AC_CHECK_HEADER([jni.h],,
 382         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 383 CPPFLAGS=$sr_save_cppflags
 384
 385 AS_IF([test -z "$sr_java_missing"],
 386         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 387 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 388
 389 ##############################
 390 ##  Finalize configuration  ##
 391 ##############################
 392
 393 # Add mandatory dependencies to module list.
 394 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 395 AC_SUBST([SR_PKGLIBS])
 396
 397 # Retrieve the compile and link flags for all modules combined.
 398 # Also, bail out at this point if any module dependency is not met.
 399 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 400 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 401
 402 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 403 # the C++ bindings are enabled.
 404 AM_COND_IF([BINDINGS_CXX], [
 405         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 406         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 407 ])
 408 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 409 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 410
 411 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 412         [Build-time version of libzip.])
 413 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 414         [The canonical host libsigrok will run on.])
 415
 416 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 417
 418 AC_OUTPUT
 419
 420 # Prepare bindings report messages.
 421 m4_define([SR_PREPARE_BINDING_REPORT], [
 422         sr_report_$1=
 423         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 424         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 425 ])
 426 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 427
 428 cat >&AS_MESSAGE_FD <<_EOF
 429
 430 libsigrok configuration summary:
 431  - Package version................. $SR_PACKAGE_VERSION
 432  - Library ABI version............. $SR_LIB_VERSION
 433  - Prefix.......................... $prefix
 434  - Building on..................... $build
 435  - Building for.................... $host
 436  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 437  - C compiler warnings............. $SR_WFLAGS
 438  - C++ compiler warnings........... $SR_WXXFLAGS
 439
 440 Detected libraries (required):
 441  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 442  - libzip >= 0.10.................. $sr_libzip_version
 443
 444 Detected libraries (optional):
 445 $sr_pkglibs_summary
 446 Enabled hardware drivers:
 447 $sr_driver_summary
 448 Enabled SCPI backends:
 449  - TCP............................. yes
 450  - RPC............................. $sr_cv_have_rpc
 451  - serial.......................... $sr_have_libserialport
 452  - VISA............................ $sr_have_librevisa
 453  - GPIB............................ $sr_have_libgpib
 454  - USBTMC.......................... $sr_have_libusb
 455
 456 Enabled language bindings:
 457  - C++............................. $BINDINGS_CXX$sr_report_cxx
 458  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 459  - Java............................ $BINDINGS_JAVA$sr_report_java
 460
 461 _EOF