configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45
  46 # Required for per-target flags or subdir-objects with C sources.
  47 AM_PROG_CC_C_O
  48
  49 # Initialize libtool.
  50 LT_INIT
  51
  52 # Set up the libsigrok version defines.
  53 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  54
  55 # Library version for libsigrok (NOT the same as the package version).
  56 # Carefully read the libtool docs before updating these numbers!
  57 # The algorithm for determining which number to change (and how) is nontrivial!
  58 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  59 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  60
  61 #############################
  62 ##  Optional dependencies  ##
  63 #############################
  64
  65 AC_LANG([C])
  66
  67 # Initialize pkg-config.
  68 # We require at least 0.22, as "Requires.private" behaviour changed there.
  69 PKG_PROG_PKG_CONFIG([0.22])
  70
  71 # Keep track of all checked modules so we can list them at the end.
  72 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  73
  74 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  75 # These are used to derive the compiler flags and for the "Requires.private"
  76 # field in the generated libsigrok.pc file.
  77 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  78 SR_PKGLIBS_TESTS=
  79 SR_PKGLIBS_CXX=
  80 SR_PKGLIBS_PYTHON=
  81 SR_EXTRA_LIBS=
  82
  83 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  84         [libserialport >= 0.1.1])
  85
  86 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  87         [libftdi1 >= 1.0], [libftdi >= 0.16])
  88
  89 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  90 # This means libusb-1.0 is always available; no need to check for it.
  91 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
  92
  93 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
  94         [libusb-1.0 >= 1.0.16])
  95
  96 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
  97         [librevisa >= 0.0.20130412])
  98
  99 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 100         [libgpib])
 101
 102 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 103         sr_save_LIBS=$LIBS
 104         LIBS="-lieee1284 $LIBS"
 105         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 106                                 [[(void) ieee1284_open(0, 0, 0);]])],
 107                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 108         sr_save_LIBS=$LIBS
 109 ])
 110 AS_IF([test "x$sr_have_libieee1284" = xyes],
 111         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 112
 113 ######################
 114 ##  Feature checks  ##
 115 ######################
 116
 117 # The Check unit testing framework is optional. Disable if not found.
 118 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 119 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 120
 121 # Enable the C99 standard if possible, and enforce the use
 122 # of SR_API to explicitly mark all public API functions.
 123 SR_EXTRA_CFLAGS=
 124 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 125 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 126
 127 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 128
 129 # Check host characteristics.
 130 AC_SYS_LARGEFILE
 131 AC_C_BIGENDIAN
 132
 133 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 134 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 135 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 136
 137 # We need to link against the Winsock2 library for SCPI over TCP.
 138 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 139
 140 # libm (the standard math library) is always needed.
 141 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 142
 143 # RPC is only needed for VXI support.
 144 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 145         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 146                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 147                         [[(void) clnt_create("", 0, 0, "");]])],
 148                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 149 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 150         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 151 # VXI support is only compiled if RPC support was found.
 152 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 153
 154 ########################
 155 ##  Hardware drivers  ##
 156 ########################
 157
 158 # Keep track of all drivers so we can list them at the end.
 159 SR_VAR_SUMMARY([sr_driver_summary])
 160
 161 # Check whether the sr_deps_avail list contains all of the arguments.
 162 # Unavailable dependencies are collected in sr_deps_missing.
 163 sr_check_driver_deps() {
 164         sr_deps_missing=
 165         for sr_dep
 166         do
 167                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 168                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 169         done
 170         test -z "$sr_deps_missing" || return 1
 171 }
 172
 173 AC_ARG_ENABLE([all-drivers],
 174         [AS_HELP_STRING([--enable-all-drivers],
 175                         [enable all drivers by default [default=yes]])],
 176         [], [enable_all_drivers=yes])
 177
 178 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 179 m4_define([_SR_DRIVER], [
 180         AC_ARG_ENABLE([$2],
 181                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 182                 [$3=$enableval], [$3=$enable_all_drivers])
 183
 184         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 185                 sr_check_driver_deps $4 \
 186                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 187         ])], [sr_hw_info='no (disabled)'])
 188         sr_driver_summary_append "$2" "$sr_hw_info"
 189
 190         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 191         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 192 ])
 193
 194 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 195 m4_define([SR_DRIVER],
 196         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 197
 198 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 199 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 200 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 201 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 202 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 203 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 204 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 205 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 206 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 207 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 208 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 209 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 210 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 211 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 212 SR_DRIVER([demo], [demo])
 213 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 214 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 215 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 216 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 217 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 218 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 219 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 220 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 221 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 222 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 223 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 224 SR_DRIVER([maynuo-m97], [maynuo-m97])
 225 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 226 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 227 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 228 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 229 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 230 SR_DRIVER([Rigol DS], [rigol-ds])
 231 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 232 SR_DRIVER([SCPI PPS], [scpi-pps])
 233 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 234 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 235 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 236 SR_DRIVER([Testo], [testo], [libusb])
 237 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 238 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 239 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 240 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 241 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 242 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 243
 244 ###############################
 245 ##  Language bindings setup  ##
 246 ###############################
 247
 248 AC_LANG([C++])
 249 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 250
 251 AC_ARG_ENABLE([bindings],
 252         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 253         [], [enable_bindings=yes])
 254
 255 AC_ARG_ENABLE([cxx],
 256         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 257         [], [enable_cxx=$enable_bindings])
 258
 259 AC_ARG_ENABLE([python],
 260         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 261         [], [enable_python=$enable_bindings])
 262
 263 AC_ARG_ENABLE([java],
 264         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 265         [], [enable_java=$enable_bindings])
 266
 267 ####################
 268 ##  C++ bindings  ##
 269 ####################
 270
 271 sr_cxx_missing=
 272
 273 # Check if the C++ compiler supports the C++11 standard.
 274 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 275 AS_IF([test "x$HAVE_CXX11" != x1],
 276         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 277
 278 # The C++ bindings need glibmm.
 279 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 280 AS_IF([test "x$sr_have_glibmm" != xyes],
 281         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 282
 283 # The C++ bindings use Doxygen to parse libsigrok symbols.
 284 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 285 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 286         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 287
 288 # Python is needed for the C++ bindings.
 289 AM_PATH_PYTHON([2.7],
 290         [HAVE_PYTHON=yes],
 291         [HAVE_PYTHON=no
 292         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 293
 294 AS_IF([test -z "$sr_cxx_missing"],
 295         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 296 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 297
 298 # C++ bindings want stoi and stod.
 299 AM_COND_IF([BINDINGS_CXX], [
 300         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 301                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 302                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 303                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 304         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 305                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 306                         [Specifies whether we have the stoi and stod functions.])])
 307 ])
 308
 309 #######################
 310 ##  Python bindings  ##
 311 #######################
 312
 313 AS_IF([test "x$BINDINGS_CXX" = xyes],
 314         [sr_python_missing=],
 315         [sr_python_missing='C++ bindings'])
 316
 317 # The Python bindings need Python development files.
 318 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 319         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 320 AS_IF([test "x$sr_have_python_dev" != xyes],
 321         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 322
 323 # PyGObject is needed for the Python bindings.
 324 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 325 AS_IF([test "x$sr_have_pygobject" != xyes],
 326         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 327
 328 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 329         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 330                 [Whether last argument to pyg_flags_get_value() is signed.])])
 331
 332 # The Python bindings need the setuptools Python module.
 333 # We'll let it go through even if the AX macro wasn't found,
 334 # as the Python module may still be there.
 335 HAVE_PYMOD_SETUPTOOLS=yes
 336 m4_ifdef([AX_PYTHON_MODULE],
 337         [AX_PYTHON_MODULE([setuptools])],
 338         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 339 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 340         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 341
 342 # The Python bindings use SWIG to generate code.
 343 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 344 AS_IF([test "x$SWIG" = x],
 345         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 346
 347 AS_IF([test -z "$sr_python_missing"],
 348         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 349 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 350
 351 ####################
 352 ##  Java bindings ##
 353 ####################
 354
 355 AS_IF([test "x$BINDINGS_CXX" = xyes],
 356         [sr_java_missing=],
 357         [sr_java_missing='C++ bindings'])
 358
 359 # The Java bindings use SWIG to generate code.
 360 AS_IF([test "x$SWIG" = x],
 361         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 362
 363 # Find Java compiler and JNI includes for Java bindings.
 364 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 365 AS_IF([test "x$HAVE_JAVAC" = xno],
 366         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 367
 368 AC_ARG_WITH([jni-include-path],
 369         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 370                 [specify JNI include directories [default=detect]])],
 371         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 372
 373 JNI_CPPFLAGS=
 374 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 375         AX_PROG_JAVAC
 376         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 377                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 378                 ## If we can find jni.h without any special search path, skip
 379                 ## the execution of the broken macro to increase our chances of
 380                 ## success.
 381                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 382                         [AX_JNI_INCLUDE_DIR])
 383         ])
 384 ])
 385 for sr_dir in $JNI_INCLUDE_DIRS
 386 do
 387         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 388 done
 389 AC_SUBST([JNI_CPPFLAGS])
 390
 391 sr_save_cppflags=$CPPFLAGS
 392 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 393 AC_CHECK_HEADER([jni.h],,
 394         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 395 CPPFLAGS=$sr_save_cppflags
 396
 397 AS_IF([test -z "$sr_java_missing"],
 398         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 399 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 400
 401 ##############################
 402 ##  Finalize configuration  ##
 403 ##############################
 404
 405 # Add mandatory dependencies to module list.
 406 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 407 AC_SUBST([SR_PKGLIBS])
 408
 409 # Retrieve the compile and link flags for all modules combined.
 410 # Also, bail out at this point if any module dependency is not met.
 411 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 412 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 413
 414 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 415 # the C++ bindings are enabled.
 416 AM_COND_IF([BINDINGS_CXX], [
 417         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 418         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 419 ])
 420 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 421 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 422
 423 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 424         [Build-time version of libzip.])
 425 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 426         [The canonical host libsigrok will run on.])
 427
 428 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 429
 430 AC_OUTPUT
 431
 432 # Prepare bindings report messages.
 433 m4_define([SR_PREPARE_BINDING_REPORT], [
 434         sr_report_$1=
 435         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 436         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 437 ])
 438 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 439
 440 cat >&AS_MESSAGE_FD <<_EOF
 441
 442 libsigrok configuration summary:
 443  - Package version................. $SR_PACKAGE_VERSION
 444  - Library ABI version............. $SR_LIB_VERSION
 445  - Prefix.......................... $prefix
 446  - Building on..................... $build
 447  - Building for.................... $host
 448  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 449  - C compiler warnings............. $SR_WFLAGS
 450  - C++ compiler warnings........... $SR_WXXFLAGS
 451
 452 Detected libraries (required):
 453  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 454  - libzip >= 0.10.................. $sr_libzip_version
 455
 456 Detected libraries (optional):
 457 $sr_pkglibs_summary
 458 Enabled hardware drivers:
 459 $sr_driver_summary
 460 Enabled SCPI backends:
 461  - TCP............................. yes
 462  - RPC............................. $sr_cv_have_rpc
 463  - serial.......................... $sr_have_libserialport
 464  - VISA............................ $sr_have_librevisa
 465  - GPIB............................ $sr_have_libgpib
 466  - USBTMC.......................... $sr_have_libusb
 467
 468 Enabled language bindings:
 469  - C++............................. $BINDINGS_CXX$sr_report_cxx
 470  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 471  - Java............................ $BINDINGS_JAVA$sr_report_java
 472
 473 _EOF