configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [4])
  27 m4_define([sr_package_version_micro], [0])
  28
  29 AC_INIT([libsigrok], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro],
  30         [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 COMMON_FLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48 CFLAGS="$COMMON_FLAGS -std=c11 -D_POSIX_C_SOURCE=200112L -Wmissing-prototypes"
  49 CXXFLAGS="-std=c++11 $COMMON_FLAGS"
  50
  51 # Checks for programs.
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_CXX
  55 AC_PROG_INSTALL
  56 AC_PROG_LN_S
  57
  58 # Required for per-target flags or subdir-objects with C sources.
  59 AM_PROG_CC_C_O
  60
  61 # Initialize libtool.
  62 LT_INIT
  63
  64 # Initialize pkg-config.
  65 # We require at least 0.22, as "Requires.private" behaviour changed there.
  66 PKG_PROG_PKG_CONFIG([0.22])
  67
  68 CONFIG_STATUS_DEPENDENCIES=
  69 SR_PACKAGE_VERSION="AC_PACKAGE_VERSION"
  70
  71 # Check if we can get revision information from git.
  72 sr_head=`git -C "$srcdir" rev-parse --verify --short HEAD 2>&AS_MESSAGE_LOG_FD`
  73
  74 AS_IF([test "$?" -eq 0 && test -n "$sr_head"], [
  75         CONFIG_STATUS_DEPENDENCIES='$(top_srcdir)/.git/HEAD'
  76         sr_head_name=`git -C "$srcdir" rev-parse --symbolic-full-name HEAD 2>&AS_MESSAGE_LOG_FD`
  77         AS_IF([test "$?" -eq 0 && test -f "$srcdir/.git/$sr_head_name"],
  78                 [CONFIG_STATUS_DEPENDENCIES="$CONFIG_STATUS_DEPENDENCIES \$(top_srcdir)/.git/$sr_head_name"])
  79
  80         # Append the revision hash unless we are exactly on a tagged release.
  81         git -C "$srcdir" describe --match 'AC_PACKAGE_NAME-AC_PACKAGE_VERSION' \
  82                 --exact-match >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD \
  83         || SR_PACKAGE_VERSION="$SR_PACKAGE_VERSION-git-$sr_head"
  84 ])
  85 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
  86 AC_SUBST([SR_PACKAGE_VERSION])
  87
  88 AC_DEFINE([SR_PACKAGE_VERSION_MAJOR], [sr_package_version_major], [.])
  89 AC_DEFINE([SR_PACKAGE_VERSION_MINOR], [sr_package_version_minor], [.])
  90 AC_DEFINE([SR_PACKAGE_VERSION_MICRO], [sr_package_version_micro], [.])
  91 AC_DEFINE_UNQUOTED([SR_PACKAGE_VERSION_STRING], ["$SR_PACKAGE_VERSION"], [.])
  92
  93 # Library version for libsigrok (NOT the same as the package version).
  94 # Carefully read the libtool docs before updating these numbers!
  95 # The algorithm for determining which number to change (and how) is nontrivial!
  96 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  97 SR_LIB_VERSION_CURRENT=2
  98 SR_LIB_VERSION_REVISION=0
  99 SR_LIB_VERSION_AGE=0
 100
 101 AC_SUBST([SR_LIB_VERSION], ["$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"])
 102 AC_SUBST([SR_LIB_LDFLAGS], ["-version-info $SR_LIB_VERSION"])
 103
 104 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_CURRENT], [$SR_LIB_VERSION_CURRENT], [.])
 105 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_REVISION], [$SR_LIB_VERSION_REVISION], [.])
 106 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_AGE], [$SR_LIB_VERSION_AGE], [.])
 107 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_STRING], ["$SR_LIB_VERSION"], [.])
 108
 109 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
 110         [enable all drivers by default [default=yes]]),
 111         [HW_ENABLED_DEFAULT="$enableval"],
 112         [HW_ENABLED_DEFAULT="yes"])
 113
 114 # Usage: DRIVER([Device name], [driver-name])
 115 # An optional third argument [no] disables that driver.
 116 m4_define([driverize], [m4_tolower(m4_bpatsubst([$1], [[^0-9a-zA-Z-]+], [-]))])
 117 m4_define([upperize], [m4_toupper(m4_bpatsubst([$1], [[^0-9a-zA-Z_]+], [_]))])
 118 AC_DEFUN([DRIVER], [
 119         if test -z "$3"; then
 120                 default=$HW_ENABLED_DEFAULT
 121         else
 122                 default="$3"
 123         fi
 124         AC_ARG_ENABLE($2, AC_HELP_STRING([--enable-$2], [enable $1 support]),
 125                 [m4_join([], [HW_], upperize([$2]))="$enableval"],
 126                 [m4_join([], [HW_], upperize([$2]))=$default])
 127         dots=$(echo -n ".............................." | cut -c 1-$(expr 32 - $(echo -n $2|wc -c)))
 128         driver_summary="${driver_summary}  - $2${dots} \${m4_join([], [HW_], upperize([$2]))}@"
 129 ])
 130
 131 DRIVER([Agilent DMM], [agilent-dmm])
 132 DRIVER([Appa 55II], [appa-55ii])
 133 DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 134 DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 135 DRIVER([BayLibre ACME], [baylibre-acme])
 136 DRIVER([BeagleLogic], [beaglelogic])
 137 DRIVER([Brymen BM86x], [brymen-bm86x])
 138 DRIVER([Brymen DMM], [brymen-dmm])
 139 DRIVER([CEM DT-885x], [cem-dt-885x])
 140 DRIVER([Center 3xx], [center-3xx])
 141 DRIVER([ChronoVu LA], [chronovu-la])
 142 DRIVER([Colead SLM], [colead-slm])
 143 DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 144 DRIVER([DER EE DE-5000], [deree-de5000])
 145 DRIVER([demo], [demo])
 146 DRIVER([Fluke DMM], [fluke-dmm])
 147 DRIVER([fx2lafw], [fx2lafw])
 148 DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 149 DRIVER([Hameg HMO], [hameg-hmo])
 150 DRIVER([Hantek DSO], [hantek-dso])
 151 DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 152 DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 153 DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 154 DRIVER([Lascar EL-USB], [lascar-el-usb])
 155 DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 156 DRIVER([maynuo-m97], [maynuo-m97])
 157 DRIVER([MIC 985xx], [mic-985xx])
 158 DRIVER([Motech LPS 30x], [motech-lps-30x])
 159 DRIVER([Norma DMM], [norma-dmm])
 160 DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 161 DRIVER([Pipistrello-OLS], [pipistrello-ols])
 162 DRIVER([Rigol DS], [rigol-ds])
 163 DRIVER([Saleae Logic16], [saleae-logic16])
 164 DRIVER([SCPI PPS], [scpi-pps])
 165 DRIVER([serial DMM], [serial-dmm])
 166 DRIVER([Sysclk LWLA], [sysclk-lwla])
 167 DRIVER([Teleinfo], [teleinfo])
 168 DRIVER([Testo], [testo])
 169 DRIVER([Tondaj SL-814], [tondaj-sl-814])
 170 DRIVER([UNI-T DMM], [uni-t-dmm])
 171 DRIVER([UNI-T UT32x], [uni-t-ut32x])
 172 DRIVER([Victor DMM], [victor-dmm])
 173 DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 174 DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 175
 176 AC_ARG_ENABLE(libserialport,
 177         AC_HELP_STRING([--disable-libserialport],
 178         [disable libserialport support [default=detect]]))
 179
 180 AC_ARG_ENABLE(libftdi,
 181         AC_HELP_STRING([--disable-libftdi],
 182         [disable libftdi support [default=detect]]))
 183
 184 AC_ARG_ENABLE(libusb,
 185         AC_HELP_STRING([--disable-libusb],
 186         [disable libusb support [default=detect]]))
 187
 188 # Language binding '--enable' options:
 189
 190 AC_ARG_ENABLE(bindings,
 191         AC_HELP_STRING([--enable-bindings],
 192         [build language bindings [default=yes]]),
 193         [BINDINGS_ALL="$enableval"], [BINDINGS_ALL="yes"])
 194
 195 AC_ARG_ENABLE(cxx,
 196         AC_HELP_STRING([--enable-cxx],
 197         [build C++ bindings [default=yes]]),
 198         [BINDINGS_CXX="$enableval"], [BINDINGS_CXX=$BINDINGS_ALL])
 199
 200 AC_ARG_ENABLE(python,
 201         AC_HELP_STRING([--enable-python],
 202         [build Python bindings [default=yes]]),
 203         [BINDINGS_PYTHON="$enableval"], [BINDINGS_PYTHON=$BINDINGS_ALL])
 204
 205 AC_ARG_ENABLE(java,
 206         AC_HELP_STRING([--enable-java],
 207         [build Java bindings [default=yes]]),
 208         [BINDINGS_JAVA="$enableval"], [BINDINGS_JAVA=$BINDINGS_ALL])
 209
 210 AC_ARG_WITH(jni-include-path,
 211         AC_HELP_STRING([--with-jni-include-path=path],
 212         [specify include path for JNI [default=autodetect]]),
 213         [JNI_INCLUDE_DIRS="$withval"], [JNI_INCLUDE_DIRS=auto])
 214
 215 # Check if the C++ compiler supports the C++11 standard.
 216
 217 m4_ifdef([AX_CXX_COMPILE_STDCXX_11], [AX_CXX_COMPILE_STDCXX_11(,[optional])],
 218         [AC_MSG_NOTICE([Missing macro m4_toupper(aX_CXX_COMPILE_STDCXX_11), no C++11 check])])
 219
 220 if test "x$HAVE_CXX11" != "x1"; then
 221         BINDINGS_CXX="no"; cxx_msg="C++11 compiler required"
 222 fi
 223
 224 # The C++ bindings use Doxygen to parse libsigrok symbols.
 225 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes])
 226 if test "x$HAVE_DOXYGEN" != "xyes"; then
 227         BINDINGS_CXX="no"; cxx_msg="Doxygen required"
 228 fi
 229
 230 # Python is needed for the C++ bindings.
 231 AM_PATH_PYTHON([2.7], [HAVE_PYTHON="yes"],
 232         [HAVE_PYTHON="no"; BINDINGS_CXX="no"; cxx_msg="Python required"])
 233
 234 # The Python bindings need Python development files.
 235 PKG_CHECK_MODULES([python], [python >= 2.7],
 236         [CXXFLAGS="$CXXFLAGS $python_CFLAGS";
 237         CXXLIBS="$CXXLIBS $python_LIBS"],
 238 [PKG_CHECK_MODULES([python27], [python-2.7 >= 2.7],
 239         [CXXFLAGS="$CXXFLAGS $python27_CFLAGS";
 240         CXXLIBS="$CXXLIBS $python27_LIBS"],
 241                 [BINDINGS_PYTHON="no"; python_msg="Python headers required"])])
 242
 243 # The Python bindings need the setuptools Python module.
 244 m4_ifdef([AX_PYTHON_MODULE], [AX_PYTHON_MODULE([setuptools])],
 245         # We'll let it go through even if the macro wasn't found, the Python
 246         # module may still be there.
 247         [HAVE_PYTHON_SETUPTOOLS="yes";
 248                 AC_MSG_NOTICE([Missing macro m4_toupper(aX_PYTHON_MODULE), no setuptools check])]
 249 )
 250 if test "x$HAVE_PYMOD_SETUPTOOLS" != "xyes"; then
 251         BINDINGS_PYTHON="no"; python_msg="Python setuptools module required"
 252 fi
 253
 254 # The Python and Java bindings use SWIG to generate code.
 255 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes])
 256 if test "x$HAVE_SWIG" != "xyes"; then
 257         BINDINGS_PYTHON="no"; python_msg="SWIG required"
 258         BINDINGS_JAVA="no"; java_msg="SWIG required"
 259 fi
 260
 261 # Checks for libraries.
 262
 263 case "$host" in
 264 *mingw*)
 265         # We need to link against the Winsock2 library for SCPI over TCP.
 266         LIBS="$LIBS -lws2_32";;
 267 esac
 268
 269 # This variable collects the pkg-config names of all detected libs.
 270 # It is then used to construct the "Requires.private:" field in the
 271 # libsigrok.pc file.
 272 SR_PKGLIBS=""
 273
 274 # libm (the standard math library) is always needed.
 275 AC_SEARCH_LIBS([pow], [m])
 276
 277 # RPC is only needed for VXI support.
 278 AC_MSG_CHECKING([for RPC support])
 279 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <rpc/rpc.h>],
 280                         [CLIENT *rpc_test(void)],
 281                         [{ return clnt_create("", 0, 0, ""); }])],
 282                 [AC_MSG_RESULT([yes]); have_rpc=1],
 283                 [AC_MSG_RESULT([no]);  have_rpc=0])
 284 # Define HAVE_RPC in config.h if we found RPC support.
 285 AC_DEFINE_UNQUOTED(HAVE_RPC, [$have_rpc], [Specifies whether we have RPC support.])
 286 # VXI support is only compiled if RPC support was found.
 287 AM_CONDITIONAL(NEED_RPC, test "x$have_rpc" != "x0")
 288
 289 AC_DEFINE_UNQUOTED(HOST, ["$host"], [.])
 290
 291 # libglib-2.0 is always needed. Abort if it's not found.
 292 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 293 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 294 AM_PATH_GLIB_2_0([2.32.0],
 295         [LIB_CFLAGS="$LIB_CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 296
 297 # libzip is always needed. Abort if it's not found.
 298 PKG_CHECK_MODULES([libzip], [libzip >= 0.10],
 299         [LIB_CFLAGS="$LIB_CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 300         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 301 libzip_ver=`$PKG_CONFIG --modversion libzip`
 302 AC_DEFINE_UNQUOTED(HAVE_LIBZIP_VER, ["$libzip_ver"], [.])
 303
 304 # libserialport is only needed for some hardware drivers. Disable the
 305 # respective drivers if it is not found.
 306 if test "x$enable_libserialport" != "xno"; then
 307         PKG_CHECK_MODULES([libserialport], [libserialport >= 0.1.1],
 308                 [have_libserialport="yes"; LIB_CFLAGS="$LIB_CFLAGS $libserialport_CFLAGS";
 309                 LIBS="$LIBS $libserialport_LIBS";
 310                 SR_PKGLIBS="$SR_PKGLIBS libserialport"],
 311                 [have_libserialport="no"])
 312         if test "x$enable_libserialport$have_libserialport" = "xyesno"; then
 313                 AC_MSG_ERROR([libserialport support requested, but it was not found.])
 314         fi
 315 else
 316         have_libserialport="no"
 317 fi
 318 if test "x$have_libserialport" = "xno"; then
 319         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 320         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 321         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 322         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 323         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 324         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 325         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 326         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 327 else
 328         # Define HAVE_LIBSERIALPORT in config.h if we found libserialport.
 329         AC_DEFINE_UNQUOTED(HAVE_LIBSERIALPORT, [1],
 330                 [Specifies whether we have libserialport.])
 331 fi
 332
 333 # Serial port helper code is only compiled in if libserialport was found.
 334 AM_CONDITIONAL(NEED_SERIAL, test "x$have_libserialport" != xno)
 335
 336 # The VISA SCPI backend is only compiled in if librevisa was found.
 337 PKG_CHECK_MODULES([librevisa], [librevisa >= 0.0.20130412],
 338         [have_librevisa="yes"; LIB_CFLAGS="$LIB_CFLAGS $librevisa_CFLAGS";
 339         LIBS="$LIBS $librevisa_LIBS";
 340         SR_PKGLIBS="$SR_PKGLIBS librevisa"],
 341         [have_librevisa="no"])
 342 AM_CONDITIONAL(NEED_VISA, test "x$have_librevisa" != xno)
 343 if test "x$have_librevisa" != "xno"; then
 344         # Define HAVE_LIBREVISA in config.h if we found librevisa.
 345         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA, [1],
 346                 [Specifies whether we have librevisa.])
 347         librevisa_ver=`$PKG_CONFIG --modversion librevisa`
 348         AC_DEFINE_UNQUOTED(HAVE_LIBREVISA_VER, ["$librevisa_ver"], [.])
 349 fi
 350
 351 # The GPIB SCPI backend is only compiled in if libgpib is found.
 352 PKG_CHECK_MODULES([libgpib], [libgpib],
 353         [have_libgpib="yes"; LIB_CFLAGS="$LIB_CFLAGS $libgpib_CFLAGS";
 354         LIBS="$LIBS $libgpib_LIBS";
 355         SR_PKGLIBS="$SR_PKGLIBS libgpib"],
 356         [have_libgpib="no"])
 357 AM_CONDITIONAL(NEED_GPIB, test "x$have_libgpib" != xno)
 358 if test "x$have_libgpib" != "xno"; then
 359         # Define HAVE_LIBGPIB in config.h if we found libgpib.
 360         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB, [1],
 361                 [Specifies whether we have libgpib.])
 362         libgpib_ver=`$PKG_CONFIG --modversion libgpib`
 363         AC_DEFINE_UNQUOTED(HAVE_LIBGPIB_VER, ["$libgpib_ver"], [.])
 364 fi
 365
 366 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 367 # drivers if it is not found.
 368 if test "x$enable_libusb" != "xno"; then
 369         case "$host" in
 370         *freebsd*)
 371                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 372                 # This means libusb-1.0 is always available, no need to check for it,
 373                 # and no need to (potentially) disable any drivers if it's not found.
 374                 have_libusb1_0="yes"
 375                 ;;
 376         *)
 377                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.16],
 378                         [have_libusb1_0="yes"; LIB_CFLAGS="$LIB_CFLAGS $libusb_CFLAGS";
 379                         LIBS="$LIBS $libusb_LIBS";
 380                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 381                         [have_libusb1_0="no"])
 382                 if test "x$enable_libusb$have_libusb1_0" = "xyesno"; then
 383                         AC_MSG_ERROR([libusb support requested, but it was not found.])
 384                 fi
 385                 ;;
 386         esac
 387 else
 388         have_libusb1_0="no"
 389 fi
 390 if test "x$have_libusb1_0" = "xno"; then
 391         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 392         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 393         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 394         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 395         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 396         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 397 else
 398         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 399         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 400                 [Specifies whether we have libusb-1.0.])
 401 fi
 402
 403 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 404 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 405
 406 # libftdi is only needed for some hardware drivers. Disable them if not found.
 407 if test "x$enable_libftdi" != "xno"; then
 408         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 409                 [have_libftdi="yes"; LIB_CFLAGS="$LIB_CFLAGS $libftdi_CFLAGS";
 410                 LIBS="$LIBS $libftdi_LIBS"; SR_PKGLIBS="$SR_PKGLIBS libftdi";
 411                 libftdi_ver=`$PKG_CONFIG --modversion libftdi`],
 412                 [PKG_CHECK_MODULES([libftdi1], [libftdi1 >= 1.0],
 413                         [LIB_CFLAGS="$LIB_CFLAGS $libftdi1_CFLAGS";
 414                         LIBS="$LIBS $libftdi1_LIBS";
 415                         SR_PKGLIBS="$SR_PKGLIBS libftdi1";
 416                         libftdi_ver=`$PKG_CONFIG --modversion libftdi1`],
 417                         [have_libftdi="no"])])
 418         if test "x$enable_libftdi$have_libftdi" = "xyesno"; then
 419                 AC_MSG_ERROR([libftdi support requested, but it was not found.])
 420         fi
 421 else
 422         have_libftdi="no"
 423 fi
 424 if test "x$have_libftdi" = "xno"; then
 425         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 426         HW_PIPISTRELLO_OLS="no";
 427 else
 428         # Define HAVE_LIBFTDI in config.h if we found libftdi.
 429         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI, [1],
 430                 [Specifies whether we have libftdi.])
 431         AC_DEFINE_UNQUOTED(HAVE_LIBFTDI_VER, ["$libftdi_ver"], [.])
 432 fi
 433
 434 # glibmm-2.4 is needed for the C++ bindings.
 435 PKG_CHECK_MODULES([glibmm], [glibmm-2.4 >= 2.32.0],
 436         [CXXFLAGS="$CXXFLAGS $glibmm_CFLAGS";
 437         CXXLIBS="$CXXLIBS $glibmm_LIBS"],
 438         [BINDINGS_CXX="no"; cxx_msg="glibmm required"])
 439
 440 # C++ bindings want stoi and stod.
 441 if test "x$BINDINGS_CXX" = "xyes"; then
 442         AC_LANG_PUSH([C++])
 443         AC_MSG_CHECKING([for stoi and stod])
 444         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <string>],
 445                 [{ return std::stoi("1") + std::stod("1.0"); }])],
 446                 [AC_MSG_RESULT([yes]);
 447                 AC_DEFINE_UNQUOTED(HAVE_STOI_STOD, [1],
 448                 [Specifies whether we have the stoi and stod functions.])],
 449                 [AC_MSG_RESULT([no])])
 450         AC_LANG_POP([C++])
 451 fi
 452
 453 # PyGObject is needed for the Python bindings.
 454 PKG_CHECK_MODULES([pygobject], [pygobject-3.0 >= 3.0.0],
 455         [CXXFLAGS="$CXXFLAGS $pygobject_CFLAGS";
 456         CXXLIBS="$CXXLIBS $pygobject_LIBS";
 457         PKG_CHECK_MODULES([pygobject_3_7_91], [pygobject-3.0 >= 3.7.91],
 458                 [pyg_flags_signed=0], [pyg_flags_signed=1]);
 459         AC_DEFINE_UNQUOTED(PYGOBJECT_FLAGS_SIGNED, [$pyg_flags_signed],
 460                 [Whether last argument to pyg_flags_get_value() is signed.])],
 461         [BINDINGS_PYTHON="no"; python_msg="Python pygobject module required"])
 462
 463 # The Check unit testing framework is optional. Disable if not found.
 464 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 465         [have_check="yes"], [have_check="no"])
 466 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 467
 468 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 469 # build it if these headers aren't available.
 470 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h], [], [HW_BEAGLELOGIC="no"])
 471
 472 # The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
 473 # this header isn't available.
 474 AC_CHECK_HEADERS([sys/timerfd.h], [], [HW_BAYLIBRE_ACME="no"])
 475
 476 # The ACME driver can only be built for Linux.
 477 case "$host" in
 478         *linux*) ;;
 479         *) HW_BAYLIBRE_ACME="no" ;;
 480 esac
 481
 482 AC_SUBST(SR_PKGLIBS)
 483
 484 CFLAGS="$CFLAGS $LIB_CFLAGS"
 485 CXXFLAGS="$CXXFLAGS $LIB_CFLAGS"
 486
 487 # Find Java compiler and JNI includes for Java bindings.
 488 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 489 if test "x$HAVE_JAVAC" = "xyes" && test "x$BINDINGS_JAVA" = "xyes"; then
 490         AX_PROG_JAVAC
 491         if test "x$JNI_INCLUDE_DIRS" = "xauto"; then
 492                 if test "x$cross_compiling" = "xyes"; then
 493                         JNI_INCLUDE_DIRS=
 494                 else
 495                         AX_JNI_INCLUDE_DIR
 496                 fi
 497         fi
 498         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS; do
 499                 CXXFLAGS="$CXXFLAGS -I$JNI_INCLUDE_DIR"
 500         done
 501         AC_LANG_PUSH([C++])
 502         AC_CHECK_HEADERS([jni.h], [], [BINDINGS_JAVA="no"; java_msg="Java JNI headers required"])
 503         AC_LANG_POP([C++])
 504 else
 505         BINDINGS_JAVA="no"; java_msg="Java compiler required"
 506 fi
 507
 508 # Python and Java bindings depend on C++ bindings.
 509 if test "x$BINDINGS_CXX" != "xyes"; then
 510         BINDINGS_PYTHON="no"; python_msg="C++ bindings required"
 511         BINDINGS_JAVA="no"; java_msg="C++ bindings required"
 512 fi
 513
 514 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 515
 516 AC_DEFUN([DRIVER2], [
 517         AM_CONDITIONAL($1, test "x$2" = "xyes")
 518         if test "x$2" = "xyes"; then AC_DEFINE($3, 1, [.]) fi
 519 ])
 520
 521 DRIVER2([HW_AGILENT_DMM], [$HW_AGILENT_DMM], [HAVE_HW_AGILENT_DMM])
 522 DRIVER2([HW_APPA_55II], [$HW_APPA_55II], [HAVE_HW_APPA_55II])
 523 DRIVER2([HW_ASIX_SIGMA], [$HW_ASIX_SIGMA], [HAVE_HW_ASIX_SIGMA])
 524 DRIVER2([HW_ATTEN_PPS3XXX], [$HW_ATTEN_PPS3XXX], [HAVE_HW_ATTEN_PPS3XXX])
 525 DRIVER2([HW_BAYLIBRE_ACME], [$HW_BAYLIBRE_ACME], [HAVE_HW_BAYLIBRE_ACME])
 526 DRIVER2([HW_BEAGLELOGIC], [$HW_BEAGLELOGIC], [HAVE_HW_BEAGLELOGIC])
 527 DRIVER2([HW_BRYMEN_BM86X], [$HW_BRYMEN_BM86X], [HAVE_HW_BRYMEN_BM86X])
 528 DRIVER2([HW_BRYMEN_DMM], [$HW_BRYMEN_DMM], [HAVE_HW_BRYMEN_DMM])
 529 DRIVER2([HW_CEM_DT_885X], [$HW_CEM_DT_885X], [HAVE_HW_CEM_DT_885X])
 530 DRIVER2([HW_CENTER_3XX], [$HW_CENTER_3XX], [HAVE_HW_CENTER_3XX])
 531 DRIVER2([HW_CHRONOVU_LA], [$HW_CHRONOVU_LA], [HAVE_HW_CHRONOVU_LA])
 532 DRIVER2([HW_COLEAD_SLM], [$HW_COLEAD_SLM], [HAVE_HW_COLEAD_SLM])
 533 DRIVER2([HW_CONRAD_DIGI_35_CPU], [$HW_CONRAD_DIGI_35_CPU], [HAVE_HW_CONRAD_DIGI_35_CPU])
 534 DRIVER2([HW_DEMO], [$HW_DEMO], [HAVE_HW_DEMO])
 535 DRIVER2([HW_DEREE_DE5000], [$HW_DEREE_DE5000], [HAVE_HW_DEREE_DE5000])
 536 DRIVER2([HW_FLUKE_DMM], [$HW_FLUKE_DMM], [HAVE_HW_FLUKE_DMM])
 537 DRIVER2([HW_FX2LAFW], [$HW_FX2LAFW], [HAVE_HW_FX2LAFW])
 538 DRIVER2([HW_GMC_MH_1X_2X], [$HW_GMC_MH_1X_2X], [HAVE_HW_GMC_MH_1X_2X])
 539 DRIVER2([HW_HAMEG_HMO], [$HW_HAMEG_HMO], [HAVE_HW_HAMEG_HMO])
 540 DRIVER2([HW_HANTEK_DSO], [$HW_HANTEK_DSO], [HAVE_HW_HANTEK_DSO])
 541 DRIVER2([HW_IKALOGIC_SCANALOGIC2], [$HW_IKALOGIC_SCANALOGIC2], [HAVE_HW_IKALOGIC_SCANALOGIC2])
 542 DRIVER2([HW_IKALOGIC_SCANAPLUS], [$HW_IKALOGIC_SCANAPLUS], [HAVE_HW_IKALOGIC_SCANAPLUS])
 543 DRIVER2([HW_KECHENG_KC_330B], [$HW_KECHENG_KC_330B], [HAVE_HW_KECHENG_KC_330B])
 544 DRIVER2([HW_LASCAR_EL_USB], [$HW_LASCAR_EL_USB], [HAVE_HW_LASCAR_EL_USB])
 545 DRIVER2([HW_MANSON_HCS_3XXX], [$HW_MANSON_HCS_3XXX], [HAVE_HW_MANSON_HCS_3XXX])
 546 DRIVER2([HW_MAYNUO_M97], [$HW_MAYNUO_M97], [HAVE_HW_MAYNUO_M97])
 547 DRIVER2([HW_MIC_985XX], [$HW_MIC_985XX], [HAVE_HW_MIC_985XX])
 548 DRIVER2([HW_MOTECH_LPS_30X], [$HW_MOTECH_LPS_30X], [HAVE_HW_MOTECH_LPS_30X])
 549 DRIVER2([HW_NORMA_DMM], [$HW_NORMA_DMM], [HAVE_HW_NORMA_DMM])
 550 DRIVER2([HW_OPENBENCH_LOGIC_SNIFFER], [$HW_OPENBENCH_LOGIC_SNIFFER], [HAVE_HW_OPENBENCH_LOGIC_SNIFFER])
 551 DRIVER2([HW_PIPISTRELLO_OLS], [$HW_PIPISTRELLO_OLS], [HAVE_HW_PIPISTRELLO_OLS])
 552 DRIVER2([HW_RIGOL_DS], [$HW_RIGOL_DS], [HAVE_HW_RIGOL_DS])
 553 DRIVER2([HW_SALEAE_LOGIC16], [$HW_SALEAE_LOGIC16], [HAVE_HW_SALEAE_LOGIC16])
 554 DRIVER2([HW_SCPI_PPS], [$HW_SCPI_PPS], [HAVE_HW_SCPI_PPS])
 555 DRIVER2([HW_SERIAL_DMM], [$HW_SERIAL_DMM], [HAVE_HW_SERIAL_DMM])
 556 DRIVER2([HW_SYSCLK_LWLA], [$HW_SYSCLK_LWLA], [HAVE_HW_SYSCLK_LWLA])
 557 DRIVER2([HW_TELEINFO], [$HW_TELEINFO], [HAVE_HW_TELEINFO])
 558 DRIVER2([HW_TESTO], [$HW_TESTO], [HAVE_HW_TESTO])
 559 DRIVER2([HW_TONDAJ_SL_814], [$HW_TONDAJ_SL_814], [HAVE_HW_TONDAJ_SL_814])
 560 DRIVER2([HW_UNI_T_DMM], [$HW_UNI_T_DMM], [HAVE_HW_UNI_T_DMM])
 561 DRIVER2([HW_UNI_T_UT32X], [$HW_UNI_T_UT32X], [HAVE_HW_UNI_T_UT32X])
 562 DRIVER2([HW_VICTOR_DMM], [$HW_VICTOR_DMM], [HAVE_HW_VICTOR_DMM])
 563 DRIVER2([HW_YOKOGAWA_DLM], [$HW_YOKOGAWA_DLM], [HAVE_HW_YOKOGAWA_DLM])
 564 DRIVER2([HW_ZEROPLUS_LOGIC_CUBE], [$HW_ZEROPLUS_LOGIC_CUBE], [HAVE_HW_ZEROPLUS_LOGIC_CUBE])
 565
 566 AM_CONDITIONAL(BINDINGS_CXX, test x$BINDINGS_CXX = xyes)
 567
 568 AM_CONDITIONAL(BINDINGS_PYTHON, test x$BINDINGS_PYTHON = xyes)
 569
 570 AM_CONDITIONAL(BINDINGS_JAVA, test x$BINDINGS_JAVA = xyes)
 571
 572 # Checks for header files.
 573 # These are already implicitly checked: inttypes.h stdint.h stdlib.h string.h
 574 # unistd.h memory.h strings.h dlfcn.h sys/types.h sys/stat.h.
 575
 576 # Checks for typedefs, structures, and compiler characteristics.
 577 AC_C_BIGENDIAN
 578
 579 AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
 580 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 581 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 582
 583 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 584
 585 AC_OUTPUT
 586
 587 echo
 588 echo "libsigrok configuration summary:"
 589 echo
 590 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 591 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 592 echo "  - Prefix: $prefix"
 593 echo "  - Building on: $build"
 594 echo "  - Building for: $host"
 595 echo
 596 echo "Detected libraries:"
 597 echo
 598
 599 # Note: This only works for libs with pkg-config integration.
 600 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.10" "libserialport >= 0.1.1" \
 601         "librevisa >= 0.0.20130412" "libusb-1.0 >= 1.0.16" "libftdi >= 0.16" \
 602         "libftdi1 >= 1.0" "libgpib" "glibmm-2.4 >= 2.32.0" \
 603         "pygobject-3.0 >= 3.0.0" "check >= 0.9.4"
 604 do
 605         optional="OPTIONAL"
 606         if test "x$lib" = "xglib-2.0 >= 2.32.0"; then optional="REQUIRED"; fi
 607         if test "x$lib" = "xlibzip >= 0.10"; then optional="REQUIRED"; fi
 608         if `$PKG_CONFIG --exists $lib`; then
 609                 ver=`$PKG_CONFIG --modversion $lib`
 610                 answer="yes ($ver)"
 611         else
 612                 answer="no"
 613         fi
 614         echo "  - ($optional) $lib: $answer"
 615 done
 616
 617 eval echo -e "@Enabled hardware drivers:@@${driver_summary}" | tr @ \\n
 618
 619 # Prepare final bindings report messages.
 620 final_cxx=""
 621 final_python=""
 622 final_java=""
 623 if test "$enable_bindings" = "no"; then
 624         final_cxx=" (disabled)"
 625         final_python=" (disabled)"
 626         final_java=" (disabled)"
 627 else
 628         if test "$enable_cxx" = "no"; then
 629                 final_cxx=" (disabled)"
 630         elif test "$BINDINGS_CXX" = "no"; then
 631                 final_cxx=" ($cxx_msg)"
 632         fi
 633         if test "$enable_python" = "no"; then
 634                 final_python=" (disabled)"
 635         elif test "$BINDINGS_PYTHON" = "no"; then
 636                 final_python=" ($python_msg)"
 637         fi
 638         if test "$enable_java" = "no"; then
 639                 final_java=" (disabled)"
 640         elif test "$BINDINGS_JAVA" = "no"; then
 641                 final_java=" ($java_msg)"
 642         fi
 643 fi
 644
 645 echo "Enabled SCPI backends:"
 646 echo " - TCP............................. yes"
 647 if test "x$have_rpc" = "x0"; then
 648 echo " - RPC............................. no"
 649 else
 650 echo " - RPC............................. yes"
 651 fi
 652 echo " - serial.......................... $have_libserialport"
 653 echo " - VISA............................ $have_librevisa"
 654 echo " - GPIB............................ $have_libgpib"
 655 echo " - USBTMC.......................... $have_libusb1_0"
 656 echo
 657
 658 echo "Enabled language bindings:"
 659 echo " - C++............................. $BINDINGS_CXX$final_cxx"
 660 echo " - Python.......................... $BINDINGS_PYTHON$final_python"
 661 echo " - Java............................ $BINDINGS_JAVA$final_java"
 662 echo