configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [4])
  27 m4_define([sr_package_version_micro], [0])
  28
  29 AC_INIT([libsigrok], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro],
  30         [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -std=c11"
  48 CFLAGS="$CFLAGS -Wall -Wextra -Wmissing-prototypes"
  49 CFLAGS="$CFLAGS -fvisibility=hidden"
  50 CFLAGS="$CFLAGS -D_POSIX_C_SOURCE=200112L"
  51
  52 # Checks for programs.
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PROG_CXX
  56 AC_PROG_INSTALL
  57 AC_PROG_LN_S
  58
  59 # Required for per-target flags or subdir-objects with C sources.
  60 AM_PROG_CC_C_O
  61
  62 # Initialize libtool.
  63 LT_INIT
  64
  65 CONFIG_STATUS_DEPENDENCIES=
  66 SR_PACKAGE_VERSION="AC_PACKAGE_VERSION"
  67
  68 # Check if we can get revision information from git.
  69 sr_head=`git -C "$srcdir" rev-parse --verify --short HEAD 2>&AS_MESSAGE_LOG_FD`
  70
  71 AS_IF([test "$?" -eq 0 && test -n "$sr_head"], [
  72         sr_git_deps=
  73         test ! -f "$srcdir/.git/HEAD" || sr_git_deps=' $(top_srcdir)/.git/HEAD'
  74
  75         sr_head_name=`git -C "$srcdir" rev-parse --symbolic-full-name HEAD 2>&AS_MESSAGE_LOG_FD`
  76         AS_IF([test "$?" -eq 0 && test -f "$srcdir/.git/$sr_head_name"],
  77                 [sr_git_deps="$sr_git_deps \$(top_srcdir)/.git/$sr_head_name"])
  78
  79         # Use $(wildcard) so that things do not break if for whatever
  80         # reason these files do not exist anymore at make time.
  81         test -z "$sr_git_deps" || CONFIG_STATUS_DEPENDENCIES="\$(wildcard$sr_git_deps)"
  82
  83         # Append the revision hash unless we are exactly on a tagged release.
  84         git -C "$srcdir" describe --match 'AC_PACKAGE_NAME-AC_PACKAGE_VERSION' \
  85                 --exact-match >&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD \
  86         || SR_PACKAGE_VERSION="$SR_PACKAGE_VERSION-git-$sr_head"
  87 ])
  88 AC_SUBST([CONFIG_STATUS_DEPENDENCIES])
  89 AC_SUBST([SR_PACKAGE_VERSION])
  90
  91 AC_DEFINE([SR_PACKAGE_VERSION_MAJOR], [sr_package_version_major], [.])
  92 AC_DEFINE([SR_PACKAGE_VERSION_MINOR], [sr_package_version_minor], [.])
  93 AC_DEFINE([SR_PACKAGE_VERSION_MICRO], [sr_package_version_micro], [.])
  94 AC_DEFINE_UNQUOTED([SR_PACKAGE_VERSION_STRING], ["$SR_PACKAGE_VERSION"], [.])
  95
  96 # Library version for libsigrok (NOT the same as the package version).
  97 # Carefully read the libtool docs before updating these numbers!
  98 # The algorithm for determining which number to change (and how) is nontrivial!
  99 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
 100 SR_LIB_VERSION_CURRENT=2
 101 SR_LIB_VERSION_REVISION=0
 102 SR_LIB_VERSION_AGE=0
 103 AC_SUBST([SR_LIB_VERSION],
 104         ["$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"])
 105
 106 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_CURRENT], [$SR_LIB_VERSION_CURRENT], [.])
 107 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_REVISION], [$SR_LIB_VERSION_REVISION], [.])
 108 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_AGE], [$SR_LIB_VERSION_AGE], [.])
 109 AC_DEFINE_UNQUOTED([SR_LIB_VERSION_STRING], ["$SR_LIB_VERSION"], [.])
 110
 111 AC_ARG_ENABLE([all-drivers],
 112         [AS_HELP_STRING([--enable-all-drivers],
 113                         [enable all drivers by default [default=yes]])],
 114         [HW_ENABLED_DEFAULT=$enableval],
 115         [HW_ENABLED_DEFAULT=yes])
 116
 117 ## _SR_DRIVER(Device name, driver-name, enable, var-name)
 118 m4_define([_SR_DRIVER], [
 119         AC_ARG_ENABLE([$4],
 120                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 121                 [$4=$enableval], [$4=$3])
 122         m4_append([SR_DRIVER_SUMMARY],
 123                 [ - m4_translit(m4_format([%-32s], [$2]), [ ], [.]) [$]$4],
 124                 m4_newline)
 125         AC_CONFIG_COMMANDS_PRE([dnl
 126                 AM_CONDITIONAL([$4], [test "x[$]$4" = xyes])
 127                 AM_COND_IF([$4], [AC_DEFINE([HAVE_$4], [1], [Whether to support $1 device.])])
 128         ])
 129 ])
 130 ## SR_DRIVER(Device name, driver-name, [no])
 131 m4_define([SR_DRIVER],
 132         [_SR_DRIVER([$1], [$2],
 133                 m4_default_quoted([$3], [$HW_ENABLED_DEFAULT]),
 134                 m4_expand([AS_TR_CPP([HW_$2])]))])
 135
 136 SR_DRIVER([Agilent DMM], [agilent-dmm])
 137 SR_DRIVER([Appa 55II], [appa-55ii])
 138 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma])
 139 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx])
 140 SR_DRIVER([BayLibre ACME], [baylibre-acme])
 141 SR_DRIVER([BeagleLogic], [beaglelogic])
 142 SR_DRIVER([Brymen BM86x], [brymen-bm86x])
 143 SR_DRIVER([Brymen DMM], [brymen-dmm])
 144 SR_DRIVER([CEM DT-885x], [cem-dt-885x])
 145 SR_DRIVER([Center 3xx], [center-3xx])
 146 SR_DRIVER([ChronoVu LA], [chronovu-la])
 147 SR_DRIVER([Colead SLM], [colead-slm])
 148 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu])
 149 SR_DRIVER([DER EE DE-5000], [deree-de5000])
 150 SR_DRIVER([demo], [demo])
 151 SR_DRIVER([Fluke DMM], [fluke-dmm])
 152 SR_DRIVER([fx2lafw], [fx2lafw])
 153 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x])
 154 SR_DRIVER([Hameg HMO], [hameg-hmo])
 155 SR_DRIVER([Hantek DSO], [hantek-dso])
 156 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2])
 157 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus])
 158 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b])
 159 SR_DRIVER([Lascar EL-USB], [lascar-el-usb])
 160 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx])
 161 SR_DRIVER([maynuo-m97], [maynuo-m97])
 162 SR_DRIVER([MIC 985xx], [mic-985xx])
 163 SR_DRIVER([Motech LPS 30x], [motech-lps-30x])
 164 SR_DRIVER([Norma DMM], [norma-dmm])
 165 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer])
 166 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols])
 167 SR_DRIVER([Rigol DS], [rigol-ds])
 168 SR_DRIVER([Saleae Logic16], [saleae-logic16])
 169 SR_DRIVER([SCPI PPS], [scpi-pps])
 170 SR_DRIVER([serial DMM], [serial-dmm])
 171 SR_DRIVER([Sysclk LWLA], [sysclk-lwla])
 172 SR_DRIVER([Teleinfo], [teleinfo])
 173 SR_DRIVER([Testo], [testo])
 174 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814])
 175 SR_DRIVER([UNI-T DMM], [uni-t-dmm])
 176 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x])
 177 SR_DRIVER([Victor DMM], [victor-dmm])
 178 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 179 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube])
 180
 181 #############################
 182 ##  Optional dependencies  ##
 183 #############################
 184
 185 # Initialize pkg-config.
 186 # We require at least 0.22, as "Requires.private" behaviour changed there.
 187 PKG_PROG_PKG_CONFIG([0.22])
 188
 189 # This variable collects the pkg-config module names of all dependencies.
 190 # These are used to derive the compiler flags and for the "Requires.private"
 191 # field in the generated libsigrok.pc file.
 192 SR_PKGLIBS=
 193 SR_PKGLIBS_CHECK=
 194 SR_PKGLIBS_CXX=
 195 SR_PKGLIBS_PYTHON=
 196
 197 # Keep track of all checked modules so we can list them at the end.
 198 sr_pkglibs_summary=
 199 sr_nl='
 200 '
 201 ## SR_PKG_CHECK(tag, [collect-var], module...)
 202 m4_define([SR_PKG_CHECK], [
 203         sr_mod_leader=`printf '%.32s' "$3................................"`
 204         PKG_CHECK_EXISTS([$3], [
 205                 sr_have_$1=yes
 206                 m4_ifval([$2], [$2="[$]$2[$]{$2:+ }$3"])
 207                 sr_$1_version=`$PKG_CONFIG --modversion "$3" 2>&AS_MESSAGE_LOG_FD`
 208                 AS_VAR_APPEND([sr_pkglibs_summary], [" - $sr_mod_leader $sr_$1_version$sr_nl"])
 209         ], [
 210                 sr_$1_version=
 211                 AS_VAR_APPEND([sr_pkglibs_summary], [" - $sr_mod_leader no$sr_nl"])
 212                 m4_ifval([$4], [SR_PKG_CHECK([$1], [$2], m4_shift3($@))], [sr_have_$1=no])
 213         ])
 214 ])
 215
 216 ## SR_ARG_OPT_PKG(opt-name, [cpp-name], [cond-name], module...)
 217 m4_define([SR_ARG_OPT_PKG], [
 218         AC_ARG_WITH([$1], [AS_HELP_STRING([--without-$1],
 219                         [disable $1 support [default=detect]])])
 220         AS_IF([test "x$with_$1" = xno], [sr_have_$1=no],
 221                 [test "x$sr_have_$1" != xyes],
 222                         [SR_PKG_CHECK([$1], [SR_PKGLIBS], m4_shift3($@))])
 223         AS_IF([test "x$with_$1$sr_have_$1" = xyesno],
 224                 [AC_MSG_ERROR([$1 support requested, but it was not found.])])
 225         m4_ifval([$2], [AS_IF([test "x$sr_have_$1" = xyes], [
 226                 AC_DEFINE([HAVE_$2], [1], [Whether $1 is available.])
 227                 AC_DEFINE_UNQUOTED([CONF_$2_VERSION], ["$sr_$1_version"], [Build-time version of $1.])
 228         ])])
 229         m4_ifval([$3], [AM_CONDITIONAL([$3], [test "x$sr_have_$1" = xyes])])
 230 ])
 231
 232 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
 233         [libserialport >= 0.1.1])
 234 AS_IF([test "x$sr_have_libserialport" != xyes], [
 235         HW_AGILENT_DMM="no"; HW_APPA_55II="no";
 236         HW_ATTEN_PPS3XXX="no"; HW_BRYMEN_DMM="no"; HW_CEM_DT_885X="no";
 237         HW_CENTER_3XX="no"; HW_COLEAD_SLM="no"; HW_CONRAD_DIGI_35_CPU="no";
 238         HW_DEREE_DE5000="no"; HW_FLUKE_DMM="no"; HW_GMC_MH_1X_2X="no";
 239         HW_HAMEG_HMO="no"; HW_MANSON_HCS_3XXX="no"; HW_MIC_985XX="no";
 240         HW_MOTECH_LPS_30X="no"; HW_NORMA_DMM="no";
 241         HW_OPENBENCH_LOGIC_SNIFFER="no"; HW_SERIAL_DMM="no";
 242         HW_TELEINFO="no"; HW_TONDAJ_SL_814="no";
 243 ])
 244
 245 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 246         [libftdi >= 0.16], [libftdi1 >= 1.0])
 247 AS_IF([test "x$sr_have_libftdi" != xyes], [
 248         HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA="no"; HW_IKALOGIC_SCANAPLUS="no";
 249         HW_PIPISTRELLO_OLS="no";
 250 ])
 251
 252 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 253 # This means libusb-1.0 is always available; no need to check for it.
 254 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
 255
 256 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 257         [libusb-1.0 >= 1.0.16])
 258 AS_IF([test "x$sr_have_libusb" != xyes], [
 259         HW_BRYMEN_BM86X="no"; HW_FX2LAFW="no";
 260         HW_HANTEK_DSO="no"; HW_IKALOGIC_SCANALOGIC2="no";
 261         HW_KECHENG_KC_330B="no"; HW_LASCAR_EL_USB="no";
 262         HW_SYSCLK_LWLA="no"; HW_TESTO="no"; HW_UNI_T_DMM="no";
 263         HW_UNI_T_UT32X="no"; HW_VICTOR_DMM="no";
 264         HW_ZEROPLUS_LOGIC_CUBE="no"; HW_SALEAE_LOGIC16="no";
 265 ])
 266
 267 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 268         [librevisa >= 0.0.20130412])
 269
 270 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 271         [libgpib])
 272
 273 ######################
 274 ##  Feature checks  ##
 275 ######################
 276
 277 # The Check unit testing framework is optional. Disable if not found.
 278 SR_PKG_CHECK([check], [SR_PKGLIBS_CHECK], [check >= 0.9.4])
 279 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 280
 281 AC_LANG([C])
 282
 283 # Check host characteristics.
 284 AC_C_BIGENDIAN
 285
 286 # The BeagleLogic driver needs sys/mman.h and sys/ioctl.h. Don't try to
 287 # build it if these headers aren't available.
 288 AC_CHECK_HEADERS([sys/mman.h sys/ioctl.h],, [HW_BEAGLELOGIC=no])
 289
 290 # The BayLibre ACME driver needs sys/timerfd.h. Don't try to build it if
 291 # this header isn't available.
 292 AC_CHECK_HEADERS([sys/timerfd.h],, [HW_BAYLIBRE_ACME=no])
 293
 294 # RPC is only needed for VXI support.
 295 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 296         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 297                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 298                         [[(void) clnt_create("", 0, 0, "");]])],
 299                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 300 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 301         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 302 # VXI support is only compiled if RPC support was found.
 303 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 304
 305 AC_LANG([C++])
 306
 307 ###############################
 308 ##  Language bindings setup  ##
 309 ###############################
 310
 311 AC_ARG_ENABLE([bindings],
 312         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 313         [], [enable_bindings=yes])
 314
 315 AC_ARG_ENABLE([cxx],
 316         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 317         [], [enable_cxx=$enable_bindings])
 318
 319 AC_ARG_ENABLE([python],
 320         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 321         [], [enable_python=$enable_bindings])
 322
 323 AC_ARG_ENABLE([java],
 324         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 325         [], [enable_java=$enable_bindings])
 326
 327 ####################
 328 ##  C++ bindings  ##
 329 ####################
 330
 331 sr_cxx_missing=
 332
 333 # Check if the C++ compiler supports the C++11 standard.
 334 m4_ifdef([AX_CXX_COMPILE_STDCXX_11],
 335         [AX_CXX_COMPILE_STDCXX_11(, [optional])],
 336         [m4_warn(, [[Missing macro AX_CXX_COMPILE_STDCXX_11: no C++11 check possible]])])
 337 test "x$HAVE_CXX11" = x1 || sr_cxx_missing="$sr_cxx_missing C++11"
 338
 339 # The C++ bindings need glibmm.
 340 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 341 test "x$sr_have_glibmm" = xyes || sr_cxx_missing="$sr_cxx_missing glibmm"
 342
 343 # The C++ bindings use Doxygen to parse libsigrok symbols.
 344 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 345 test "x$HAVE_DOXYGEN" = xyes || sr_cxx_missing="$sr_cxx_missing Doxygen"
 346
 347 # Python is needed for the C++ bindings.
 348 AM_PATH_PYTHON([2.7],
 349         [HAVE_PYTHON=yes],
 350         [HAVE_PYTHON=no sr_cxx_missing="$sr_cxx_missing Python"])
 351
 352 AS_IF([test -z "$sr_cxx_missing"],
 353         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 354 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 355
 356 # C++ bindings want stoi and stod.
 357 AM_COND_IF([BINDINGS_CXX], [
 358         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 359                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 360                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 361                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 362         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 363                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 364                         [Specifies whether we have the stoi and stod functions.])])
 365 ])
 366
 367 #######################
 368 ##  Python bindings  ##
 369 #######################
 370
 371 sr_python_missing=
 372 test "x$BINDINGS_CXX" = xyes || sr_python_missing=" C++ bindings"
 373
 374 # The Python bindings need Python development files.
 375 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 376         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 377 test "x$sr_have_python_dev" = xyes \
 378         || sr_python_missing="$sr_python_missing Headers"
 379
 380 # PyGObject is needed for the Python bindings.
 381 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 382 test "x$sr_have_python_dev" = xyes \
 383         || sr_python_missing="$sr_python_missing PyGObject"
 384
 385 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 386         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 387                 [Whether last argument to pyg_flags_get_value() is signed.])])
 388
 389 # The Python bindings need the setuptools Python module.
 390 # We'll let it go through even if the AX macro wasn't found,
 391 # as the Python module may still be there.
 392 HAVE_PYMOD_SETUPTOOLS=yes
 393 m4_ifdef([AX_PYTHON_MODULE],
 394         [AX_PYTHON_MODULE([setuptools])],
 395         [m4_warn(, [[Missing macro AX_PYTHON_MODULE: no setuptools check]])])
 396 test "x$HAVE_PYMOD_SETUPTOOLS" = xyes \
 397         || sr_python_missing="$sr_python_missing Setuptools"
 398
 399 # The Python bindings use SWIG to generate code.
 400 AC_CHECK_PROG([HAVE_SWIG], [swig], [yes], [no])
 401 test "x$HAVE_SWIG" = xyes || sr_python_missing="$sr_python_missing SWIG"
 402
 403 AS_IF([test -z "$sr_python_missing"],
 404         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 405 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 406
 407 ####################
 408 ##  Java bindings ##
 409 ####################
 410
 411 sr_java_missing=
 412 test "x$BINDINGS_CXX" = xyes || sr_java_missing=" C++ bindings"
 413
 414 # The Java bindings use SWIG to generate code.
 415 test "x$HAVE_SWIG" = xyes || sr_java_missing="$sr_java_missing SWIG"
 416
 417 # Find Java compiler and JNI includes for Java bindings.
 418 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 419 test "x$HAVE_JAVAC" = xyes || sr_java_missing="$sr_java_missing JavaC"
 420
 421 AC_ARG_WITH([jni-include-path],
 422         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 423                 [specify JNI include directories [default=detect]])],
 424         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 425
 426 JNI_CPPFLAGS=
 427 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 428         AX_PROG_JAVAC
 429         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 430                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 431                 ## If we can find jni.h without any special search path, skip
 432                 ## the execution of the broken macro to increase our chances of
 433                 ## success.
 434                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 435                         [AX_JNI_INCLUDE_DIR])
 436         ])
 437 ])
 438 for sr_dir in $JNI_INCLUDE_DIRS
 439 do
 440         JNI_CPPFLAGS="$JNI_CPPFLAGS -I$sr_dir"
 441 done
 442 AC_SUBST([JNI_CPPFLAGS])
 443
 444 sr_save_cppflags=$CPPFLAGS
 445 CPPFLAGS=$CPPFLAGS$JNI_CPPFLAGS
 446 AC_CHECK_HEADER([jni.h],, [sr_java_missing="$sr_java_missing JNI headers"])
 447 CPPFLAGS=$sr_save_cppflags
 448
 449 AS_IF([test -z "$sr_java_missing"],
 450         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 451 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 452
 453 ##############################
 454 ##  Finalize configuration  ##
 455 ##############################
 456
 457 # Add mandatory dependencies to module list.
 458 SR_PKGLIBS="$SR_PKGLIBS${SR_PKGLIBS:+ }libzip >= 0.10"
 459 AC_SUBST([SR_PKGLIBS])
 460
 461 # Retrieve the compile and link flags for all modules combined.
 462 # Also, bail out at this point if any module dependency is not met.
 463 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 464 PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 465 PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 466 PKG_CHECK_MODULES([CHECK], [$SR_PKGLIBS_CHECK glib-2.0 $SR_PKGLIBS])
 467
 468 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 469 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 470
 471 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 472         [Build-time version of libzip.])
 473 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 474         [The canonical host libsigrok will run on.])
 475
 476 AC_LANG([C])
 477
 478 # libm (the standard math library) is always needed.
 479 AC_SEARCH_LIBS([pow], [m])
 480
 481 # We need to link against the Winsock2 library for SCPI over TCP.
 482 AS_CASE([$host], [*mingw*], [LIBS="$LIBS -lws2_32"])
 483
 484 AC_SUBST([FIRMWARE_DIR], ['$(datadir)/sigrok-firmware'])
 485 AC_SUBST([MAKEFLAGS], ['--no-print-directory'])
 486 AC_SUBST([AM_LIBTOOLFLAGS], ['--silent'])
 487
 488 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 489
 490 AC_OUTPUT
 491
 492 # Prepare bindings report messages.
 493 m4_define([sr_prepare_binding_report], [
 494         AS_IF([test "x$enable_$1" = xyes],
 495                 [sr_report_$1=$sr_$1_missing],
 496                 [sr_report_$1=' (disabled)'])
 497 ])
 498 m4_map_args([sr_prepare_binding_report], [cxx], [python], [java])
 499
 500 cat >&AS_MESSAGE_FD <<_EOF
 501
 502 libsigrok configuration summary:
 503  - Package version................. $SR_PACKAGE_VERSION
 504  - Library ABI version............. $SR_LIB_VERSION
 505  - Prefix.......................... $prefix
 506  - Building on..................... $build
 507  - Building for.................... $host
 508
 509 Detected libraries (required):
 510  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 511  - libzip >= 0.10.................. $sr_libzip_version
 512
 513 Detected libraries (optional):
 514 $sr_pkglibs_summary
 515
 516 Enabled hardware drivers:
 517 SR_DRIVER_SUMMARY
 518
 519 Enabled SCPI backends:
 520  - TCP............................. yes
 521  - RPC............................. $sr_cv_have_rpc
 522  - serial.......................... $sr_have_libserialport
 523  - VISA............................ $sr_have_librevisa
 524  - GPIB............................ $sr_have_libgpib
 525  - USBTMC.......................... $sr_have_libusb
 526
 527 Enabled language bindings:
 528  - C++............................. $BINDINGS_CXX$sr_report_cxx
 529  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 530  - Java............................ $BINDINGS_JAVA$sr_report_java
 531
 532 _EOF