configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrok (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SR_LIB_VERSION_CURRENT=1
  70 SR_LIB_VERSION_REVISION=0
  71 SR_LIB_VERSION_AGE=0
  72 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  73 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  74 AC_SUBST(SR_LIB_VERSION_CURRENT)
  75 AC_SUBST(SR_LIB_VERSION_REVISION)
  76 AC_SUBST(SR_LIB_VERSION_AGE)
  77 AC_SUBST(SR_LIB_VERSION)
  78 AC_SUBST(SR_LIB_LDFLAGS)
  79
  80 # Hardware support '--enable' options.
  81
  82 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  83         [enable all drivers by default [default=yes]]),
  84         [HW_ENABLED_DEFAULT="$enableval"],
  85         [HW_ENABLED_DEFAULT="yes"])
  86
  87 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  88         [enable Agilent DMM support [default=yes]]),
  89         [HW_AGILENT_DMM="$enableval"],
  90         [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  91
  92 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  93         [enable ALSA driver support [default=yes]]),
  94         [HW_ALSA="$enableval"],
  95         [HW_ALSA=$HW_ENABLED_DEFAULT])
  96
  97 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  98         [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
  99         [HW_ASIX_SIGMA="$enableval"],
 100         [HW_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 101
 102 AC_ARG_ENABLE(brymen-dmm, AC_HELP_STRING([--enable-brymen-dmm],
 103         [enable Brymen DMM support [default=yes]]),
 104         [HW_BRYMEN_DMM="$enableval"],
 105         [HW_BRYMEN_DMM=$HW_ENABLED_DEFAULT])
 106
 107 AC_ARG_ENABLE(cem-dt-885x, AC_HELP_STRING([--enable-cem-dt-885x],
 108         [enable CEM DT-885x support [default=yes]]),
 109         [HW_CEM_DT_885X="$enableval"],
 110         [HW_CEM_DT_885X=yes])
 111
 112 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 113         [enable ChronoVu LA8 support [default=yes]]),
 114         [HW_CHRONOVU_LA8="$enableval"],
 115         [HW_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 116
 117 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 118         [enable Colead SLM support [default=yes]]),
 119         [HW_COLEAD_SLM="$enableval"],
 120         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 121
 122 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 123         [enable demo driver support [default=yes]]),
 124         [HW_DEMO="$enableval"],
 125         [HW_DEMO=$HW_ENABLED_DEFAULT])
 126
 127 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 128         [enable Fluke DMM support [default=yes]]),
 129         [HW_FLUKE_DMM="$enableval"],
 130         [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 131
 132 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 133         [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 134         [HW_FX2LAFW="$enableval"],
 135         [HW_FX2LAFW=$HW_ENABLED_DEFAULT])
 136
 137 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 138         [enable Hantek DSO support [default=yes]]),
 139         [HW_HANTEK_DSO="$enableval"],
 140         [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 141
 142 AC_ARG_ENABLE(ikalogic-scanalogic2, AC_HELP_STRING([--enable-ikalogic-scanalogic2],
 143         [enable IKALOGIC Scanalogic2 support [default=yes]]),
 144         [HW_IKALOGIC_SCANALOGIC2="$enableval"],
 145         [HW_IKALOGIC_SCANALOGIC2=yes])
 146
 147 AC_ARG_ENABLE(ikalogic-scanaplus, AC_HELP_STRING([--enable-ikalogic-scanaplus],
 148         [enable Ikalogic ScanaPLUS support [default=yes]]),
 149         [HW_IKALOGIC_SCANAPLUS="$enableval"],
 150         [HW_IKALOGIC_SCANAPLUS=yes])
 151
 152 AC_ARG_ENABLE(kecheng-kc-330b, AC_HELP_STRING([--enable-kecheng-kc-330b],
 153         [enable Kecheng KC-330B support [default=yes]]),
 154         [HW_KECHENG_KC_330B="$enableval"],
 155         [HW_KECHENG_KC_330B=yes])
 156
 157 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 158         [enable Lascar EL-USB support [default=yes]]),
 159         [HW_LASCAR_EL_USB="$enableval"],
 160         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 161
 162 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 163         [enable Link Instruments MSO-19 support [default=yes]]),
 164         [HW_LINK_MSO19="$enableval"],
 165         [HW_LINK_MSO19=$HW_ENABLED_DEFAULT])
 166
 167 AC_ARG_ENABLE(mic-985xx, AC_HELP_STRING([--enable-mic-985xx],
 168         [enable MIC 985xx support [default=yes]]),
 169         [HW_MIC_985XX="$enableval"],
 170         [HW_MIC_985XX=$HW_ENABLED_DEFAULT])
 171
 172 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 173         [enable Nexus Osciprime support [default=yes]]),
 174         [HW_NEXUS_OSCIPRIME="$enableval"],
 175         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 176
 177 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 178         [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 179         [HW_OLS="$enableval"],
 180         [HW_OLS=$HW_ENABLED_DEFAULT])
 181
 182 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 183         [enable Rigol DS1xx2 support [default=yes]]),
 184         [HW_RIGOL_DS1XX2="$enableval"],
 185         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 186
 187 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 188         [enable serial DMM support [default=yes]]),
 189         [HW_SERIAL_DMM="$enableval"],
 190         [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 191
 192 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 193         [enable Tondaj SL-814 support [default=yes]]),
 194         [HW_TONDAJ_SL_814="$enableval"],
 195         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 196
 197 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 198         [enable UNI-T DMM support [default=yes]]),
 199         [HW_UNI_T_DMM="$enableval"],
 200         [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 201
 202 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 203         [enable victor-dmm support [default=yes]]),
 204         [HW_VICTOR_DMM="$enableval"],
 205         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 206
 207 AC_ARG_ENABLE(zeroplus-logic-cube,
 208         AC_HELP_STRING([--enable-zeroplus-logic-cube],
 209         [enable ZEROPLUS Logic Cube support [default=yes]]),
 210         [HW_ZEROPLUS_LOGIC_CUBE="$enableval"],
 211         [HW_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 212
 213 # Checks for libraries.
 214
 215 # This variable collects the pkg-config names of all detected libs.
 216 # It is then used to construct the "Requires.private:" field in the
 217 # libsigrok.pc file.
 218 SR_PKGLIBS=""
 219
 220 # libm (the standard math library) is always needed.
 221 AC_SEARCH_LIBS([pow], [m])
 222
 223 # libglib-2.0 is always needed. Abort if it's not found.
 224 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 225 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 226 AM_PATH_GLIB_2_0([2.32.0],
 227         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 228
 229 # libzip is always needed. Abort if it's not found.
 230 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 231         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 232         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 233
 234 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 235 # drivers if it is not found.
 236 case "$host" in
 237 *freebsd*)
 238         # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 239         # This means libusb-1.0 is always available, no need to check for it,
 240         # and no need to (potentially) disable any drivers if it's not found.
 241         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 242                 [Specifies whether we have a libusb.h header.])
 243         ;;
 244 *)
 245         PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 246                 [have_libusb1_0="yes"; CFLAGS="$CFLAGS $libusb_CFLAGS";
 247                 LIBS="$LIBS $libusb_LIBS";
 248                 SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 249                 [have_libusb1_0="no"; HW_FX2LAFW="no"; HW_HANTEK_DSO="no";
 250                 HW_IKALOGIC_SCANALOGIC2="no"; HW_LASCAR_EL_USB="no";
 251                 HW_NEXUS_OSCIPRIME="no"; HW_UNI_T_DMM="no"; HW_VICTOR_DMM="no";
 252                 HW_ZEROPLUS_LOGIC_CUBE="no"])
 253
 254         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 255         if test "x$have_libusb1_0" != "xno"; then
 256                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 257                         [Specifies whether we have a libusb.h header.])
 258         fi
 259         ;;
 260 esac
 261
 262 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 263 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 264
 265 # libftdi is only needed for some hardware drivers. Disable them if not found.
 266 PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 267         [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 268         LIBS="$LIBS $libftdi_LIBS";
 269         SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 270         [HW_ASIX_SIGMA="no"; HW_CHRONOVU_LA8="no"])
 271
 272 # libudev is only needed for some hardware drivers. Disable them if not found.
 273 PKG_CHECK_MODULES([libudev], [libudev >= 151],
 274         [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 275         SR_PKGLIBS="$SR_PKGLIBS libudev"],
 276         [HW_LINK_MSO19="no"])
 277
 278 # ALSA is only needed for some hardware drivers. Disable them if not found.
 279 PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 280         [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 281         SR_PKGLIBS="$SR_PKGLIBS alsa"],
 282         [HW_ALSA="no"])
 283
 284 # The Check unit testing framework is optional. Disable if not found.
 285 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 286         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
 287         LIBS="$LIBS $check_LIBS"], [have_check="no"])
 288 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 289
 290 # The Rigol DS1xx2 driver currently uses the Linux kernel usbtmc module
 291 # (though it is planned to rewrite the driver to be portable later).
 292 # Thus, it will be disabled for non-Linux builds for now.
 293 case "$host" in
 294 *linux*)
 295         # Do nothing. Whether the driver is enabled is determined by the
 296         # previous --enable-all-drivers/--disable-all-drivers and/or any
 297         # --enable-rigol-ds1xx2/--disable-rigol-ds1xx2 options.
 298         ;;
 299 *)
 300         # Disable the driver for builds that don't target Linux.
 301         HW_RIGOL_DS1XX2="no"
 302         ;;
 303 esac
 304
 305 AC_SUBST(SR_PKGLIBS)
 306
 307 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 308
 309 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 310 if test "x$HW_AGILENT_DMM" = "xyes"; then
 311         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 312 fi
 313
 314 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
 315 if test "x$HW_ALSA" = "xyes"; then
 316         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 317 fi
 318
 319 AM_CONDITIONAL(HW_ASIX_SIGMA, test x$HW_ASIX_SIGMA = xyes)
 320 if test "x$HW_ASIX_SIGMA" = "xyes"; then
 321         AC_DEFINE(HAVE_HW_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 322 fi
 323
 324 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 325 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 326         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 327 fi
 328
 329 AM_CONDITIONAL(HW_CEM_DT_885X, test x$HW_CEM_DT_885X = xyes)
 330 if test "x$HW_CEM_DT_885X" = "xyes"; then
 331         AC_DEFINE(HAVE_HW_CEM_DT_885X, 1, [CEM DT-885x support])
 332 fi
 333
 334 AM_CONDITIONAL(HW_CHRONOVU_LA8, test x$HW_CHRONOVU_LA8 = xyes)
 335 if test "x$HW_CHRONOVU_LA8" = "xyes"; then
 336         AC_DEFINE(HAVE_HW_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 337 fi
 338
 339 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 340 if test "x$HW_COLEAD_SLM" = "xyes"; then
 341         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 342 fi
 343
 344 AM_CONDITIONAL(HW_DEMO, test x$HW_DEMO = xyes)
 345 if test "x$HW_DEMO" = "xyes"; then
 346         AC_DEFINE(HAVE_HW_DEMO, 1, [Demo driver support])
 347 fi
 348
 349 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 350 if test "x$HW_FLUKE_DMM" = "xyes"; then
 351         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 352 fi
 353
 354 AM_CONDITIONAL(HW_FX2LAFW, test x$HW_FX2LAFW = xyes)
 355 if test "x$HW_FX2LAFW" = "xyes"; then
 356         AC_DEFINE(HAVE_HW_FX2LAFW, 1, [fx2lafw support])
 357 fi
 358
 359 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 360 if test "x$HW_HANTEK_DSO" = "xyes"; then
 361         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 362 fi
 363
 364 AM_CONDITIONAL(HW_IKALOGIC_SCANALOGIC2, test x$HW_IKALOGIC_SCANALOGIC2 = xyes)
 365 if test "x$HW_IKALOGIC_SCANALOGIC2" = "xyes"; then
 366         AC_DEFINE(HAVE_HW_IKALOGIC_SCANALOGIC2, 1, [IKALOGIC Scanalogic2 support])
 367 fi
 368
 369 AM_CONDITIONAL(HW_IKALOGIC_SCANAPLUS, test x$HW_IKALOGIC_SCANAPLUS = xyes)
 370 if test "x$HW_IKALOGIC_SCANAPLUS" = "xyes"; then
 371         AC_DEFINE(HAVE_HW_IKALOGIC_SCANAPLUS, 1, [Ikalogic ScanaPLUS support])
 372 fi
 373
 374 AM_CONDITIONAL(HW_KECHENG_KC_330B, test x$HW_KECHENG_KC_330B = xyes)
 375 if test "x$HW_KECHENG_KC_330B" = "xyes"; then
 376         AC_DEFINE(HAVE_HW_KECHENG_KC_330B, 1, [Kecheng KC-330B support])
 377 fi
 378
 379 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 380 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 381         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 382 fi
 383
 384 AM_CONDITIONAL(HW_LINK_MSO19, test x$HW_LINK_MSO19 = xyes)
 385 if test "x$HW_LINK_MSO19" = "xyes"; then
 386         AC_DEFINE(HAVE_HW_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 387 fi
 388
 389 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 390 if test "x$HW_MIC_985XX" = "xyes"; then
 391         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 392 fi
 393
 394 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 395 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 396         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 397 fi
 398
 399 AM_CONDITIONAL(HW_OLS, test x$HW_OLS = xyes)
 400 if test "x$HW_OLS" = "xyes"; then
 401         AC_DEFINE(HAVE_HW_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 402 fi
 403
 404 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 405 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 406         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 407 fi
 408
 409 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 410 if test "x$HW_SERIAL_DMM" = "xyes"; then
 411         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 412 fi
 413
 414 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 415 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 416         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 417 fi
 418
 419 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 420 if test "x$HW_UNI_T_DMM" = "xyes"; then
 421         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 422 fi
 423
 424 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 425 if test "x$HW_VICTOR_DMM" = "xyes"; then
 426         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 427 fi
 428
 429 AM_CONDITIONAL(HW_ZEROPLUS_LOGIC_CUBE, test x$HW_ZEROPLUS_LOGIC_CUBE = xyes)
 430 if test "x$HW_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 431         AC_DEFINE(HAVE_HW_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 432 fi
 433
 434 # Checks for header files.
 435 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 436 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 437
 438 # Checks for typedefs, structures, and compiler characteristics.
 439 AC_C_INLINE
 440 AC_TYPE_INT8_T
 441 AC_TYPE_INT16_T
 442 AC_TYPE_INT32_T
 443 AC_TYPE_INT64_T
 444 AC_TYPE_UINT8_T
 445 AC_TYPE_UINT16_T
 446 AC_TYPE_UINT32_T
 447 AC_TYPE_UINT64_T
 448 AC_TYPE_SIZE_T
 449
 450 # Checks for library functions.
 451 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 452
 453 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 454 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 455 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 456
 457 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 458 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 459 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 460 SR_PACKAGE_VERSION=sr_package_version
 461
 462 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 463 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 464 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 465 AC_SUBST(SR_PACKAGE_VERSION)
 466
 467 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 468                  hardware/agilent-dmm/Makefile
 469                  hardware/alsa/Makefile
 470                  hardware/asix-sigma/Makefile
 471                  hardware/brymen-dmm/Makefile
 472                  hardware/cem-dt-885x/Makefile
 473                  hardware/chronovu-la8/Makefile
 474                  hardware/colead-slm/Makefile
 475                  hardware/common/Makefile
 476                  hardware/ikalogic-scanalogic2/Makefile
 477                  hardware/ikalogic-scanaplus/Makefile
 478                  hardware/kecheng-kc-330b/Makefile
 479                  hardware/lascar-el-usb/Makefile
 480                  hardware/mic-985xx/Makefile
 481                  hardware/nexus-osciprime/Makefile
 482                  hardware/rigol-ds1xx2/Makefile
 483                  hardware/tondaj-sl-814/Makefile
 484                  hardware/victor-dmm/Makefile
 485                  hardware/common/dmm/Makefile
 486                  hardware/demo/Makefile
 487                  hardware/fluke-dmm/Makefile
 488                  hardware/fx2lafw/Makefile
 489                  hardware/hantek-dso/Makefile
 490                  hardware/link-mso19/Makefile
 491                  hardware/openbench-logic-sniffer/Makefile
 492                  hardware/serial-dmm/Makefile
 493                  hardware/uni-t-dmm/Makefile
 494                  hardware/zeroplus-logic-cube/Makefile
 495                  input/Makefile
 496                  output/Makefile
 497                  output/text/Makefile
 498                  libsigrok.pc
 499                  contrib/Makefile
 500                  tests/Makefile
 501                 ])
 502
 503 AC_OUTPUT
 504
 505 echo
 506 echo "libsigrok configuration summary:"
 507 echo
 508 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 509 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 510 echo "  - Prefix: $prefix"
 511 echo "  - Building on: $build"
 512 echo "  - Building for: $host"
 513 echo
 514 echo "Detected libraries:"
 515 echo
 516
 517 # Note: This only works for libs with pkg-config integration.
 518 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.8" "libusb-1.0 >= 1.0.9" "libftdi >= 0.16" "libudev >= 151" "alsa >= 1.0" "check >= 0.9.4"; do
 519         if `$PKG_CONFIG --exists $lib`; then
 520                 ver=`$PKG_CONFIG --modversion $lib`
 521                 answer="yes ($ver)"
 522         else
 523                 answer="no"
 524         fi
 525         echo "  - $lib: $answer"
 526 done
 527
 528 echo -e "\nEnabled hardware drivers:\n"
 529 echo "  - agilent-dmm..................... $HW_AGILENT_DMM"
 530 echo "  - alsa............................ $HW_ALSA"
 531 echo "  - asix-sigma...................... $HW_ASIX_SIGMA"
 532 echo "  - brymen-dmm...................... $HW_BRYMEN_DMM"
 533 echo "  - cem-dt-885x..................... $HW_CEM_DT_885X"
 534 echo "  - chronovu-la8.................... $HW_CHRONOVU_LA8"
 535 echo "  - colead-slm...................... $HW_COLEAD_SLM"
 536 echo "  - demo............................ $HW_DEMO"
 537 echo "  - fluke-dmm....................... $HW_FLUKE_DMM"
 538 echo "  - fx2lafw......................... $HW_FX2LAFW"
 539 echo "  - hantek-dso...................... $HW_HANTEK_DSO"
 540 echo "  - ikalogic-scanalogic2............ $HW_IKALOGIC_SCANALOGIC2"
 541 echo "  - ikalogic-scanaplus.............. $HW_IKALOGIC_SCANAPLUS"
 542 echo "  - kecheng-kc-330b................. $HW_KECHENG_KC_330B"
 543 echo "  - lascar-el-usb................... $HW_LASCAR_EL_USB"
 544 echo "  - link-mso19...................... $HW_LINK_MSO19"
 545 echo "  - mic-985xx....................... $HW_MIC_985XX"
 546 echo "  - nexus-osciprime................. $HW_NEXUS_OSCIPRIME"
 547 echo "  - openbench-logic-sniffer......... $HW_OLS"
 548 echo "  - rigol-ds1xx2.................... $HW_RIGOL_DS1XX2"
 549 echo "  - serial-dmm...................... $HW_SERIAL_DMM"
 550 echo "  - tondaj-sl-814................... $HW_TONDAJ_SL_814"
 551 echo "  - uni-t-dmm....................... $HW_UNI_T_DMM"
 552 echo "  - victor-dmm...................... $HW_VICTOR_DMM"
 553 echo "  - zeroplus-logic-cube............. $HW_ZEROPLUS_LOGIC_CUBE"
 554 echo
 555