configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AH_TOP([#ifndef SR_CONFIG_H
  37 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  38 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  39
  40 # Checks for programs.
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AC_PROG_INSTALL
  44 AC_PROG_LN_S
  45
  46 # Required for per-target flags or subdir-objects with C sources.
  47 AM_PROG_CC_C_O
  48
  49 # Initialize libtool.
  50 LT_INIT
  51
  52 # Set up the libsigrok version defines.
  53 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  54
  55 # Library version for libsigrok (NOT the same as the package version).
  56 # Carefully read the libtool docs before updating these numbers!
  57 # The algorithm for determining which number to change (and how) is nontrivial!
  58 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  59 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  60
  61 #############################
  62 ##  Optional dependencies  ##
  63 #############################
  64
  65 # Initialize pkg-config.
  66 # We require at least 0.22, as "Requires.private" behaviour changed there.
  67 PKG_PROG_PKG_CONFIG([0.22])
  68
  69 # Keep track of all checked modules so we can list them at the end.
  70 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  71
  72 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  73 # These are used to derive the compiler flags and for the "Requires.private"
  74 # field in the generated libsigrok.pc file.
  75 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  76 SR_PKGLIBS_TESTS=
  77 SR_PKGLIBS_CXX=
  78 SR_PKGLIBS_PYTHON=
  79
  80 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  81         [libserialport >= 0.1.1])
  82
  83 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
  84         [libftdi1 >= 1.0], [libftdi >= 0.16])
  85
  86 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
  87 # This means libusb-1.0 is always available; no need to check for it.
  88 AS_CASE([$host], [*freebsd*], [sr_have_libusb=yes])
  89
  90 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
  91         [libusb-1.0 >= 1.0.16])
  92
  93 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
  94         [librevisa >= 0.0.20130412])
  95
  96 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
  97         [libgpib])
  98
  99 ######################
 100 ##  Feature checks  ##
 101 ######################
 102
 103 # The Check unit testing framework is optional. Disable if not found.
 104 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 105 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 106
 107 AC_LANG([C])
 108
 109 # Enable the C99 standard if possible, and enforce the use
 110 # of SR_API to explicitly mark all public API functions.
 111 SR_EXTRA_CFLAGS=
 112 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 113 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 114
 115 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 116
 117 # Check host characteristics.
 118 AC_C_BIGENDIAN
 119
 120 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 121 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 122 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 123
 124 # We need to link against the Winsock2 library for SCPI over TCP.
 125 AS_CASE([$host], [*-mingw*], [SR_EXTRA_LIBS='-lws2_32'], [SR_EXTRA_LIBS=])
 126
 127 # libm (the standard math library) is always needed.
 128 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 129
 130 # RPC is only needed for VXI support.
 131 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 132         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 133                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 134                         [[(void) clnt_create("", 0, 0, "");]])],
 135                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 136 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 137         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 138 # VXI support is only compiled if RPC support was found.
 139 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 140
 141 ########################
 142 ##  Hardware drivers  ##
 143 ########################
 144
 145 # Keep track of all drivers so we can list them at the end.
 146 SR_VAR_SUMMARY([sr_driver_summary])
 147
 148 # Check whether the sr_deps_avail list contains all of the arguments.
 149 # Unavailable dependencies are collected in sr_deps_missing.
 150 sr_check_driver_deps() {
 151         sr_deps_missing=
 152         for sr_dep
 153         do
 154                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 155                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 156         done
 157         test -z "$sr_deps_missing" || return 1
 158 }
 159
 160 AC_ARG_ENABLE([all-drivers],
 161         [AS_HELP_STRING([--enable-all-drivers],
 162                         [enable all drivers by default [default=yes]])],
 163         [], [enable_all_drivers=yes])
 164
 165 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 166 m4_define([_SR_DRIVER], [
 167         AC_ARG_ENABLE([$2],
 168                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 169                 [$3=$enableval], [$3=$enable_all_drivers])
 170
 171         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 172                 sr_check_driver_deps $4 \
 173                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 174         ])], [sr_hw_info='no (disabled)'])
 175         sr_driver_summary_append "$2" "$sr_hw_info"
 176
 177         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 178         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 179 ])
 180
 181 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 182 m4_define([SR_DRIVER],
 183         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 184
 185 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 186 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 187 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 188 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 189 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 190 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 191 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 192 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 193 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 194 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 195 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 196 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 197 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 198 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 199 SR_DRIVER([demo], [demo])
 200 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 201 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 202 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 203 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 204 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 205 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 206 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 207 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 208 SR_DRIVER([KERN scale], [kern-scale])
 209 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 210 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 211 SR_DRIVER([maynuo-m97], [maynuo-m97])
 212 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 213 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 214 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 215 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 216 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 217 SR_DRIVER([Rigol DS], [rigol-ds])
 218 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 219 SR_DRIVER([SCPI PPS], [scpi-pps])
 220 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 221 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 222 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 223 SR_DRIVER([Testo], [testo], [libusb])
 224 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 225 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 226 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 227 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 228 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 229 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 230
 231 ###############################
 232 ##  Language bindings setup  ##
 233 ###############################
 234
 235 AC_LANG([C++])
 236 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 237
 238 AC_ARG_ENABLE([bindings],
 239         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 240         [], [enable_bindings=yes])
 241
 242 AC_ARG_ENABLE([cxx],
 243         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 244         [], [enable_cxx=$enable_bindings])
 245
 246 AC_ARG_ENABLE([python],
 247         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 248         [], [enable_python=$enable_bindings])
 249
 250 AC_ARG_ENABLE([java],
 251         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 252         [], [enable_java=$enable_bindings])
 253
 254 ####################
 255 ##  C++ bindings  ##
 256 ####################
 257
 258 sr_cxx_missing=
 259
 260 # Check if the C++ compiler supports the C++11 standard.
 261 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 262 AS_IF([test "x$HAVE_CXX11" != x1],
 263         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 264
 265 # The C++ bindings need glibmm.
 266 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 267 AS_IF([test "x$sr_have_glibmm" != xyes],
 268         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 269
 270 # The C++ bindings use Doxygen to parse libsigrok symbols.
 271 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 272 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 273         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 274
 275 # Python is needed for the C++ bindings.
 276 AM_PATH_PYTHON([2.7],
 277         [HAVE_PYTHON=yes],
 278         [HAVE_PYTHON=no
 279         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 280
 281 AS_IF([test -z "$sr_cxx_missing"],
 282         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 283 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 284
 285 # C++ bindings want stoi and stod.
 286 AM_COND_IF([BINDINGS_CXX], [
 287         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 288                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 289                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 290                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 291         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 292                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 293                         [Specifies whether we have the stoi and stod functions.])])
 294 ])
 295
 296 #######################
 297 ##  Python bindings  ##
 298 #######################
 299
 300 AS_IF([test "x$BINDINGS_CXX" = xyes],
 301         [sr_python_missing=],
 302         [sr_python_missing='C++ bindings'])
 303
 304 # The Python bindings need Python development files.
 305 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 306         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 307 AS_IF([test "x$sr_have_python_dev" != xyes],
 308         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 309
 310 # PyGObject is needed for the Python bindings.
 311 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 312 AS_IF([test "x$sr_have_pygobject" != xyes],
 313         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 314
 315 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 316         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 317                 [Whether last argument to pyg_flags_get_value() is signed.])])
 318
 319 # The Python bindings need the setuptools Python module.
 320 # We'll let it go through even if the AX macro wasn't found,
 321 # as the Python module may still be there.
 322 HAVE_PYMOD_SETUPTOOLS=yes
 323 m4_ifdef([AX_PYTHON_MODULE],
 324         [AX_PYTHON_MODULE([setuptools])],
 325         [m4_warn([unsupported], [Missing macro AX_PYTHON_MODULE: no setuptools check])])
 326 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 327         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 328
 329 # The Python bindings use SWIG to generate code.
 330 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 331 AS_IF([test "x$SWIG" = x],
 332         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 333
 334 AS_IF([test -z "$sr_python_missing"],
 335         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 336 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 337
 338 ####################
 339 ##  Java bindings ##
 340 ####################
 341
 342 AS_IF([test "x$BINDINGS_CXX" = xyes],
 343         [sr_java_missing=],
 344         [sr_java_missing='C++ bindings'])
 345
 346 # The Java bindings use SWIG to generate code.
 347 AS_IF([test "x$SWIG" = x],
 348         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 349
 350 # Find Java compiler and JNI includes for Java bindings.
 351 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 352 AS_IF([test "x$HAVE_JAVAC" = xno],
 353         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 354
 355 AC_ARG_WITH([jni-include-path],
 356         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 357                 [specify JNI include directories [default=detect]])],
 358         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 359
 360 JNI_CPPFLAGS=
 361 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 362         AX_PROG_JAVAC
 363         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 364                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 365                 ## If we can find jni.h without any special search path, skip
 366                 ## the execution of the broken macro to increase our chances of
 367                 ## success.
 368                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 369                         [AX_JNI_INCLUDE_DIR])
 370         ])
 371 ])
 372 for sr_dir in $JNI_INCLUDE_DIRS
 373 do
 374         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 375 done
 376 AC_SUBST([JNI_CPPFLAGS])
 377
 378 sr_save_cppflags=$CPPFLAGS
 379 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 380 AC_CHECK_HEADER([jni.h],,
 381         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 382 CPPFLAGS=$sr_save_cppflags
 383
 384 AS_IF([test -z "$sr_java_missing"],
 385         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 386 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 387
 388 ##############################
 389 ##  Finalize configuration  ##
 390 ##############################
 391
 392 # Add mandatory dependencies to module list.
 393 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 394 AC_SUBST([SR_PKGLIBS])
 395
 396 # Retrieve the compile and link flags for all modules combined.
 397 # Also, bail out at this point if any module dependency is not met.
 398 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 399 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 400
 401 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 402 # the C++ bindings are enabled.
 403 AM_COND_IF([BINDINGS_CXX], [
 404         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 405         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 406 ])
 407 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 408 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 409
 410 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 411         [Build-time version of libzip.])
 412 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 413         [The canonical host libsigrok will run on.])
 414
 415 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 416
 417 AC_OUTPUT
 418
 419 # Prepare bindings report messages.
 420 m4_define([SR_PREPARE_BINDING_REPORT], [
 421         sr_report_$1=
 422         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 423         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 424 ])
 425 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 426
 427 cat >&AS_MESSAGE_FD <<_EOF
 428
 429 libsigrok configuration summary:
 430  - Package version................. $SR_PACKAGE_VERSION
 431  - Library ABI version............. $SR_LIB_VERSION
 432  - Prefix.......................... $prefix
 433  - Building on..................... $build
 434  - Building for.................... $host
 435  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 436  - C compiler warnings............. $SR_WFLAGS
 437  - C++ compiler warnings........... $SR_WXXFLAGS
 438
 439 Detected libraries (required):
 440  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 441  - libzip >= 0.10.................. $sr_libzip_version
 442
 443 Detected libraries (optional):
 444 $sr_pkglibs_summary
 445 Enabled hardware drivers:
 446 $sr_driver_summary
 447 Enabled SCPI backends:
 448  - TCP............................. yes
 449  - RPC............................. $sr_cv_have_rpc
 450  - serial.......................... $sr_have_libserialport
 451  - VISA............................ $sr_have_librevisa
 452  - GPIB............................ $sr_have_libgpib
 453  - USBTMC.......................... $sr_have_libusb
 454
 455 Enabled language bindings:
 456  - C++............................. $BINDINGS_CXX$sr_report_cxx
 457  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 458  - Java............................ $BINDINGS_JAVA$sr_report_java
 459
 460 _EOF