configure.ac

   1 ##
   2 ## This file is part of the sigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror std-options check-news])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrok (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SR_LIB_VERSION_CURRENT=2
  70 SR_LIB_VERSION_REVISION=0
  71 SR_LIB_VERSION_AGE=0
  72 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  73 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  74 AC_SUBST(SR_LIB_VERSION_CURRENT)
  75 AC_SUBST(SR_LIB_VERSION_REVISION)
  76 AC_SUBST(SR_LIB_VERSION_AGE)
  77 AC_SUBST(SR_LIB_VERSION)
  78 AC_SUBST(SR_LIB_LDFLAGS)
  79
  80 # Hardware support '--enable' options.
  81
  82 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  83         [enable all drivers by default [default=yes]]),
  84         [HW_ENABLED_DEFAULT="$enableval"],
  85         [HW_ENABLED_DEFAULT="yes"])
  86
  87 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  88         [enable Agilent DMM support [default=yes]]),
  89         [HW_AGILENT_DMM="$enableval"],
  90         [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  91 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
  92 if test "x$HW_AGILENT_DMM" = "xyes"; then
  93         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
  94 fi
  95
  96 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  97         [enable ALSA driver support [default=yes]]),
  98         [HW_ALSA="$enableval"],
  99         [HW_ALSA=$HW_ENABLED_DEFAULT])
 100 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
 101 if test "x$HW_ALSA" = "xyes"; then
 102         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 103 fi
 104
 105 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
 106         [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
 107         [LA_ASIX_SIGMA="$enableval"],
 108         [LA_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 109 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 110 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 111         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 112 fi
 113
 114 AC_ARG_ENABLE(brymen-dmm, AC_HELP_STRING([--enable-brymen-dmm],
 115         [enable Brymen DMM support [default=yes]]),
 116         [HW_BRYMEN_DMM="$enableval"],
 117         [HW_BRYMEN_DMM=yes])
 118 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 119 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 120         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [brymen-dmm support])
 121 fi
 122
 123 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 124         [enable ChronoVu LA8 support [default=yes]]),
 125         [LA_CHRONOVU_LA8="$enableval"],
 126         [LA_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 127 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 128 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 129         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 130 fi
 131
 132 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 133         [enable Colead SLM support [default=yes]]),
 134         [HW_COLEAD_SLM="$enableval"],
 135         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 136 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 137 if test "x$HW_COLEAD_SLM" = "xyes"; then
 138         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 139 fi
 140
 141 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 142         [enable demo driver support [default=yes]]),
 143         [LA_DEMO="$enableval"],
 144         [LA_DEMO=$HW_ENABLED_DEFAULT])
 145 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 146 if test "x$LA_DEMO" = "xyes"; then
 147         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 148 fi
 149
 150 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 151         [enable Fluke DMM support [default=yes]]),
 152         [HW_FLUKE_DMM="$enableval"],
 153         [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 154 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 155 if test "x$HW_FLUKE_DMM" = "xyes"; then
 156         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 157 fi
 158
 159 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 160         [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 161         [LA_FX2LAFW="$enableval"],
 162         [LA_FX2LAFW=$HW_ENABLED_DEFAULT])
 163 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 164 if test "x$LA_FX2LAFW" = "xyes"; then
 165         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 166 fi
 167
 168 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 169         [enable Hantek DSO support [default=yes]]),
 170         [HW_HANTEK_DSO="$enableval"],
 171         [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 172 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 173 if test "x$HW_HANTEK_DSO" = "xyes"; then
 174         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 175 fi
 176
 177 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 178         [enable Lascar EL-USB support [default=yes]]),
 179         [HW_LASCAR_EL_USB="$enableval"],
 180         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 181 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 182 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 183         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 184 fi
 185
 186 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 187         [enable Link Instruments MSO-19 support [default=yes]]),
 188         [LA_LINK_MSO19="$enableval"],
 189         [LA_LINK_MSO19=$HW_ENABLED_DEFAULT])
 190 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 191 if test "x$LA_LINK_MSO19" = "xyes"; then
 192         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 193 fi
 194
 195 AC_ARG_ENABLE(mic-985xx, AC_HELP_STRING([--enable-mic-985xx],
 196         [enable MIC 985xx support [default=yes]]),
 197         [HW_MIC_985XX="$enableval"],
 198         [HW_MIC_985XX=yes])
 199 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 200 if test "x$HW_MIC_985XX" = "xyes"; then
 201         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 202 fi
 203
 204 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 205         [enable Nexus Osciprime support [default=yes]]),
 206         [HW_NEXUS_OSCIPRIME="$enableval"],
 207         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 208 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 209 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 210         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 211 fi
 212
 213 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 214         [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 215         [LA_OLS="$enableval"],
 216         [LA_OLS=$HW_ENABLED_DEFAULT])
 217 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 218 if test "x$LA_OLS" = "xyes"; then
 219         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 220 fi
 221
 222 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 223         [enable Rigol DS1xx2 support [default=yes]]),
 224         [HW_RIGOL_DS1XX2="$enableval"],
 225         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 226 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 227 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 228         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 229 fi
 230
 231 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 232         [enable serial DMM support [default=yes]]),
 233         [HW_SERIAL_DMM="$enableval"],
 234         [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 235 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 236 if test "x$HW_SERIAL_DMM" = "xyes"; then
 237         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 238 fi
 239
 240 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 241         [enable Tondaj SL-814 support [default=yes]]),
 242         [HW_TONDAJ_SL_814="$enableval"],
 243         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 244 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 245 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 246         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 247 fi
 248
 249 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 250         [enable UNI-T DMM support [default=yes]]),
 251         [HW_UNI_T_DMM="$enableval"],
 252         [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 253 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 254 if test "x$HW_UNI_T_DMM" = "xyes"; then
 255         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 256 fi
 257
 258 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 259         [enable victor-dmm support [default=yes]]),
 260         [HW_VICTOR_DMM="$enableval"],
 261         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 262 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 263 if test "x$HW_VICTOR_DMM" = "xyes"; then
 264         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [victor-dmm support])
 265 fi
 266
 267 AC_ARG_ENABLE(zeroplus-logic-cube,
 268         AC_HELP_STRING([--enable-zeroplus-logic-cube],
 269         [enable ZEROPLUS Logic Cube support [default=yes]]),
 270         [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 271         [LA_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 272 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 273 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 274         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 275 fi
 276
 277 # Checks for libraries.
 278
 279 # This variable collects the pkg-config names of all detected libs.
 280 # It is then used to construct the "Requires.private:" field in the
 281 # libsigrok.pc file.
 282 SR_PKGLIBS=""
 283
 284 # libglib-2.0 is always needed.
 285 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 286 AM_PATH_GLIB_2_0([2.28.0],
 287         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 288
 289 # libusb-1.0 is only needed for some hardware drivers.
 290 if test "x$LA_ASIX_SIGMA" != xno \
 291    -o "x$LA_CHRONOVU_LA8" != xno \
 292    -o "x$LA_FX2LAFW" != xno \
 293    -o "x$HW_HANTEK_DSO" != xno \
 294    -o "x$LA_ZEROPLUS_LOGIC_CUBE" != xno; then
 295         case "$build" in
 296         *freebsd*)
 297                 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 298                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 299                         [Specifies whether we have a libusb.h header.])
 300                 ;;
 301         *)
 302                 PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 303                         [CFLAGS="$CFLAGS $libusb_CFLAGS";
 304                         LIBS="$LIBS $libusb_LIBS";
 305                         SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"])
 306                 # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 307                 if test "x$libusb_CFLAGS" != "x"; then
 308                         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 309                                 [Specifies whether we have a libusb.h header.])
 310                 fi
 311                 ;;
 312         esac
 313 fi
 314
 315 # libzip is always needed.
 316 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 317         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 318         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 319
 320 # libftdi is only needed for some hardware drivers.
 321 if test "x$LA_ASIX_SIGMA" != xno \
 322      -o "x$LA_CHRONOVU_LA8" != xno; then
 323         PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 324                 [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 325                 LIBS="$LIBS $libftdi_LIBS";
 326                 SR_PKGLIBS="$SR_PKGLIBS libftdi"])
 327 fi
 328
 329 # libudev is only needed for some hardware drivers.
 330 if test "x$LA_LINK_MSO19" != xno; then
 331         PKG_CHECK_MODULES([libudev], [libudev >= 151],
 332                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 333                 SR_PKGLIBS="$SR_PKGLIBS libudev"])
 334 fi
 335
 336 # ALSA is only needed for some hardware drivers.
 337 if test "x$HW_ALSA" != xno; then
 338         PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 339                 [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 340                 SR_PKGLIBS="$SR_PKGLIBS alsa"])
 341 fi
 342
 343 # The Check unit testing framework is optional.
 344 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 345         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
 346         LIBS="$LIBS $check_LIBS"], [have_check="no"])
 347 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 348
 349 # EZUSB FX2 firmware helper code is only needed for some hardware drivers.
 350 AM_CONDITIONAL(NEED_EZUSB, \
 351         test "x$LA_FX2LAFW" != xno \
 352         -o "x$HW_HANTEK_DSO" != xno \
 353 )
 354
 355 # Serial port helper code is only needed for some hardware drivers.
 356 AM_CONDITIONAL(NEED_SERIAL, \
 357         test "x$HW_AGILENT_DMM" != xno \
 358         -o "x$HW_COLEAD_SLM" != xno \
 359         -o "x$HW_FLUKE_DMM" != xno \
 360         -o "x$LA_LINK_MSO19" != xno \
 361         -o "x$LA_OLS" != xno \
 362         -o "x$HW_SERIAL_DMM" != xno \
 363         -o "x$HW_TONDAJ_SL_814" != xno \
 364 )
 365
 366 AC_SUBST(SR_PKGLIBS)
 367
 368 # Checks for header files.
 369 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 370 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 371
 372 # Checks for typedefs, structures, and compiler characteristics.
 373 AC_C_INLINE
 374 AC_TYPE_INT8_T
 375 AC_TYPE_INT16_T
 376 AC_TYPE_INT32_T
 377 AC_TYPE_INT64_T
 378 AC_TYPE_UINT8_T
 379 AC_TYPE_UINT16_T
 380 AC_TYPE_UINT32_T
 381 AC_TYPE_UINT64_T
 382 AC_TYPE_SIZE_T
 383
 384 # Checks for library functions.
 385 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 386
 387 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 388 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 389 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 390
 391 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 392 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 393 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 394 SR_PACKAGE_VERSION=sr_package_version
 395
 396 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 397 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 398 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 399 AC_SUBST(SR_PACKAGE_VERSION)
 400
 401 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 402                  hardware/agilent-dmm/Makefile
 403                  hardware/alsa/Makefile
 404                  hardware/asix-sigma/Makefile
 405                  hardware/brymen-dmm/Makefile
 406                  hardware/chronovu-la8/Makefile
 407                  hardware/colead-slm/Makefile
 408                  hardware/common/Makefile
 409                  hardware/lascar-el-usb/Makefile
 410                  hardware/mic-985xx/Makefile
 411                  hardware/nexus-osciprime/Makefile
 412                  hardware/rigol-ds1xx2/Makefile
 413                  hardware/tondaj-sl-814/Makefile
 414                  hardware/victor-dmm/Makefile
 415                  hardware/common/dmm/Makefile
 416                  hardware/demo/Makefile
 417                  hardware/fluke-dmm/Makefile
 418                  hardware/fx2lafw/Makefile
 419                  hardware/hantek-dso/Makefile
 420                  hardware/link-mso19/Makefile
 421                  hardware/openbench-logic-sniffer/Makefile
 422                  hardware/serial-dmm/Makefile
 423                  hardware/uni-t-dmm/Makefile
 424                  hardware/zeroplus-logic-cube/Makefile
 425                  input/Makefile
 426                  output/Makefile
 427                  output/text/Makefile
 428                  libsigrok.pc
 429                  contrib/Makefile
 430                  tests/Makefile
 431                 ])
 432
 433 AC_OUTPUT
 434
 435 echo
 436 echo "libsigrok configuration summary:"
 437 echo
 438 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 439 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 440 echo "  - Prefix: $prefix"
 441 echo
 442 echo "Detected libraries:"
 443 echo
 444
 445 # Note: This only works for libs with pkg-config integration.
 446 for lib in "glib-2.0" "libusb-1.0" "libzip" "libftdi" "libudev" "alsa" "check"; do
 447         if `$PKG_CONFIG --exists $lib`; then
 448                 ver=`$PKG_CONFIG --modversion $lib`
 449                 answer="yes ($ver)"
 450         else
 451                 answer="no"
 452         fi
 453         echo "  - $lib: $answer"
 454 done
 455
 456 echo -e "\nEnabled hardware drivers:\n"
 457 echo "  - Agilent DMM..................... $HW_AGILENT_DMM"
 458 echo "  - ALSA............................ $HW_ALSA"
 459 echo "  - ASIX SIGMA/SIGMA2............... $LA_ASIX_SIGMA"
 460 echo "  - Brymen DMM...................... $HW_BRYMEN_DMM"
 461 echo "  - ChronoVu LA8.................... $LA_CHRONOVU_LA8"
 462 echo "  - Colead SLM...................... $HW_COLEAD_SLM"
 463 echo "  - Demo driver..................... $LA_DEMO"
 464 echo "  - Fluke DMM....................... $HW_FLUKE_DMM"
 465 echo "  - fx2lafw (for FX2 LAs)........... $LA_FX2LAFW"
 466 echo "  - Hantek DSO...................... $HW_HANTEK_DSO"
 467 echo "  - Lascar EL-USB................... $HW_LASCAR_EL_USB"
 468 echo "  - Link MSO-19..................... $LA_LINK_MSO19"
 469 echo "  - MIC 985xx....................... $HW_MIC_985XX"
 470 echo "  - Nexus Osciprime................. $HW_NEXUS_OSCIPRIME"
 471 echo "  - Openbench Logic Sniffer......... $LA_OLS"
 472 echo "  - Rigol DS1xx2.................... $HW_RIGOL_DS1XX2"
 473 echo "  - Serial DMM...................... $HW_SERIAL_DMM"
 474 echo "  - Tondaj SL-814................... $HW_TONDAJ_SL_814"
 475 echo "  - UNI-T DMM....................... $HW_UNI_T_DMM"
 476 echo "  - Victor DMM...................... $HW_VICTOR_DMM"
 477 echo "  - ZEROPLUS Logic Cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 478 echo
 479