configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libsigrok package version number (NOT the same as shared lib version!).
  25 m4_define([sr_package_version_major], [0])
  26 m4_define([sr_package_version_minor], [2])
  27 m4_define([sr_package_version_micro], [0])
  28 m4_define([sr_package_version], [sr_package_version_major.sr_package_version_minor.sr_package_version_micro])
  29
  30 AC_INIT([libsigrok], [sr_package_version], [sigrok-devel@lists.sourceforge.net],
  31         [libsigrok], [http://www.sigrok.org])
  32 AC_CONFIG_HEADER([config.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror check-news color-tests])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SR_CONFIG_H
  42 #define SR_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SR_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra. Add -fvisibility=hidden
  46 # and enforce use of SR_API to explicitly mark all public API functions.
  47 CFLAGS="$CFLAGS -Wall -Wextra -fvisibility=hidden"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libsigrok (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SR_LIB_VERSION_CURRENT=2
  70 SR_LIB_VERSION_REVISION=0
  71 SR_LIB_VERSION_AGE=0
  72 SR_LIB_VERSION="$SR_LIB_VERSION_CURRENT:$SR_LIB_VERSION_REVISION:$SR_LIB_VERSION_AGE"
  73 SR_LIB_LDFLAGS="-version-info $SR_LIB_VERSION"
  74 AC_SUBST(SR_LIB_VERSION_CURRENT)
  75 AC_SUBST(SR_LIB_VERSION_REVISION)
  76 AC_SUBST(SR_LIB_VERSION_AGE)
  77 AC_SUBST(SR_LIB_VERSION)
  78 AC_SUBST(SR_LIB_LDFLAGS)
  79
  80 # Hardware support '--enable' options.
  81
  82 AC_ARG_ENABLE(all-drivers, AC_HELP_STRING([--enable-all-drivers],
  83         [enable all drivers by default [default=yes]]),
  84         [HW_ENABLED_DEFAULT="$enableval"],
  85         [HW_ENABLED_DEFAULT="yes"])
  86
  87 AC_ARG_ENABLE(agilent-dmm, AC_HELP_STRING([--enable-agilent-dmm],
  88         [enable Agilent DMM support [default=yes]]),
  89         [HW_AGILENT_DMM="$enableval"],
  90         [HW_AGILENT_DMM=$HW_ENABLED_DEFAULT])
  91
  92 AC_ARG_ENABLE(alsa, AC_HELP_STRING([--enable-alsa],
  93         [enable ALSA driver support [default=yes]]),
  94         [HW_ALSA="$enableval"],
  95         [HW_ALSA=$HW_ENABLED_DEFAULT])
  96
  97 AC_ARG_ENABLE(asix-sigma, AC_HELP_STRING([--enable-asix-sigma],
  98         [enable ASIX SIGMA/SIGMA2 support [default=yes]]),
  99         [LA_ASIX_SIGMA="$enableval"],
 100         [LA_ASIX_SIGMA=$HW_ENABLED_DEFAULT])
 101
 102 AC_ARG_ENABLE(brymen-dmm, AC_HELP_STRING([--enable-brymen-dmm],
 103         [enable Brymen DMM support [default=yes]]),
 104         [HW_BRYMEN_DMM="$enableval"],
 105         [HW_BRYMEN_DMM=$HW_ENABLED_DEFAULT])
 106
 107 AC_ARG_ENABLE(chronovu-la8, AC_HELP_STRING([--enable-chronovu-la8],
 108         [enable ChronoVu LA8 support [default=yes]]),
 109         [LA_CHRONOVU_LA8="$enableval"],
 110         [LA_CHRONOVU_LA8=$HW_ENABLED_DEFAULT])
 111
 112 AC_ARG_ENABLE(colead-slm, AC_HELP_STRING([--enable-colead-slm],
 113         [enable Colead SLM support [default=yes]]),
 114         [HW_COLEAD_SLM="$enableval"],
 115         [HW_COLEAD_SLM=$HW_ENABLED_DEFAULT])
 116
 117 AC_ARG_ENABLE(demo, AC_HELP_STRING([--enable-demo],
 118         [enable demo driver support [default=yes]]),
 119         [LA_DEMO="$enableval"],
 120         [LA_DEMO=$HW_ENABLED_DEFAULT])
 121
 122 AC_ARG_ENABLE(fluke-dmm, AC_HELP_STRING([--enable-fluke-dmm],
 123         [enable Fluke DMM support [default=yes]]),
 124         [HW_FLUKE_DMM="$enableval"],
 125         [HW_FLUKE_DMM=$HW_ENABLED_DEFAULT])
 126
 127 AC_ARG_ENABLE(fx2lafw, AC_HELP_STRING([--enable-fx2lafw],
 128         [enable fx2lafw support (for FX2 LAs). [default=yes]]),
 129         [LA_FX2LAFW="$enableval"],
 130         [LA_FX2LAFW=$HW_ENABLED_DEFAULT])
 131
 132 AC_ARG_ENABLE(hantek-dso, AC_HELP_STRING([--enable-hantek-dso],
 133         [enable Hantek DSO support [default=yes]]),
 134         [HW_HANTEK_DSO="$enableval"],
 135         [HW_HANTEK_DSO=$HW_ENABLED_DEFAULT])
 136
 137 AC_ARG_ENABLE(lascar-el-usb, AC_HELP_STRING([--enable-lascar-el-usb],
 138         [enable Lascar EL-USB support [default=yes]]),
 139         [HW_LASCAR_EL_USB="$enableval"],
 140         [HW_LASCAR_EL_USB=$HW_ENABLED_DEFAULT])
 141
 142 AC_ARG_ENABLE(link-mso19, AC_HELP_STRING([--enable-link-mso19],
 143         [enable Link Instruments MSO-19 support [default=yes]]),
 144         [LA_LINK_MSO19="$enableval"],
 145         [LA_LINK_MSO19=$HW_ENABLED_DEFAULT])
 146
 147 AC_ARG_ENABLE(mic-985xx, AC_HELP_STRING([--enable-mic-985xx],
 148         [enable MIC 985xx support [default=yes]]),
 149         [HW_MIC_985XX="$enableval"],
 150         [HW_MIC_985XX=$HW_ENABLED_DEFAULT])
 151
 152 AC_ARG_ENABLE(nexus-osciprime, AC_HELP_STRING([--enable-nexus-osciprime],
 153         [enable Nexus Osciprime support [default=yes]]),
 154         [HW_NEXUS_OSCIPRIME="$enableval"],
 155         [HW_NEXUS_OSCIPRIME=$HW_ENABLED_DEFAULT])
 156
 157 AC_ARG_ENABLE(ols, AC_HELP_STRING([--enable-ols],
 158         [enable OpenBench Logic Sniffer (OLS) support [default=yes]]),
 159         [LA_OLS="$enableval"],
 160         [LA_OLS=$HW_ENABLED_DEFAULT])
 161
 162 AC_ARG_ENABLE(rigol-ds1xx2, AC_HELP_STRING([--enable-rigol-ds1xx2],
 163         [enable Rigol DS1xx2 support [default=yes]]),
 164         [HW_RIGOL_DS1XX2="$enableval"],
 165         [HW_RIGOL_DS1XX2=$HW_ENABLED_DEFAULT])
 166
 167 AC_ARG_ENABLE(serial-dmm, AC_HELP_STRING([--enable-serial-dmm],
 168         [enable serial DMM support [default=yes]]),
 169         [HW_SERIAL_DMM="$enableval"],
 170         [HW_SERIAL_DMM=$HW_ENABLED_DEFAULT])
 171
 172 AC_ARG_ENABLE(tondaj-sl-814, AC_HELP_STRING([--enable-tondaj-sl-814],
 173         [enable Tondaj SL-814 support [default=yes]]),
 174         [HW_TONDAJ_SL_814="$enableval"],
 175         [HW_TONDAJ_SL_814=$HW_ENABLED_DEFAULT])
 176
 177 AC_ARG_ENABLE(uni-t-dmm, AC_HELP_STRING([--enable-uni-t-dmm],
 178         [enable UNI-T DMM support [default=yes]]),
 179         [HW_UNI_T_DMM="$enableval"],
 180         [HW_UNI_T_DMM=$HW_ENABLED_DEFAULT])
 181
 182 AC_ARG_ENABLE(victor-dmm, AC_HELP_STRING([--enable-victor-dmm],
 183         [enable victor-dmm support [default=yes]]),
 184         [HW_VICTOR_DMM="$enableval"],
 185         [HW_VICTOR_DMM=$HW_ENABLED_DEFAULT])
 186
 187 AC_ARG_ENABLE(zeroplus-logic-cube,
 188         AC_HELP_STRING([--enable-zeroplus-logic-cube],
 189         [enable ZEROPLUS Logic Cube support [default=yes]]),
 190         [LA_ZEROPLUS_LOGIC_CUBE="$enableval"],
 191         [LA_ZEROPLUS_LOGIC_CUBE=$HW_ENABLED_DEFAULT])
 192
 193 # Checks for libraries.
 194
 195 # This variable collects the pkg-config names of all detected libs.
 196 # It is then used to construct the "Requires.private:" field in the
 197 # libsigrok.pc file.
 198 SR_PKGLIBS=""
 199
 200 # libglib-2.0 is always needed. Abort if it's not found.
 201 # Note: glib-2.0 is part of the libsigrok API (hard pkg-config requirement).
 202 # We require at least 2.32.0 due to e.g. g_variant_new_fixed_array().
 203 AM_PATH_GLIB_2_0([2.32.0],
 204         [CFLAGS="$CFLAGS $GLIB_CFLAGS"; LIBS="$LIBS $GLIB_LIBS"])
 205
 206 # libzip is always needed. Abort if it's not found.
 207 PKG_CHECK_MODULES([libzip], [libzip >= 0.8],
 208         [CFLAGS="$CFLAGS $libzip_CFLAGS"; LIBS="$LIBS $libzip_LIBS";
 209         SR_PKGLIBS="$SR_PKGLIBS libzip"])
 210
 211 # libusb-1.0 is only needed for some hardware drivers. Disable the respective
 212 # drivers if it is not found.
 213 case "$host" in
 214 *freebsd*)
 215         # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 216         # This means libusb-1.0 is always available, no need to check for it,
 217         # and no need to (potentially) disable any drivers if it's not found.
 218         AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 219                 [Specifies whether we have a libusb.h header.])
 220         ;;
 221 *)
 222         PKG_CHECK_MODULES([libusb], [libusb-1.0 >= 1.0.9],
 223                 [have_libusb1_0="yes"; CFLAGS="$CFLAGS $libusb_CFLAGS";
 224                 LIBS="$LIBS $libusb_LIBS";
 225                 SR_PKGLIBS="$SR_PKGLIBS libusb-1.0"],
 226                 [have_libusb1_0="no"; LA_FX2LAFW="no"; HW_HANTEK_DSO="no";
 227                 HW_LASCAR_EL_USB="no"; HW_NEXUS_OSCIPRIME="no";
 228                 HW_UNI_T_DMM="no"; HW_VICTOR_DMM="no";
 229                 LA_ZEROPLUS_LOGIC_CUBE="no"])
 230
 231         # Define HAVE_LIBUSB_1_0 in config.h if we found libusb-1.0.
 232         if test "x$have_libusb1_0" != "xno"; then
 233                 AC_DEFINE_UNQUOTED(HAVE_LIBUSB_1_0, [1],
 234                         [Specifies whether we have a libusb.h header.])
 235         fi
 236         ;;
 237 esac
 238
 239 # USB + FX2 firmware helper code is only compiled in if libusb-1.0 was found.
 240 AM_CONDITIONAL(NEED_USB, test "x$have_libusb1_0" != xno)
 241
 242 # libftdi is only needed for some hardware drivers. Disable them if not found.
 243 PKG_CHECK_MODULES([libftdi], [libftdi >= 0.16],
 244         [CFLAGS="$CFLAGS $libftdi_CFLAGS";
 245         LIBS="$LIBS $libftdi_LIBS";
 246         SR_PKGLIBS="$SR_PKGLIBS libftdi"],
 247         [LA_ASIX_SIGMA="no"; LA_CHRONOVU_LA8="no"])
 248
 249 # libudev is only needed for some hardware drivers. Disable them if not found.
 250 PKG_CHECK_MODULES([libudev], [libudev >= 151],
 251         [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
 252         SR_PKGLIBS="$SR_PKGLIBS libudev"],
 253         [LA_LINK_MSO19="no"])
 254
 255 # ALSA is only needed for some hardware drivers. Disable them if not found.
 256 PKG_CHECK_MODULES([alsa], [alsa >= 1.0],
 257         [CFLAGS="$CFLAGS $alsa_CFLAGS"; LIBS="$LIBS $alsa_LIBS";
 258         SR_PKGLIBS="$SR_PKGLIBS alsa"],
 259         [HW_ALSA="no"])
 260
 261 # The Check unit testing framework is optional. Disable if not found.
 262 PKG_CHECK_MODULES([check], [check >= 0.9.4],
 263         [have_check="yes"; CFLAGS="$CFLAGS $check_CFLAGS";
 264         LIBS="$LIBS $check_LIBS"], [have_check="no"])
 265 AM_CONDITIONAL(HAVE_CHECK, test x"$have_check" = "xyes")
 266
 267 # The Rigol DS1xx2 driver currently uses the Linux kernel usbtmc module
 268 # (though it is planned to rewrite the driver to be portable later).
 269 # Thus, it will be disabled for non-Linux builds for now.
 270 case "$host" in
 271 *linux*)
 272         # Do nothing. Whether the driver is enabled is determined by the
 273         # previous --enable-all-drivers/--disable-all-drivers and/or any
 274         # --enable-rigol-ds1xx2/--disable-rigol-ds1xx2 options.
 275         ;;
 276 *)
 277         # Disable the driver for builds that don't target Linux.
 278         HW_RIGOL_DS1XX2="no"
 279         ;;
 280 esac
 281
 282 AC_SUBST(SR_PKGLIBS)
 283
 284 # Now set AM_CONDITIONALs and AC_DEFINEs for the enabled/disabled drivers.
 285
 286 AM_CONDITIONAL(HW_AGILENT_DMM, test x$HW_AGILENT_DMM = xyes)
 287 if test "x$HW_AGILENT_DMM" = "xyes"; then
 288         AC_DEFINE(HAVE_HW_AGILENT_DMM, 1, [Agilent DMM support])
 289 fi
 290
 291 AM_CONDITIONAL(HW_ALSA, test x$HW_ALSA = xyes)
 292 if test "x$HW_ALSA" = "xyes"; then
 293         AC_DEFINE(HAVE_HW_ALSA, 1, [ALSA driver support])
 294 fi
 295
 296 AM_CONDITIONAL(LA_ASIX_SIGMA, test x$LA_ASIX_SIGMA = xyes)
 297 if test "x$LA_ASIX_SIGMA" = "xyes"; then
 298         AC_DEFINE(HAVE_LA_ASIX_SIGMA, 1, [ASIX SIGMA/SIGMA2 support])
 299 fi
 300
 301 AM_CONDITIONAL(HW_BRYMEN_DMM, test x$HW_BRYMEN_DMM = xyes)
 302 if test "x$HW_BRYMEN_DMM" = "xyes"; then
 303         AC_DEFINE(HAVE_HW_BRYMEN_DMM, 1, [Brymen DMM support])
 304 fi
 305
 306 AM_CONDITIONAL(LA_CHRONOVU_LA8, test x$LA_CHRONOVU_LA8 = xyes)
 307 if test "x$LA_CHRONOVU_LA8" = "xyes"; then
 308         AC_DEFINE(HAVE_LA_CHRONOVU_LA8, 1, [ChronoVu LA8 support])
 309 fi
 310
 311 AM_CONDITIONAL(HW_COLEAD_SLM, test x$HW_COLEAD_SLM = xyes)
 312 if test "x$HW_COLEAD_SLM" = "xyes"; then
 313         AC_DEFINE(HAVE_HW_COLEAD_SLM, 1, [Colead SLM support])
 314 fi
 315
 316 AM_CONDITIONAL(LA_DEMO, test x$LA_DEMO = xyes)
 317 if test "x$LA_DEMO" = "xyes"; then
 318         AC_DEFINE(HAVE_LA_DEMO, 1, [Demo driver support])
 319 fi
 320
 321 AM_CONDITIONAL(HW_FLUKE_DMM, test x$HW_FLUKE_DMM = xyes)
 322 if test "x$HW_FLUKE_DMM" = "xyes"; then
 323         AC_DEFINE(HAVE_HW_FLUKE_DMM, 1, [Fluke DMM support])
 324 fi
 325
 326 AM_CONDITIONAL(LA_FX2LAFW, test x$LA_FX2LAFW = xyes)
 327 if test "x$LA_FX2LAFW" = "xyes"; then
 328         AC_DEFINE(HAVE_LA_FX2LAFW, 1, [fx2lafw support])
 329 fi
 330
 331 AM_CONDITIONAL(HW_HANTEK_DSO, test x$HW_HANTEK_DSO = xyes)
 332 if test "x$HW_HANTEK_DSO" = "xyes"; then
 333         AC_DEFINE(HAVE_HW_HANTEK_DSO, 1, [Hantek DSO support])
 334 fi
 335
 336 AM_CONDITIONAL(HW_LASCAR_EL_USB, test x$HW_LASCAR_EL_USB = xyes)
 337 if test "x$HW_LASCAR_EL_USB" = "xyes"; then
 338         AC_DEFINE(HAVE_HW_LASCAR_EL_USB, 1, [Lascar EL-USB support])
 339 fi
 340
 341 AM_CONDITIONAL(LA_LINK_MSO19, test x$LA_LINK_MSO19 = xyes)
 342 if test "x$LA_LINK_MSO19" = "xyes"; then
 343         AC_DEFINE(HAVE_LA_LINK_MSO19, 1, [Link Instruments MSO-19 support])
 344 fi
 345
 346 AM_CONDITIONAL(HW_MIC_985XX, test x$HW_MIC_985XX = xyes)
 347 if test "x$HW_MIC_985XX" = "xyes"; then
 348         AC_DEFINE(HAVE_HW_MIC_985XX, 1, [MIC 985xx support])
 349 fi
 350
 351 AM_CONDITIONAL(HW_NEXUS_OSCIPRIME, test x$HW_NEXUS_OSCIPRIME = xyes)
 352 if test "x$HW_NEXUS_OSCIPRIME" = "xyes"; then
 353         AC_DEFINE(HAVE_HW_NEXUS_OSCIPRIME, 1, [Nexus Osciprime support])
 354 fi
 355
 356 AM_CONDITIONAL(LA_OLS, test x$LA_OLS = xyes)
 357 if test "x$LA_OLS" = "xyes"; then
 358         AC_DEFINE(HAVE_LA_OLS, 1, [OpenBench Logic Sniffer (OLS) support])
 359 fi
 360
 361 AM_CONDITIONAL(HW_RIGOL_DS1XX2, test x$HW_RIGOL_DS1XX2 = xyes)
 362 if test "x$HW_RIGOL_DS1XX2" = "xyes"; then
 363         AC_DEFINE(HAVE_HW_RIGOL_DS1XX2, 1, [Rigol DS1xx2 support])
 364 fi
 365
 366 AM_CONDITIONAL(HW_SERIAL_DMM, test x$HW_SERIAL_DMM = xyes)
 367 if test "x$HW_SERIAL_DMM" = "xyes"; then
 368         AC_DEFINE(HAVE_HW_SERIAL_DMM, 1, [Serial DMM support])
 369 fi
 370
 371 AM_CONDITIONAL(HW_TONDAJ_SL_814, test x$HW_TONDAJ_SL_814 = xyes)
 372 if test "x$HW_TONDAJ_SL_814" = "xyes"; then
 373         AC_DEFINE(HAVE_HW_TONDAJ_SL_814, 1, [Tondaj SL-814 support])
 374 fi
 375
 376 AM_CONDITIONAL(HW_UNI_T_DMM, test x$HW_UNI_T_DMM = xyes)
 377 if test "x$HW_UNI_T_DMM" = "xyes"; then
 378         AC_DEFINE(HAVE_HW_UNI_T_DMM, 1, [UNI-T DMM support])
 379 fi
 380
 381 AM_CONDITIONAL(HW_VICTOR_DMM, test x$HW_VICTOR_DMM = xyes)
 382 if test "x$HW_VICTOR_DMM" = "xyes"; then
 383         AC_DEFINE(HAVE_HW_VICTOR_DMM, 1, [Victor DMM support])
 384 fi
 385
 386 AM_CONDITIONAL(LA_ZEROPLUS_LOGIC_CUBE, test x$LA_ZEROPLUS_LOGIC_CUBE = xyes)
 387 if test "x$LA_ZEROPLUS_LOGIC_CUBE" = "xyes"; then
 388         AC_DEFINE(HAVE_LA_ZEROPLUS_LOGIC_CUBE, 1, [ZEROPLUS Logic Cube support])
 389 fi
 390
 391 # Checks for header files.
 392 # These are already checked: inttypes.h stdint.h stdlib.h string.h unistd.h.
 393 AC_CHECK_HEADERS([fcntl.h sys/time.h termios.h])
 394
 395 # Checks for typedefs, structures, and compiler characteristics.
 396 AC_C_INLINE
 397 AC_TYPE_INT8_T
 398 AC_TYPE_INT16_T
 399 AC_TYPE_INT32_T
 400 AC_TYPE_INT64_T
 401 AC_TYPE_UINT8_T
 402 AC_TYPE_UINT16_T
 403 AC_TYPE_UINT32_T
 404 AC_TYPE_UINT64_T
 405 AC_TYPE_SIZE_T
 406
 407 # Checks for library functions.
 408 AC_CHECK_FUNCS([gettimeofday memset strchr strcspn strdup strerror strncasecmp strstr strtol strtoul strtoull])
 409
 410 AC_SUBST(FIRMWARE_DIR, "$datadir/sigrok-firmware")
 411 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 412 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 413
 414 SR_PACKAGE_VERSION_MAJOR=sr_package_version_major
 415 SR_PACKAGE_VERSION_MINOR=sr_package_version_minor
 416 SR_PACKAGE_VERSION_MICRO=sr_package_version_micro
 417 SR_PACKAGE_VERSION=sr_package_version
 418
 419 AC_SUBST(SR_PACKAGE_VERSION_MAJOR)
 420 AC_SUBST(SR_PACKAGE_VERSION_MINOR)
 421 AC_SUBST(SR_PACKAGE_VERSION_MICRO)
 422 AC_SUBST(SR_PACKAGE_VERSION)
 423
 424 AC_CONFIG_FILES([Makefile version.h hardware/Makefile
 425                  hardware/agilent-dmm/Makefile
 426                  hardware/alsa/Makefile
 427                  hardware/asix-sigma/Makefile
 428                  hardware/brymen-dmm/Makefile
 429                  hardware/chronovu-la8/Makefile
 430                  hardware/colead-slm/Makefile
 431                  hardware/common/Makefile
 432                  hardware/lascar-el-usb/Makefile
 433                  hardware/mic-985xx/Makefile
 434                  hardware/nexus-osciprime/Makefile
 435                  hardware/rigol-ds1xx2/Makefile
 436                  hardware/tondaj-sl-814/Makefile
 437                  hardware/victor-dmm/Makefile
 438                  hardware/common/dmm/Makefile
 439                  hardware/demo/Makefile
 440                  hardware/fluke-dmm/Makefile
 441                  hardware/fx2lafw/Makefile
 442                  hardware/hantek-dso/Makefile
 443                  hardware/link-mso19/Makefile
 444                  hardware/openbench-logic-sniffer/Makefile
 445                  hardware/serial-dmm/Makefile
 446                  hardware/uni-t-dmm/Makefile
 447                  hardware/zeroplus-logic-cube/Makefile
 448                  input/Makefile
 449                  output/Makefile
 450                  output/text/Makefile
 451                  libsigrok.pc
 452                  contrib/Makefile
 453                  tests/Makefile
 454                 ])
 455
 456 AC_OUTPUT
 457
 458 echo
 459 echo "libsigrok configuration summary:"
 460 echo
 461 echo "  - Package version (major.minor.micro):    $SR_PACKAGE_VERSION"
 462 echo "  - Library version (current:revision:age): $SR_LIB_VERSION"
 463 echo "  - Prefix: $prefix"
 464 echo "  - Building on: $build"
 465 echo "  - Building for: $host"
 466 echo
 467 echo "Detected libraries:"
 468 echo
 469
 470 # Note: This only works for libs with pkg-config integration.
 471 for lib in "glib-2.0 >= 2.32.0" "libzip >= 0.8" "libusb-1.0 >= 1.0.9" "libftdi >= 0.16" "libudev >= 151" "alsa >= 1.0" "check >= 0.9.4"; do
 472         if `$PKG_CONFIG --exists $lib`; then
 473                 ver=`$PKG_CONFIG --modversion $lib`
 474                 answer="yes ($ver)"
 475         else
 476                 answer="no"
 477         fi
 478         echo "  - $lib: $answer"
 479 done
 480
 481 echo -e "\nEnabled hardware drivers:\n"
 482 echo "  - agilent-dmm..................... $HW_AGILENT_DMM"
 483 echo "  - alsa............................ $HW_ALSA"
 484 echo "  - asix-sigma...................... $LA_ASIX_SIGMA"
 485 echo "  - brymen-dmm...................... $HW_BRYMEN_DMM"
 486 echo "  - chronovu-la8.................... $LA_CHRONOVU_LA8"
 487 echo "  - colead-slm...................... $HW_COLEAD_SLM"
 488 echo "  - demo............................ $LA_DEMO"
 489 echo "  - fluke-dmm....................... $HW_FLUKE_DMM"
 490 echo "  - fx2lafw......................... $LA_FX2LAFW"
 491 echo "  - hantek-dso...................... $HW_HANTEK_DSO"
 492 echo "  - lascar-el-usb................... $HW_LASCAR_EL_USB"
 493 echo "  - link-mso19...................... $LA_LINK_MSO19"
 494 echo "  - mic-985xx....................... $HW_MIC_985XX"
 495 echo "  - nexus-osciprime................. $HW_NEXUS_OSCIPRIME"
 496 echo "  - openbench-logic-sniffer......... $LA_OLS"
 497 echo "  - rigol-ds1xx2.................... $HW_RIGOL_DS1XX2"
 498 echo "  - serial-dmm...................... $HW_SERIAL_DMM"
 499 echo "  - tondaj-sl-814................... $HW_TONDAJ_SL_814"
 500 echo "  - uni-t-dmm....................... $HW_UNI_T_DMM"
 501 echo "  - victor-dmm...................... $HW_VICTOR_DMM"
 502 echo "  - zeroplus-logic-cube............. $LA_ZEROPLUS_LOGIC_CUBE"
 503 echo
 504