configure.ac

   1 ##
   2 ## This file is part of the libsigrok project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU General Public License as published by
   9 ## the Free Software Foundation, either version 3 of the License, or
  10 ## (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([libsigrok], [0.4.0],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [libsigrok], [http://www.sigrok.org])
  27 AC_CONFIG_MACRO_DIR([m4])
  28 AC_CONFIG_AUX_DIR([autostuff])
  29 AC_CONFIG_HEADERS([config.h include/libsigrok/version.h])
  30
  31 # We require at least automake 1.11 (needed for 'silent rules').
  32 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests])
  33 AM_SILENT_RULES([yes])
  34 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  35
  36 AC_CANONICAL_HOST
  37
  38 # Checks for programs.
  39 AC_PROG_CC
  40 AC_PROG_CXX
  41 AC_PROG_INSTALL
  42 AC_PROG_LN_S
  43
  44 # Required for per-target flags or subdir-objects with C sources.
  45 AM_PROG_CC_C_O
  46
  47 # Set the standard the C library headers should conform to.
  48 AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */
  49 #ifndef _POSIX_C_SOURCE
  50 # define _POSIX_C_SOURCE 200112L
  51 #endif])
  52
  53 # Get compiler versions.
  54 SR_PROG_VERSION([$CC], [sr_cc_version])
  55 SR_PROG_VERSION([$CXX], [sr_cxx_version])
  56
  57 # Check for optional make features.
  58 SR_PROG_MAKE_ORDER_ONLY
  59
  60 # Initialize libtool.
  61 LT_INIT
  62
  63 # Set up the libsigrok version defines.
  64 SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION])
  65
  66 # Library version for libsigrok (NOT the same as the package version).
  67 # Carefully read the libtool docs before updating these numbers!
  68 # The algorithm for determining which number to change (and how) is nontrivial!
  69 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  70 SR_LIB_VERSION_SET([SR_LIB_VERSION], [2:0:0])
  71
  72 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  73
  74 #############################
  75 ##  Optional dependencies  ##
  76 #############################
  77
  78 AC_LANG([C])
  79
  80 # Initialize pkg-config.
  81 # We require at least 0.22, as "Requires.private" behaviour changed there.
  82 PKG_PROG_PKG_CONFIG([0.22])
  83
  84 # Keep track of all checked modules so we can list them at the end.
  85 SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary])
  86
  87 # Collect the pkg-config module names of all dependencies in SR_PKGLIBS.
  88 # These are used to derive the compiler flags and for the "Requires.private"
  89 # field in the generated libsigrok.pc file.
  90 SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail])
  91 SR_PKGLIBS_TESTS=
  92 SR_PKGLIBS_CXX=
  93 SR_PKGLIBS_PYTHON=
  94 SR_EXTRA_LIBS=
  95
  96 SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], [NEED_SERIAL],
  97         [libserialport >= 0.1.1])
  98
  99 SR_ARG_OPT_PKG([libftdi], [LIBFTDI],,
 100         [libftdi1 >= 1.0], [libftdi >= 0.16])
 101
 102 # FreeBSD comes with an "integrated" libusb-1.0-style USB API.
 103 # This means libusb-1.0 is always available; no need to check for it.
 104 # On Windows, require the latest version we can get our hands on,
 105 # until the new generic event handling has seen an official release.
 106 AS_CASE([$host_os],
 107         [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes],
 108         [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'],
 109         [sr_libusb_req='libusb-1.0 >= 1.0.16'])
 110
 111 SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB],
 112         [$sr_libusb_req])
 113
 114 SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA],
 115         [librevisa >= 0.0.20130412])
 116
 117 SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB],
 118         [libgpib])
 119
 120 SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [
 121         sr_save_LIBS=$LIBS
 122         LIBS="-lieee1284 $LIBS"
 123         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]],
 124                                 [[(void) ieee1284_open(0, 0, 0);]])],
 125                 [sr_have_libieee1284=yes], [sr_have_libieee1284=no])
 126         LIBS=$sr_save_LIBS
 127 ])
 128 AS_IF([test "x$sr_have_libieee1284" = xyes],
 129         [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])])
 130
 131 ######################
 132 ##  Feature checks  ##
 133 ######################
 134
 135 # The Check unit testing framework is optional. Disable if not found.
 136 SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4])
 137 AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes])
 138
 139 # Enable the C99 standard if possible, and enforce the use
 140 # of SR_API to explicitly mark all public API functions.
 141 SR_EXTRA_CFLAGS=
 142 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99])
 143 SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden])
 144
 145 SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes])
 146
 147 # Check host characteristics.
 148 AC_SYS_LARGEFILE
 149 AC_C_BIGENDIAN
 150
 151 AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])])
 152 AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])])
 153 AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])])
 154
 155 # We need to link against the Winsock2 library for SCPI over TCP.
 156 AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])])
 157
 158 # libm (the standard math library) is always needed.
 159 SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m])
 160
 161 # RPC is only needed for VXI support.
 162 AC_CACHE_CHECK([for RPC support], [sr_cv_have_rpc],
 163         [AC_LINK_IFELSE([AC_LANG_PROGRAM(
 164                         [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]],
 165                         [[(void) clnt_create("", 0, 0, "");]])],
 166                 [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no])])
 167 AS_IF([test "x$sr_cv_have_rpc" = xyes],
 168         [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support.])])
 169 # VXI support is only compiled if RPC support was found.
 170 AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes])
 171
 172 ########################
 173 ##  Hardware drivers  ##
 174 ########################
 175
 176 # Keep track of all drivers so we can list them at the end.
 177 SR_VAR_SUMMARY([sr_driver_summary])
 178
 179 # Check whether the sr_deps_avail list contains all of the arguments.
 180 # Unavailable dependencies are collected in sr_deps_missing.
 181 sr_check_driver_deps() {
 182         sr_deps_missing=
 183         for sr_dep
 184         do
 185                 AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],,
 186                         [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])])
 187         done
 188         test -z "$sr_deps_missing" || return 1
 189 }
 190
 191 AC_ARG_ENABLE([all-drivers],
 192         [AS_HELP_STRING([--enable-all-drivers],
 193                         [enable all drivers by default [default=yes]])],
 194         [], [enable_all_drivers=yes])
 195
 196 ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...])
 197 m4_define([_SR_DRIVER], [
 198         AC_ARG_ENABLE([$2],
 199                 [AS_HELP_STRING([--enable-$2], [enable $1 support])],
 200                 [$3=$enableval], [$3=$enable_all_drivers])
 201
 202         AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [
 203                 sr_check_driver_deps $4 \
 204                         || $3=no sr_hw_info="no (missing: $sr_deps_missing)"
 205         ])], [sr_hw_info='no (disabled)'])
 206         sr_driver_summary_append "$2" "$sr_hw_info"
 207
 208         AM_CONDITIONAL([$3], [test "x[$]$3" = xyes])
 209         AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.])])
 210 ])
 211
 212 ## SR_DRIVER(Device name, driver-name, [dependencies...])
 213 m4_define([SR_DRIVER],
 214         [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])])
 215
 216 SR_DRIVER([Agilent DMM], [agilent-dmm], [libserialport])
 217 SR_DRIVER([Appa 55II], [appa-55ii], [libserialport])
 218 SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi])
 219 SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [libserialport])
 220 SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h])
 221 SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h])
 222 SR_DRIVER([Brymen BM86x], [brymen-bm86x], [libusb])
 223 SR_DRIVER([Brymen DMM], [brymen-dmm], [libserialport])
 224 SR_DRIVER([CEM DT-885x], [cem-dt-885x], [libserialport])
 225 SR_DRIVER([Center 3xx], [center-3xx], [libserialport])
 226 SR_DRIVER([ChronoVu LA], [chronovu-la], [libftdi])
 227 SR_DRIVER([Colead SLM], [colead-slm], [libserialport])
 228 SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [libserialport])
 229 SR_DRIVER([DER EE DE-5000], [deree-de5000], [libserialport])
 230 SR_DRIVER([demo], [demo])
 231 SR_DRIVER([Fluke DMM], [fluke-dmm], [libserialport])
 232 SR_DRIVER([fx2lafw], [fx2lafw], [libusb])
 233 SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [libserialport])
 234 SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [libserialport])
 235 SR_DRIVER([Hameg HMO], [hameg-hmo], [libserialport])
 236 SR_DRIVER([Hantek DSO], [hantek-dso], [libusb])
 237 SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284])
 238 SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb])
 239 SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi])
 240 SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb])
 241 SR_DRIVER([KERN scale], [kern-scale], [libserialport])
 242 SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb])
 243 SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [libserialport])
 244 SR_DRIVER([maynuo-m97], [maynuo-m97])
 245 SR_DRIVER([MIC 985xx], [mic-985xx], [libserialport])
 246 SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [libserialport])
 247 SR_DRIVER([Norma DMM], [norma-dmm], [libserialport])
 248 SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [libserialport])
 249 SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi])
 250 SR_DRIVER([Rigol DS], [rigol-ds])
 251 SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb])
 252 SR_DRIVER([SCPI PPS], [scpi-pps])
 253 SR_DRIVER([serial DMM], [serial-dmm], [libserialport])
 254 SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb])
 255 SR_DRIVER([Teleinfo], [teleinfo], [libserialport])
 256 SR_DRIVER([Testo], [testo], [libusb])
 257 SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [libserialport])
 258 SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb])
 259 SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [libusb])
 260 SR_DRIVER([Victor DMM], [victor-dmm], [libusb])
 261 SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm])
 262 SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb])
 263
 264 ###############################
 265 ##  Language bindings setup  ##
 266 ###############################
 267
 268 AC_LANG([C++])
 269 SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra])
 270
 271 AC_ARG_ENABLE([bindings],
 272         [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])],
 273         [], [enable_bindings=yes])
 274
 275 AC_ARG_ENABLE([cxx],
 276         [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])],
 277         [], [enable_cxx=$enable_bindings])
 278
 279 AC_ARG_ENABLE([python],
 280         [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])],
 281         [], [enable_python=$enable_bindings])
 282
 283 AC_ARG_ENABLE([java],
 284         [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])],
 285         [], [enable_java=$enable_bindings])
 286
 287 ####################
 288 ##  C++ bindings  ##
 289 ####################
 290
 291 sr_cxx_missing=
 292
 293 # Check if the C++ compiler supports the C++11 standard.
 294 AX_CXX_COMPILE_STDCXX_11([noext], [optional])
 295 AS_IF([test "x$HAVE_CXX11" != x1],
 296         [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])])
 297
 298 # The C++ bindings need glibmm.
 299 SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0])
 300 AS_IF([test "x$sr_have_glibmm" != xyes],
 301         [SR_APPEND([sr_cxx_missing], [', '], [glibmm])])
 302
 303 # The C++ bindings use Doxygen to parse libsigrok symbols.
 304 AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no])
 305 AS_IF([test "x$HAVE_DOXYGEN" != xyes],
 306         [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])])
 307
 308 # Python is needed for the C++ bindings.
 309 AM_PATH_PYTHON([2.7],
 310         [HAVE_PYTHON=yes],
 311         [HAVE_PYTHON=no
 312         SR_APPEND([sr_cxx_missing], [', '], [Python])])
 313
 314 AS_IF([test -z "$sr_cxx_missing"],
 315         [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no])
 316 AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes])
 317
 318 # C++ bindings want stoi and stod.
 319 AM_COND_IF([BINDINGS_CXX], [
 320         AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod],
 321                 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]],
 322                                 [[(void) std::stoi("1"); (void) std::stod("1.0");]])],
 323                         [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])])
 324         AS_IF([test "x$sr_cv_have_stoi_stod" = xyes],
 325                 [AC_DEFINE([HAVE_STOI_STOD], [1],
 326                         [Specifies whether we have the stoi and stod functions.])])
 327 ])
 328
 329 #######################
 330 ##  Python bindings  ##
 331 #######################
 332
 333 AS_IF([test "x$BINDINGS_CXX" = xyes],
 334         [sr_python_missing=],
 335         [sr_python_missing='C++ bindings'])
 336
 337 # The Python bindings need Python development files.
 338 SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON],
 339         [python >= 2.7], [python2 >= 2.7], [python27 >= 2.7])
 340 AS_IF([test "x$sr_have_python_dev" != xyes],
 341         [SR_APPEND([sr_python_missing], [', '], [Headers])])
 342
 343 # PyGObject is needed for the Python bindings.
 344 SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0])
 345 AS_IF([test "x$sr_have_pygobject" != xyes],
 346         [SR_APPEND([sr_python_missing], [', '], [PyGObject])])
 347
 348 PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91],
 349         [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1],
 350                 [Whether last argument to pyg_flags_get_value() is signed.])])
 351
 352 # The Python bindings need the setuptools and numpy Python modules.
 353 # We'll let it go through even if the AX macro wasn't found, as the
 354 # Python modules may still be there.
 355 m4_ifdef([AX_PYTHON_MODULE], [
 356         AX_PYTHON_MODULE([setuptools])
 357         AX_PYTHON_MODULE([numpy])
 358 ], [
 359         HAVE_PYMOD_SETUPTOOLS=yes
 360         HAVE_PYMOD_NUMPY=yes
 361         m4_warn([unsupported],
 362                 [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy])
 363 ])
 364 AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes],
 365         [SR_APPEND([sr_python_missing], [', '], [setuptools])])
 366 AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes],
 367         [SR_APPEND([sr_python_missing], [', '], [numpy])])
 368
 369 # The Python bindings use SWIG to generate code.
 370 AC_CHECK_PROGS([SWIG], [swig swig3.0 swig2.0])
 371 AS_IF([test "x$SWIG" = x],
 372         [SR_APPEND([sr_python_missing], [', '], [SWIG])])
 373
 374 AS_IF([test -z "$sr_python_missing"],
 375         [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no])
 376 AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes])
 377
 378 ####################
 379 ##  Java bindings ##
 380 ####################
 381
 382 AS_IF([test "x$BINDINGS_CXX" = xyes],
 383         [sr_java_missing=],
 384         [sr_java_missing='C++ bindings'])
 385
 386 # The Java bindings use SWIG to generate code.
 387 AS_IF([test "x$SWIG" = x],
 388         [SR_APPEND([sr_java_missing], [', '], [SWIG])])
 389
 390 # Find Java compiler and JNI includes for Java bindings.
 391 AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no])
 392 AS_IF([test "x$HAVE_JAVAC" = xno],
 393         [SR_APPEND([sr_java_missing], [', '], [JavaC])])
 394
 395 AC_ARG_WITH([jni-include-path],
 396         [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]],
 397                 [specify JNI include directories [default=detect]])],
 398         [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=])
 399
 400 JNI_CPPFLAGS=
 401 AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [
 402         AX_PROG_JAVAC
 403         AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [
 404                 ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR:
 405                 ## If we can find jni.h without any special search path, skip
 406                 ## the execution of the broken macro to increase our chances of
 407                 ## success.
 408                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],,
 409                         [AX_JNI_INCLUDE_DIR])
 410         ])
 411 ])
 412 for sr_dir in $JNI_INCLUDE_DIRS
 413 do
 414         SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"])
 415 done
 416 AC_SUBST([JNI_CPPFLAGS])
 417
 418 sr_save_cppflags=$CPPFLAGS
 419 SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS])
 420 AC_CHECK_HEADER([jni.h],,
 421         [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])])
 422 CPPFLAGS=$sr_save_cppflags
 423
 424 AS_IF([test -z "$sr_java_missing"],
 425         [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no])
 426 AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes])
 427
 428 ##############################
 429 ##  Finalize configuration  ##
 430 ##############################
 431
 432 # Add mandatory dependencies to module list.
 433 SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10'])
 434 AC_SUBST([SR_PKGLIBS])
 435
 436 # Retrieve the compile and link flags for all modules combined.
 437 # Also, bail out at this point if any module dependency is not met.
 438 PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS])
 439 PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS])
 440
 441 # SR_PKGLIBS_CXX may be empty, so only invoke these checks when
 442 # the C++ bindings are enabled.
 443 AM_COND_IF([BINDINGS_CXX], [
 444         PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX])
 445         PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX])
 446 ])
 447
 448 # Check for specific libusb features, now that we know the CFLAGS.
 449 AC_LANG([C])
 450 sr_save_cflags=$CFLAGS
 451 CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS"
 452 AC_CHECK_TYPES([libusb_os_handle],
 453         [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no],
 454         [[#include <libusb.h>]])
 455 CFLAGS=$sr_save_cflags
 456 AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*],
 457         [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])])
 458
 459 sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD`
 460 sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD`
 461
 462 AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"],
 463         [Build-time version of libzip.])
 464 AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"],
 465         [The canonical host libsigrok will run on.])
 466
 467 AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc])
 468
 469 AC_OUTPUT
 470
 471 # Prepare bindings report messages.
 472 m4_define([SR_PREPARE_BINDING_REPORT], [
 473         sr_report_$1=
 474         test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)"
 475         test "x$enable_$1" = xyes || sr_report_$1=' (disabled)'
 476 ])
 477 m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [java])
 478
 479 cat >&AS_MESSAGE_FD <<_EOF
 480
 481 libsigrok configuration summary:
 482  - Package version................. $SR_PACKAGE_VERSION
 483  - Library ABI version............. $SR_LIB_VERSION
 484  - Prefix.......................... $prefix
 485  - Building on..................... $build
 486  - Building for.................... $host
 487
 488 Compile configuration:
 489  - C compiler...................... $CC
 490  - C compiler version.............. $sr_cc_version
 491  - C compiler flags................ $CFLAGS
 492  - Additional C compiler flags..... $SR_EXTRA_CFLAGS
 493  - C compiler warnings............. $SR_WFLAGS
 494  - C++ compiler.................... $CXX
 495  - C++ compiler version............ $sr_cxx_version
 496  - C++ compiler flags.............. $CXXFLAGS
 497  - C++ compiler warnings........... $SR_WXXFLAGS
 498
 499 Detected libraries (required):
 500  - glib-2.0 >= 2.32.0.............. $sr_glib_version
 501  - libzip >= 0.10.................. $sr_libzip_version
 502
 503 Detected libraries (optional):
 504 $sr_pkglibs_summary
 505 Enabled hardware drivers:
 506 $sr_driver_summary
 507 Enabled SCPI backends:
 508  - TCP............................. yes
 509  - RPC............................. $sr_cv_have_rpc
 510  - serial.......................... $sr_have_libserialport
 511  - VISA............................ $sr_have_librevisa
 512  - GPIB............................ $sr_have_libgpib
 513  - USBTMC.......................... $sr_have_libusb
 514
 515 Enabled language bindings:
 516  - C++............................. $BINDINGS_CXX$sr_report_cxx
 517  - Python.......................... $BINDINGS_PYTHON$sr_report_python
 518  - Java............................ $BINDINGS_JAVA$sr_report_java
 519
 520 _EOF