configure.ac

   1 ##
   2 ## This file is part of the libserialport project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2013 Martin Ling <martin-libserialport@earth.li>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU Lesser General Public License as
   9 ## published by the Free Software Foundation, either version 3 of the
  10 ## License, or (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU Lesser General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libserialport package version number (NOT the same as shared lib version!).
  25 m4_define([sp_package_version_major], [0])
  26 m4_define([sp_package_version_minor], [1])
  27 m4_define([sp_package_version_micro], [0])
  28 m4_define([sp_package_version], [sp_package_version_major.sp_package_version_minor.sp_package_version_micro])
  29
  30 AC_INIT([libserialport], [sp_package_version], [martin-libserialport@earth.li],
  31         [libserialport], [http://sigrok.org/wiki/Libserialport])
  32 AC_CONFIG_MACRO_DIR([autostuff])
  33 AC_CONFIG_AUX_DIR([autostuff])
  34
  35 AC_CANONICAL_TARGET
  36
  37 # We require at least automake 1.11 (needed for 'silent rules').
  38 AM_INIT_AUTOMAKE([1.11 -Wall -Werror])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  40 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  41
  42 AH_TOP([#ifndef SP_CONFIG_H
  43 #define SP_CONFIG_H    /* To stop multiple inclusions. */])
  44 AH_BOTTOM([#endif /* SP_CONFIG_H */])
  45
  46 # Enable more compiler warnings via -Wall and -Wextra.
  47 CFLAGS="$CFLAGS -Wall -Wextra"
  48
  49 # Checks for programs.
  50 AC_PROG_CC
  51 AC_PROG_CPP
  52 AC_PROG_INSTALL
  53 AC_PROG_LN_S
  54
  55 # Required for per-target flags or subdir-objects with C sources.
  56 AM_PROG_CC_C_O
  57
  58 # Initialize libtool.
  59 LT_INIT
  60
  61 # Initialize pkg-config.
  62 # We require at least 0.22, as "Requires.private" behaviour changed there.
  63 PKG_PROG_PKG_CONFIG([0.22])
  64
  65 # Library version for libserialport (NOT the same as the package version).
  66 # Carefully read the libtool docs before updating these numbers!
  67 # The algorithm for determining which number to change (and how) is nontrivial!
  68 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  69 SP_LIB_VERSION_CURRENT=0
  70 SP_LIB_VERSION_REVISION=0
  71 SP_LIB_VERSION_AGE=0
  72 SP_LIB_VERSION="$SP_LIB_VERSION_CURRENT:$SP_LIB_VERSION_REVISION:$SP_LIB_VERSION_AGE"
  73 SP_LIB_LDFLAGS="-version-info $SP_LIB_VERSION"
  74 AC_SUBST(SP_LIB_VERSION_CURRENT)
  75 AC_SUBST(SP_LIB_VERSION_REVISION)
  76 AC_SUBST(SP_LIB_VERSION_AGE)
  77 AC_SUBST(SP_LIB_VERSION)
  78 AC_SUBST(SP_LIB_LDFLAGS)
  79
  80 # Checks for libraries.
  81
  82 # This variable collects the pkg-config names of all detected libs.
  83 # It is then used to construct the "Requires.private:" field in the
  84 # libserialport.pc file.
  85 SP_PKGLIBS=""
  86
  87 case $target_os in
  88 *linux*)
  89         # On Linux libudev is currently a hard requirement.
  90         PKG_CHECK_MODULES([libudev], [libudev >= 0],
  91                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
  92                 SP_PKGLIBS="$SP_PKGLIBS libudev"])
  93         ;;
  94 *darwin*)
  95         LDFLAGS="$LDFLAGS -Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation"
  96         AC_CHECK_HEADER(IOKit/IOKitLib.h, [], [AC_MSG_ERROR([IOKit/IOKitLib.h not found])])
  97         ;;
  98 esac
  99
 100 AC_SUBST(SP_PKGLIBS)
 101
 102 # Checks for header files.
 103 # These are already checked: inttypes.h dlfcn.h memory.h stdint.h stdlib.h
 104 # string.h strings.h sys/types.h sys/stat.h unistd.h
 105 AC_CHECK_HEADERS([errno.h fcntl.h stddef.h sys/ioctl.h termios.h])
 106
 107 # Checks for typedefs, structures, and compiler characteristics.
 108 AC_C_INLINE
 109 AC_TYPE_SIZE_T
 110 AC_TYPE_SSIZE_T
 111 AC_CHECK_TYPE([struct termios2],[AC_DEFINE(HAVE_TERMIOS2, 1)],[],[[#include <linux/termios.h>]])
 112 AC_CHECK_TYPE([struct termiox],[AC_DEFINE(HAVE_TERMIOX, 1)],[],[[#include <linux/termios.h>]])
 113
 114 # Checks for library functions.
 115 AC_CHECK_FUNCS([strerror])
 116
 117 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 118 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 119
 120 SP_PACKAGE_VERSION_MAJOR=sp_package_version_major
 121 SP_PACKAGE_VERSION_MINOR=sp_package_version_minor
 122 SP_PACKAGE_VERSION_MICRO=sp_package_version_micro
 123 SP_PACKAGE_VERSION=sp_package_version
 124
 125 AC_SUBST(SP_PACKAGE_VERSION_MAJOR)
 126 AC_SUBST(SP_PACKAGE_VERSION_MINOR)
 127 AC_SUBST(SP_PACKAGE_VERSION_MICRO)
 128 AC_SUBST(SP_PACKAGE_VERSION)
 129
 130 AC_CONFIG_FILES([Makefile libserialport.h libserialport.pc])
 131
 132 AC_OUTPUT
 133
 134 echo
 135 echo "libserialport configuration summary:"
 136 echo
 137 echo "  - Package version (major.minor.micro):    $SP_PACKAGE_VERSION"
 138 echo "  - Library version (current:revision:age): $SP_LIB_VERSION"
 139 echo "  - Prefix: $prefix"
 140 echo "  - Building on: $build"
 141 echo "  - Building for: $host"
 142 echo