configure.ac

   1 ##
   2 ## This file is part of the libserialport project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2013 Martin Ling <martin-libserialport@earth.li>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU Lesser General Public License as
   9 ## published by the Free Software Foundation, either version 3 of the
  10 ## License, or (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU Lesser General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libserialport package version number (NOT the same as shared lib version!).
  25 m4_define([sp_package_version_major], [0])
  26 m4_define([sp_package_version_minor], [1])
  27 m4_define([sp_package_version], [sp_package_version_major.sp_package_version_minor])
  28
  29 AC_INIT([libserialport], [sp_package_version], [martin-libserialport@earth.li],
  30         [libserialport], [http://sigrok.org/wiki/Libserialport])
  31 AC_CONFIG_MACRO_DIR([autostuff])
  32 AC_CONFIG_AUX_DIR([autostuff])
  33
  34 AC_CANONICAL_TARGET
  35
  36 # We require at least automake 1.11 (needed for 'silent rules').
  37 AM_INIT_AUTOMAKE([1.11 -Wall -Werror])
  38 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  39 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  40
  41 AH_TOP([#ifndef SP_CONFIG_H
  42 #define SP_CONFIG_H    /* To stop multiple inclusions. */])
  43 AH_BOTTOM([#endif /* SP_CONFIG_H */])
  44
  45 # Enable more compiler warnings via -Wall and -Wextra.
  46 CFLAGS="$CFLAGS -Wall -Wextra"
  47
  48 # Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_CPP
  51 AC_PROG_INSTALL
  52 AC_PROG_LN_S
  53
  54 # Required for per-target flags or subdir-objects with C sources.
  55 AM_PROG_CC_C_O
  56
  57 # Initialize libtool.
  58 LT_INIT
  59
  60 # Initialize pkg-config.
  61 # We require at least 0.22, as "Requires.private" behaviour changed there.
  62 PKG_PROG_PKG_CONFIG([0.22])
  63
  64 # Library version for libserialport (NOT the same as the package version).
  65 # Carefully read the libtool docs before updating these numbers!
  66 # The algorithm for determining which number to change (and how) is nontrivial!
  67 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  68 SP_LIB_VERSION_CURRENT=0
  69 SP_LIB_VERSION_REVISION=0
  70 SP_LIB_VERSION_AGE=0
  71 SP_LIB_VERSION="$SP_LIB_VERSION_CURRENT:$SP_LIB_VERSION_REVISION:$SP_LIB_VERSION_AGE"
  72 SP_LIB_LDFLAGS="-version-info $SP_LIB_VERSION"
  73 AC_SUBST(SP_LIB_VERSION_CURRENT)
  74 AC_SUBST(SP_LIB_VERSION_REVISION)
  75 AC_SUBST(SP_LIB_VERSION_AGE)
  76 AC_SUBST(SP_LIB_VERSION)
  77 AC_SUBST(SP_LIB_LDFLAGS)
  78
  79 # Checks for libraries.
  80
  81 # This variable collects the pkg-config names of all detected libs.
  82 # It is then used to construct the "Requires.private:" field in the
  83 # libserialport.pc file.
  84 SP_PKGLIBS=""
  85
  86 case $target_os in
  87 *linux*)
  88         # On Linux libudev is currently a hard requirement.
  89         PKG_CHECK_MODULES([libudev], [libudev >= 0],
  90                 [CFLAGS="$CFLAGS $libudev_CFLAGS"; LIBS="$LIBS $libudev_LIBS";
  91                 SP_PKGLIBS="$SP_PKGLIBS libudev"])
  92         ;;
  93 *darwin*)
  94         LDFLAGS="$LDFLAGS -Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation"
  95         AC_CHECK_HEADER(IOKit/IOKitLib.h, [], [AC_MSG_ERROR([IOKit/IOKitLib.h not found])])
  96         ;;
  97 esac
  98
  99 AC_SUBST(SP_PKGLIBS)
 100
 101 # Checks for header files.
 102 # These are already checked: inttypes.h dlfcn.h memory.h stdint.h stdlib.h
 103 # string.h strings.h sys/types.h sys/stat.h unistd.h
 104 AC_CHECK_HEADERS([errno.h fcntl.h stddef.h sys/ioctl.h termios.h])
 105
 106 # Checks for typedefs, structures, and compiler characteristics.
 107 AC_C_INLINE
 108 AC_TYPE_SIZE_T
 109 AC_TYPE_SSIZE_T
 110 AC_CHECK_TYPE([struct termios2],[AC_DEFINE(HAVE_TERMIOS2, 1)],[],[[#include <linux/termios.h>]])
 111 AC_CHECK_TYPE([struct termiox],[AC_DEFINE(HAVE_TERMIOX, 1)],[],[[#include <linux/termios.h>]])
 112
 113 # Checks for library functions.
 114 AC_CHECK_FUNCS([strerror])
 115
 116 AC_SUBST(MAKEFLAGS, '--no-print-directory')
 117 AC_SUBST(AM_LIBTOOLFLAGS, '--silent')
 118
 119 SP_PACKAGE_VERSION_MAJOR=sp_package_version_major
 120 SP_PACKAGE_VERSION_MINOR=sp_package_version_minor
 121 SP_PACKAGE_VERSION=sp_package_version
 122
 123 AC_SUBST(SP_PACKAGE_VERSION_MAJOR)
 124 AC_SUBST(SP_PACKAGE_VERSION_MINOR)
 125 AC_SUBST(SP_PACKAGE_VERSION)
 126
 127 AC_CONFIG_FILES([Makefile libserialport.h libserialport.pc])
 128
 129 AC_OUTPUT
 130
 131 echo
 132 echo "libserialport configuration summary:"
 133 echo
 134 echo "  - Package version (major.minor):          $SP_PACKAGE_VERSION"
 135 echo "  - Library version (current:revision:age): $SP_LIB_VERSION"
 136 echo "  - Prefix: $prefix"
 137 echo "  - Building on: $build"
 138 echo "  - Building for: $host"
 139 echo