configure.ac

   1 ##
   2 ## This file is part of the libserialport project.
   3 ##
   4 ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com>
   5 ## Copyright (C) 2013 Martin Ling <martin-libserialport@earth.li>
   6 ##
   7 ## This program is free software: you can redistribute it and/or modify
   8 ## it under the terms of the GNU Lesser General Public License as
   9 ## published by the Free Software Foundation, either version 3 of the
  10 ## License, or (at your option) any later version.
  11 ##
  12 ## This program is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU Lesser General Public License
  18 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 # libserialport package version number (NOT the same as shared lib version!).
  25 m4_define([sp_package_version_major], [0])
  26 m4_define([sp_package_version_minor], [1])
  27 m4_define([sp_package_version_micro], [1])
  28 m4_define([sp_package_version], [sp_package_version_major.sp_package_version_minor.sp_package_version_micro])
  29
  30 AC_INIT([libserialport], [sp_package_version], [martin-libserialport@earth.li],
  31         [libserialport], [http://sigrok.org/wiki/Libserialport])
  32 AC_CONFIG_HEADERS([config.h libserialport.h])
  33 AC_CONFIG_MACRO_DIR([autostuff])
  34 AC_CONFIG_AUX_DIR([autostuff])
  35
  36 AH_BOTTOM([#if HAVE_STRUCT_TERMIOS_C_ISPEED && HAVE_STRUCT_TERMIOS_C_OSPEED
  37 # define HAVE_TERMIOS_SPEED 1
  38 #endif
  39 #if HAVE_STRUCT_TERMIOS2_C_ISPEED && HAVE_STRUCT_TERMIOS2_C_OSPEED
  40 # define HAVE_TERMIOS2_SPEED 1
  41 #endif])
  42
  43 # We require at least automake 1.11 (needed for 'silent rules').
  44 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define check-news])
  45 AM_SILENT_RULES([yes])
  46 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  47
  48 # Checks for programs.
  49 AC_PROG_CC
  50 AC_PROG_INSTALL
  51 AC_PROG_LN_S
  52
  53 ## SP_PROG_VERSION(program, sh-var)
  54 ## Obtain the version of <program> and store it in <sh-var>.
  55 AC_DEFUN([SP_PROG_VERSION],
  56 [dnl
  57 m4_assert([$# >= 2])[]dnl
  58 sp_prog_ver=`$1 --version 2>&AS_MESSAGE_LOG_FD | sed 1q 2>&AS_MESSAGE_LOG_FD`
  59 AS_CASE([[$]?:$sp_prog_ver],
  60         [[0:*[0-9].[0-9]*]], [$2=$sp_prog_ver],
  61         [$2=unknown])[]dnl
  62 ])
  63
  64 SP_PROG_VERSION([$CC], [sp_cc_version])
  65
  66 # Initialize libtool.
  67 LT_INIT
  68
  69 AC_DEFINE([SP_PACKAGE_VERSION_MAJOR], [sp_package_version_major], [.])
  70 AC_DEFINE([SP_PACKAGE_VERSION_MINOR], [sp_package_version_minor], [.])
  71 AC_DEFINE([SP_PACKAGE_VERSION_MICRO], [sp_package_version_micro], [.])
  72 AC_DEFINE([SP_PACKAGE_VERSION_STRING], ["sp_package_version"], [.])
  73 AC_SUBST([SP_PACKAGE_VERSION], [sp_package_version])
  74
  75 # Library version for libserialport (NOT the same as the package version).
  76 # Carefully read the libtool docs before updating these numbers!
  77 # The algorithm for determining which number to change (and how) is nontrivial!
  78 # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info
  79 SP_LIB_VERSION_CURRENT=1
  80 SP_LIB_VERSION_REVISION=0
  81 SP_LIB_VERSION_AGE=1
  82 AC_SUBST([SP_LIB_VERSION],
  83         ["$SP_LIB_VERSION_CURRENT:$SP_LIB_VERSION_REVISION:$SP_LIB_VERSION_AGE"])
  84
  85 AC_DEFINE_UNQUOTED([SP_LIB_VERSION_CURRENT], [$SP_LIB_VERSION_CURRENT], [.])
  86 AC_DEFINE_UNQUOTED([SP_LIB_VERSION_REVISION], [$SP_LIB_VERSION_REVISION], [.])
  87 AC_DEFINE_UNQUOTED([SP_LIB_VERSION_AGE], [$SP_LIB_VERSION_AGE], [.])
  88 AC_DEFINE_UNQUOTED([SP_LIB_VERSION_STRING], ["$SP_LIB_VERSION"], [.])
  89
  90 AM_CONDITIONAL([LINUX], [test -z "${host_os##linux*}" || test -z "${host_os##uclinux*}"])
  91 AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"])
  92 AM_CONDITIONAL([MACOSX], [test -z "${host_os##darwin*}"])
  93 AM_CONDITIONAL([FREEBSD], [test -z "${host_os##freebsd*}"])
  94
  95 AM_COND_IF([WIN32], [SP_LIBS='-lsetupapi'], [SP_LIBS=])
  96 AC_SUBST([SP_LIBS])
  97
  98 AM_COND_IF([FREEBSD], [SP_PKGLIBS='libusb-2.0'], [SP_PKGLIBS=])
  99 AC_SUBST([SP_PKGLIBS])
 100
 101 AM_COND_IF([MACOSX], [AC_CHECK_HEADER([IOKit/IOKitLib.h], [],
 102         [AC_MSG_ERROR([IOKit/IOKitLib.h not found])])])
 103
 104 AS_CASE([$host_os], [linux*|darwin*|mingw*|cygwin*|freebsd*],, [
 105         AC_DEFINE([NO_ENUMERATION], [1], [Enumeration is unsupported.])
 106         AC_DEFINE([NO_PORT_METADATA], [1], [Port metadata is unavailable.])
 107 ])
 108
 109 AC_SYS_LARGEFILE
 110
 111 # Define size_t if not defined as standard.
 112 AC_TYPE_SIZE_T
 113
 114 # Check for specific termios structures.
 115 AC_CHECK_TYPES([struct termios2, struct termiox],,,
 116         [[#include <linux/termios.h>]])
 117 AC_CHECK_MEMBERS([struct termios.c_ispeed, struct termios.c_ospeed,
 118                 struct termios2.c_ispeed, struct termios2.c_ospeed],,,
 119         [[#include <linux/termios.h>]])
 120
 121 # Check for the BOTHER definition, needed for setting arbitrary baud rates.
 122 # We can't just #ifdef BOTHER in the code, because of the separation between
 123 # code using libc headers and code using kernel termios.h headers.
 124 AC_CHECK_DECLS([BOTHER],,, [[#include <linux/termios.h>]])
 125
 126 # Check for serial_struct.
 127 AC_CHECK_TYPES([struct serial_struct],,, [[#include <linux/serial.h>]])
 128
 129 AC_CACHE_CHECK([for visibility control], [sp_cv_visibility_control], [
 130         sp_saved_CFLAGS=$CFLAGS
 131         CFLAGS="$CFLAGS -Werror"
 132         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 133                 [[__attribute__((visibility("hidden"))) void foo(void) {}]])],
 134                 [sp_cv_visibility_control=attribute],
 135                 [AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 136                         [[__declspec(dllexport) void foo(void) {}]])],
 137                         [sp_cv_visibility_control=declspec],
 138                         [sp_cv_visibility_control=none])])
 139         CFLAGS=$sp_saved_CFLAGS
 140 ])
 141 AS_CASE([$sp_cv_visibility_control],
 142         [attribute],    [SP_API='__attribute__((visibility("default")))'
 143                         SP_PRIV='__attribute__((visibility("hidden")))'],
 144         [declspec],     [SP_API='__declspec(dllexport)' SP_PRIV=],
 145                         [SP_API= SP_PRIV=])
 146 AC_DEFINE_UNQUOTED([SP_API], [$SP_API], [Macro preceding public API functions])
 147 AC_DEFINE_UNQUOTED([SP_PRIV], [$SP_PRIV], [Macro preceding private functions])
 148
 149 AC_CONFIG_FILES([Makefile libserialport.pc])
 150
 151 AC_OUTPUT
 152
 153 cat >&AS_MESSAGE_FD <<_EOF
 154
 155 libserialport configuration summary:
 156
 157  - Package version................. $SP_PACKAGE_VERSION
 158  - Library ABI version............. $SP_LIB_VERSION
 159  - Prefix.......................... $prefix
 160  - Building on..................... $build
 161  - Building for.................... $host
 162  - Building shared / static........ $enable_shared / $enable_static
 163
 164 Compile configuration:
 165  - C compiler...................... $CC
 166  - C compiler version.............. $sp_cc_version
 167  - C compiler flags................ $CFLAGS
 168  - Linker flags.................... $LDFLAGS
 169
 170 _EOF