]>
Commit | Line | Data |
---|---|---|
1 | ## | |
2 | ## This file is part of the libsigrok project. | |
3 | ## | |
4 | ## Copyright (C) 2010-2012 Bert Vermeulen <bert@biot.com> | |
5 | ## Copyright (C) 2012 Alexandru Gagniuc <mr.nuke.me@gmail.com> | |
6 | ## | |
7 | ## This program is free software: you can redistribute it and/or modify | |
8 | ## it under the terms of the GNU General Public License as published by | |
9 | ## the Free Software Foundation, either version 3 of the License, or | |
10 | ## (at your option) any later version. | |
11 | ## | |
12 | ## This program is distributed in the hope that it will be useful, | |
13 | ## but WITHOUT ANY WARRANTY; without even the implied warranty of | |
14 | ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
15 | ## GNU General Public License for more details. | |
16 | ## | |
17 | ## You should have received a copy of the GNU General Public License | |
18 | ## along with this program. If not, see <http://www.gnu.org/licenses/>. | |
19 | ## | |
20 | ||
21 | # We require at least autoconf 2.63 (AC_INIT format changed there). | |
22 | AC_PREREQ([2.63]) | |
23 | ||
24 | AC_INIT([libsigrok], [0.6.0], | |
25 | [sigrok-devel@lists.sourceforge.net], | |
26 | [libsigrok], [http://www.sigrok.org]) | |
27 | AC_CONFIG_MACRO_DIR([m4]) | |
28 | AC_CONFIG_AUX_DIR([autostuff]) | |
29 | AC_CONFIG_HEADERS([config.h include/libsigrok/version.h]) | |
30 | ||
31 | # We require at least automake 1.11 (needed for 'silent rules'). | |
32 | AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define nostdinc subdir-objects check-news color-tests]) | |
33 | AM_SILENT_RULES([yes]) | |
34 | m4_ifdef([AM_PROG_AR], [AM_PROG_AR]) | |
35 | ||
36 | AC_CANONICAL_HOST | |
37 | ||
38 | # Checks for programs. | |
39 | AC_PROG_CC | |
40 | AC_PROG_CXX | |
41 | AC_PROG_INSTALL | |
42 | AC_PROG_LN_S | |
43 | ||
44 | # Required for per-target flags or subdir-objects with C sources. | |
45 | AM_PROG_CC_C_O | |
46 | ||
47 | # Set the standard the C library headers should conform to. | |
48 | AH_VERBATIM([_POSIX_C_SOURCE], [/* The targeted POSIX standard. */ | |
49 | #ifndef _POSIX_C_SOURCE | |
50 | # define _POSIX_C_SOURCE 200112L | |
51 | #endif]) | |
52 | ||
53 | # Get compiler versions. | |
54 | SR_PROG_VERSION([$CC], [sr_cc_version]) | |
55 | SR_PROG_VERSION([$CXX], [sr_cxx_version]) | |
56 | ||
57 | # Check for optional make features. | |
58 | SR_PROG_MAKE_ORDER_ONLY | |
59 | ||
60 | # Initialize libtool. | |
61 | LT_INIT | |
62 | ||
63 | # Set up the libsigrok version defines. | |
64 | SR_PKG_VERSION_SET([SR_PACKAGE_VERSION], [AC_PACKAGE_VERSION]) | |
65 | ||
66 | # Library version for libsigrok (NOT the same as the package version). | |
67 | # Carefully read the libtool docs before updating these numbers! | |
68 | # The algorithm for determining which number to change (and how) is nontrivial! | |
69 | # http://www.gnu.org/software/libtool/manual/libtool.html#Updating-version-info | |
70 | # Format: current:revision:age. | |
71 | SR_LIB_VERSION_SET([SR_LIB_VERSION], [4:0:0]) | |
72 | ||
73 | AM_CONDITIONAL([WIN32], [test -z "${host_os##mingw*}" || test -z "${host_os##cygwin*}"]) | |
74 | ||
75 | ############################# | |
76 | ## Optional dependencies ## | |
77 | ############################# | |
78 | ||
79 | AC_LANG([C]) | |
80 | ||
81 | # Initialize pkg-config. | |
82 | # We require at least 0.22, as "Requires.private" behaviour changed there. | |
83 | PKG_PROG_PKG_CONFIG([0.22]) | |
84 | ||
85 | # Keep track of all checked modules so we can list them at the end. | |
86 | SR_PKG_CHECK_SUMMARY([sr_pkglibs_summary]) | |
87 | ||
88 | # Collect the pkg-config module names of all dependencies in SR_PKGLIBS. | |
89 | # These are used to derive the compiler flags and for the "Requires.private" | |
90 | # field in the generated libsigrok.pc file. | |
91 | SR_VAR_OPT_PKG([SR_PKGLIBS], [sr_deps_avail]) | |
92 | SR_PKGLIBS_TESTS= | |
93 | SR_PKGLIBS_CXX= | |
94 | SR_PKGLIBS_PYTHON= | |
95 | SR_PKGLIBS_RUBY= | |
96 | SR_EXTRA_LIBS= | |
97 | SR_EXTRA_CXX_LIBS= | |
98 | ||
99 | SR_ARG_OPT_PKG([libserialport], [LIBSERIALPORT], , | |
100 | [libserialport >= 0.1.1]) | |
101 | ||
102 | SR_ARG_OPT_PKG([libftdi], [LIBFTDI], , [libftdi1 >= 1.0]) | |
103 | ||
104 | # pkg-config file names: MinGW/MacOSX: hidapi; Linux: hidapi-hidraw/-libusb | |
105 | SR_ARG_OPT_PKG([libhidapi], [LIBHIDAPI], , | |
106 | [hidapi >= 0.8.0], [hidapi-hidraw >= 0.8.0], [hidapi-libusb >= 0.8.0]) | |
107 | ||
108 | SR_ARG_OPT_PKG([libbluez], [LIBBLUEZ], , [bluez >= 4.0]) | |
109 | ||
110 | SR_ARG_OPT_PKG([libnettle], [LIBNETTLE], , [nettle]) | |
111 | ||
112 | # FreeBSD comes with an "integrated" libusb-1.0-style USB API. | |
113 | # This means libusb-1.0 is always available; no need to check for it. | |
114 | # On Windows, require the latest version we can get our hands on, | |
115 | # until the new generic event handling has seen an official release. | |
116 | AS_CASE([$host_os], | |
117 | [freebsd*], [sr_libusb_req='libusb-1.0' sr_have_libusb=yes], | |
118 | [mingw*], [sr_libusb_req='libusb-1.0 >= 1.0.20'], | |
119 | [sr_libusb_req='libusb-1.0 >= 1.0.16']) | |
120 | ||
121 | SR_ARG_OPT_PKG([libusb], [LIBUSB_1_0], [NEED_USB], | |
122 | [$sr_libusb_req]) | |
123 | ||
124 | SR_ARG_OPT_PKG([librevisa], [LIBREVISA], [NEED_VISA], | |
125 | [librevisa >= 0.0.20130412]) | |
126 | ||
127 | SR_ARG_OPT_PKG([libgpib], [LIBGPIB], [NEED_GPIB], | |
128 | [libgpib]) | |
129 | ||
130 | SR_ARG_OPT_CHECK([libieee1284], [LIBIEEE1284],, [ | |
131 | sr_save_LIBS=$LIBS | |
132 | LIBS="-lieee1284 $LIBS" | |
133 | AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <ieee1284.h>]], | |
134 | [[(void) ieee1284_open(0, 0, 0);]])], | |
135 | [sr_have_libieee1284=yes], [sr_have_libieee1284=no]) | |
136 | LIBS=$sr_save_LIBS | |
137 | ]) | |
138 | AS_IF([test "x$sr_have_libieee1284" = xyes], | |
139 | [SR_PREPEND([SR_EXTRA_LIBS], [-lieee1284])]) | |
140 | ||
141 | SR_ARG_OPT_PKG([libgio], [LIBGIO], , [gio-2.0 >= 2.24.0]) | |
142 | ||
143 | # See if any of the (potentially platform specific) libs are available | |
144 | # which provide some means of Bluetooth communication. | |
145 | AS_IF([test "x$sr_have_libbluez" = xyes], | |
146 | sr_have_bluetooth=yes, sr_have_bluetooth=no) | |
147 | AS_IF([test "x$sr_have_bluetooth" = xyes], | |
148 | [AC_DEFINE([HAVE_BLUETOOTH], [1], [Specifies whether Bluetooth communication is supported.])]) | |
149 | AS_IF([test "x$sr_have_bluetooth" = xyes], | |
150 | [SR_APPEND([sr_deps_avail], [bluetooth_comm])]) | |
151 | ||
152 | AS_IF([test "x$sr_have_libserialport" = xyes -o "x$sr_have_libhidapi" = xyes -o "x$sr_have_bluetooth" = xyes], | |
153 | sr_have_serial_comm=yes, sr_have_serial_comm=no) | |
154 | AS_IF([test "x$sr_have_serial_comm" = xyes], | |
155 | [AC_DEFINE([HAVE_SERIAL_COMM], [1], [Specifies whether serial communication is supported.])]) | |
156 | AS_IF([test "x$sr_have_serial_comm" = xyes], | |
157 | [SR_APPEND([sr_deps_avail], [serial_comm])]) | |
158 | AM_CONDITIONAL([NEED_SERIAL], [test "x$sr_have_serial_comm" = xyes]) | |
159 | ||
160 | ###################### | |
161 | ## Feature checks ## | |
162 | ###################### | |
163 | ||
164 | # The Check unit testing framework is optional. Disable if not found. | |
165 | SR_PKG_CHECK([check], [SR_PKGLIBS_TESTS], [check >= 0.9.4]) | |
166 | AM_CONDITIONAL([HAVE_CHECK], [test "x$sr_have_check" = xyes]) | |
167 | ||
168 | # Enable the C99 standard if possible, and enforce the use | |
169 | # of SR_API to explicitly mark all public API functions. | |
170 | SR_EXTRA_CFLAGS= | |
171 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [C99], [-std=c99 -c99 -AC99 -qlanglvl=extc99]) | |
172 | SR_CHECK_COMPILE_FLAGS([SR_EXTRA_CFLAGS], [visibility], [-fvisibility=hidden]) | |
173 | ||
174 | SR_ARG_ENABLE_WARNINGS([SR_WFLAGS], [-Wall], [-Wall -Wextra -Wmissing-prototypes]) | |
175 | ||
176 | # Check host characteristics. | |
177 | AC_SYS_LARGEFILE | |
178 | AC_C_BIGENDIAN | |
179 | ||
180 | AC_CHECK_HEADERS([sys/mman.h], [SR_APPEND([sr_deps_avail], [sys_mman_h])]) | |
181 | AC_CHECK_HEADERS([sys/ioctl.h], [SR_APPEND([sr_deps_avail], [sys_ioctl_h])]) | |
182 | AC_CHECK_HEADERS([sys/timerfd.h], [SR_APPEND([sr_deps_avail], [sys_timerfd_h])]) | |
183 | ||
184 | # We need to link against the Winsock2 library for SCPI over TCP. | |
185 | AS_CASE([$host_os], [mingw*], [SR_PREPEND([SR_EXTRA_LIBS], [-lws2_32])]) | |
186 | ||
187 | # libm (the standard math library) is always needed. | |
188 | SR_SEARCH_LIBS([SR_EXTRA_LIBS], [pow], [m]) | |
189 | ||
190 | # RPC is only needed for VXI support. | |
191 | AC_CACHE_CHECK([for SunRPC support], [sr_cv_have_sunrpc], | |
192 | [AC_LINK_IFELSE([AC_LANG_PROGRAM( | |
193 | [[#include <rpc/rpc.h>]m4_newline[CLIENT *rpc_test(void);]], | |
194 | [[(void) clnt_create("", 0, 0, "");]])], | |
195 | [RPC_CFLAGS=""; RPC_LIBS=""; sr_cv_have_sunrpc=yes], | |
196 | [sr_cv_have_sunrpc=no])]) | |
197 | PKG_CHECK_MODULES([TIRPC], | |
198 | [libtirpc], | |
199 | [RPC_CFLAGS=$TIRPC_CFLAGS; SR_PREPEND([SR_EXTRA_LIBS], [$TIRPC_LIBS]); sr_cv_have_tirpc=yes], | |
200 | [sr_cv_have_tirpc=no]) | |
201 | AS_IF([test "x$sr_cv_have_sunrpc" = xyes -o "x$sr_cv_have_tirpc" = xyes], | |
202 | [sr_cv_have_rpc=yes], [sr_cv_have_rpc=no]) | |
203 | ||
204 | AC_SUBST(RPC_CFLAGS) | |
205 | AC_SUBST(RPC_LIBS) | |
206 | ||
207 | AS_IF([test "x$sr_cv_have_rpc" = xyes], | |
208 | [AC_DEFINE([HAVE_RPC], [1], [Specifies whether we have RPC support (either by SunRPC or libtirpc).])]) | |
209 | ||
210 | # VXI support is only compiled if RPC support was found. | |
211 | AM_CONDITIONAL([NEED_RPC], [test "x$sr_cv_have_rpc" = xyes]) | |
212 | ||
213 | # Check for compiler support of 128 bit integers | |
214 | AC_CHECK_TYPES([__int128_t, __uint128_t], [], [], []) | |
215 | ||
216 | ######################## | |
217 | ## Hardware drivers ## | |
218 | ######################## | |
219 | ||
220 | # Keep track of all drivers so we can list them at the end. | |
221 | SR_VAR_SUMMARY([sr_driver_summary]) | |
222 | ||
223 | # Check whether the sr_deps_avail list contains all of the arguments. | |
224 | # Unavailable dependencies are collected in sr_deps_missing. | |
225 | sr_check_driver_deps() { | |
226 | sr_deps_missing= | |
227 | for sr_dep | |
228 | do | |
229 | AS_CASE([" $sr_deps_avail "], [*" $sr_dep "*],, | |
230 | [SR_APPEND([sr_deps_missing], [', '], [$sr_dep])]) | |
231 | done | |
232 | test -z "$sr_deps_missing" || return 1 | |
233 | } | |
234 | ||
235 | AC_ARG_ENABLE([all-drivers], | |
236 | [AS_HELP_STRING([--enable-all-drivers], | |
237 | [enable all drivers by default [default=yes]])], | |
238 | [], [enable_all_drivers=yes]) | |
239 | ||
240 | ## _SR_DRIVER(Device name, driver-name, var-name, [dependencies...]) | |
241 | m4_define([_SR_DRIVER], [ | |
242 | AC_ARG_ENABLE([$2], | |
243 | [AS_HELP_STRING([--enable-$2], [enable $1 support])], | |
244 | [$3=$enableval], [$3=$enable_all_drivers]) | |
245 | ||
246 | AS_IF([test "x[$]$3" = xyes], [sr_hw_info=yes[]m4_ifval([$4], [ | |
247 | sr_check_driver_deps $4 \ | |
248 | || $3=no sr_hw_info="no (missing: $sr_deps_missing)" | |
249 | ])], [sr_hw_info='no (disabled)']) | |
250 | sr_driver_summary_append "$2" "$sr_hw_info" | |
251 | ||
252 | AM_CONDITIONAL([$3], [test "x[$]$3" = xyes]) | |
253 | AM_COND_IF([$3], [AC_DEFINE([HAVE_$3], [1], [Whether to support $1 device.]) AC_DEFINE([HAVE_DRIVERS], [1], [Whether at least one driver is enabled.])]) | |
254 | ]) | |
255 | ||
256 | ## SR_DRIVER(Device name, driver-name, [dependencies...]) | |
257 | m4_define([SR_DRIVER], | |
258 | [_SR_DRIVER([$1], [$2], m4_expand([AS_TR_CPP([HW_$2])]), [$3])]) | |
259 | ||
260 | SR_DRIVER([Agilent DMM], [agilent-dmm], [serial_comm]) | |
261 | SR_DRIVER([Appa 55II], [appa-55ii], [serial_comm]) | |
262 | SR_DRIVER([Arachnid Labs Re:load Pro], [arachnid-labs-re-load-pro], [serial_comm]) | |
263 | SR_DRIVER([ASIX SIGMA/SIGMA2], [asix-sigma], [libftdi]) | |
264 | SR_DRIVER([Atten PPS3xxx], [atten-pps3xxx], [serial_comm]) | |
265 | SR_DRIVER([BayLibre ACME], [baylibre-acme], [sys_timerfd_h]) | |
266 | SR_DRIVER([BeagleLogic], [beaglelogic], [sys_mman_h sys_ioctl_h]) | |
267 | SR_DRIVER([CEM DT-885x], [cem-dt-885x], [serial_comm]) | |
268 | SR_DRIVER([Center 3xx], [center-3xx], [serial_comm]) | |
269 | SR_DRIVER([ChronoVu LA], [chronovu-la], [libusb libftdi]) | |
270 | SR_DRIVER([Colead SLM], [colead-slm], [serial_comm]) | |
271 | SR_DRIVER([Conrad DIGI 35 CPU], [conrad-digi-35-cpu], [serial_comm]) | |
272 | SR_DRIVER([demo], [demo]) | |
273 | SR_DRIVER([DreamSourceLab DSLogic], [dreamsourcelab-dslogic], [libusb]) | |
274 | SR_DRIVER([Fluke 45], [fluke-45]) | |
275 | SR_DRIVER([Fluke DMM], [fluke-dmm], [serial_comm]) | |
276 | SR_DRIVER([FTDI LA], [ftdi-la], [libusb libftdi]) | |
277 | SR_DRIVER([fx2lafw], [fx2lafw], [libusb]) | |
278 | SR_DRIVER([GMC MH 1x/2x], [gmc-mh-1x-2x], [serial_comm]) | |
279 | SR_DRIVER([GW Instek GDS-800], [gwinstek-gds-800], [serial_comm]) | |
280 | SR_DRIVER([GW Instek GPD], [gwinstek-gpd], [serial_comm]) | |
281 | SR_DRIVER([Hameg HMO], [hameg-hmo], [serial_comm]) | |
282 | SR_DRIVER([Hantek 4032L], [hantek-4032l], [libusb]) | |
283 | SR_DRIVER([Hantek 6xxx], [hantek-6xxx], [libusb]) | |
284 | SR_DRIVER([Hantek DSO], [hantek-dso], [libusb]) | |
285 | SR_DRIVER([HP 3457A], [hp-3457a]) | |
286 | SR_DRIVER([HP 3478A], [hp-3478a], [libgpib]) | |
287 | SR_DRIVER([hp-59306a], [hp-59306a]) | |
288 | SR_DRIVER([Hung-Chang DSO-2100], [hung-chang-dso-2100], [libieee1284]) | |
289 | SR_DRIVER([Ikalogic Scanalogic-2], [ikalogic-scanalogic2], [libusb]) | |
290 | SR_DRIVER([Ikalogic Scanaplus], [ikalogic-scanaplus], [libftdi]) | |
291 | SR_DRIVER([IPDBG LA], [ipdbg-la]) | |
292 | SR_DRIVER([ITECH IT8500], [itech-it8500], [serial_comm]) | |
293 | SR_DRIVER([Kecheng KC-330B], [kecheng-kc-330b], [libusb]) | |
294 | SR_DRIVER([KERN scale], [kern-scale], [serial_comm]) | |
295 | SR_DRIVER([Kingst LA2016], [kingst-la2016], [libusb]) | |
296 | SR_DRIVER([Korad KAxxxxP], [korad-kaxxxxp], [serial_comm]) | |
297 | SR_DRIVER([Lascar EL-USB], [lascar-el-usb], [libusb]) | |
298 | SR_DRIVER([LeCroy LogicStudio], [lecroy-logicstudio], [libusb]) | |
299 | SR_DRIVER([LeCroy X-Stream], [lecroy-xstream]) | |
300 | SR_DRIVER([Manson HCS-3xxx], [manson-hcs-3xxx], [serial_comm]) | |
301 | SR_DRIVER([Mastech MS6514], [mastech-ms6514], [serial_comm]) | |
302 | SR_DRIVER([maynuo-m97], [maynuo-m97]) | |
303 | SR_DRIVER([MIC 985xx], [mic-985xx], [serial_comm]) | |
304 | SR_DRIVER([Microchip PICkit2], [microchip-pickit2], [libusb]) | |
305 | SR_DRIVER([Mooshimeter DMM], [mooshimeter-dmm], [bluetooth_comm libgio]) | |
306 | SR_DRIVER([Motech LPS 30x], [motech-lps-30x], [serial_comm]) | |
307 | SR_DRIVER([Norma DMM], [norma-dmm], [serial_comm]) | |
308 | SR_DRIVER([OpenBench Logic Sniffer], [openbench-logic-sniffer], [serial_comm]) | |
309 | SR_DRIVER([PCE PCE-322A], [pce-322a], [serial_comm]) | |
310 | SR_DRIVER([Pipistrello-OLS], [pipistrello-ols], [libftdi]) | |
311 | SR_DRIVER([RDTech DPSxxxx/DPHxxxx], [rdtech-dps], [serial_comm]) | |
312 | SR_DRIVER([RDTech UMXX], [rdtech-um], [serial_comm]) | |
313 | SR_DRIVER([RDTech TCXX], [rdtech-tc], [serial_comm libnettle]) | |
314 | SR_DRIVER([Rigol DS], [rigol-ds]) | |
315 | SR_DRIVER([Rigol DG], [rigol-dg]) | |
316 | SR_DRIVER([Rohde&Schwarz SME-0x], [rohde-schwarz-sme-0x], [serial_comm]) | |
317 | SR_DRIVER([Saleae Logic16], [saleae-logic16], [libusb]) | |
318 | SR_DRIVER([Saleae Logic Pro], [saleae-logic-pro], [libusb]) | |
319 | SR_DRIVER([SCPI DMM], [scpi-dmm]) | |
320 | SR_DRIVER([SCPI PPS], [scpi-pps]) | |
321 | SR_DRIVER([serial DMM], [serial-dmm], [serial_comm]) | |
322 | SR_DRIVER([serial LCR], [serial-lcr], [serial_comm]) | |
323 | SR_DRIVER([Siglent SDS], [siglent-sds]) | |
324 | SR_DRIVER([Sysclk LWLA], [sysclk-lwla], [libusb]) | |
325 | SR_DRIVER([Sysclk SLA5032], [sysclk-sla5032], [libusb]) | |
326 | SR_DRIVER([Teleinfo], [teleinfo], [serial_comm]) | |
327 | SR_DRIVER([Testo], [testo], [libusb]) | |
328 | SR_DRIVER([Tondaj SL-814], [tondaj-sl-814], [serial_comm]) | |
329 | SR_DRIVER([UNI-T DMM], [uni-t-dmm], [libusb]) | |
330 | SR_DRIVER([UNI-T UT181A], [uni-t-ut181a], [serial_comm]) | |
331 | SR_DRIVER([UNI-T UT32x], [uni-t-ut32x], [serial_comm]) | |
332 | SR_DRIVER([Yokogawa DL/DLM], [yokogawa-dlm]) | |
333 | SR_DRIVER([ZEROPLUS Logic Cube], [zeroplus-logic-cube], [libusb]) | |
334 | SR_DRIVER([ZKETECH EBD-USB], [zketech-ebd-usb], [serial_comm]) | |
335 | ||
336 | ############################### | |
337 | ## Language bindings setup ## | |
338 | ############################### | |
339 | ||
340 | AC_LANG([C++]) | |
341 | SR_ARG_ENABLE_WARNINGS([SR_WXXFLAGS], [-Wall], [-Wall -Wextra]) | |
342 | ||
343 | AC_ARG_ENABLE([bindings], | |
344 | [AS_HELP_STRING([--enable-bindings], [build language bindings [default=yes]])], | |
345 | [], [enable_bindings=yes]) | |
346 | ||
347 | AC_ARG_ENABLE([cxx], | |
348 | [AS_HELP_STRING([--enable-cxx], [build C++ bindings [default=yes]])], | |
349 | [], [enable_cxx=$enable_bindings]) | |
350 | ||
351 | AC_ARG_ENABLE([python], | |
352 | [AS_HELP_STRING([--enable-python], [build Python bindings [default=yes]])], | |
353 | [], [enable_python=$enable_bindings]) | |
354 | ||
355 | AC_ARG_ENABLE([ruby], | |
356 | [AS_HELP_STRING([--enable-ruby], [build Ruby bindings [default=yes]])], | |
357 | [], [enable_ruby=$enable_bindings]) | |
358 | ||
359 | AC_ARG_ENABLE([java], | |
360 | [AS_HELP_STRING([--enable-java], [build Java bindings [default=yes]])], | |
361 | [], [enable_java=$enable_bindings]) | |
362 | ||
363 | #################### | |
364 | ## C++ bindings ## | |
365 | #################### | |
366 | ||
367 | sr_cxx_missing= | |
368 | ||
369 | # Check if the C++ compiler supports the C++11 standard. | |
370 | AX_CXX_COMPILE_STDCXX([11], [noext], [optional]) | |
371 | AS_IF([test "x$HAVE_CXX11" != x1], | |
372 | [SR_APPEND([sr_cxx_missing], [', '], ['C++11'])]) | |
373 | ||
374 | # The C++ bindings need glibmm. | |
375 | SR_PKG_CHECK([glibmm], [SR_PKGLIBS_CXX], [glibmm-2.4 >= 2.32.0]) | |
376 | AS_IF([test "x$sr_have_glibmm" != xyes], | |
377 | [SR_APPEND([sr_cxx_missing], [', '], [glibmm])]) | |
378 | ||
379 | # The C++ bindings use Doxygen to parse libsigrok symbols. | |
380 | AC_CHECK_PROG([HAVE_DOXYGEN], [doxygen], [yes], [no]) | |
381 | AS_IF([test "x$HAVE_DOXYGEN" != xyes], | |
382 | [SR_APPEND([sr_cxx_missing], [', '], [Doxygen])]) | |
383 | ||
384 | # Link C++ code with gnustl_shared if it exists (Android) | |
385 | SR_SEARCH_LIBS([SR_EXTRA_CXX_LIBS], [__cxa_throw], [gnustl_shared]) | |
386 | ||
387 | # Python is needed for the C++ bindings. | |
388 | AM_PATH_PYTHON([2.7], | |
389 | [HAVE_PYTHON=yes], | |
390 | [HAVE_PYTHON=no | |
391 | SR_APPEND([sr_cxx_missing], [', '], [Python])]) | |
392 | ||
393 | AS_IF([test -z "$sr_cxx_missing"], | |
394 | [BINDINGS_CXX=$enable_cxx], [BINDINGS_CXX=no]) | |
395 | AM_CONDITIONAL([BINDINGS_CXX], [test "x$BINDINGS_CXX" = xyes]) | |
396 | ||
397 | # C++ bindings want stoi and stod. | |
398 | AM_COND_IF([BINDINGS_CXX], [ | |
399 | AC_CACHE_CHECK([for stoi and stod], [sr_cv_have_stoi_stod], | |
400 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string>]], | |
401 | [[(void) std::stoi("1"); (void) std::stod("1.0");]])], | |
402 | [sr_cv_have_stoi_stod=yes], [sr_cv_have_stoi_stod=no])]) | |
403 | AS_IF([test "x$sr_cv_have_stoi_stod" = xyes], | |
404 | [AC_DEFINE([HAVE_STOI_STOD], [1], | |
405 | [Specifies whether we have the stoi and stod functions.])]) | |
406 | ]) | |
407 | ||
408 | ####################### | |
409 | ## Python bindings ## | |
410 | ####################### | |
411 | ||
412 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
413 | [sr_python_missing=], | |
414 | [sr_python_missing='C++ bindings']) | |
415 | ||
416 | # Extract major and minor version number of the Python interpreter. | |
417 | sr_pymajor=${PYTHON_VERSION%%.*} | |
418 | sr_pyminor=${PYTHON_VERSION#*.} | |
419 | ||
420 | # The Python bindings need Python development files. Check for either | |
421 | # Python 3 or Python 2 headers depending on the interpreter version. | |
422 | SR_PKG_CHECK([python_dev], [SR_PKGLIBS_PYTHON], | |
423 | [python = $PYTHON_VERSION], | |
424 | [python$sr_pymajor = $PYTHON_VERSION], | |
425 | [python$sr_pymajor$sr_pyminor = $PYTHON_VERSION], | |
426 | [python-$PYTHON_VERSION = $PYTHON_VERSION]) | |
427 | ||
428 | AS_IF([test "x$sr_have_python_dev" != xyes], | |
429 | [SR_APPEND([sr_python_missing], [', '], [Headers])]) | |
430 | ||
431 | # PyGObject is needed for the Python bindings. | |
432 | SR_PKG_CHECK([pygobject], [SR_PKGLIBS_PYTHON], [pygobject-3.0 >= 3.0.0]) | |
433 | AS_IF([test "x$sr_have_pygobject" != xyes], | |
434 | [SR_APPEND([sr_python_missing], [', '], [PyGObject])]) | |
435 | ||
436 | PKG_CHECK_EXISTS([pygobject-3.0 < 3.7.91], | |
437 | [AC_DEFINE([PYGOBJECT_FLAGS_SIGNED], [1], | |
438 | [Whether last argument to pyg_flags_get_value() is signed.])]) | |
439 | ||
440 | # The Python bindings need the setuptools and numpy Python modules. | |
441 | # We'll let it go through even if the AX macro wasn't found, as the | |
442 | # Python modules may still be there. | |
443 | m4_ifdef([AX_PYTHON_MODULE], [ | |
444 | AX_PYTHON_MODULE([setuptools]) | |
445 | AX_PYTHON_MODULE([numpy]) | |
446 | ], [ | |
447 | HAVE_PYMOD_SETUPTOOLS=yes | |
448 | HAVE_PYMOD_NUMPY=yes | |
449 | m4_warn([unsupported], | |
450 | [Missing macro AX_PYTHON_MODULE: no check for setuptools and numpy]) | |
451 | ]) | |
452 | AS_IF([test "x$HAVE_PYMOD_SETUPTOOLS" != xyes], | |
453 | [SR_APPEND([sr_python_missing], [', '], [setuptools])]) | |
454 | AS_IF([test "x$HAVE_PYMOD_NUMPY" != xyes], | |
455 | [SR_APPEND([sr_python_missing], [', '], [numpy])]) | |
456 | ||
457 | # The Python bindings use SWIG to generate code. | |
458 | AC_CHECK_PROGS([SWIG], [swig swig4.0 swig3.0 swig2.0]) | |
459 | AS_IF([test "x$SWIG" != x], | |
460 | AC_MSG_CHECKING([for $SWIG version]) | |
461 | [SWIG_VERSION=`$SWIG -version 2>&1 | sed -n 's/SWIG Version //p'`] | |
462 | AC_MSG_RESULT([$SWIG_VERSION])) | |
463 | AS_IF([test "x$SWIG" = x], | |
464 | [SR_APPEND([sr_python_missing], [', '], [SWIG])]) | |
465 | ||
466 | AS_IF([test -z "$sr_python_missing"], | |
467 | [BINDINGS_PYTHON=$enable_python], [BINDINGS_PYTHON=no]) | |
468 | AM_CONDITIONAL([BINDINGS_PYTHON], [test "x$BINDINGS_PYTHON" = xyes]) | |
469 | ||
470 | ##################### | |
471 | ## Ruby bindings ## | |
472 | ##################### | |
473 | ||
474 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
475 | [sr_ruby_missing=], | |
476 | [sr_ruby_missing='C++ bindings']) | |
477 | ||
478 | AC_PATH_PROGS(RUBY, ["${RUBY-ruby}"], []) | |
479 | AS_IF([test "x$RUBY" != x], | |
480 | AC_MSG_CHECKING([for Ruby version]) | |
481 | [RUBY_VERSION=`$RUBY -e 'puts RUBY_VERSION'`] | |
482 | AC_MSG_RESULT([$RUBY_VERSION]) | |
483 | [RUBY_DLEXT=`$RUBY -rrbconfig -e 'puts RbConfig::CONFIG[["DLEXT"]]'`] | |
484 | AC_SUBST(RUBY_DLEXT)) | |
485 | ||
486 | AS_IF([test "x$RUBY" = x], | |
487 | [SR_APPEND([sr_ruby_missing], [', '], [Ruby])]) | |
488 | ||
489 | # Extract major and minor version number of the Ruby interpreter. | |
490 | sr_rbmajor=${RUBY_VERSION%%.*} | |
491 | sr_rbminor=${RUBY_VERSION#*.} | |
492 | sr_rbminor=${sr_rbminor%%.*} | |
493 | ||
494 | # The Ruby bindings need Ruby development files. | |
495 | SR_PKG_CHECK([ruby_dev], [SR_PKGLIBS_RUBY], | |
496 | [ruby >= 2.5.0], | |
497 | [ruby-$sr_rbmajor.$sr_rbminor >= 2.5.0]) | |
498 | ||
499 | AS_IF([test "x$sr_have_ruby_dev" != xyes], | |
500 | [SR_APPEND([sr_ruby_missing], [', '], [Headers])]) | |
501 | ||
502 | # The Ruby bindings use SWIG >= 3.0.8 to generate code. | |
503 | AS_IF([test "x$SWIG" = x], | |
504 | [SR_APPEND([sr_ruby_missing], [', '], [SWIG])], | |
505 | [AS_VERSION_COMPARE($SWIG_VERSION, "3.0.8", | |
506 | [SR_APPEND([sr_ruby_missing], [', '], ['SWIG >= 3.0.8'])])]) | |
507 | ||
508 | AS_IF([test -z "$sr_ruby_missing"], | |
509 | [BINDINGS_RUBY=$enable_ruby], [BINDINGS_RUBY=no]) | |
510 | AM_CONDITIONAL([BINDINGS_RUBY], [test "x$BINDINGS_RUBY" = xyes]) | |
511 | ||
512 | #################### | |
513 | ## Java bindings ## | |
514 | #################### | |
515 | ||
516 | AS_IF([test "x$BINDINGS_CXX" = xyes], | |
517 | [sr_java_missing=], | |
518 | [sr_java_missing='C++ bindings']) | |
519 | ||
520 | # The Java bindings use SWIG to generate code. | |
521 | AS_IF([test "x$SWIG" = x], | |
522 | [SR_APPEND([sr_java_missing], [', '], [SWIG])]) | |
523 | ||
524 | # Find Java compiler and JNI includes for Java bindings. | |
525 | AC_CHECK_PROG([HAVE_JAVAC], [javac], [yes], [no]) | |
526 | AS_IF([test "x$HAVE_JAVAC" = xno], | |
527 | [SR_APPEND([sr_java_missing], [', '], [JavaC])]) | |
528 | ||
529 | AC_ARG_WITH([jni-include-path], | |
530 | [AS_HELP_STRING([[--with-jni-include-path=DIR-LIST (space-separated)]], | |
531 | [specify JNI include directories [default=detect]])], | |
532 | [JNI_INCLUDE_DIRS=" $withval"], [JNI_INCLUDE_DIRS=]) | |
533 | ||
534 | JNI_CPPFLAGS= | |
535 | AS_IF([test "x$enable_java$HAVE_JAVAC" = xyesyes], [ | |
536 | AX_PROG_JAVAC | |
537 | AS_IF([test -z "$JNI_INCLUDE_DIRS" && test "x$cross_compiling" != xyes], [ | |
538 | ## Work around the totally broken logic in AX_JNI_INCLUDE_DIR: | |
539 | ## If we can find jni.h without any special search path, skip | |
540 | ## the execution of the broken macro to increase our chances of | |
541 | ## success. | |
542 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <jni.h>]], [])],, | |
543 | [AX_JNI_INCLUDE_DIR]) | |
544 | ]) | |
545 | ]) | |
546 | for sr_dir in $JNI_INCLUDE_DIRS | |
547 | do | |
548 | SR_APPEND([JNI_CPPFLAGS], ["-I$sr_dir"]) | |
549 | done | |
550 | AC_SUBST([JNI_CPPFLAGS]) | |
551 | ||
552 | sr_save_cppflags=$CPPFLAGS | |
553 | SR_APPEND([CPPFLAGS], [$JNI_CPPFLAGS]) | |
554 | AC_CHECK_HEADER([jni.h],, | |
555 | [SR_APPEND([sr_java_missing], [', '], ['JNI headers'])]) | |
556 | CPPFLAGS=$sr_save_cppflags | |
557 | ||
558 | AS_IF([test -z "$sr_java_missing"], | |
559 | [BINDINGS_JAVA=$enable_java], [BINDINGS_JAVA=no]) | |
560 | AM_CONDITIONAL([BINDINGS_JAVA], [test "x$BINDINGS_JAVA" = xyes]) | |
561 | ||
562 | ############################## | |
563 | ## Finalize configuration ## | |
564 | ############################## | |
565 | ||
566 | # Add mandatory dependencies to module list. | |
567 | SR_APPEND([SR_PKGLIBS], ['libzip >= 0.10']) | |
568 | AC_SUBST([SR_PKGLIBS]) | |
569 | ||
570 | # Retrieve the compile and link flags for all modules combined. | |
571 | # Also, bail out at this point if any module dependency is not met. | |
572 | PKG_CHECK_MODULES([LIBSIGROK], [glib-2.0 >= 2.32.0 $SR_PKGLIBS]) | |
573 | PKG_CHECK_MODULES([TESTS], [$SR_PKGLIBS_TESTS glib-2.0 $SR_PKGLIBS]) | |
574 | ||
575 | # SR_PKGLIBS_CXX may be empty, so only invoke these checks when | |
576 | # the C++ bindings are enabled. | |
577 | AM_COND_IF([BINDINGS_CXX], [ | |
578 | PKG_CHECK_MODULES([LIBSIGROKCXX], [$SR_PKGLIBS_CXX]) | |
579 | PKG_CHECK_MODULES([PYSIGROK], [$SR_PKGLIBS_PYTHON $SR_PKGLIBS_CXX]) | |
580 | PKG_CHECK_MODULES([RBSIGROK], [$SR_PKGLIBS_RUBY $SR_PKGLIBS_CXX], [AC_SUBST(RBSIGROK_EXTDIR, "lib/$($PKG_CONFIG --variable=sitearch $SR_PKGLIBS_RUBY)/$($PKG_CONFIG --variable=RUBY_BASE_NAME $SR_PKGLIBS_RUBY)/vendor_ruby/$($PKG_CONFIG --variable=ruby_version $SR_PKGLIBS_RUBY)")]) | |
581 | ]) | |
582 | ||
583 | # Check for specific libusb features, now that we know the CFLAGS. | |
584 | AC_LANG([C]) | |
585 | sr_save_cflags=$CFLAGS | |
586 | sr_save_libs=$LIBS | |
587 | CFLAGS="$LIBSIGROK_CFLAGS $CFLAGS" | |
588 | LIBS="$LIBSIGROK_LIBS $LIBS" | |
589 | AC_CHECK_TYPES([libusb_os_handle], | |
590 | [sr_have_libusb_os_handle=yes], [sr_have_libusb_os_handle=no], | |
591 | [[#include <libusb.h>]]) | |
592 | AC_CHECK_FUNCS([zip_discard]) | |
593 | LIBS=$sr_save_libs | |
594 | CFLAGS=$sr_save_cflags | |
595 | ||
596 | AM_COND_IF([NEED_USB], [AS_CASE([$sr_have_libusb_os_handle:$host_os], [no:mingw*], | |
597 | [AC_MSG_ERROR([Windows builds require the event-abstraction branch of libusb])])]) | |
598 | ||
599 | sr_glib_version=`$PKG_CONFIG --modversion glib-2.0 2>&AS_MESSAGE_LOG_FD` | |
600 | sr_libzip_version=`$PKG_CONFIG --modversion libzip 2>&AS_MESSAGE_LOG_FD` | |
601 | ||
602 | AC_DEFINE_UNQUOTED([CONF_LIBZIP_VERSION], ["$sr_libzip_version"], | |
603 | [Build-time version of libzip.]) | |
604 | AC_DEFINE_UNQUOTED([CONF_HOST], ["$host"], | |
605 | [The canonical host libsigrok will run on.]) | |
606 | ||
607 | AC_CONFIG_FILES([Makefile libsigrok.pc bindings/cxx/libsigrokcxx.pc]) | |
608 | ||
609 | AC_OUTPUT | |
610 | ||
611 | # Prepare bindings report messages. | |
612 | m4_define([SR_PREPARE_BINDING_REPORT], [ | |
613 | sr_report_$1= | |
614 | test -z "$sr_$1_missing" || sr_report_$1=" (missing: $sr_$1_missing)" | |
615 | test "x$enable_$1" = xyes || sr_report_$1=' (disabled)' | |
616 | ]) | |
617 | m4_map_args([SR_PREPARE_BINDING_REPORT], [cxx], [python], [ruby], [java]) | |
618 | ||
619 | cat >&AS_MESSAGE_FD <<_EOF | |
620 | ||
621 | libsigrok configuration summary: | |
622 | - Package version................. $SR_PACKAGE_VERSION | |
623 | - Library ABI version............. $SR_LIB_VERSION | |
624 | - Prefix.......................... $prefix | |
625 | - Building on..................... $build | |
626 | - Building for.................... $host | |
627 | - Building shared / static........ $enable_shared / $enable_static | |
628 | ||
629 | Compile configuration: | |
630 | - C compiler...................... $CC | |
631 | - C compiler version.............. $sr_cc_version | |
632 | - C compiler flags................ $CFLAGS | |
633 | - Additional C compiler flags..... $SR_EXTRA_CFLAGS | |
634 | - C compiler warnings............. $SR_WFLAGS | |
635 | - C++ compiler.................... $CXX | |
636 | - C++ compiler version............ $sr_cxx_version | |
637 | - C++ compiler flags.............. $CXXFLAGS | |
638 | - C++ compiler warnings........... $SR_WXXFLAGS | |
639 | - Linker flags.................... $LDFLAGS | |
640 | ||
641 | Detected libraries (required): | |
642 | - glib-2.0 >= 2.32.0.............. $sr_glib_version | |
643 | - libzip >= 0.10.................. $sr_libzip_version | |
644 | ||
645 | Detected libraries (optional): | |
646 | $sr_pkglibs_summary | |
647 | Enabled hardware drivers: | |
648 | $sr_driver_summary | |
649 | Enabled serial communication transports: | |
650 | - serial comm ................... $sr_have_serial_comm | |
651 | - libserialport ................. $sr_have_libserialport | |
652 | - hidapi ........................ $sr_have_libhidapi | |
653 | - bluetooth ..................... $sr_have_bluetooth | |
654 | - bluez ......................... $sr_have_libbluez | |
655 | ||
656 | Enabled SCPI backends: | |
657 | - TCP............................. yes | |
658 | - SunRPC ......................... $sr_cv_have_sunrpc | |
659 | - TI-RPC ......................... $sr_cv_have_tirpc | |
660 | - RPC............................. $sr_cv_have_rpc | |
661 | - serial.......................... $sr_have_serial_comm | |
662 | - VISA............................ $sr_have_librevisa | |
663 | - GPIB............................ $sr_have_libgpib | |
664 | - USBTMC.......................... $sr_have_libusb | |
665 | ||
666 | Enabled language bindings: | |
667 | - C++............................. $BINDINGS_CXX$sr_report_cxx | |
668 | - Python.......................... $BINDINGS_PYTHON$sr_report_python | |
669 | - Ruby............................ $BINDINGS_RUBY$sr_report_ruby | |
670 | - Java............................ $BINDINGS_JAVA$sr_report_java | |
671 | ||
672 | _EOF | |
673 | ||
674 | # Emit a warning if the C++ bindings are not being built. | |
675 | AM_COND_IF([BINDINGS_CXX], [], [ | |
676 | cat >&AS_MESSAGE_FD <<_EOF | |
677 | =============================================================================== | |
678 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING | |
679 | =============================================================================== | |
680 | === === | |
681 | === The libsigrok C++ bindings are not being built since you === | |
682 | === are missing one or more dependencies (see above)! === | |
683 | === === | |
684 | === This means you won't be able to compile frontends that require === | |
685 | === the C++ bindings (such as PulseView)! You also won't be able to build === | |
686 | === other bindings and frontends using those (such as sigrok-meter)! === | |
687 | === === | |
688 | =============================================================================== | |
689 | WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING WARNING | |
690 | =============================================================================== | |
691 | ||
692 | _EOF | |
693 | ]) |