configure.ac

   1 ##
   2 ## This file is part of the sigrok-firmware-fx2lafw project.
   3 ##
   4 ## Copyright (C) 2013 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, write to the Free Software
  18 ## Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301 USA
  19 ##
  20
  21 # We require at least autoconf 2.63 (AC_INIT format changed there).
  22 AC_PREREQ([2.63])
  23
  24 AC_INIT([sigrok-firmware-fx2lafw], [0.1.3],
  25         [sigrok-devel@lists.sourceforge.net],
  26         [sigrok-firmware-fx2lafw], [http://www.sigrok.org])
  27 AC_CONFIG_AUX_DIR([autostuff])
  28
  29 # We require at least automake 1.11 (needed for 'silent rules').
  30 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news])
  31 AM_SILENT_RULES([yes])
  32
  33 AC_PROG_INSTALL
  34 AC_PROG_LN_S
  35
  36 # On Fedora, all sdcc tools have an 'sdcc-' prefix in the filename.
  37 AC_CHECK_PROGS([SDCC], [sdcc sdcc-sdcc])
  38 AS_IF([test "x$SDCC" = x],
  39         [AC_MSG_ERROR([cannot find sdcc.])])
  40
  41 AC_CHECK_PROGS([SDCCLIB], [sdcclib sdcc-sdcclib])
  42 AS_IF([test "x$SDCCLIB" = x],
  43         [AC_MSG_ERROR([cannot find sdcclib.])])
  44
  45 sf_sdcc_version=`$SDCC --version | sed -n 's/.* \([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\) .*/\1/p;q' 2>&AS_MESSAGE_LOG_FD`
  46 AS_VERSION_COMPARE([$sf_sdcc_version], [2.9.0],
  47         [AC_MSG_ERROR([At least version 2.9.0 of sdcc is required.])])
  48
  49 AC_CHECK_PROGS([OBJCOPY], [objcopy])
  50 AC_CHECK_PROGS([MAKEBIN], [makebin sdcc-makebin])
  51 AS_IF([test "x$OBJCOPY$MAKEBIN" = x],
  52         [AC_MSG_ERROR([cannot find objcopy or makebin.])])
  53
  54 AM_CONDITIONAL([FOUND_OBJCOPY], [test "x$OBJCOPY" != x])
  55 AM_CONDITIONAL([FOUND_MAKEBIN], [test "x$MAKEBIN" != x])
  56
  57 # The sdcc 8051 assembler binary has/had different names:
  58 # Newer sdcc, Debian / Ubuntu: sdas8051
  59 # Newer sdcc, Fedora: sdcc-sdas8051
  60 # Older sdcc: asx8051
  61 AC_CHECK_PROGS([SDAS8051], [sdas8051 sdcc-sdas8051 asx8051])
  62 AS_IF([test "x$SDAS8051" = x],
  63         [AC_MSG_ERROR([cannot find sdas8051.])])
  64
  65 AC_CONFIG_FILES([Makefile])
  66 AC_OUTPUT
  67
  68 cat >&AS_MESSAGE_FD <<_EOF
  69
  70 sigrok-firmware-fx2lafw configuration summary:
  71  - Package version................. $PACKAGE_VERSION
  72  - Prefix.......................... $prefix
  73
  74 Compile configuration:
  75  - C compiler...................... $SDCC
  76  - C compiler version.............. $sf_sdcc_version
  77
  78 _EOF