configure.ac

   1 ##
   2 ## This file is part of the sigrok-firmware-fx2lafw project.
   3 ##
   4 ## Copyright (C) 2013 Uwe Hermann <uwe@hermann-uwe.de>
   5 ##
   6 ## This program is free software; you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation; either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program; if not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # We require at least autoconf 2.63 (AC_INIT format changed there).
  21 AC_PREREQ([2.63])
  22
  23 AC_INIT([sigrok-firmware-fx2lafw], [0.1.7],
  24         [sigrok-devel@lists.sourceforge.net],
  25         [sigrok-firmware-fx2lafw], [http://www.sigrok.org])
  26 AC_CONFIG_AUX_DIR([autostuff])
  27
  28 # We require at least automake 1.11 (needed for 'silent rules').
  29 AM_INIT_AUTOMAKE([1.11 -Wall -Werror no-define subdir-objects check-news])
  30 AM_SILENT_RULES([yes])
  31
  32 AC_PROG_INSTALL
  33 AC_PROG_LN_S
  34
  35 # On Fedora, all sdcc tools have an 'sdcc-' prefix in the filename.
  36 AC_CHECK_PROGS([SDCC], [sdcc sdcc-sdcc])
  37 AS_IF([test "x$SDCC" = x],
  38         [AC_MSG_ERROR([cannot find sdcc.])])
  39
  40 AC_CHECK_PROGS([SDAR], [sdar sdcc-sdar])
  41 AS_IF([test "x$SDAR" = x],
  42         [AC_MSG_ERROR([cannot find sdar.])])
  43
  44 sf_sdcc_version=`$SDCC --version | sed -n 's/.* \([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\) .*/\1/p;q' 2>&AS_MESSAGE_LOG_FD`
  45 AS_VERSION_COMPARE([$sf_sdcc_version], [3.4.0],
  46         [AC_MSG_ERROR([At least version 3.4.0 of sdcc is required.])])
  47
  48 AC_CHECK_PROGS([OBJCOPY], [objcopy])
  49 AC_CHECK_PROGS([MAKEBIN], [makebin sdcc-makebin])
  50 AS_IF([test "x$OBJCOPY$MAKEBIN" = x],
  51         [AC_MSG_ERROR([cannot find objcopy or makebin.])])
  52
  53 AM_CONDITIONAL([FOUND_OBJCOPY], [test "x$OBJCOPY" != x])
  54 AM_CONDITIONAL([FOUND_MAKEBIN], [test "x$MAKEBIN" != x])
  55
  56 # The sdcc 8051 assembler binary has/had different names:
  57 # Newer sdcc, Debian / Ubuntu: sdas8051
  58 # Newer sdcc, Fedora: sdcc-sdas8051
  59 # Older sdcc: asx8051
  60 AC_CHECK_PROGS([SDAS8051], [sdas8051 sdcc-sdas8051 asx8051])
  61 AS_IF([test "x$SDAS8051" = x],
  62         [AC_MSG_ERROR([cannot find sdas8051.])])
  63
  64 AC_CONFIG_FILES([Makefile])
  65 AC_OUTPUT
  66
  67 cat >&AS_MESSAGE_FD <<_EOF
  68
  69 sigrok-firmware-fx2lafw configuration summary:
  70  - Package version................. $PACKAGE_VERSION
  71  - Prefix.......................... $prefix
  72
  73 Compile configuration:
  74  - C compiler...................... $SDCC
  75  - C compiler version.............. $sf_sdcc_version
  76
  77 _EOF